home *** CD-ROM | disk | FTP | other *** search
/ SGI Developer Toolbox 6.1 / SGI Developer Toolbox 6.1 - Disc 4.iso / lib / mathlib / libblas / src_original / stpsv.f < prev    next >
Encoding:
Text File  |  1994-08-02  |  9.5 KB  |  306 lines
  1. *
  2. ************************************************************************
  3. *
  4.       SUBROUTINE STPSV ( UPLO, TRANS, DIAG, N, AP, X, INCX )
  5. *     .. Scalar Arguments ..
  6.       INTEGER            INCX, N
  7.       CHARACTER*1        DIAG, TRANS, UPLO
  8. *     .. Array Arguments ..
  9.       REAL               AP( * ), X( * )
  10. *     ..
  11. *
  12. *  Purpose
  13. *  =======
  14. *
  15. *  STPSV  solves one of the systems of equations
  16. *
  17. *     A*x = b,   or   A'*x = b,
  18. *
  19. *  where b and x are n element vectors and A is an n by n unit, or
  20. *  non-unit, upper or lower triangular matrix, supplied in packed form.
  21. *
  22. *  No test for singularity or near-singularity is included in this
  23. *  routine. Such tests must be performed before calling this routine.
  24. *
  25. *  Parameters
  26. *  ==========
  27. *
  28. *  UPLO   - CHARACTER*1.
  29. *           On entry, UPLO specifies whether the matrix is an upper or
  30. *           lower triangular matrix as follows:
  31. *
  32. *              UPLO = 'U' or 'u'   A is an upper triangular matrix.
  33. *
  34. *              UPLO = 'L' or 'l'   A is a lower triangular matrix.
  35. *
  36. *           Unchanged on exit.
  37. *
  38. *  TRANS  - CHARACTER*1.
  39. *           On entry, TRANS specifies the equations to be solved as
  40. *           follows:
  41. *
  42. *              TRANS = 'N' or 'n'   A*x = b.
  43. *
  44. *              TRANS = 'T' or 't'   A'*x = b.
  45. *
  46. *              TRANS = 'C' or 'c'   A'*x = b.
  47. *
  48. *           Unchanged on exit.
  49. *
  50. *  DIAG   - CHARACTER*1.
  51. *           On entry, DIAG specifies whether or not A is unit
  52. *           triangular as follows:
  53. *
  54. *              DIAG = 'U' or 'u'   A is assumed to be unit triangular.
  55. *
  56. *              DIAG = 'N' or 'n'   A is not assumed to be unit
  57. *                                  triangular.
  58. *
  59. *           Unchanged on exit.
  60. *
  61. *  N      - INTEGER.
  62. *           On entry, N specifies the order of the matrix A.
  63. *           N must be at least zero.
  64. *           Unchanged on exit.
  65. *
  66. *  AP     - REAL             array of DIMENSION at least
  67. *           ( ( n*( n + 1 ) )/2 ).
  68. *           Before entry with  UPLO = 'U' or 'u', the array AP must
  69. *           contain the upper triangular matrix packed sequentially,
  70. *           column by column, so that AP( 1 ) contains a( 1, 1 ),
  71. *           AP( 2 ) and AP( 3 ) contain a( 1, 2 ) and a( 2, 2 )
  72. *           respectively, and so on.
  73. *           Before entry with UPLO = 'L' or 'l', the array AP must
  74. *           contain the lower triangular matrix packed sequentially,
  75. *           column by column, so that AP( 1 ) contains a( 1, 1 ),
  76. *           AP( 2 ) and AP( 3 ) contain a( 2, 1 ) and a( 3, 1 )
  77. *           respectively, and so on.
  78. *           Note that when  DIAG = 'U' or 'u', the diagonal elements of
  79. *           A are not referenced, but are assumed to be unity.
  80. *           Unchanged on exit.
  81. *
  82. *  X      - REAL             array of dimension at least
  83. *           ( 1 + ( n - 1 )*abs( INCX ) ).
  84. *           Before entry, the incremented array X must contain the n
  85. *           element right-hand side vector b. On exit, X is overwritten
  86. *           with the solution vector x.
  87. *
  88. *  INCX   - INTEGER.
  89. *           On entry, INCX specifies the increment for the elements of
  90. *           X. INCX must not be zero.
  91. *           Unchanged on exit.
  92. *
  93. *
  94. *  Level 2 Blas routine.
  95. *
  96. *  -- Written on 22-October-1986.
  97. *     Jack Dongarra, Argonne National Lab.
  98. *     Jeremy Du Croz, Nag Central Office.
  99. *     Sven Hammarling, Nag Central Office.
  100. *     Richard Hanson, Sandia National Labs.
  101. *
  102. *
  103. *     .. Parameters ..
  104.       REAL               ZERO
  105.       PARAMETER        ( ZERO = 0.0E+0 )
  106. *     .. Local Scalars ..
  107.       REAL               TEMP
  108.       INTEGER            I, INFO, IX, J, JX, K, KK, KX
  109.       LOGICAL            NOUNIT
  110. *     .. External Functions ..
  111.       LOGICAL            LSAME
  112.       EXTERNAL           LSAME
  113. *     .. External Subroutines ..
  114.       EXTERNAL           XERBLA
  115. *     ..
  116. *     .. Executable Statements ..
  117. *
  118. *     Test the input parameters.
  119. *
  120.       INFO = 0
  121.       IF     ( .NOT.LSAME( UPLO , 'U' ).AND.
  122.      $         .NOT.LSAME( UPLO , 'L' )      )THEN
  123.          INFO = 1
  124.       ELSE IF( .NOT.LSAME( TRANS, 'N' ).AND.
  125.      $         .NOT.LSAME( TRANS, 'T' ).AND.
  126.      $         .NOT.LSAME( TRANS, 'C' )      )THEN
  127.          INFO = 2
  128.       ELSE IF( .NOT.LSAME( DIAG , 'U' ).AND.
  129.      $         .NOT.LSAME( DIAG , 'N' )      )THEN
  130.          INFO = 3
  131.       ELSE IF( N.LT.0 )THEN
  132.          INFO = 4
  133.       ELSE IF( INCX.EQ.0 )THEN
  134.          INFO = 7
  135.       END IF
  136.       IF( INFO.NE.0 )THEN
  137.          CALL XERBLA( 'STPSV ', INFO )
  138.          RETURN
  139.       END IF
  140. *
  141. *     Quick return if possible.
  142. *
  143.       IF( N.EQ.0 )
  144.      $   RETURN
  145. *
  146.       NOUNIT = LSAME( DIAG, 'N' )
  147. *
  148. *     Set up the start point in X if the increment is not unity. This
  149. *     will be  ( N - 1 )*INCX  too small for descending loops.
  150. *
  151.       IF( INCX.LE.0 )THEN
  152.          KX = 1 - ( N - 1 )*INCX
  153.       ELSE IF( INCX.NE.1 )THEN
  154.          KX = 1
  155.       END IF
  156. *
  157. *     Start the operations. In this version the elements of AP are
  158. *     accessed sequentially with one pass through AP.
  159. *
  160.       IF( LSAME( TRANS, 'N' ) )THEN
  161. *
  162. *        Form  x := inv( A )*x.
  163. *
  164.          IF( LSAME( UPLO, 'U' ) )THEN
  165.             KK = ( N*( N + 1 ) )/2
  166.             IF( INCX.EQ.1 )THEN
  167.                DO 20, J = N, 1, -1
  168.                   IF( X( J ).NE.ZERO )THEN
  169.                      IF( NOUNIT )
  170.      $                  X( J ) = X( J )/AP( KK )
  171.                      TEMP = X( J )
  172.                      K    = KK     - 1
  173.                      DO 10, I = J - 1, 1, -1
  174.                         X( I ) = X( I ) - TEMP*AP( K )
  175.                         K      = K      - 1
  176.    10                CONTINUE
  177.                   END IF
  178.                   KK = KK - J
  179.    20          CONTINUE
  180.             ELSE
  181.                JX = KX + ( N - 1 )*INCX
  182.                DO 40, J = N, 1, -1
  183.                   IF( X( JX ).NE.ZERO )THEN
  184.                      IF( NOUNIT )
  185.      $                  X( JX ) = X( JX )/AP( KK )
  186.                      TEMP = X( JX )
  187.                      IX   = JX
  188.                      DO 30, K = KK - 1, KK - J + 1, -1
  189.                         IX      = IX      - INCX
  190.                         X( IX ) = X( IX ) - TEMP*AP( K )
  191.    30                CONTINUE
  192.                   END IF
  193.                   JX = JX - INCX
  194.                   KK = KK - J
  195.    40          CONTINUE
  196.             END IF
  197.          ELSE
  198.             KK = 1
  199.             IF( INCX.EQ.1 )THEN
  200.                DO 60, J = 1, N
  201.                   IF( X( J ).NE.ZERO )THEN
  202.                      IF( NOUNIT )
  203.      $                  X( J ) = X( J )/AP( KK )
  204.                      TEMP = X( J )
  205.                      K    = KK     + 1
  206.                      DO 50, I = J + 1, N
  207.                         X( I ) = X( I ) - TEMP*AP( K )
  208.                         K      = K      + 1
  209.    50                CONTINUE
  210.                   END IF
  211.                   KK = KK + ( N - J + 1 )
  212.    60          CONTINUE
  213.             ELSE
  214.                JX = KX
  215.                DO 80, J = 1, N
  216.                   IF( X( JX ).NE.ZERO )THEN
  217.                      IF( NOUNIT )
  218.      $                  X( JX ) = X( JX )/AP( KK )
  219.                      TEMP = X( JX )
  220.                      IX   = JX
  221.                      DO 70, K = KK + 1, KK + N - J
  222.                         IX      = IX      + INCX
  223.                         X( IX ) = X( IX ) - TEMP*AP( K )
  224.    70                CONTINUE
  225.                   END IF
  226.                   JX = JX + INCX
  227.                   KK = KK + ( N - J + 1 )
  228.    80          CONTINUE
  229.             END IF
  230.          END IF
  231.       ELSE
  232. *
  233. *        Form  x := inv( A' )*x.
  234. *
  235.          IF( LSAME( UPLO, 'U' ) )THEN
  236.             KK = 1
  237.             IF( INCX.EQ.1 )THEN
  238.                DO 100, J = 1, N
  239.                   TEMP = X( J )
  240.                   K    = KK
  241.                   DO 90, I = 1, J - 1
  242.                      TEMP = TEMP - AP( K )*X( I )
  243.                      K    = K    + 1
  244.    90             CONTINUE
  245.                   IF( NOUNIT )
  246.      $               TEMP = TEMP/AP( KK + J - 1 )
  247.                   X( J ) = TEMP
  248.                   KK     = KK   + J
  249.   100          CONTINUE
  250.             ELSE
  251.                JX = KX
  252.                DO 120, J = 1, N
  253.                   TEMP = X( JX )
  254.                   IX   = KX
  255.                   DO 110, K = KK, KK + J - 2
  256.                      TEMP = TEMP - AP( K )*X( IX )
  257.                      IX   = IX   + INCX
  258.   110             CONTINUE
  259.                   IF( NOUNIT )
  260.      $               TEMP = TEMP/AP( KK + J - 1 )
  261.                   X( JX ) = TEMP
  262.                   JX      = JX   + INCX
  263.                   KK      = KK   + J
  264.   120          CONTINUE
  265.             END IF
  266.          ELSE
  267.             KK = ( N*( N + 1 ) )/2
  268.             IF( INCX.EQ.1 )THEN
  269.                DO 140, J = N, 1, -1
  270.                   TEMP = X( J )
  271.                   K = KK
  272.                   DO 130, I = N, J + 1, -1
  273.                      TEMP = TEMP - AP( K )*X( I )
  274.                      K    = K    - 1
  275.   130             CONTINUE
  276.                   IF( NOUNIT )
  277.      $               TEMP = TEMP/AP( KK - N + J )
  278.                   X( J ) = TEMP
  279.                   KK     = KK   - ( N - J + 1 )
  280.   140          CONTINUE
  281.             ELSE
  282.                KX = KX + ( N - 1 )*INCX
  283.                JX = KX
  284.                DO 160, J = N, 1, -1
  285.                   TEMP = X( JX )
  286.                   IX   = KX
  287.                   DO 150, K = KK, KK - ( N - ( J + 1 ) ), -1
  288.                      TEMP = TEMP - AP( K )*X( IX )
  289.                      IX   = IX   - INCX
  290.   150             CONTINUE
  291.                   IF( NOUNIT )
  292.      $               TEMP = TEMP/AP( KK - N + J )
  293.                   X( JX ) = TEMP
  294.                   JX      = JX   - INCX
  295.                   KK      = KK   - (N - J + 1 )
  296.   160          CONTINUE
  297.             END IF
  298.          END IF
  299.       END IF
  300. *
  301.       RETURN
  302. *
  303. *     End of STPSV .
  304. *
  305.       END
  306.