home *** CD-ROM | disk | FTP | other *** search
/ 17 Bit Software 2: Collection B / 17Bit_Collection_B.iso / files / 1794.dms / in.adf / Extensions_Sources / Extension_Sources.Lzh / _music.s < prev    next >
Encoding:
Text File  |  1992-02-01  |  86.7 KB  |  4,360 lines
  1. ;---------------------------------------------------------------------
  2. ;    **   **   **  ***   ***   ****     **    ***  **  ****
  3. ;   ****  *** *** ** ** **     ** **   ****  **    ** **  **
  4. ;  **  ** ** * ** ** **  ***   *****  **  **  ***  ** **
  5. ;  ****** **   ** ** **    **  **  ** ******    ** ** **
  6. ;  **  ** **   ** ** ** *  **  **  ** **  ** *  ** ** **  **
  7. ;  **  ** **   **  ***   ***   *****  **  **  ***  **  ****
  8. ;---------------------------------------------------------------------
  9. ; Music extension source code, V1.5  Last change 21/10/1991
  10. ; By Francois Lionet
  11. ; StarTrecker adaptation by Gary Simon & F.L.
  12. ; AMOS and AMOS Compiler (c) Europress Software 1991
  13. ; To be used with AMOS1.3 and over
  14. ;--------------------------------------------------------------------- 
  15. ; This file is public domain
  16. ;---------------------------------------------------------------------
  17. ;
  18. ; This listing explains how to create an extension for both AMOS and the
  19. ; AMOS compiler. Two possibilities for you:
  20. ;   - You have already made an extension for AMOS 1.2 versions, you'll 
  21. ;     have to re-write your code to have them work with AMOS 1.3 and the
  22. ;     compiler. Do not panic, as it is not a big deal.
  23. ;   - This is the first extension you write. Please ignore the text 
  24. ;     referencing to the old extension system.
  25. ;
  26. ; >>> What's an extension?
  27. ;
  28. ; An extension to AMOS is a machine language program that adds new 
  29. ; instructions to the already huge AMOS instruction set. This system is
  30. ; designed to be as powerfull as AMOS itself: the extension includes its 
  31. ; own token list, its own routines. It can even access some main AMOS
  32. ; routines via special macros. It has a total access to the internal AMOS 
  33. ; data zone, and to the graphic library functions.
  34. ;
  35. ; To produce your own extension, I suggest you copy and rename this
  36. ; file, and remove the used code. This way you will not forgive one line.
  37. ; Also keep in mind that you can perfectly call AMOS from within MONAM2,
  38. ; and set some ILLEGAL instructions where you want to debug. To flip back to
  39. ; MONAM2 display, just press AMIGA-A.
  40. ;
  41. ; I have designed the extension system so that one only file works with 
  42. ; both AMOS interpretor and compiler. 
  43. ;     - The extension is more a compiler library than a one chunk program:
  44. ;    it is done so that the compiler can pick one routine here and there
  45. ;    to cope with the program it is compiling.
  46. ;    - AMOS 1.3 extension loader works a little like the compiler, exept
  47. ;    that all instructions are loaded and relocated.
  48. ;
  49. ; This code was assembled with GENIM2 on a A3000 25 Mhz machine, but a
  50. ; A500 can do it very well!
  51. ; The assembled program must be ONE CHUNK only, you must not link the 
  52. ; the symbol table with it. Also be sure that you program is totally 
  53. ; relocatable (see later) : if not it will add a relocation chunk to 
  54. ; the output code, and your extension will simply crash AMOS on loading
  55. ; (and the compiler too!).
  56.  
  57. **********************************************************************
  58. ;
  59. ; Here we go now!
  60. ;
  61. ; Here comes the number of the extension in the list of extensions in
  62. ; Config1_3.AMOS program (minus one).
  63. ; This number is used later to reference the extension in internal AMOS 
  64. ; tables...
  65. ;
  66. ExtNb        equ    1-1
  67.  
  68. ; You must include all this files, they can be found in the folder where
  69. ; you found this program. Do not remove the RsSet instruction!
  70.          Include    "_Equ.s"
  71.         RsSet    DataLong
  72.         Include "_Pointe.s"
  73.         Include "_CEqu.s"
  74.         Include    "_WEqu.s"
  75.         Include    "_LEqu.s"
  76.  
  77. ; A usefull macro to find the address of data in the extension's own 
  78. ; datazone (see later)...
  79. DLea        MACRO
  80.         move.l    ExtAdr+ExtNb*16(a5),\2
  81.         add.w    #\1-MB,\2
  82.         ENDM
  83.  
  84. ; Another macro to load the base address of the datazone...
  85. DLoad        MACRO
  86.         move.l    ExtAdr+ExtNb*16(a5),\1
  87.         ENDM
  88.  
  89. ; Now some equates used by the music extension itself. Ignore this in your
  90. ; code!
  91.  
  92. Translate    equ -30
  93.  
  94. *************** Enveloppes definitions
  95.         RsReset
  96. EnvNb:        rs.w    1
  97. EnvDVol:    rs.w    1
  98. EnvVol:        rs.l    1
  99. EnvDelta:    rs.l     1
  100. EnvAd:        rs.l    1
  101. EnvDeb:        rs.l    1
  102. EnvLong:    equ     __Rs
  103.  
  104. *************** Wave definition
  105. LWave:        equ     256+128+64+32+16+8+4+2
  106.     LNoise:        equ     LWave
  107.         RsReset
  108. WaveNext:    rs.l    1
  109. WaveNb:        rs.w    1
  110. WaveEnv:    rs.w    16*2
  111. WaveDeb:    rs.b    LWave
  112. WaveLong:    equ     __Rs
  113.  
  114. *************** Music voice data
  115.         RsReset
  116. VoiAdr        rs.l    1
  117. VoiDeb        rs.l    1
  118. VoiInst        rs.l    1
  119. VoiDPat        rs.l    1
  120. VoiPat        rs.l    1
  121. VoiCpt        rs.w    1
  122. VoiRep        rs.w    1
  123. VoiNote        rs.w    1
  124. VoiDVol        rs.w    1
  125. VoiVol        rs.w    1
  126. VoiEffect    rs.l    1
  127. VoiValue    rs.w    1
  128. VoiPToTo    rs.w    1
  129. VoiPTone    rs.b    1
  130. VoiVib        rs.b    1
  131. VoiLong        equ     __Rs
  132.  
  133. *************** MUBASE table
  134.         RsReset
  135. * Voix 0
  136. MuVoix0        equ    __Rs
  137. VoiAdr0        rs.l    1
  138. VoiDeb0        rs.l    1
  139. VoiInst0    rs.l    1
  140. VoiDPat0    rs.l    1
  141. VoiPat0        rs.l    1
  142. VoiCpt0        rs.w    1
  143. VoiRep0        rs.w    1
  144. VoiNote0    rs.w    1
  145. VoiDVol0    rs.w    1
  146. VoiVol0        rs.w    1
  147. VoiEffect0    rs.l    1
  148. VoiValue0    rs.w    1
  149. VoiPToTo0    rs.w    1
  150. VoiPTone0    rs.b    1
  151. VoiVib0        rs.b    1
  152. * Voix 1
  153. MuVoix1        equ    __Rs
  154. VoiAdr1        rs.l    1
  155. VoiDeb1        rs.l    1
  156. VoiInst1    rs.l    1
  157. VoiDPat1    rs.l    1
  158. VoiPat1        rs.l    1
  159. VoiCpt1        rs.w    1
  160. VoiRep1        rs.w    1
  161. VoiNote1    rs.w    1
  162. VoiDVol1    rs.w    1
  163. VoiVol1        rs.w    1
  164. VoiEffect1    rs.l    1
  165. VoiValue1    rs.w    1
  166. VoiPToTo1    rs.w    1
  167. VoiPTone1    rs.b    1
  168. VoiVib1        rs.b    1
  169. * Voix 2
  170. MuVoix2        equ    __Rs
  171. VoiAdr2        rs.l    1
  172. VoiDeb2        rs.l    1
  173. VoiInst2    rs.l    1
  174. VoiDPat2    rs.l    1
  175. VoiPat2        rs.l    1
  176. VoiCpt2        rs.w    1
  177. VoiRep2        rs.w    1
  178. VoiNote2    rs.w    1
  179. VoiDVol2    rs.w    1
  180. VoiVol2        rs.w    1
  181. VoiEffect2    rs.l    1
  182. VoiValue2    rs.w    1
  183. VoiPToTo2    rs.w    1
  184. VoiPTone2    rs.b    1
  185. VoiVib2        rs.b    1
  186. * Voix 3
  187. MuVoix3        equ    __Rs
  188. VoiAdr3        rs.l    1
  189. VoiDeb3        rs.l    1
  190. VoiInst3    rs.l    1
  191. VoiDPat3    rs.l    1
  192. VoiPat3        rs.l    1
  193. VoiCpt3        rs.w    1
  194. VoiRep3        rs.w    1
  195. VoiNote3    rs.w    1
  196. VoiDVol3    rs.w    1
  197. VoiVol3        rs.w    1
  198. VoiEffect3    rs.l    1
  199. VoiValue3    rs.w    1
  200. VoiPToTo3    rs.w    1
  201. VoiPTone3    rs.b    1
  202. VoiVib3        rs.b    1
  203.  
  204. * Other data
  205. MuCpt        rs.w    1
  206. MuTempo        rs.w    1
  207. MuStart        rs.w    1
  208. MuStop        rs.w    1
  209. * Total length
  210. MuLong        equ     __Rs
  211.  
  212. IntEnaR        equ    $1c
  213. IntReqR        equ    $1e
  214. is_data        equ    $0e
  215. is_code        equ    $12
  216. ln_pri        equ    $09
  217. ln_type        equ    $08
  218.  
  219. ; All the above did not produce any byte of code. Here is the real beginning
  220. ; of the program. It MUST begin by a small table of pointers so that both
  221. ; AMOS and the compiler know where to get their data...
  222. ; Please remark that everything is relocatable...
  223.  
  224. ******************************************************************
  225. *    AMOS MUSIC EXTENSION
  226. ;
  227. ; First, a pointer to the token list
  228. Start    dc.l    C_Tk-C_Off
  229. ;
  230. ; Then, a pointer to the first library function
  231.     dc.l    C_Lib-C_Tk
  232. ;
  233. ; Then to the title
  234.     dc.l    C_Title-C_Lib
  235. ;
  236. ; From title to the end of the program
  237.     dc.l    C_End-C_Title
  238. ;
  239. ; An important flag. Imagine a program does not call your extension, the 
  240. ; compiler will NOT copy any routine from it in the object program. For 
  241. ; certain extensions, like MUSIC, COMPACT, it is perfect.
  242. ; But for the REQUEST extension, even if it is not called, the first routine 
  243. ; MUST be called, otherwise AMOS requester will not work!
  244. ; So, a value of 0 indicates to copy if needed only,
  245. ; A value of -1 forces the copy of the first library routine...
  246.     dc.w    0    
  247.  
  248. ******************************************************************
  249. *    Offset to library
  250. ;
  251. ; This list contains all informations for the compiler 
  252. ; and AMOS to locate your routines, in a relocatable way.
  253. ; You can produce such tables using the MAKE_LABEL.AMOS utility, found 
  254. ; on this very disc.
  255. ; All labels MUST be in order. The size of each routine MUST BE EVEN,
  256. ; as the size is divided by two. So be carefull to put an EVEN instruction
  257. ; after some text...
  258. ; You easily understand that the size of each routine can reach 128K, 
  259. ; which is largely enough. You can have up to 2000 routines in the list.
  260. ; The main AMOS.Lib library has 1100 labels...
  261.  
  262. C_Off   dc.w (L1-L0)/2,(L2-L1)/2,(L3-L2)/2,(L4-L3)/2
  263.         dc.w (L5-L4)/2,(L6-L5)/2,(L7-L6)/2,(L8-L7)/2
  264.         dc.w (L9-L8)/2,(L10-L9)/2,(L11-L10)/2,(L12-L11)/2
  265.         dc.w (L13-L12)/2,(L14-L13)/2,(L15-L14)/2,(L16-L15)/2
  266.         dc.w (L17-L16)/2,(L18-L17)/2,(L19-L18)/2,(L20-L19)/2
  267.         dc.w (L21-L20)/2,(L22-L21)/2,(L23-L22)/2,(L24-L23)/2
  268.         dc.w (L25-L24)/2,(L26-L25)/2,(L27-L26)/2,(L28-L27)/2
  269.         dc.w (L29-L28)/2,(L30-L29)/2,(L31-L30)/2,(L32-L31)/2
  270.         dc.w (L33-L32)/2,(L34-L33)/2,(L35-L34)/2,(L36-L35)/2
  271.         dc.w (L37-L36)/2,(L38-L37)/2,(L39-L38)/2,(L40-L39)/2
  272.         dc.w (L41-L40)/2,(L42-L41)/2,(L43-L42)/2,(L44-L43)/2
  273.         dc.w (L45-L44)/2,(L46-L45)/2,(L47-L46)/2,(L48-L47)/2
  274.         dc.w (L49-L48)/2,(L50-L49)/2,(L51-L50)/2,(L52-L51)/2
  275.         dc.w (L53-L52)/2,(L54-L53)/2,(L55-L54)/2,(L56-L55)/2
  276.         dc.w (L57-L56)/2,(L58-L57)/2,(L59-L58)/2,(L60-L59)/2
  277.         dc.w (L61-L60)/2,(L62-L61)/2,(L63-L62)/2,(L64-L63)/2
  278.         dc.w (L65-L64)/2,(L66-L65)/2,(L67-L66)/2,(L68-L67)/2
  279.         dc.w (L69-L68)/2,(L70-L69)/2,(L71-L70)/2,(L72-L71)/2
  280.         dc.w (L73-L72)/2,(L74-L73)/2,(L75-L74)/2,(L76-L75)/2
  281.         dc.w (L77-L76)/2,(L78-L77)/2,(L79-L78)/2,(L80-L79)/2
  282.         dc.w (L81-L80)/2,(L82-L81)/2,(L83-L82)/2,(L84-L83)/2
  283.         dc.w (L85-L84)/2,(L86-L85)/2,(L87-L86)/2,(L88-L87)/2
  284.     dc.w (L89-L88)/2,(L90-L89)/2,(L91-L90)/2,(L92-L91)/2
  285.         dc.w (L93-L92)/2,(L94-L93)/2,(L95-L94)/2,(L96-L95)/2
  286.         dc.w (L97-L96)/2,(L98-L97)/2,(L99-L98)/2,(L100-L99)/2
  287.         dc.w (L101-L100)/2,(L102-L101)/2
  288. ; Do not forget the LAST label!!!
  289.  
  290. ******************************************************************
  291. *    TOKEN TABLE
  292. ;
  293. ;
  294. ;    
  295. ; This table is the crucial point of the extension! It tells
  296. ; everything the tokenisation process needs to know. You have to 
  297. ; be carefull when writing it!
  298. ;
  299. ; The format is simple:
  300. ;    dc.w    Number of instruction,Number of function
  301. ;    dc.b    "instruction nam","e"+$80,"Param list",-1[or -2]
  302. ;
  303. ;    (1) Number of instruction / function
  304. ;        You must state the one that is needed for this token.
  305. ;               I suggest you keep the same method of referencing the
  306. ;        routines than mine: L_name, this label being defined
  307. ;        in the main program. (If you come from a 1.23 extension,
  308. ;        changing your program is easy: just add L_ before the 
  309. ;        name of each routine.
  310. ;        A -1 means take no routine is called (example a 
  311. ;        instruction only will have a -1 in the function space...)
  312. ;
  313. ;    (2) Instruction name
  314. ;        It must be finished by the letter plus $80. Be carefull
  315. ;        ARGASM assembler produces bad code if you do "a"+$80, 
  316. ;        he wants $80+"a"!!!
  317. ;        - You can SET A MARK in the token table with a "!" before
  318. ;        the name. See later
  319. ;        -Using a $80 ALONE as a name definition, will force AMOS
  320. ;        to point to the previous "!" mark...
  321. ;    
  322. ;    (3) Param list
  323. ;        This list tells AMOS everything about the instruction.
  324. ;
  325. ;    - First character:
  326. ;        The first character defines the TYPE on instruction:
  327. ;            I--> instruction
  328. ;            0--> function that returns a integer
  329. ;            1--> function that returns a float
  330. ;            2--> function that returns a string
  331. ;            V--> reserved variable. In that case, you must
  332. ;                state the type int-float-string
  333. ;    - If your instruction does not need parameters, then you stop
  334. ;    - Your instruction needs parameters, now comes the param list
  335. ;            Type,TypetType,Type...
  336. ;        Type of the parameter (0 1 2)
  337. ;        Comma or "t" for TO
  338. ;
  339. ;    (4) End of instruction
  340. ;            "-1" states the end of the instruction
  341. ;            "-2" tells AMOS that another parameter list
  342. ;                 can be accepted. if so, MUST follow the
  343. ;                 complete instruction definition as explained
  344. ;                 but with another param list.
  345. ;    If so, you can use the "!" and $80 facility not to rewrite the
  346. ;    full name of the instruction...See SAM LOOP ON instruction for an
  347. ;    example...
  348. ;
  349. ;    Remember that AMOS token list comes first, so names like:
  350. ;    PRINTHELLO will never work: AMOS will tokenise PRINT first!
  351. ;    Extension token list are explored in order of number...
  352.  
  353. ; The next two lines needs to be unchanged...
  354. C_Tk:    dc.w     1,0
  355.     dc.b     $80,-1
  356.  
  357. ; Now the real tokens...
  358.     dc.w    -1,L_FMB
  359.     dc.b    "mubas","e"+$80,"0",-1
  360.     dc.w    -1,L_FVu
  361.     dc.b    "vumete","r"+$80,"00",-1
  362.     dc.w    L_IVoice,-1
  363.     dc.b    "voic","e"+$80,"I0",-1
  364.     dc.w    L_IMusOff,-1
  365.     dc.b    "music of","f"+$80,"I",-1
  366.     dc.w    L_IMuStop,-1
  367.     dc.b    "music sto","p"+$80,"I",-1
  368.     dc.w    L_ITempo,-1
  369.     dc.b    "temp","o"+$80,"I0",-1
  370.     dc.w    L_IMusic,-1
  371.     dc.b    "musi","c"+$80,"I0",-1
  372.  
  373.     dc.w    L_INoTo,-1
  374.     dc.b    "noise t","o"+$80,"I0",-1
  375.     dc.w    L_Boom,-1
  376.     dc.b     "boo","m"+$80,"I",-1
  377.     dc.w    L_Shoot,-1
  378.     dc.b    "shoo","t"+$80,"I",-1
  379.     dc.w    L_ISBank,-1
  380.     dc.b    "sam ban","k"+$80,"I0",-1
  381.     dc.w    L_ISLOn0,-1
  382.     dc.b    "!sam loop o","n"+$80,"I",-2
  383.     dc.w    L_ISLOn1,-1
  384.     dc.b    $80,"I",-1
  385.     dc.w    L_ISLOf0,-1
  386.     dc.b    "sam loop of","f"+$80,"I",-2
  387.     dc.w    L_ISLOf1,-1
  388.     dc.b    $80,"I0",-1
  389.     dc.w    L_ISamTo,-1
  390.     dc.b    "sampl","e"+$80,"I0t0",-1
  391.     dc.w     L_ISam1,-1
  392.     dc.b     "!sam pla","y"+$80,"I0",-2
  393.     dc.w    L_ISam2,-1
  394.     dc.b    $80,"I0,0",-2
  395.     dc.w     L_ISam3,-1
  396.     dc.b    $80,"I0,0,0",-1 
  397.     dc.w     L_ISamR,-1
  398.     dc.b     "sam ra","w"+$80,"I0,0,0,0",-1    
  399.     dc.w    L_Bell0,-1
  400.     dc.b     "!bel","l"+$80,"I",-2
  401.     dc.w     L_Bell1,-1
  402.     dc.b    $80,"I0",-1
  403.     dc.w    L_IPlOf0,-1
  404.     dc.b    "!play of","f"+$80,"I",-2
  405.     dc.w    L_IPlOf1,-1
  406.     dc.b    $80,"I0",-1
  407.     dc.w     L_IPlay2,-1
  408.     dc.b    "!pla","y"+$80,"I0,0",-2
  409.     dc.w    L_IPlay3,-1
  410.     dc.b    $80,"I0,0,0",-1
  411.     dc.w     L_ISWave,-1
  412.     dc.b     "set wav","e"+$80,"I0,2",-1
  413.     dc.w    L_IDWave1,-1
  414.     dc.b    "del wav","e"+$80,"I0",-1
  415.     dc.w    L_ISEnv,-1
  416.     dc.b    "set enve","l"+$80,"I0,0t0,0",-1
  417.     dc.w    L_IMVol,-1
  418.     dc.b    "mvolum","e"+$80,"I0",-1
  419.     dc.w     L_IVol1,-1
  420.     dc.b    "!volum","e"+$80,"I0",-2
  421.     dc.w     L_IVol2,-1
  422.     dc.b    $80,"I0,0",-1
  423.     dc.w    L_IWave,-1
  424.     dc.b     "wav","e"+$80,"I0t0",-1
  425.     dc.w    L_LedOn,-1
  426.     dc.b    "led o","n"+$80,"I",-1
  427.     dc.w    L_LedOf,-1
  428.     dc.b    "led of","f"+$80,"I",-1
  429.     dc.w    L_ISay1,-1
  430.     dc.b    "!sa","y"+$80,"I2",-2
  431.     dc.w    L_ISay2,-1
  432.     dc.b    $80,"I2,0",-1
  433.     dc.w    L_ITalk,-1
  434.     dc.b    "set tal","k"+$80,"I0,0,0,0",-1
  435.     dc.w    L_SLoad,-1
  436.     dc.b    "sloa","d"+$80,"I0t0,0",-1
  437.     dc.w    -1,L_Samswapped
  438.     dc.b    "sam swappe","d"+$80,"00",-1
  439.     dc.w    L_SamSwap,-1
  440.     dc.b    "sam swa","p"+$80,"I0t0,0",-1
  441.     dc.w     L_SamStop0,-1
  442.     dc.b    "!sam sto","p"+$80,"I",-2
  443.     dc.w    L_SamStop1,-1
  444.     dc.b    $80,"I0",-1
  445.  
  446.     dc.w    L_TrackStop,-1
  447.     dc.b    "track sto","p"+$80,"I",-1
  448.     dc.w    L_TrackLoopon,-1
  449.     dc.b    "track loop o","n"+$80,"I",-1
  450.     dc.w    L_TrackLoopof,-1
  451.     dc.b    "track loop o","f"+$80,"I",-1
  452.     dc.w    L_TrackPlay0,-1
  453.     dc.b    "!track pla","y"+$80,"I",-2
  454.     dc.w    L_TrackPlay1,-1
  455.     dc.b    $80,"I0",-2
  456.     dc.w    L_TrackPlay2,-1
  457.     dc.b    $80,"I0,0",-1
  458.     dc.w    L_TrackLoad,-1
  459.     dc.b    "track loa","d"+$80,"I2,0",-1
  460.  
  461.     
  462.     dc.w     0
  463.  
  464. ;
  465. ; Now come the big part, the library. Every routine is delimited by the
  466. ; two labels: L(N) and L(N+1).
  467. ; AMOS loads the whole extension, but the compiler works differently:
  468. ; The compiler picks each routine in the library and copy it into the
  469. ; program, INDIVIDUALLY. It means that you MUST NEVER perform a JMP, a
  470. ; BSR or get an address from one library routine to another: the distance
  471. ; between them may change!!! Use the special macros instead...
  472. ;
  473. ; Importants points to follow: 
  474. ;
  475. ;    - Your code must be (pc), TOTALLY relocatable, check carefully your
  476. ;      code!
  477. ;    - You cannot directly call other library routines from one routine
  478. ;    by doing a BSR, but I have defined special macros (in S_CEQU file) 
  479. ;    to allow you to easily do so. Here is the list of available macros:
  480. ;
  481. ;    RBsr    L_Routine    does a simple BSR to the routine
  482. ;    RBra    L_Routine    as a normal BRA
  483. ;    RBeq    L_Routine    as a normal Beq
  484. ;    RBne    L_Routine    ...
  485. ;    RBcc    L_Routine
  486. ;    RBcs    L_Routine
  487. ;    RBlt    L_Routine
  488. ;    RBge    L_Routine
  489. ;    RBls    L_Routine
  490. ;    RBhi    L_Routine
  491. ;    RBle    L_Routine
  492. ;    RBpl    L_Routine
  493. ;    RBmi    L_Routine
  494. ;
  495. ; I remind you that you can only use this to call an library routine
  496. ; from ANOTHER routine. You cannot do a call WITHIN a routine, or call
  497. ; the number of the routine your caling from...
  498. ; The compiler (and AMOS1.3 extension loading part) will manage to find
  499. ; the good addresses in your program from the offset table.
  500. ;
  501. ; You can also call some main AMOS.Lib routines, to do so, use the 
  502. ; following macros:
  503. ;
  504. ;    RJsr    L_Routine    
  505. ;    RJmp    L_Routine    
  506. ; 
  507. ; As you do not have access any more to the small table with jumps to the
  508. ; routines within AMOS, here is the concordance of the routines (the numbers
  509. ; are just refecrences to the old AMOS 1.23 calling table, and is not of
  510. ; any use in AMOS1.3):
  511. ;
  512. ;    04- Normal error    RJmp    L_Error
  513. ;    08- Specific error    RJmp     L_Error
  514. ;    0C- D3->A0 Bank address    RJsr    L_BankAd
  515. ;    10- Performs update    RJsr    L_Tests
  516. ;    14- Wait routine    RJsr    L_WaitRout
  517. ;    18- Get screen address    RJsr    L_GetEc
  518. ;    1C- Address or bank?    RJsr    L_AdOuBank
  519. ;    20- Erases bank #D3    RJsr    L_EffBank
  520. ;    24- Ask for string     RJsr    L_Demande
  521. ;
  522. ; Explanation:
  523. ;    04- Normal error, please look to the last routine in the library.
  524. ;    08- D3.l (number of bank-1) -> A0 Bank address
  525. ;    10- Performs update
  526. ;     14- Wait routine (see play)
  527. ;    18- Get screen address D0.l= screen number, return A0= adress
  528. ;    1C- Address or memory bank? (D3.l)
  529. ;    20- Erases bank #D3.l
  530. ;    24- D3.l is the length to ask for. Return A0/A1 point to free space.
  531. ;        Poke your string there, add the length of it to A0, EVEN the 
  532. ;        adress to the highest multiple of two, and move it into
  533. ;        HICHAINE(a5) location...
  534. ;
  535. ; Some extra routines:
  536. ;    RJsr    L_RamChip    Ask for CLEAR, CHIP ram, size D0, 
  537. ;                returns address in D0, nothing changed
  538. ;    RJsr    L_RamChip2    CHIP, not cleared
  539. ;    RJsr    L_RamFast    CLEAR, fast mem
  540. ;    RJsr    L_RamFast2    Fast mem, not cleared
  541. ;    RJsr    L_RamFree    Free memory A1/D0
  542. ;
  543. ; You will see in the S_LEQU all the labels in the AMOS.Lib file, you
  544. ; can if you want have fun calling some of them. But such code will
  545. ; only work with the compiler: the AMOS1.3 loader will NOT recognise
  546. ; such calls!
  547. ;
  548. ;    HOW DOES IT WORK?
  549. ;
  550. ; Having a look at the S_CEQU file, you see that I use special codes
  551. ; to show the compiler that it has to copy the asked routine and relocate
  552. ; the branch. Some remarks:
  553. ;    - The size of a Rbsr is 4 bytes, like the normal branch, it does
  554. ; not change the program (you can make some jumps over it)
  555. ;    - Although I have coded the signal, and put a lot a security, 
  556. ; a mischance may lead to the compiler thinking there is a RBsr where
  557. ; there is nothing than normal data. The result may be disastrous! So if
  558. ; you have BIG parts of datas in which you do not make any special calls,
  559. ; you can put before it the macro: RDATA. It tells the compiler that 
  560. ; the following code, up to the end of the library routine (up to the next
  561. ; L(N) label) is normal data: the compiler will not check for RBranches...
  562. ; Up to now, I have not been forced to do so, but if something goes wrong,
  563. ; try that!
  564. ;
  565. ;
  566. ;    THE NEW GRAPHIC VECTORS (if you come from AMOS1.23)
  567. ;
  568. ; AMOS1.23 graphic functions used 3 vectors in locations $100,$104 and $108
  569. ; to point to the routines. All the graphic macros
  570. ; (like Eccall, Wicall, Sycall) loaded these adresses...
  571. ; This was VERY bad, it was really a  shame to do so on the Amiga. So the
  572. ; compiler had to produce good code, repectfull to the system. That's why
  573. ; I had to put the vector in the AMOS internal datazone, pointed to by 
  574. ; A5.
  575. ; Coming from AMOS1.23, nothing have change for you, as long you assemble 
  576. ; you program with the new S_EQU file, which takes care of that. 
  577. ; The only difference is that register A5 MUST BE LOADED WITH THE 
  578. ; DATAZONE ADDRESS before using one of the macro! So check your code!
  579.  
  580. iii        equ    0
  581.  
  582. C_Lib
  583. ******************************************************************
  584. *        COLD START
  585. *
  586. ; The first routine of the library will perform all initialisations in the
  587. ; booting of AMOS.
  588. ;
  589. ; I have put here all the music datazone, and all the interrupt routines.
  590. ; I suggest you put all you C-Code here too if you have some...
  591.  
  592. ; ALL the following code, from L0 to L1 will be copied into the compiled 
  593. ; program (if any music is used in the program) at once. All RBSR, RBRA etc
  594. ; will be detected and relocated. AMOS1.3 extension loader does the same.
  595.  
  596. L0    movem.l    a3-a6,-(sp)
  597.  
  598. ;
  599. ; Here I store the address of the extension data zone in the special area
  600.     lea    MB(pc),a3
  601.     move.l    a3,ExtAdr+ExtNb*16(a5)
  602. ;
  603. ; Here, I store the address of the routine called by DEFAULT, or RUN
  604.     lea    MusDef(pc),a0
  605.     move.l    a0,ExtAdr+ExtNb*16+4(a5)
  606. ;
  607. ; Here, the address of the END routine,
  608.     lea    MusEnd(pc),a0
  609.     move.l    a0,ExtAdr+ExtNb*16+8(a5)
  610. ;
  611. ; And now the Bank check routine..
  612.     lea    BkCheck(pc),a0
  613.     move.l    a0,ExtAdr+ExtNb*16+12(a5)
  614.  
  615. ; mt: allocate memory for am wave forms
  616.     move.l    #488,d0
  617.     Sycall    SyChip
  618.     move.l    d0,mt_amwave-MB(a3)
  619.     move.l    d0,a0
  620.     lea    96(a0),a2
  621.     move.l    a2,mt_noise-MB(a3)
  622.     lea    32(a2),a2
  623.     move.l    a2,mt_ams-MB(a3)
  624.     moveq    #121,d0
  625.     lea    mt_amwaveforms-MB(a3),a1
  626. .lp    move.l    (a1)+,(a0)+
  627.     dbf    d0,.lp
  628.  
  629. ; You are not obliged to store something in the above areas, you can leave
  630. ; them to zero if no routine is to be called...
  631. ;
  632. ; In AMOS data zone, stands 8 long words allowing you to simply
  633. ; put a patch in the VBL interrupt. The first on is at VBLRout.
  634. ; At each VBL, AMOS explores this list, and call all address <> 0
  635. ; It stops at the FIRST zero. The music patch is the first routine
  636. ; called.
  637.     lea    MusInt(pc),a0        * Interrupt routine
  638.     move.l    a0,VBLRout(a5)
  639. ; 50/60 herz?
  640.     move.l    #3546895,MusClock-MB(a3)
  641.     move.w    #100,TempoBase-MB(a3)
  642.     EcCall    NTSC            * Is system NTSC?
  643.     tst.w    d1
  644.     beq.s    ItsPAL
  645.     move.w    #120,TempoBase-MB(a3)
  646.     move.l    #3579545,MusClock-MB(a3)
  647. ItsPAL    
  648. ; Install sample interrupts
  649.     lea    Sami_handler(pc),a0
  650.     move.l    a0,Sami_handad-MB(a3)
  651.  
  652. ; As you can see, you MUST preserve A3-A6, and return in D0 the 
  653. ; Number of the extension if everything went allright. If an error has
  654. ; occured (no more memory, no file found etc...), return -1 in D0 and
  655. ; AMOS will refuse to start.
  656.     movem.l    (sp)+,a3-a6
  657.     moveq    #ExtNb,d0        * NO ERRORS
  658.     rts
  659.  
  660. ******* SCREEN RESET
  661. ; This routine is called each time a DEFAULT occurs...
  662. ;
  663. ; The next instruction loads the internal datazone address. I could have
  664. ; of course done a load MB(pc),a3 as the datazone is in the same
  665. ; library chunk. 
  666.  
  667. MusDef    DLoad    a3    
  668. * Reset TRACKER music
  669.     RBsr    L_TrackStop
  670.     clr.b    sorploop-MB(a3)
  671. * Reset Sam_interrupts
  672.     move.w    #$000F,Circuits+DmaCon
  673.     Rbsr    L_Sami_install
  674. * Init narrator
  675.     Rbsr    L_NarInit
  676. * Init musique
  677.     Rbsr    L_RazWave        * Reset waves
  678.     move.l    Buffer(a5),a0        * Draw square wave
  679.     move.l    a0,a1
  680.     moveq    #127,d0
  681. MuDf1    move.b    #-127,128(a0)
  682.     move.b    #127,(a0)+
  683.     dbra    d0,MuDf1
  684.     moveq    #0,d1            * 0-> Noise
  685.     Rbsr    L_NeWave
  686.     moveq    #1,d1            * 1-> Square wave
  687.     Rbsr    L_NeWave
  688.     move.w    #LNoise/2-1,d2        * Draw first noise
  689.     move.w    BSeed-MB(a3),d1
  690.     move.l    WaveBase-MB(a3),a0
  691.     lea    WaveDeb(a0),a0
  692. MuDf2    add.w    Circuits+6,d1
  693.     mulu    #$3171,d1
  694.     lsr.l    #8,d1
  695.     move.w    d1,(a0)+
  696.     dbra    d2,MuDf2
  697.     move.w    d1,BSeed-MB(a3)
  698.     moveq    #56,d0            * Default settings
  699.     moveq    #%1111,d1
  700.     Rbsr    L_Vol
  701.     Rbsr    L_MVol
  702.     move.w    #5,SamBank-MB(a3)    * Sample bank=5    
  703.     moveq    #-1,d0            * Sam loop off
  704.     moveq    #-1,d1
  705.     Rbsr    L_SL0
  706.     Rbra    L_MuInit
  707.  
  708. ******* QUIT
  709. ; This routine is called when you quit AMOS or when the compiled program
  710. ; ends. If you have opend devices, reserved memory you MUST close and
  711. ; restore everything to normal.
  712.  
  713. MusEnd:    DLoad    a3
  714. * No more VBL
  715.     clr.l    VBLRout(a5)
  716. * No more Sami
  717.     RBsr    L_Sami_remove
  718. * End narrator (if there)
  719.     move.l    $4.w,a6
  720.     tst.l    TranBase-MB(a3)
  721.     beq.s    NarEnd
  722.     lea    WriteRep-MB(a3),a1
  723.     jsr    RemPort(a6)
  724.     lea    TalkIO-MB(a3),a1
  725.     jsr    CloseDev(a6)
  726.     move.l    TranBase-MB(a3),a1
  727.     jsr    CloseLib(a6)
  728. * End music
  729. NarEnd    Rbsr    L_MOff
  730.     moveq    #%1111,d0
  731.     Rbsr    L_EnvOff
  732.     Rbsr    L_RazWave
  733.     lea    Circuits,a0
  734.     move.w    #$000F,DmaCon(a0)
  735.     clr.w    $a8(a0)
  736.     clr.w    $b8(a0)
  737.     clr.w    $c8(a0)
  738.     clr.w    $d8(a0)
  739. * mt: remove data zone
  740.     move.l    #488,d0
  741.     move.l    mt_amwave-MB(a3),a1
  742.     Sycall    SyFree
  743. * Finished!
  744.     rts
  745.  
  746. ******* LOOK FOR MUSIC BANK
  747. ; This routine is called after any bank has been loaded, reserved or erased.
  748. ; Here, if a music is being played and if the music bank is erased, I MUST
  749. ; stop the music, otherwise it might crash the computer. That's why I
  750. ; do a checksum on the first bytes of the bank to see if they have changed...
  751. BkCheck    RBsr    L_TrackCheck        * Check Tracker.
  752. * Check normal music.
  753.     DLoad    a3
  754.     move.l    MusBank-MB(a3),d0    * Address of OLD music bank
  755.     move.l    2*8(a0),d1        * Address of ACTUAL music bank
  756.     beq.s    BkNo            * 8 bytes per bank (here bank 3)
  757.     move.l    d1,a1            * Looks for "Musi"
  758.     move.l    (a1),d2        
  759.     cmp.l    BkMus-MB(a3),d2
  760.     bne.s    BkNo
  761.     lea    8(a1),a1
  762.     moveq    #0,d1            * Performs a check sum
  763.     add.l    (a1),d1
  764.     add.l    4(a1),d1
  765.     add.l    8(a1),d1
  766.     add.l    12(a1),d1
  767.     cmp.l    d0,a1
  768.     bne.s    BkNew
  769.     cmp.l    MusCheck-MB(a3),d1
  770.     bne.s    BkNew
  771. * Same bank! Do nothing!
  772.     rts
  773. * No more bank!
  774. BkNo    tst.l    d0
  775.     beq.s    BkNo1
  776.     Rbsr    L_MuInit
  777.     clr.l    MusBank-MB(a3)
  778. BkNo1    rts
  779. * A NEW bank
  780. BkNew    move.l    a1,MusBank-MB(a3)
  781.     move.l    d1,MusCheck-MB(a3)
  782.     Rbsr    L_MuInit
  783.     move.l    MusBank-MB(a3),a0
  784.     move.l    a0,a1
  785.     add.l    (a0),a1
  786.     move.l    a1,BankInst-MB(a3)
  787.     move.l    a0,a1
  788.     add.l    4(a0),a1
  789.     move.l    a1,BankSong-MB(a3)
  790.     add.l    8(a0),a0
  791.     move.l    a0,BankPat-MB(a3)
  792.     rts
  793.  
  794. ***********************************************************
  795. *
  796. *    INTERRUPT ROUTINES
  797. *
  798. ***********************************************************    
  799.  
  800. ******* Sami interrupt handlers
  801. Sami_handler
  802.     add.w    Sami_reg(a1),a0
  803.     move.l    Sami_pos(a1),d0
  804.     cmp.l    Sami_long(a1),d0
  805.     bcc.s    .whatnow
  806. * Poursuit la lecture du sample
  807. .samloop
  808.     move.l    d0,d1
  809.     add.l    #Sami_lplay,d1
  810.     cmp.l    Sami_long(a1),d1
  811.     bls.s    .skip
  812.     move.l    Sami_long(a1),d1
  813. .skip    move.l    d1,Sami_pos(a1)
  814.     sub.l    d0,d1
  815.     lsr.l    #1,d1
  816.     add.l    Sami_adr(a1),d0
  817.     move.l    d0,(a0)                * AUDxLOC
  818.     move.w    d1,4(a0)            * AUDxLEN
  819.     move.w    Sami_dvol(a1),d0
  820.     bmi.s    .skip1
  821.     move.w    d0,8(a0)            * AUDxVOL
  822. .skip1    move.w    Sami_bit(a1),Circuits+IntReq
  823.     rts
  824. * Sample termine. Que faire?
  825. .whatnow
  826.     move.l    d0,d1
  827.     move.l    Sami_radr(a1),d0        * Double buffer?
  828.     bne.s    .swap
  829.     move.l    Sami_rpos(a1),d0        * Boucler?
  830.     bpl.s    .samloop
  831.     bset    #7,Sami_pos(a1)            * Attend?
  832.     tst.l    d1
  833.     bpl.s    .skip1
  834. * Fin du sample-> met du blanc!
  835.     move.w    #0,$a(a0)
  836.     move.w    Sami_dma(a1),d0
  837.     moveq    #0,d1
  838.     bset    d0,d1
  839.     move.w    d1,Circuits+DmaCon
  840.     tst.w    Sami_dvol(a1)
  841.     bmi.s    .skip2
  842.     lea    MB(pc),a0            * Restart music
  843.     bset    d0,MuReStart+1-MB(a0)
  844. .skip2    move.w    Sami_bit(a1),Circuits+IntEna    * No more interrupts
  845.     move.w    Sami_bit(a1),Circuits+IntReq
  846.     rts
  847. * Change de buffer
  848. .swap    clr.l    Sami_radr(a1)
  849.     move.l    d0,Sami_adr(a1)
  850.     move.l    Sami_rlong(a1),Sami_long(a1)
  851.     moveq    #0,d0
  852.     bra    .samloop
  853.  
  854. ******* VBL Entry
  855. MusInt    lea    MB(pc),a3    
  856.     move.w    EnvOn-MB(a3),d0
  857.     beq    Music
  858.     lea    EnvBase-MB(a3),a0
  859.     lea    $a0(a6),a2
  860.     moveq    #0,d1
  861.     moveq    #3,d2
  862.     moveq    #0,d5
  863. MuInt1    btst    d1,d0
  864.     beq.s    MuIntN
  865.     move.l    EnvDelta(a0),d3
  866.     add.l    EnvVol(a0),d3
  867.     move.l    d3,EnvVol(a0)
  868.     swap    d3
  869.     move.w    d3,8(a2)
  870. MuInt2    subq.w    #1,EnvNb(a0)
  871.     bne.s    MuIntN
  872.     Rbsr    L_MuIntE
  873. MuIntN    lea    EnvLong(a0),a0
  874.     lea    $10(a2),a2
  875.     addq.w    #1,d1
  876.     dbra    d2,MuInt1
  877.     move.w    d0,EnvOn-MB(a3)
  878.     move.w    d5,DmaCon(a6)
  879.     lsl.w    #7,d5
  880.     move.w    d5,IntEna(a6)
  881. ******* Make noise?
  882.     tst.w    Noise-MB(a3)
  883.     beq.s    Music
  884.     move.w    PNoise-MB(a3),d0
  885.     moveq    #7,d2
  886.     move.w    BSeed-MB(a3),d1
  887.     move.l    WaveBase-MB(a3),a0
  888. INoi1    add.w    6(a6),d1
  889.     mulu    #$3171,d1
  890.     lsr.l    #8,d1
  891.     move.w    d1,WaveDeb(a0,d0.w)
  892.     subq.w    #2,d0
  893.     bpl.s    INoi2
  894.     move.w    #LNoise-2,d0
  895. INoi2    dbra    d2,INoi1
  896.     move.w    d0,PNoise-MB(a3)
  897.     move.w    d1,BSeed-MB(a3)
  898.  
  899. *******    Music routine
  900. Music:    move.l    MuBase-MB(a3),d0
  901.     beq    Tracker
  902.     movem.l    a4-a6,-(sp)
  903.     move.l    d0,a5
  904.     bsr    MuEvery
  905. * Here is a smart counter, which gives progressive results
  906. * from zero to 100(PAL), 120(NTSC)...
  907.     move.w    MuCpt(a5),d0
  908.     add.w    MuTempo(a5),d0
  909.     move.w    d0,MuCpt(a5)
  910.     move.w    TempoBase-MB(a3),d1
  911.     cmp.w    d1,d0
  912.     bcs    MuEff
  913.     sub.w    d1,MuCpt(a5)
  914. * Lets go for one step of music!
  915.     moveq    #0,d5
  916.     moveq    #0,d7
  917.     move.l    a5,a4
  918.  
  919.     tst.b    VoiCpt+1(a4)
  920.     beq.s    Mus0
  921.     addq.w    #1,d5
  922.     subq.b    #1,VoiCpt+1(a4)
  923.     bne.s    Mus0
  924.     moveq    #0,d6
  925.     move.l    MuChip0-MB(a3),a6
  926.     bsr    MuStep
  927. Mus0    
  928.     lea    MuVoix1(a5),a4
  929.     tst.b    VoiCpt+1(a4)
  930.     beq.s    Mus1
  931.     addq.w    #1,d5
  932.     subq.b    #1,VoiCpt+1(a4)
  933.     bne.s    Mus1
  934.     moveq    #1,d6
  935.     move.l    MuChip1-MB(a3),a6
  936.     bsr    MuStep
  937. Mus1
  938.     lea    MuVoix2(a5),a4
  939.     tst.b    VoiCpt+1(a4)
  940.     beq.s    Mus2
  941.     addq.w    #1,d5
  942.     subq.b    #1,VoiCpt+1(a4)
  943.     bne.s    Mus2
  944.     moveq    #2,d6
  945.     move.l    MuChip2-MB(a3),a6
  946.     bsr    MuStep
  947. Mus2    
  948.     lea    MuVoix3(a5),a4
  949.     tst.b    VoiCpt+1(a4)
  950.     beq.s    Mus3
  951.     addq.w    #1,d5
  952.     subq.b    #1,VoiCpt+1(a4)
  953.     bne.s    Mus3
  954.     moveq    #3,d6
  955.     move.l    MuChip3-MB(a3),a6
  956.     bsr    MuStep
  957. Mus3    
  958.     and.w    MuDMAsk-MB(a3),d7
  959.     move.w    d7,$DFF096
  960.     tst.w    d5
  961.     beq.s    MuFin
  962.     bne.s    MuEnd
  963. MuEff    bsr    DoEffects
  964. MuEnd    movem.l    (sp)+,a4-a6
  965. MuEnd1    rts
  966. * Finished?
  967. MuFin    subq.w    #1,MuNumber-MB(a3)
  968.     beq    MuFini
  969. * Restarts previous music
  970.     move.w    MuNumber-MB(a3),d0
  971.     subq.w    #1,d0
  972.     mulu    #MuLong,d0
  973.     lea    MuBuffer-MB(a3),a0
  974.     add.w    d0,a0
  975.     move.l    a0,MuBase-MB(a3)
  976.     move.w    MuDMAsk-MB(a3),MuReStart-MB(a3)
  977.     clr.w    MuStart(a0)
  978.     clr.w    MuStop(a0)
  979.     bra.s    MuEnd
  980. * Really finished!
  981. MuFini    clr.l    MuBase-MB(a3)
  982.     Rbsr    L_MOff
  983.     bra.s    MuEnd
  984.  
  985. ******* One step of music for one voice
  986. MuStep    lea    MuJumps(pc),a1
  987.     move.l    VoiAdr(a4),a2
  988. MuSt0    move.w    (a2)+,d0
  989.     bpl.s    DoNote
  990.     move.w    d0,d1
  991.     and.w    #$7F00,d0
  992.     lsr.w    #6,d0
  993.     jmp    0(a1,d0.w)
  994.  
  995. ******* Play a note
  996. DoNote    btst    #14,d0
  997.     bne.s    OldNote
  998. * Play normal note
  999.     and.w    #$0FFF,d0
  1000.     move.l    BankInst-MB(a3),d1
  1001.     move.l    VoiInst(a4),a0
  1002.     add.l    (a0),d1
  1003.     move.l    d1,(a6)
  1004.     move.w    8(a0),$04(a6)
  1005.     bset    d6,d7
  1006.     bclr    d6,MuStop+1(a5)
  1007.     bset    d6,MuStart+1(a5)
  1008.     move.b    VoiVol+1(a4),0(a3,d6.w)
  1009.     tst.b    VoiPTone(a4)
  1010.     bne.s    MuSt1
  1011. * No portamento
  1012.     move.w    d0,VoiNote(a4)
  1013.     move.w    d0,$06(a6)
  1014.     bra.s    MuSt0
  1015. * Start portamento
  1016. MuSt1    clr.b    VoiPTone(a4)
  1017.     move.w    d0,VoiPToTo(a4)
  1018.     lea    MuPTone(pc),a0
  1019.     move.l    a0,VoiEffect(a4)
  1020.     bra.s    MuSt0
  1021. * Play note compatible with first version
  1022. OldNote    move.w    d0,VoiCpt(a4)
  1023.     move.w    (a2)+,d0
  1024.     beq.s    ONoteE
  1025.     and.w    #$0FFF,d0
  1026.     move.w    d0,VoiNote(a4)
  1027.     move.w    d0,$06(a6)
  1028.     move.l    BankInst-MB(a3),d0
  1029.     move.l    VoiInst(a4),a0
  1030.     add.l    (a0),d0
  1031.     move.l    d0,(a6)
  1032.     move.w    8(a0),$04(a6)
  1033.     bset    d6,d7
  1034.     bclr    d6,MuStop+1(a5)
  1035.     bset    d6,MuStart+1(a5)
  1036.     move.b    VoiVol+1(a4),0(a3,d6.w)
  1037. ONoteE    move.l    a2,VoiAdr(a4)
  1038.     rts
  1039.  
  1040. ******* Jump table to labels
  1041. MuJumps    bra    EtEnd            * 00-> Fin pattern
  1042.     bra    MuSt0            * 01-> Old Slide up
  1043.     bra    MuSt0            * 02-> Old Slide down
  1044.     bra    EtSVol            * 03-> Set volume
  1045.     bra    EtStop            * 04-> Stop effet
  1046.     bra    EtRep            * 05-> Repeat
  1047.     bra    EtLOn            * 06-> Led On
  1048.     bra    EtLOff            * 07-> Led Off
  1049.     bra    EtTemp            * 08-> Set Tempo
  1050.     bra    EtInst            * 09-> Set Instrument
  1051.     bra    EtArp            * 10-> Arpeggiato
  1052.     bra    EtPort            * 11-> Portamento
  1053.     bra    EtVib            * 12-> Vibrato
  1054.     bra    EtVSl            * 13-> Volume slide
  1055.     bra    EtSlU            * 14-> Slide up
  1056.     bra    EtSlD            * 15-> Slide down
  1057.      bra    EtDel            * 16-> Delay
  1058.     bra    EtJmp            * 17-> Position jump
  1059.     bra    MuSt0            * 18-> Free space
  1060.     bra    MuSt0            * 19-> Free space
  1061.     bra    MuSt0            * 20-> Free space
  1062.     bra    MuSt0            * 21-> Free space
  1063.     bra    MuSt0            * 22-> Free space
  1064.     bra    MuSt0            * 23-> Free space
  1065.     bra    MuSt0            * 24-> Free space
  1066.     bra    MuSt0            * 25-> Free space
  1067.     bra    MuSt0            * 26-> Free space
  1068.     bra    MuSt0            * 27-> Free space
  1069.     bra    MuSt0            * 28-> Free space
  1070.     bra    MuSt0            * 29-> Free space
  1071.     bra    MuSt0            * 30-> Free space
  1072.     bra    MuSt0            * 31-> Free space
  1073.  
  1074. ******* End of a pattern
  1075. EtEnd    clr.w    VoiCpt(a4)
  1076.     clr.w    VoiRep(a4)
  1077.     clr.l    VoiDeb(a4)
  1078.     lea    NoEffect(pc),a0
  1079.     move.l    a0,VoiEffect(a4)
  1080.     move.l    VoiPat(a4),a0
  1081. RePat    moveq    #0,d0
  1082.     move.w    (a0)+,d0
  1083.     bmi.s    EtEnd1
  1084.     move.l    a0,VoiPat(a4)
  1085.     move.l    BankPat-MB(a3),a0
  1086.     cmp.w    (a0),d0
  1087.     bhi.s    EtEndX
  1088.     lsl.w    #2,d0
  1089.     add.w    d6,d0
  1090.     lsl.w    #1,d0
  1091.     move.w    2(a0,d0.w),d0
  1092.     beq.s    EtEndX
  1093.     lea    0(a0,d0.l),a2
  1094.     bra    MuSt0
  1095. EtEndX    rts
  1096. EtEnd1    cmp.w    #-1,d0
  1097.     beq.s    EtEndX
  1098.      move.l    VoiDPat(a4),a0
  1099.     bra.s    RePat
  1100. ******* Change instrument
  1101. EtInst    and.w    #$00FF,d1
  1102.     move.l    BankInst-MB(a3),a0
  1103.     lsl.w    #5,d1
  1104.     lea    2(a0,d1.w),a0
  1105.     move.l    a0,VoiInst(a4)
  1106.     move.w    12(a0),d0
  1107.     cmp.w    #64,d0
  1108.     bcs.s    EtInst1
  1109.     moveq    #63,d0
  1110. EtInst1    move.w    d0,VoiDVol(a4)
  1111.     mulu    MuVolume-MB(a3),d0
  1112.     lsr.w    #6,d0
  1113.     move.w    d0,VoiVol(a4)
  1114.     bra    MuSt0
  1115. ******* Set Volume
  1116. EtSVol    and.w    #$00FF,d1
  1117.     cmp.w    #64,d1
  1118.     bcs.s    EtSVol1
  1119.     moveq    #63,d1
  1120. EtSVol1    move.w    d1,VoiDVol(a4)
  1121.     mulu    MuVolume-MB(a3),d1
  1122.     lsr.w    #6,d1
  1123.     move.w    d1,VoiVol(a4)
  1124.     bra    MuSt0
  1125. ******* Set Tempo
  1126. EtTemp    and.w    #$00FF,d1
  1127.     move.w    d1,MuTempo(a5)
  1128.     bra    MuSt0
  1129. ******* Led On
  1130. EtLOn    bclr    #1,$bfe001
  1131.     bra    MuSt0
  1132. ******* Led Off
  1133. EtLOff    bset    #1,$bfe001
  1134.     bra    MuSt0
  1135. ******* Repeat
  1136. EtRep    and.w    #$00FF,d1
  1137.     bne.s    EtRep1
  1138.     move.l    a2,VoiDeb(a4)
  1139.     bra    MuSt0
  1140. EtRep1    tst.w    VoiRep(a4)
  1141.     bne.s    EtRep2
  1142.     move.w    d1,VoiRep(a4)
  1143.     bra    MuSt0
  1144. EtRep2    subq.w    #1,VoiRep(a4)
  1145.     beq    MuSt0
  1146.     move.l    VoiDeb(a4),d0
  1147.     beq    MuSt0
  1148.     move.l    d0,a2
  1149.     bra    MuSt0
  1150. ******* Arpeggio
  1151. EtArp    move.b    d1,VoiValue+1(a4)
  1152.     lea    MuArp(pc),a0
  1153.     move.l    a0,VoiEffect(a4)
  1154.     bra    MuSt0
  1155. ******* Portamento
  1156. EtPort    move.b    #1,VoiPTone(a4)
  1157.     lea    MuPTone(pc),a0
  1158.     bra.s    EtSetE
  1159. ******* Vibrato
  1160. EtVib    lea    MuVib(pc),a0
  1161.     bra.s    EtSetE
  1162. ******* Volume slide
  1163. EtVSl    and.w    #$00FF,d1
  1164.     move.w    d1,d0
  1165.     lsr.w    #4,d0
  1166.     tst.w    d0
  1167.     bne.s    VsEnd
  1168.     and.w    #$000F,d1
  1169.     neg.w    d1
  1170.     move.w    d1,d0
  1171. VsEnd    move.w    d0,VoiValue(a4)
  1172.     lea    MuVSl(pc),a0
  1173.     move.l    a0,VoiEffect(a4)
  1174.     bra    MuSt0
  1175. ******* Slide up
  1176. EtSlU    and.w    #$00FF,d1
  1177.     neg.w    d1
  1178.     lea    MuSlide(pc),a0
  1179.     bra.s    EtSte
  1180. ******* Slide Down
  1181. EtSlD    lea    MuSlide(pc),a0
  1182. EtSetE    and.w    #$00FF,d1
  1183. EtSte    move.w    d1,VoiValue(a4)
  1184.     move.l    a0,VoiEffect(a4)
  1185.     bra    MuSt0
  1186. ******* Stop effect
  1187. EtStop    lea    NoEffect(pc),a0
  1188.     move.l    a0,VoiEffect(a4)
  1189.     bra    MuSt0
  1190. ******* Jump to pattern
  1191. EtJmp    and.w    #$00FF,d1
  1192.     lsl.w    #1,d1
  1193.     move.l    VoiDPat(a4),a0
  1194.     add.w    d1,a0
  1195.     move.l    a0,VoiPat(a4)
  1196.     bra    EtEnd
  1197. ******* Delay
  1198. EtDel    move.w    d1,VoiCpt(a4)
  1199.     move.l    a2,VoiAdr(a4)
  1200.     rts
  1201.  
  1202. ******* Effect routines
  1203.  
  1204. * Performs all effects
  1205. DoEffects
  1206.     move.l    a5,a4
  1207.     move.l    MuChip0-MB(a3),a6
  1208.     move.l    VoiEffect(a4),a0
  1209.     jsr    (a0)
  1210.     move.w    VoiVol(a4),$08(a6)
  1211.     lea    MuVoix1(a5),a4
  1212.     move.l    MuChip1-MB(a3),a6
  1213.     move.l    VoiEffect(a4),a0
  1214.     jsr    (a0)
  1215.     move.w    VoiVol(a4),$08(a6)
  1216.     lea    MuVoix2(a5),a4
  1217.     move.l    MuChip2-MB(a3),a6
  1218.     move.l    VoiEffect(a4),a0
  1219.     jsr    (a0)
  1220.     move.w    VoiVol(a4),$08(a6)
  1221.     lea    MuVoix3(a5),a4
  1222.     move.l    MuChip3-MB(a3),a6
  1223.     move.l    VoiEffect(a4),a0
  1224.     jsr    (a0)
  1225.     move.w    VoiVol(a4),$08(a6)
  1226.     rts
  1227.  
  1228. * TONE SLIDE
  1229. MuSlide    move.w    VoiValue(a4),d0
  1230.     beq.s    NoMoreE
  1231.     add.w    VoiNote(a4),d0
  1232.     cmp.w    #$71,d0
  1233.     bcc.s    MuSl1
  1234.     moveq    #$71,d0
  1235.     bsr    NoMoreE
  1236. MuSl1    cmp.w    #$358,d0
  1237.     bls.s    MuSl2
  1238.     move.w    #$358,d0
  1239.     bsr    NoMoreE
  1240. MuSl2    move.w    d0,VoiNote(a4)
  1241.     move.w    d0,$06(a6)
  1242.     rts
  1243. NoMoreE    lea    NoEffect(pc),a0
  1244.     move.l    a0,VoiEffect(a4)
  1245.     rts
  1246. NoEffect
  1247.     move.w    VoiNote(a4),$06(a6)
  1248.     rts
  1249.  
  1250. * ARPEGGIO
  1251. MuArp    moveq    #0,d0
  1252.     move.b    VoiValue+1(a4),d0
  1253.     move.b    VoiValue(a4),d1
  1254.     cmp.b    #3,d1
  1255.     bcs.s    MuArp0
  1256.     moveq    #2,d1
  1257. MuArp0    subq.b    #1,d1
  1258.     move.b    d1,VoiValue(a4)
  1259.     beq.s    MuArp2
  1260.     bpl.s    MuArp1
  1261.     lsr.b    #4,d0
  1262.     bra.s    MuArp3
  1263. MuArp1    and.b    #$0f,d0
  1264.     bra.s    MuArp3
  1265. MuArp2    move.w    VoiNote(a4),d2
  1266.     bra.s    MuArp4
  1267. MuArp3    add.w    d0,d0
  1268.     moveq    #0,d1
  1269.     move.w    VoiNote(a4),d1
  1270.     lea    Periods(pc),a0
  1271.     moveq    #$24,d3
  1272. MuArpL    move.w    (a0,d0.w),d2
  1273.     cmp.w    (a0),d1
  1274.     bge.s    MuArp4
  1275.     addq.l    #2,a0
  1276.     dbra    d3,MuArpL
  1277.     rts
  1278. MuArp4    move.w    d2,$06(a6)
  1279.     rts
  1280.  
  1281. * PORTAMENTO
  1282. MuPTone    move.w    VoiValue(a4),d0
  1283.     move.w    VoiNote(a4),d1
  1284.     cmp.w    VoiPToTo(a4),d1
  1285.     beq.s    MuPTo3
  1286.     bcs.s    MuPTo1
  1287.     sub.w    d0,d1
  1288.     cmp.w    VoiPToTo(a4),d1
  1289.     bhi.s    MuPto4
  1290.     bra.s    MuPTo2
  1291. MuPTo1    add.w    d0,d1
  1292.     cmp.w    VoiPToTo(a4),d1
  1293.     bcs.s    MuPTo4
  1294. MuPTo2    move.w    VoiPToTo(a4),d1
  1295. MuPTo3    bsr    NoMoreE
  1296. MuPTo4    move.w    d1,VoiNote(a4)
  1297.     move.w    d1,$06(a6)
  1298.     rts
  1299.  
  1300. * VIBRATO
  1301. MuVib    move.b    VoiVib(a4),d0
  1302.     lea    Sinus(pc),a0
  1303.     lsr.w    #2,d0
  1304.     and.w    #$1f,d0
  1305.     moveq    #0,d2
  1306.     move.b    0(a0,d0.w),d2
  1307.     move.b    VoiValue+1(a4),d0
  1308.     and.w    #$0F,d0
  1309.     mulu    d0,d2
  1310.     lsr.w    #$06,d2
  1311.     move.w    VoiNote(a4),d0
  1312.     tst.b    VoiVib(a4)
  1313.     bmi.s    MuVib1
  1314.     add.w    d2,d0
  1315.     bra.s    MuVib2
  1316. MuVib1    sub.w    d2,d0
  1317. MuVib2    move.w    d0,$06(a6)
  1318.     move.b    VoiValue+1(a4),d0
  1319.     lsr.w    #2,d0
  1320.     and.w    #$3C,d0
  1321.     add.b    d0,VoiVib(a4)
  1322.     rts
  1323.  
  1324. * VOLUME SLIDE
  1325. MuVSl    move.w    VoiDVol(a4),d0
  1326.     add.w    VoiValue(a4),d0
  1327.     bpl.s    MuVSl1
  1328.     clr.w    d0
  1329. MuVSl1    cmp.w    #$40,d0
  1330.     bcs.s    MuVSl2
  1331.     moveq    #$3F,d0
  1332. MuVSl2    move.w    d0,VoiDVol(a4)
  1333.     mulu    MuVolume-MB(a3),d0
  1334.     lsr.w    #6,d0
  1335.     move.w    d0,VoiVol(a4)
  1336.     rts
  1337.  
  1338. *******    Routine called every VBL
  1339. MuEvery    
  1340.  
  1341. * Second step of sample?
  1342.     move.w    MuStop(a5),d0
  1343.     beq    MuEvX
  1344.     move.l    BankInst-MB(a3),d1
  1345.     btst    #0,d0                * Voix 0
  1346.     beq.s    MuEv0
  1347.     move.l    MuChip0-MB(a3),a6
  1348.     move.l    VoiInst0(a5),a0
  1349.     move.l    d1,d2
  1350.     add.l    4(a0),d2
  1351.     move.l    d2,(a6)
  1352.     move.w    10(a0),$04(a6)
  1353. MuEv0    btst    #1,d0                * Voix 1
  1354.     beq.s    MuEv1
  1355.     move.l    MuChip1-MB(a3),a6
  1356.     move.l    VoiInst1(a5),a0
  1357.     move.l    d1,d2
  1358.     add.l    4(a0),d2
  1359.     move.l    d2,(a6)
  1360.     move.w    10(a0),$04(a6)
  1361. MuEv1    btst    #2,d0                * Voix 2
  1362.     beq.s    MuEv2
  1363.     move.l    MuChip2-MB(a3),a6
  1364.     move.l    VoiInst2(a5),a0
  1365.     move.l    d1,d2
  1366.     add.l    4(a0),d2
  1367.     move.l    d2,(a6)
  1368.     move.w    10(a0),$04(a6)
  1369. MuEv2    btst    #3,d0                * Voix 3
  1370.     beq.s    MuEv3
  1371.     move.l    MuChip3-MB(a3),a6
  1372.     move.l    VoiInst3(a5),a0
  1373.     move.l    d1,d2
  1374.     add.l    4(a0),d2
  1375.     move.l    d2,(a6)
  1376.     move.w    10(a0),$04(a6)
  1377. MuEv3    
  1378.  
  1379. * Start a voice
  1380. MuEvX    move.w    MuStart(a5),d1
  1381.     move.w    d1,MuStop(a5)
  1382.     clr.w    MuStart(a5)
  1383.     or.w    d1,d0
  1384.     and.w    MuDMAsk-MB(a3),d0
  1385.     bset    #15,d0
  1386.     move.w    d0,$DFF096
  1387.  
  1388. * Restart voices?
  1389.     move.w    MuReStart-MB(a3),d0
  1390.     beq    MuRsX
  1391.     moveq    #0,d3
  1392.     btst    #0,d0                * Voix 0
  1393.     beq.s    MuRs0
  1394.     lea    $DFF0A0,a6
  1395.     move.l    a6,MuChip0-MB(a3)
  1396.     move.w    #2,$04(a6)
  1397.     tst.l    VoiInst0(a5)
  1398.     beq.s    MuRs0
  1399.     bset    #0,d3
  1400. MuRs0    btst    #1,d0                * Voix 1
  1401.     beq.s    MuRs1
  1402.     lea    $DFF0B0,a6
  1403.     move.l    a6,MuChip1-MB(a3)
  1404.     move.w    #2,$04(a6)
  1405.     tst.l    VoiInst1(a5)
  1406.     beq.s    MuRs1
  1407.     bset    #1,d3
  1408. MuRs1    btst    #2,d0                * Voix 2
  1409.     beq.s    MuRs2
  1410.     lea    $DFF0C0,a6
  1411.     move.l    a6,MuChip2-MB(a3)
  1412.     move.w    #2,$04(a6)
  1413.     tst.l    VoiInst2(a5)
  1414.     beq.s    MuRs2
  1415.     bset    #2,d3
  1416. MuRs2    btst    #3,d0                * Voix 3
  1417.     beq.s    MuRs3
  1418.     lea    $DFF0D0,a6
  1419.     move.l    a6,MuChip3-MB(a3)
  1420.     move.w    #2,$04(a6)
  1421.     tst.l    VoiInst3(a5)
  1422.     beq.s    MuRs3
  1423.     bset    #3,d3
  1424. MuRs3    clr.w    MuReStart-MB(a3)
  1425.     or.w    d0,MuDMAsk-MB(a3)
  1426.     or.w    d3,MuStop(a5)
  1427. MuRsX    
  1428.     rts
  1429.  
  1430.  
  1431. ***********************************************************
  1432. *
  1433. *    TRACKER INTERRUPT ROUTINES
  1434. *
  1435. ***********************************************************    
  1436. Tracker
  1437.     lea    MB(pc),a3
  1438.     tst.b    mt_on-MB(a3)
  1439.     beq.s    mt_i
  1440.     movem.l    a4-a6,-(sp)
  1441.     bsr.s    mt_music
  1442.     lea    MB(pc),a3
  1443.     tst.b    sorpend-MB(a3)
  1444.     beq.s    .nof
  1445.     clr.w    $dff0a8
  1446.     clr.w    $dff0b8
  1447.     clr.w    $dff0c8
  1448.     clr.w    $dff0d8
  1449.     move.w    #$f,$dff096
  1450.     clr.b    mt_on-MB(a3)
  1451. .nof    movem.l    (sp)+,a4-a6
  1452. mt_i    rts
  1453.  
  1454. mt_music:
  1455.     lea    (a3),a6
  1456.  
  1457.     move.l    mt_data-MB(a6),a0
  1458.     addq.b    #1,mt_counter-MB(a6)
  1459.     move.b    mt_counter-MB(a6),d0
  1460.     cmp.b    mt_speed-MB(a6),d0
  1461.     blt    mt_nonew
  1462.     clr.b    mt_counter-MB(a6)
  1463.  
  1464.     move.l    mt_data-MB(a6),a0
  1465.     lea    $c(a0),a3
  1466.     lea    $3b8(a0),a2
  1467.     lea    $43c(a0),a0
  1468.  
  1469.     moveq    #0,d0
  1470.     moveq    #0,d1
  1471.     move.b    mt_songpos-MB(a6),d0
  1472.     move.b    (a2,d0.w),d1
  1473.     lsl.w    #8,d1
  1474.     lsl.w    #2,d1
  1475.     add.w    mt_pattpos-MB(a6),d1
  1476.     clr.w    mt_dmacon-MB(a6)
  1477.  
  1478.     lea    $dff0a0,a5
  1479.     lea    mt_voice1-MB(a6),a4
  1480.     moveq    #0,d6
  1481.     bsr    mt_playvoice
  1482.     addq.l    #4,d1
  1483.     lea    $dff0b0,a5
  1484.     lea    mt_voice2-MB(a6),a4
  1485.     moveq    #1,d6
  1486.     bsr    mt_playvoice
  1487.     addq.l    #4,d1
  1488.     lea    $dff0c0,a5
  1489.     lea    mt_voice3-MB(a6),a4
  1490.     moveq    #2,d6
  1491.     bsr    mt_playvoice
  1492.     addq.l    #4,d1
  1493.     lea    $dff0d0,a5
  1494.     lea    mt_voice4-MB(a6),a4
  1495.     moveq    #3,d6
  1496.     bsr    mt_playvoice
  1497.  
  1498.     bsr    mt_wait
  1499.     move.w    mt_dmacon-MB(a6),d0
  1500.     or.w    #$8000,d0
  1501.     move.w    d0,$dff096
  1502.     bsr    mt_wait
  1503. mt_nodma:
  1504.     lea    mt_voice1-MB(a6),a4
  1505.     move.l    $a(a4),$a0+$dff000
  1506.     move.w    $e(a4),$a4+$dff000
  1507.     tst.w    30(a4)
  1508.     bne.s    mt_nov1
  1509.     move.w    $12(a4),$a8+$dff000
  1510. mt_nov1:lea    mt_voice2-MB(a6),a4
  1511.     move.l    $a(a4),$b0+$dff000
  1512.     move.w    $e(a4),$b4+$dff000
  1513.     tst.w    30(a4)
  1514.     bne.s    mt_nov2
  1515.     move.w    $12(a4),$b8+$dff000
  1516. mt_nov2:lea    mt_voice3-MB(a6),a4
  1517.     move.l    $a(a4),$c0+$dff000
  1518.     move.w    $e(a4),$c4+$dff000
  1519.     tst.w    30(a4)
  1520.     bne.s    mt_nov3
  1521.     move.w    $12(a4),$c8+$dff000
  1522. mt_nov3:lea    mt_voice4-MB(a6),a4
  1523.     move.l    $a(a4),$d0+$dff000
  1524.     tst.w    30(a4)
  1525.     bne.s    mt_nov4
  1526.     move.w    $e(a4),$d4+$dff000
  1527.     move.w    $12(a4),$d8+$dff000
  1528.  
  1529. mt_nov4:add.w    #$10,mt_pattpos-MB(a6)
  1530.     cmp.w    #$400,mt_pattpos-MB(a6)
  1531.     bne.s    mt_exit
  1532. mt_next:clr.w    mt_pattpos-MB(a6)
  1533.     clr.b    mt_break-MB(a6)
  1534.     move.l    mt_data-MB(a6),a0
  1535.     tst.b    sorp-MB(a6)
  1536.     beq    song
  1537.     cmp.b    #1,sorploop-MB(a6)
  1538.     beq    rep
  1539.     move.b    #1,sorpend-MB(a6)
  1540. rep    rts
  1541.  
  1542. song    clr.w    mt_pattpos-MB(a6)
  1543.     addq.b    #1,mt_songpos-MB(a6)
  1544.     and.b    #$7f,mt_songpos-MB(a6)
  1545.     move.b    $3b6(a0),d0
  1546.     cmp.b    mt_songpos-MB(a6),d0
  1547.     bne.s    mt_exit
  1548.     tst.b    sorploop-MB(a6)
  1549.     bne    srep
  1550.     move.b    #1,sorpend-MB(a6)
  1551.     rts
  1552.  
  1553. srep    move.b    omt_songpos-MB(a6),mt_songpos-MB(a6)
  1554. mt_exit:tst.b    mt_break-MB(a6)
  1555.     bne.s    mt_next
  1556.     bra    mt_amhandler
  1557.  
  1558. mt_wait:moveq    #4,d3        
  1559. mt_wai2:move.b    $dff006,d2    
  1560. mt_wai3:cmp.b    $dff006,d2    
  1561.     beq.s    mt_wai3
  1562.     dbf    d3,mt_wai2    
  1563.     moveq    #8,d2
  1564. mt_wai4:dbf    d2,mt_wai4
  1565.  
  1566. mt_nonew:
  1567.     lea    mt_voice1-MB(a6),a4
  1568.     lea    $dff0a0,a5
  1569.     bsr    mt_com
  1570.     lea    mt_voice2-MB(a6),a4
  1571.     lea    $dff0b0,a5
  1572.     bsr    mt_com
  1573.     lea    mt_voice3-MB(a6),a4
  1574.     lea    $dff0c0,a5
  1575.     bsr    mt_com
  1576.     lea    mt_voice4-MB(a6),a4
  1577.     lea    $dff0d0,a5
  1578.     bsr    mt_com
  1579.     bra.s    mt_exit
  1580.  
  1581.  
  1582. mt_playvoice:
  1583.     move.l    (a0,d1.l),(a4)
  1584.     moveq    #0,d2
  1585.     move.b    2(a4),d2
  1586.     lsr.b    #4,d2
  1587.     move.b    (a4),d0
  1588.     and.b    #$f0,d0
  1589.     or.b    d0,d2
  1590.     beq    mt_oldinstr
  1591.  
  1592.     lea    mt_samplestarts-4-MB(a6),a1
  1593.     move.w    d2,34(a4)
  1594.     move.w    d2,d0
  1595.     mulu    #120,d0
  1596.     add.l    mt_data2-MB(a6),d0
  1597.     move.l    a0,-(sp)
  1598.     move.l    d0,a0
  1599.     clr.w    30(a4)
  1600.     cmp.w    #"AM",(a0)
  1601.     bne.s    mt_noa9
  1602.     move.w    6(a0),d0
  1603.     lsr.w    #2,d0
  1604.     st    30(a4)
  1605. mt_noa9:move.l    (sp)+,a0
  1606.  
  1607.     asl.w    #2,d2
  1608.     move.l    (a1,d2.l),4(a4)
  1609.     lsr.w    #2,d2
  1610.     mulu    #30,d2
  1611.     move.w    (a3,d2.w),8(a4)
  1612.     tst.w    30(a4)
  1613.     beq.s    mt_noa8
  1614.     move.w    d0,$12(a4)
  1615.     bra.s    mt_noa7
  1616. mt_noa8:move.w    2(a3,d2.w),$12(a4)
  1617. mt_noa7:moveq    #0,d3
  1618.     move.w    4(a3,d2.w),d3
  1619.     tst.w    d3
  1620.     beq.s    mt_noloop
  1621.     move.l    4(a4),d0
  1622.     asl.w    #1,d3
  1623.     add.l    d3,d0
  1624.     move.l    d0,$a(a4)
  1625.     move.w    4(a3,d2.w),d0
  1626.     add.w    6(a3,d2.w),d0
  1627.     move.w    d0,8(a4)
  1628.     bra.s    mt_hejaSverige
  1629. mt_noloop:
  1630.     move.l    4(a4),d0
  1631.     add.l    d3,d0
  1632.     move.l    d0,$a(a4)
  1633. mt_hejaSverige:
  1634.     move.w    6(a3,d2.w),$e(a4)
  1635.  
  1636. mt_oldinstr:
  1637.     move.w    (a4),d0
  1638.     and.w    #$fff,d0
  1639.     beq    mt_com2
  1640.     tst.w    30(a4)
  1641.     bne.s    mt_rambo
  1642.     tst.w    8(a4)
  1643.     beq    mt_stopsound
  1644.     tst.b    $12(a4)
  1645.     bne    mt_stopsound
  1646.     move.b    2(a4),d0
  1647.     and.b    #$f,d0
  1648.     cmp.b    #5,d0
  1649.     beq    mt_setport
  1650.     cmp.b    #3,d0
  1651.     beq    mt_setport
  1652.  
  1653. mt_rambo:
  1654.     move.w    (a4),$10(a4)
  1655.     and.w    #$fff,$10(a4)
  1656.     move.w    $1a(a4),$dff096
  1657.     clr.b    $19(a4)
  1658.  
  1659.     tst.w    30(a4)
  1660.     beq.s    mt_noaminst
  1661.     move.l    a0,-(sp)
  1662.     move.w    34(a4),d0
  1663.     mulu    #120,d0
  1664.     add.l    mt_data2-MB(a6),d0
  1665.     move.l    d0,a0
  1666.     moveq    #0,d0
  1667.     move.w    26(a0),d0
  1668.     lsl.w    #5,d0
  1669.     
  1670.     move.l    a0,-(sp)
  1671.     move.l    mt_amwave-MB(a6),a0
  1672.     add.l    a0,d0    
  1673.     move.l    (sp)+,a0
  1674.  
  1675.     move.l    d0,(a5)
  1676.     move.w    #16,4(a5)
  1677.     move.l    d0,$a(a4)
  1678.     move.w    #16,$e(a4)
  1679.     move.w    6(a0),32(a4)
  1680.     move.l    #1,36(a4)
  1681.     move.w    34(a0),d0
  1682.     move.w    d1,-(sp)
  1683.     move.w    $10(a4),d1
  1684.     lsl.w    d0,d1
  1685.     move.w    d1,$10(a4)
  1686.     move.w    d1,6(a5)
  1687.     move.w    (sp)+,d1
  1688.     move.l    (sp)+,a0
  1689.     bra.s    mt_juck
  1690.  
  1691. mt_noaminst:
  1692.     move.l    4(a4),(a5)
  1693.     move.w    8(a4),4(a5)
  1694.     move.w    $10(a4),6(a5)
  1695.  
  1696. mt_juck:
  1697.     move.b    $13(a4),MuVu-MB(a6,d6.w)    * Vu-metres...
  1698.     move.w    $1a(a4),d0
  1699.     or.w    d0,mt_dmacon-MB(a6)
  1700.     bra    mt_com2
  1701.  
  1702. mt_stopsound:
  1703.     move.w    $1a(a4),$dff096
  1704.     bra    mt_com2
  1705.  
  1706. mt_setport:
  1707.     move.w    (a4),d2
  1708.     and.w    #$fff,d2
  1709.     move.w    d2,$16(a4)
  1710.     move.w    $10(a4),d0
  1711.     clr.b    $14(a4)
  1712.     cmp.w    d0,d2
  1713.     beq.s    mt_clrport
  1714.     bge    mt_com2
  1715.     move.b    #1,$14(a4)
  1716.     bra    mt_com2
  1717. mt_clrport:
  1718.     clr.w    $16(a4)
  1719.     rts
  1720.  
  1721. mt_port:move.b    3(a4),d0
  1722.     beq.s    mt_port2
  1723.     move.b    d0,$15(a4)
  1724.     clr.b    3(a4)
  1725. mt_port2:
  1726.     tst.w    $16(a4)
  1727.     beq.s    mt_rts
  1728.     moveq    #0,d0
  1729.     move.b    $15(a4),d0
  1730.     tst.b    $14(a4)
  1731.     bne.s    mt_sub
  1732.     add.w    d0,$10(a4)
  1733.     move.w    $16(a4),d0
  1734.     cmp.w    $10(a4),d0
  1735.     bgt.s    mt_portok
  1736.     move.w    $16(a4),$10(a4)
  1737.     clr.w    $16(a4)
  1738. mt_portok:
  1739.     move.w    $10(a4),6(a5)
  1740. mt_rts:    rts
  1741.  
  1742. mt_sub:    sub.w    d0,$10(a4)
  1743.     move.w    $16(a4),d0
  1744.     cmp.w    $10(a4),d0
  1745.     blt.s    mt_portok
  1746.     move.w    $16(a4),$10(a4)
  1747.     clr.w    $16(a4)
  1748.     move.w    $10(a4),6(a5)
  1749.     rts
  1750.  
  1751.  
  1752. mt_vib:    move.b    $3(a4),d0
  1753.     beq.s    mt_vib2
  1754.     move.b    d0,$18(a4)
  1755.  
  1756. mt_vib2:move.b    $19(a4),d0
  1757.     lsr.w    #2,d0
  1758.     and.w    #$1f,d0
  1759.     moveq    #0,d2
  1760.  
  1761.     move.l    a0,-(sp)
  1762.     lea    mt_sin-MB(a6),a0
  1763.     move.b    (a0,d0.w),d2
  1764.     move.l    (sp)+,a0
  1765.  
  1766.     move.b    $18(a4),d0
  1767.     and.w    #$f,d0
  1768.     mulu    d0,d2
  1769.     lsr.w    #7,d2
  1770.     move.w    $10(a4),d0
  1771.     tst.b    $19(a4)
  1772.     bmi.s    mt_vibsub
  1773.     add.w    d2,d0
  1774.     bra.s    mt_vib3
  1775. mt_vibsub:
  1776.     sub.w    d2,d0
  1777. mt_vib3:move.w    d0,6(a5)
  1778.     move.b    $18(a4),d0
  1779.     lsr.w    #2,d0
  1780.     and.w    #$3c,d0
  1781.     add.b    d0,$19(a4)
  1782.     rts
  1783.  
  1784.  
  1785. mt_arp:    moveq    #0,d0
  1786.     move.b    mt_counter-MB(a6),d0
  1787.  
  1788.     move.l    a0,-(sp)
  1789.     lea    mt_arplist-MB(a6),a0
  1790.     move.b    (a0,d0.w),d0
  1791.     move.l    (sp)+,a0
  1792.     tst.b    d0
  1793.  
  1794.     beq.s    mt_arp0
  1795.     cmp.b    #2,d0
  1796.     beq.s    mt_arp2
  1797. mt_arp1:moveq    #0,d0
  1798.     move.b    3(a4),d0
  1799.     lsr.b    #4,d0
  1800.     bra.s    mt_arpdo
  1801. mt_arp2:moveq    #0,d0
  1802.     move.b    3(a4),d0
  1803.     and.b    #$f,d0
  1804. mt_arpdo:
  1805.     asl.w    #1,d0
  1806.     move.w    $10(a4),d1
  1807.     and.w    #$fff,d1
  1808.     lea    mt_periods-MB(a6),a0
  1809.     moveq    #$24,d2
  1810. mt_arp3:cmp.w    (a0)+,d1
  1811.     bge.s    mt_arpfound
  1812.     dbf    d2,mt_arp3
  1813. mt_arp0:move.w    $10(a4),6(a5)
  1814.     rts
  1815. mt_arpfound:
  1816.     move.w    -2(a0,d0.w),6(a5)
  1817.     rts
  1818.  
  1819. mt_normper:
  1820.     move.w    $10(a4),6(a5)
  1821.     rts
  1822.  
  1823. mt_com:    move.w    2(a4),d0
  1824.     and.w    #$fff,d0
  1825.     beq.s    mt_normper
  1826.     move.b    2(a4),d0
  1827.     and.b    #$f,d0
  1828.     tst.b    d0
  1829.     beq.s    mt_arp
  1830.     cmp.b    #1,d0
  1831.     beq.s    mt_portup
  1832.     cmp.b    #2,d0
  1833.     beq.s    mt_portdown
  1834.     cmp.b    #3,d0
  1835.     beq    mt_port
  1836.     cmp.b    #4,d0
  1837.     beq    mt_vib
  1838.     cmp.b    #5,d0
  1839.     beq.s    mt_volport
  1840.     cmp.b    #6,d0
  1841.     beq.s    mt_volvib
  1842.     move.w    $10(a4),6(a5)
  1843.     cmp.b    #$a,d0
  1844.     beq.s    mt_volslide
  1845.     rts
  1846.  
  1847. mt_portup:
  1848.     moveq    #0,d0
  1849.     move.b    3(a4),d0
  1850.     sub.w    d0,$10(a4)
  1851.     move.w    $10(a4),d0
  1852.     cmp.w    #$71,d0
  1853.     bpl.s    mt_portup2
  1854.     move.w    #$71,$10(a4)
  1855. mt_portup2:
  1856.     move.w    $10(a4),6(a5)
  1857.     rts
  1858.  
  1859. mt_portdown:
  1860.     moveq    #0,d0
  1861.     move.b    3(a4),d0
  1862.     add.w    d0,$10(a4)
  1863.     move.w    $10(a4),d0
  1864.     cmp.w    #$358,d0
  1865.     bmi.s    mt_portdown2
  1866.     move.w    #$358,$10(a4)
  1867. mt_portdown2:
  1868.     move.w    $10(a4),6(a5)
  1869.     rts
  1870.  
  1871. mt_volvib:
  1872.      bsr    mt_vib2
  1873.      bra.s    mt_volslide
  1874. mt_volport:
  1875.      bsr    mt_port2
  1876.  
  1877. mt_volslide:
  1878.     moveq    #0,d0
  1879.     move.b    3(a4),d0
  1880.     lsr.b    #4,d0
  1881.     beq.s    mt_vol3
  1882.     add.b    d0,$13(a4)
  1883.     cmp.b    #$40,$13(a4)
  1884.     bmi.s    mt_vol2
  1885.     move.b    #$40,$13(a4)
  1886. mt_vol2:moveq    #0,d0
  1887.     move.b    $13(a4),d0
  1888.     move.w    d0,8(a5)
  1889.     rts
  1890.  
  1891. mt_vol3:move.b    3(a4),d0
  1892.     and.b    #$f,d0
  1893.     sub.b    d0,$13(a4)
  1894.     bpl.s    mt_vol4
  1895.     clr.b    $13(a4)
  1896. mt_vol4:moveq    #0,d0
  1897.     move.b    $13(a4),d0
  1898.     move.w    d0,8(a5)
  1899.     rts
  1900.  
  1901. mt_com2:move.b    $2(a4),d0
  1902.     and.b    #$f,d0
  1903.     cmp.b    #$e,d0
  1904.     beq.s    mt_filter
  1905.     cmp.b    #$d,d0
  1906.     beq.s    mt_pattbreak
  1907.     cmp.b    #$b,d0
  1908.     beq.s    mt_songjmp
  1909.     cmp.b    #$c,d0
  1910.     beq.s    mt_setvol
  1911.     cmp.b    #$f,d0
  1912.     beq.s    mt_setspeed
  1913.     rts
  1914.  
  1915. mt_filter:
  1916.     move.b    3(a4),d0
  1917.     and.b    #1,d0
  1918.     asl.b    #1,d0
  1919.     and.b    #$fd,$bfe001
  1920.     or.b    d0,$bfe001
  1921.     rts
  1922.  
  1923. mt_pattbreak:
  1924.     move.b    #1,mt_break-Mb(a6)
  1925.     rts
  1926.  
  1927. mt_songjmp:
  1928.     move.b    #1,mt_break-MB(a6)
  1929.     move.b    3(a4),d0
  1930.     subq.b    #1,d0
  1931.     move.b    d0,mt_songpos-MB(a6)
  1932.     rts
  1933.  
  1934. mt_setvol:
  1935.     cmp.b    #$40,3(a4)
  1936.     bls.s    mt_sv2
  1937.     move.b    #$40,3(a4)
  1938. mt_sv2:    moveq    #0,d0
  1939.     move.b    3(a4),d0
  1940.     move.b    d0,$13(a4)
  1941.  
  1942.     sub.b    #$20,d0
  1943.     bpl    mt_sv22
  1944.     moveq    #0,d0
  1945. mt_sv22
  1946.     move.w    d0,8(a5)
  1947.     rts
  1948.  
  1949. mt_setspeed:
  1950.     moveq    #0,d0
  1951.     move.b    3(a4),d0
  1952.     cmp.b    #$1f,d0
  1953.     bls.s    mt_sp2
  1954.     moveq    #$1f,d0
  1955. mt_sp2:    tst.w    d0
  1956.     bne.s    mt_sp3
  1957.     moveq    #1,d0
  1958. mt_sp3:    move.b    d0,mt_speed-MB(a6)
  1959.     rts
  1960.  
  1961. mt_amhandler:
  1962.     moveq    #3,d7
  1963.  
  1964.     move.l    a4,-(sp)
  1965.     lea    mt_voice1-MB(a6),a4
  1966.     lea    $dff0a0,a5        aud0lch
  1967. mt_amloop:
  1968.     tst.w    30(a4)
  1969.     beq    mt_anrp
  1970.     move.w    34(a4),d0
  1971.     mulu    #120,d0
  1972.     add.l    mt_data2-MB(a6),d0
  1973.     move.l    d0,a0
  1974.     tst.w    38(a4)
  1975.     beq    mt_anrp
  1976.     cmp.w    #1,38(a4)
  1977.     bne.s    mt_anat
  1978.     move.w    32(a4),d0
  1979.     cmp.w    8(a0),d0
  1980.     beq.s    mt_aaeq
  1981.     cmp.w    8(a0),d0
  1982.     blt.s    mt_aaad
  1983.     move.w    10(a0),d0
  1984.     sub.w    d0,32(a4)
  1985.     move.w    32(a4),d0
  1986.     cmp.w    8(a0),d0
  1987.     bgt    mt_anxt
  1988.     move.w    8(a0),32(a4)
  1989. mt_aaeq:move.w    #2,38(a4)
  1990.     bra    mt_anxt
  1991. mt_aaad:move.w    10(a0),d0
  1992.     add.w    d0,32(a4)
  1993.     move.w    32(a4),d0
  1994.     cmp.w    8(a0),d0
  1995.     blt    mt_anxt
  1996.     move.w    8(a0),32(a4)
  1997.     bra.s    mt_aaeq
  1998. mt_anat:cmp.w    #2,38(a4)
  1999.     bne.s    mt_ana2
  2000.     move.w    32(a4),d0
  2001.     cmp.w    12(a0),d0
  2002.     beq.s    mt_a2eq
  2003.     cmp.w    12(a0),d0
  2004.     blt.s    mt_a2ad
  2005.     move.w    14(a0),d0
  2006.     sub.w    d0,32(a4)
  2007.     move.w    32(a4),d0
  2008.     cmp.w    12(a0),d0
  2009.     bgt    mt_anxt
  2010.     move.w    12(a0),32(a4)
  2011. mt_a2eq:move.w    #3,38(a4)
  2012.     bra    mt_anxt
  2013. mt_a2ad:move.w    14(a0),d0
  2014.     add.w    d0,32(a4)
  2015.     move.w    32(a4),d0
  2016.     cmp.w    12(a0),d0
  2017.     blt    mt_anxt
  2018.     move.w    12(a0),32(a4)
  2019.     bra.s    mt_a2eq
  2020. mt_ana2:cmp.w    #3,38(a4)
  2021.     bne.s    mt_andc
  2022.     move.w    32(a4),d0
  2023.     cmp.w    16(a0),d0
  2024.     beq.s    mt_adeq
  2025.     cmp.w    16(a0),d0
  2026.     blt.s    mt_adad
  2027.     move.w    18(a0),d0
  2028.     sub.w    d0,32(a4)
  2029.     move.w    32(a4),d0
  2030.     cmp.w    16(a0),d0
  2031.     bgt.s    mt_anxt
  2032.     move.w    16(a0),32(a4)
  2033. mt_adeq:move.w    #4,38(a4)
  2034.     move.w    20(a0),40(a4)
  2035.     bra.s    mt_anxt
  2036. mt_adad:move.w    18(a0),d0
  2037.     add.w    d0,32(a4)
  2038.     move.w    32(a4),d0
  2039.     cmp.w    16(a0),d0
  2040.     blt.s    mt_anxt
  2041.     move.w    16(a0),32(a4)
  2042.     bra.s    mt_adeq
  2043. mt_andc:cmp.w    #4,38(a4)
  2044.     bne.s    mt_anst
  2045.     subq.w    #1,40(a4)
  2046.     bpl.s    mt_anxt
  2047.     move.w    #5,38(a4)
  2048.     bra.s    mt_anxt
  2049. mt_anst:move.w    24(a0),d0
  2050.     sub.w    d0,32(a4)
  2051.     bpl.s    mt_anxt
  2052.     clr.l    30(a4)
  2053.     clr.w    38(a4)
  2054.     move.w    26(a4),$dff096        dmaconw
  2055. mt_anxt:move.w    32(a4),d0
  2056.     lsr.w    #2,d0
  2057.     move.w    d0,8(a5)
  2058.     move.w    28(a0),d0
  2059.     add.w    d0,16(a4)
  2060.     move.w    30(a0),d1
  2061.     beq.s    mt_nvib
  2062.     move.w    36(a4),d2
  2063.     moveq    #0,d3
  2064.     cmp.w    #360,d2
  2065.     blt.s    mt_vibq
  2066.     sub.w    #360,d2
  2067.     moveq    #1,d3
  2068. mt_vibq:move.l    mt_ams-MB(a6),a2
  2069.     muls    (a2,d2.w),d1
  2070.     asr.w    #7,d1
  2071.     tst.w    d3
  2072.     beq.s    mt_nvib
  2073.     neg.w    d1
  2074. mt_nvib:add.w    16(a4),d1
  2075.     move.w    d1,6(a5)
  2076.     move.w    32(a0),d0
  2077.     add.w    d0,d0
  2078.     add.w    d0,36(a4)
  2079.     cmp.w    #720,36(a4)
  2080.     blt.s    mt_anrp
  2081.     sub.w    #720,36(a4)
  2082. mt_anrp:lea    $10(a5),a5
  2083.     lea    42(a4),a4
  2084.     dbra    d7,mt_amloop
  2085.     move.l    mt_noise-MB(a6),a0
  2086.     move.w    #$7327,d0
  2087.     moveq    #31,d1
  2088. mt_nlop:move.b    d0,(a0)+
  2089.     add.b    $dff007,d0
  2090.     eor.w    #124,d0
  2091.     rol.w    #3,d0
  2092.     dbra    d1,mt_nlop
  2093.     move.l    (sp)+,a4
  2094.     rts
  2095.  
  2096. ; Now follows a big chunk of data. Better disable the RBsr system...
  2097.  
  2098.     RDATA
  2099.  
  2100. *********************************************************************
  2101. *        MUSIC extension data zone
  2102. MB:    
  2103. MuVu        dc.l    0        * Vu Meters
  2104. MuBase        dc.l    0        * Curretn music address
  2105. MusAdr        dc.l    0        * Branch table address
  2106. MusClock    dc.l     3546895        * Clock speed
  2107. WaveBase    dc.l    0        * Wave tree
  2108. Waves        dc.w     0,0,0,0
  2109. EnvOn:        dc.w     0        * ADSR running?
  2110. EnvBase:    ds.b    EnvLong*4    * ADSR table
  2111. SamBank:    dc.w     0        * Sample bank
  2112. BSeed:        dc.w     0        * Random seed
  2113. Noise:        dc.w    0        * Noise on?
  2114. PNoise:        dc.w    0        * Pointer to noise buffer
  2115. TempoBase:    dc.w    0        * 100 (PAL) - 120 (NTSC)
  2116. *         Musique
  2117. MusBank        dc.l     0        * Music bank
  2118. MusCheck    dc.l    0        * Check sum
  2119. BankInst    dc.l    0        * Instruments
  2120. BankSong    dc.l    0        * Songs
  2121. BankPat        dc.l     0        * Patterns
  2122. MuNumber    dc.w    0        * Music priority
  2123. MuVolume    dc.w    0        * Music volume
  2124. MuDMAsk        dc.w    0        * Voice mask
  2125. MuReStart    dc.w    0        * Restart the voice
  2126. MuChip0        dc.l    0        * Circuits 0
  2127. MuChip1        dc.l     0        *       1
  2128. MuChip2        dc.l     0        *          2
  2129. MuChip3        dc.l     0        *          3
  2130. FoEnd        dc.w    $8000        * Fake empty pattern
  2131. MuBuffer    ds.b    MuLong*3    * Music tables
  2132.  
  2133. *************** Tables for effects
  2134. Sinus    
  2135.  dc.b $00,$18,$31,$4a,$61,$78,$8d,$a1,$b4,$c5,$d4,$e0,$eb,$f4,$fa,$fd
  2136.  dc.b $ff,$fd,$fa,$f4,$eb,$e0,$d4,$c5,$b4,$a1,$8d,$78,$61,$4a,$31,$18
  2137.  
  2138. Periods    
  2139.  dc.w $0358,$0328,$02fa,$02d0,$02a6,$0280,$025c,$023a,$021a,$01fc,$01e0
  2140.  dc.w $01c5,$01ac,$0194,$017d,$0168,$0153,$0140,$012e,$011d,$010d,$00fe
  2141.  dc.w $00f0,$00e2,$00d6,$00ca,$00be,$00b4,$00aa,$00a0,$0097,$008f,$0087
  2142.  dc.w $007f,$0078,$0071,$0000,$0000
  2143.  
  2144. *************** Default enveloppes
  2145. EnvDef:        dc.w 1,64,4,55,5,50,25,0,0,0
  2146. EnvShoot    dc.w 1,64,10,0,0,0
  2147. EnvBoom        dc.w 1,64,10,50,50,0,0,0
  2148. EnvBell        dc.w 1,64,4,40,25,0,0,0
  2149.  
  2150. *************** Bank headers
  2151. BkMus:        dc.b "Music   "
  2152.  
  2153. *************** Frequency / notes
  2154. TFreq:    dc.w 000,256/2
  2155.     dc.w 000,256/2
  2156.     dc.w 256,128/2
  2157.     dc.w 384,64/2
  2158.     dc.w 448,32/2
  2159.     dc.w 480,16/2
  2160.     dc.w 496,8/2
  2161.     dc.w 504,4/2
  2162.     dc.w 504,4/2
  2163. TNotes:    dc.w 00,00,00,33,35,37,39,41,44,46,49,52
  2164.     dc.w 55,58,62,65,69,73,78,82,87,92,98,104
  2165.     dc.w 110,117,123,131,139,147,156,165,175,185,196,208
  2166.     dc.w 220,233,247,262,277,294,311,330,349,370,392,415
  2167.     dc.w 440,466,494,523,554,587,622,659,698,740,784,830
  2168.     dc.w 880,932,988,1046,1109,1175,1245,1319,1397,1480,1568,1661
  2169.     dc.w 1760,1865,1986,2093,2217,2349,2489,2637,2794,2960,3136,3322
  2170.     dc.w 3520,3729,3952,4186,4435,4699,4978,5274,5588,5920,6272,6645
  2171.     dc.w 7040,7459,7902,8372
  2172.  
  2173. *************** SAMPLE PLAYER INTERRUPT STRUCTURES
  2174. Sami_lplay    equ    1024*4
  2175. Sami_bit    equ    22
  2176. Sami_dma    equ    24
  2177. Sami_reg    equ    26
  2178. Sami_adr    equ    28
  2179. Sami_long    equ    32
  2180. Sami_pos    equ    36
  2181. Sami_rpos    equ    40
  2182. Sami_radr    equ    44
  2183. Sami_rlong    equ    48
  2184. Sami_dvol    equ    52
  2185. Sami_old    equ    54
  2186. Sami_intl    equ    58
  2187.  
  2188. Sami_int    ds.b    22                * Channel 0
  2189.         dc.w    %0000000010000000    bit
  2190.         dc.w    0            dma
  2191.         dc.w    $a0            reg
  2192.         dc.l    0            adr
  2193.         dc.l    0            long
  2194.         dc.l    0            pos
  2195.         dc.l    0            rpos
  2196.         dc.l    0            radr
  2197.         dc.l    0            rlong
  2198.         dc.w    0            dvol
  2199.         dc.l    0            old            
  2200.  
  2201.         ds.b    22                * Channel 1
  2202.         dc.w    %0000000100000000    bit
  2203.         dc.w    1            dma
  2204.         dc.w    $b0            reg
  2205.         dc.l    0            adr
  2206.         dc.l    0            long
  2207.         dc.l    0            pos
  2208.         dc.l    0            rpos
  2209.         dc.l    0            radr
  2210.         dc.l    0            rlong
  2211.         dc.w    0            dvol
  2212.         dc.l    0            old            
  2213.  
  2214.         ds.b    22                * Channel 2
  2215.         dc.w    %0000001000000000    bit
  2216.         dc.w    2            dma
  2217.         dc.w    $c0            reg
  2218.         dc.l    0            adr
  2219.         dc.l    0            long
  2220.         dc.l    0            pos
  2221.         dc.l    0            rpos
  2222.         dc.l    0            radr
  2223.         dc.l    0            rlong
  2224.         dc.w    0            dvol
  2225.         dc.l    0            old            
  2226.  
  2227.         ds.b    22                * Channel 3
  2228.         dc.w    %0000010000000000    bit
  2229.         dc.w    3            dma
  2230.         dc.w    $d0            reg
  2231.         dc.l    0            adr
  2232.         dc.l    0            long
  2233.         dc.l    0            pos
  2234.         dc.l    0            rpos
  2235.         dc.l    0            radr
  2236.         dc.l    0            rlong
  2237.         dc.w    0            dvol
  2238.         dc.l    0            old            
  2239.  
  2240. Sami_OldEna    dc.w    0
  2241. Sami_empty    dc.l    0
  2242. Sami_bits    dc.w    0
  2243. Sami_handad    dc.l    0
  2244. Sami_flag    dc.w    0
  2245. SamLoops    dc.w    0
  2246. *************** NARRATOR
  2247. Amaps:        dc.b    3,5,10,12
  2248. TranBase    dc.l    0
  2249. TalkIO:        ds.l    20
  2250. WriteRep:    ds.l    8
  2251. TranName    dc.b    "translator.library",0
  2252. NarDevice    dc.b    "narrator.device",0
  2253.  
  2254. *************** Welcome message
  2255. MusWel:        dc.b     27,"Y8Music player V 1.3",0
  2256.         even
  2257.  
  2258. *********************************************************************
  2259. *    mt TRACKER data zone
  2260.  
  2261. Track_Bank    dc.w    6        Bank number 6= tracker
  2262. sorpend        dc.b    0        turn music off if 1        
  2263. sorploop    dc.b    0        0=once:1=loop 
  2264. sorp        dc.b    0        0=song:1=patt
  2265. omt_songpos    dc.b    0
  2266.  
  2267. mt_amwave    dc.l    0        address of wave forms
  2268. mt_noise    dc.l    0        address of wave forms
  2269. mt_ams        dc.l    0        address of wave forms
  2270.     even
  2271. mt_mulu:
  2272.     dc.w    0,$1e,$3c,$5a,$78,$96,$b4,$d2,$f0,$10e,$12c,$14a
  2273.     dc.w    $168,$186,$1a4,$1c2,$1e0,$1fe,$21c,$23a,$258,$276
  2274.     dc.w    $294,$2b2,$2d0,$2ee,$30c,$32a,$348,$366,$384,$3a2
  2275.  
  2276. mt_sin:    dc.b    0,$18,$31,$4a,$61,$78,$8d,$a1,$b4,$c5,$d4,$e0,$eb,$f4
  2277.     dc.b    $fa,$fd
  2278.     dc.b    $ff,$fd,$fa,$f4,$eb,$e0,$d4,$c5,$b4,$a1,$8d,$78,$61
  2279.     dc.b    $4a,$31,$18
  2280.  
  2281. mt_arplist:
  2282.     dc.b    0,1,2,0,1,2,0,1,2,0,1,2,0
  2283.     dc.b    1,2,0,1,2,0,1,2,0,1,2,0,1,2,0,1,2,0,1
  2284.  
  2285. mt_amwaveforms:
  2286.     dc.b    0,25,49,71,90,106,117,125
  2287.     dc.b    127,125,117,106,90,71,49,25
  2288.     dc.b    0,-25,-49,-71,-90,-106,-117
  2289.     dc.b    -125,-127,-125,-117,-106
  2290.     dc.b    -90,-71,-49,-25
  2291.     dc.b    -128,-120,-112,-104,-96,-88,-80,-72,-64,-56,-48
  2292.     dc.b    -40,-32,-24,-16,-8,0,8,16,24,32,40,48,56,64,72,80
  2293.     dc.b    88,96,104,112,120
  2294.     dc.b    -128
  2295.     dc.b    -128
  2296.     dc.b    -128
  2297.     dc.b    -128
  2298.     dc.b    -128
  2299.     dc.b    -128
  2300.     dc.b    -128
  2301.     dc.b    -128
  2302.     dc.b    -128
  2303.     dc.b    -128
  2304.     dc.b    -128
  2305.     dc.b    -128
  2306.     dc.b    -128
  2307.     dc.b    -128
  2308.     dc.b    -128
  2309.     dc.b    -128
  2310.     
  2311.     
  2312.     dc.b    127
  2313.     dc.b    127
  2314.     dc.b    127
  2315.     dc.b    127
  2316.     dc.b    127
  2317.     dc.b    127
  2318.     dc.b    127
  2319.     dc.b    127
  2320.     dc.b    127
  2321.     dc.b    127
  2322.     dc.b    127
  2323.     dc.b    127
  2324.     dc.b    127
  2325.     dc.b    127
  2326.     dc.b    127
  2327.     dc.b    127
  2328.     
  2329. mt_noisewave:
  2330.     dc.b    0
  2331.     dc.b    0
  2332.     dc.b    0
  2333.     dc.b    0
  2334.     dc.b    0
  2335.     dc.b    0
  2336.     dc.b    0
  2337.     dc.b    0
  2338.     dc.b    0
  2339.     dc.b    0
  2340.     dc.b    0
  2341.     dc.b    0
  2342.     dc.b    0
  2343.     dc.b    0
  2344.     dc.b    0
  2345.     dc.b    0
  2346.     dc.b    0
  2347.     dc.b    0
  2348.     dc.b    0
  2349.     dc.b    0
  2350.     dc.b    0
  2351.     dc.b    0
  2352.     dc.b    0
  2353.     dc.b    0
  2354.     dc.b    0
  2355.     dc.b    0
  2356.     dc.b    0
  2357.     dc.b    0
  2358.     dc.b    0
  2359.     dc.b    0
  2360.     dc.b    0
  2361.     dc.b    0
  2362.  
  2363. mt_amsinus:
  2364.     dc.w    0,2,4,6,8,$b,$d,$f,$11,$14,$16,$18,$1a,$1c,$1e,$21
  2365.     dc.w    $23,$25,$27,$29,$2b,$2d,$2f,$32,$34,$36,$38,$3a,$3c,$3e
  2366.     dc.w    $3f,$41,$43,$45,$47,$49,$4b,$4d,$4e,$50,$52,$53,$55,$57
  2367.     dc.w    $58,$5a,$5c,$5d,$5f,$60,$62,$63,$64,$66,$67,$68,$6a,$6b
  2368.     dc.w    $6c,$6d,$6e,$6f,$71,$72,$73,$74,$74,$75,$76,$77,$78,$79
  2369.     dc.w    $79,$7a,$7b,$7b,$7c,$7c,$7d,$7d,$7e,$7e,$7e,$7f,$7f,$7f
  2370.     dc.w    $7f,$7f,$7f,$7f,$80,$7f,$7f,$7f,$7f,$7f,$7f,$7f,$7e,$7e
  2371.     dc.w    $7e,$7d,$7d,$7c,$7c,$7b,$7b,$7a,$79,$79,$78,$77,$76,$75
  2372.     dc.w    $74,$73,$72,$71,$6f,$6e,$6d,$6c,$6b,$6a,$68,$67,$66,$64
  2373.     dc.w    $63,$62,$60,$5f,$5d,$5c,$5a,$58,$57,$55,$53,$52,$50,$4e
  2374.     dc.w    $4d,$4b,$49,$47,$45,$43,$41,$40,$3e,$3c,$3a,$38,$36,$34
  2375.     dc.w    $32,$2f,$2d,$2b,$29,$27,$25,$23,$21,$1e,$1c,$1a,$18,$16
  2376.     dc.w    $14,$11,$f,$d,$b,$8,$6,$4,$2,0
  2377.     
  2378. mt_periods:
  2379.     dc.w    $358,$328,$2fa,$2d0,$2a6,$280,$25c,$23a,$21a,$1fc,$1e0
  2380.     dc.w    $1c5,$1ac,$194,$17d,$168,$153,$140,$12e,$11d,$10d,$fe
  2381.     dc.w    $f0,$e2,$d6,$ca,$be,$b4,$aa,$a0,$97,$8f,$87
  2382.     dc.w    $7f,$78,$71,0
  2383.     
  2384.  
  2385.  
  2386. mt_speed:    dc.b    6
  2387. mt_counter:    dc.b    0
  2388. mt_pattpos:    dc.w    0
  2389. mt_songpos:    dc.b    0
  2390. mt_break:    dc.b    0
  2391. mt_dmacon:    dc.w    0
  2392. mt_samplestarts:
  2393.         dc.l    0
  2394.         dc.l    0
  2395.         dc.l    0
  2396.         dc.l    0
  2397.         dc.l    0
  2398.         dc.l    0
  2399.         dc.l    0
  2400.         dc.l    0
  2401.         dc.l    0
  2402.         dc.l    0
  2403.         dc.l    0
  2404.         dc.l    0
  2405.         dc.l    0
  2406.         dc.l    0
  2407.         dc.l    0
  2408.         dc.l    0
  2409.         dc.l    0
  2410.         dc.l    0
  2411.         dc.l    0
  2412.         dc.l    0
  2413.         dc.l    0
  2414.         dc.l    0
  2415.         dc.l    0
  2416.         dc.l    0
  2417.         dc.l    0
  2418.         dc.l    0
  2419.         dc.l    0
  2420.         dc.l    0
  2421.         dc.l    0
  2422.         dc.l    0
  2423.         dc.l    0
  2424.  
  2425.  
  2426.  
  2427. mt_voice1:
  2428.         dc.w    0
  2429.         dc.w    0
  2430.         dc.w    0
  2431.         dc.w    0
  2432.         dc.w    0
  2433.         dc.w    0
  2434.         dc.w    0
  2435.         dc.w    0
  2436.         dc.w    0
  2437.         dc.w    0
  2438.         dc.w    0
  2439.         dc.w    0
  2440.         dc.w    0
  2441.         dc.w    1
  2442.         dc.w    0
  2443.         dc.w    0
  2444.         dc.w    0
  2445.         dc.w    0
  2446.         dc.w    0
  2447.         dc.w    0
  2448.         dc.w    0
  2449. mt_voice2:
  2450.         dc.w    0
  2451.         dc.w    0
  2452.         dc.w    0
  2453.         dc.w    0
  2454.         dc.w    0
  2455.         dc.w    0
  2456.         dc.w    0
  2457.         dc.w    0
  2458.         dc.w    0
  2459.         dc.w    0
  2460.         dc.w    0
  2461.         dc.w    0
  2462.         dc.w    0
  2463.         dc.w    2
  2464.         dc.w    0
  2465.         dc.w    0
  2466.         dc.w    0
  2467.         dc.w    0
  2468.         dc.w    0
  2469.         dc.w    0
  2470.         dc.w    0
  2471. mt_voice3:
  2472.         dc.w    0
  2473.         dc.w    0
  2474.         dc.w    0
  2475.         dc.w    0
  2476.         dc.w    0
  2477.         dc.w    0
  2478.         dc.w    0
  2479.         dc.w    0
  2480.         dc.w    0
  2481.         dc.w    0
  2482.         dc.w    0
  2483.         dc.w    0
  2484.         dc.w    0
  2485.         dc.w    4
  2486.         dc.w    0
  2487.         dc.w    0
  2488.         dc.w    0
  2489.         dc.w    0
  2490.         dc.w    0
  2491.         dc.w    0
  2492.         dc.w    0
  2493. mt_voice4:    
  2494.         dc.w    0
  2495.         dc.w    0
  2496.         dc.w    0
  2497.         dc.w    0
  2498.         dc.w    0
  2499.         dc.w    0
  2500.         dc.w    0
  2501.         dc.w    0
  2502.         dc.w    0
  2503.         dc.w    0
  2504.         dc.w    0
  2505.         dc.w    0
  2506.         dc.w    0
  2507.         dc.w    8
  2508.         dc.w    0
  2509.         dc.w    0
  2510.         dc.w    0
  2511.         dc.w    0
  2512.         dc.w    0
  2513.         dc.w    0
  2514.         dc.w    0
  2515.  
  2516.  
  2517. mt_on        dc.b    0
  2518.         even
  2519.  
  2520. colour        dc.w    0
  2521.  
  2522. mt_data dc.l    0
  2523. mt_data2 dc.l    0
  2524.  
  2525.  
  2526. **********************************************************************
  2527. ; Please leave 1 or two labels free for future extension. You never
  2528. ; know!
  2529. L1
  2530.  
  2531. ; Now follow all the music routines. Some are just routines called by others,
  2532. ; some are instructions. 
  2533. ; See how a adress the internal music datazone, by using a base register
  2534. ; (usually A3) and adding the offset of the data in the datazone...
  2535.  
  2536. ; >>> How to get the parameters for the instruction?
  2537. ;
  2538. ; When an instruction or function is called, you get the parameters
  2539. ; pushed in A3. Remember that you unpile them in REVERSE order than
  2540. ; the instruction syntax.
  2541. ; As you have a entry point for each set of parameters, you know
  2542. ; how many are pushed...
  2543. ;    - INTEGER:    move.l    (a3)+,d0
  2544. ;    - STRING:    move.l    (a3)+,a0
  2545. ;            move.w    (a0)+,d0
  2546. ;        A0---> start of the string.
  2547. ;        D0---> length of the string
  2548. ;    - FLOAT:    move.l    (a3)+,d0
  2549. ;        fast floatting point format.
  2550. ;
  2551. ; IMPORTANT POINT: you MUST unpile the EXACT number of parameters,
  2552. ; to restore A3 to its original level. If you do not, you will not
  2553. ; have a immediate error, and AMOS will certainely crash on next
  2554. ; UNTIL / WEND / ENDIF / NEXT etc... 
  2555. ;
  2556. ; So, your instruction must:
  2557. ;    - Unpile the EXACT number of parameters from A3, and exit with
  2558. ;    A3 at the original level it was before collecting your parameters)
  2559. ;    - Preserve A4, A5 and A6
  2560. ; You can use D0-D7/A0-A2 freely...
  2561. ;
  2562. ; You can jump to the error routine without thinking about A3 if an error
  2563. ; occurs in your routine (via a RBra of course). BUT A4, A5 and A6 registers
  2564. ; MUST be preserved!
  2565. ;
  2566. ; You end must end by a RTS.
  2567. ;
  2568. ; >>> Functions, how to return the parameter?
  2569. ;
  2570. ; To send a function`s parameter back to AMOS, you load it in D3,
  2571. ; and put its type in D2:
  2572. ;    moveq    #0,d2    for an integer
  2573. ;    moveq    #1,d2    for a float
  2574. ;    moveq    #2,d2    for a string
  2575. ;
  2576.  
  2577. ******* Stop sound routine
  2578. L_MOff        equ    2
  2579. L2    lea    Circuits,a0
  2580.     move.w    #%0000011110000000,IntEna(a0)     * No more interrupts
  2581.     move.w    MuDMAsk-MB(a3),d0
  2582.     beq.s    MOf3
  2583.     move.w    d0,DmaCon(a0)
  2584.     moveq    #3,d1
  2585. MOf1    btst    d1,d0
  2586.     beq.s    MOf2
  2587.     move.w    #2,$a4(a0)
  2588.     clr.w    $a8(a0)
  2589. MOf2    lea    $10(a0),a0
  2590.     dbra    d1,MOf1
  2591. MOf3    rts
  2592.  
  2593. ***********************************************************
  2594. *    NARRATOR!
  2595.  
  2596. ******* Open narrator
  2597. L_OpNar        equ    3
  2598. L3    DLoad    a0
  2599.     move.l    TranBase-MB(a0),d0
  2600.     bne.s    OpNarOk
  2601.     movem.l    a3-a6,-(sp)
  2602.  
  2603.     move.l    a0,a3
  2604.     sub.l    a1,a1            * Narrator.device
  2605.     move.l    $4,a6
  2606.     jsr    FindTask(a6)
  2607.     lea    WriteRep-MB(a3),a1
  2608.     move.l    d0,$10(a1)
  2609.     jsr    AddPort(a6)
  2610.     lea    TalkIo-MB(a3),a1
  2611.     moveq    #0,d0
  2612.     moveq    #0,d1
  2613.     lea    NarDevice-MB(a3),a0
  2614.     jsr    OpenDev(a6)
  2615.     tst.l    d0
  2616.     bne    OpNarE
  2617.     Rbsr    L_NarInit
  2618.     lea    TranName-MB(a3),a1    * Translator.library
  2619.     moveq    #0,d0
  2620.     jsr    OpenLib(a6)
  2621.     move.l    d0,TranBase-MB(a3)
  2622.     beq    OpNarE
  2623. * Restore Sami interrupts
  2624.     move.l    DosBase(a5),a6
  2625.     moveq    #50,d1
  2626.     jsr    -198(a6)
  2627.     clr.w    Sami_Flag-MB(a3)
  2628.     RBsr    L_Sami_Install
  2629. * Ok!
  2630.     movem.l    (sp)+,a3-a6
  2631. OpNarOk    rts
  2632. OpNarE    movem.l    (sp)+,a3-a6
  2633. NoNar    moveq    #7,d0
  2634.     Rbra    L_Custom
  2635.  
  2636. ******* Init narrator (if here)!
  2637. L_NarInit    equ    4
  2638. L4    lea    TalkIO-MB(a3),a1
  2639.     lea    WriteRep-MB(a3),a0
  2640.     move.l    a0,14(a1)
  2641.     move.w    #150,48(a1)
  2642.     move.w    #110,50(a1)
  2643.     clr.w    52(a1)
  2644.     clr.w    54(a1)
  2645.     lea    Amaps-MB(a3),a0
  2646.     move.l    a0,56(a1)
  2647.     move.w    #4,60(a1)
  2648.     move.w    #63,62(a1)
  2649.     move.w    #22200,64(a1)
  2650.     rts
  2651.  
  2652. ******* SAY a$[,multi]
  2653. L_ISay2:    equ    5
  2654. L5    Rbsr    L_OpNar
  2655.     move.l    (a3)+,d7
  2656.     RBra    L_ISay
  2657. L_ISay1:    equ    6
  2658. L6    Rbsr    L_OpNar
  2659.     moveq    #0,d7    
  2660.     Rbra    L_ISay
  2661. L_ISay:        equ    7
  2662. L7    moveq    #%0000,d0
  2663.     Rbsr    L_StopDma
  2664.     Rbsr    L_VOnOf
  2665.     DLoad    a0
  2666.     clr.w    EnvOn-MB(a0)
  2667.     clr.w    Noise-MB(a0)
  2668.     move.l    (a3)+,a0
  2669.     moveq    #0,d0
  2670.     move.w    (a0)+,d0
  2671. * Phoneme?
  2672.     cmp.b    #"~",(a0)
  2673.     bne.s    ISayN
  2674.     addq.l    #1,a0
  2675.     move.l    Buffer(a5),a1
  2676.     move.w    d0,d1
  2677.     cmp.w    #1024,d1
  2678.     bcc    ISayN
  2679.     subq.w    #2,d1
  2680.     bmi.s    ISayN
  2681. ISayP    move.b    (a0)+,(a1)+
  2682.     dbra    d1,ISayP
  2683.     move.b    #"Q",(a1)+
  2684.     move.b    #"#",(a1)+
  2685.     move.b    #"U",(a1)+
  2686.     clr.b    (a1)+
  2687.     clr.b    (a1)+
  2688.     addq.w    #4,d0
  2689.     movem.l    a3/a6,-(sp)
  2690.     DLoad    a3
  2691.     bra.s    ISayNn
  2692. * Call TRANSLATOR
  2693. ISayN    move.l    Buffer(a5),a1
  2694.     move.l    a1,a2
  2695.     move.l    #1024,d1
  2696.     move.l    d1,d2
  2697.     lsr.w    #2,d2
  2698.     subq.w    #2,d2
  2699. ISayN1    clr.l    (a2)+
  2700.     dbra    d2,ISayN1
  2701.     movem.l    a3/a6,-(sp)
  2702.     DLoad    a3
  2703.     move.l    TranBase-MB(a3),a6
  2704.     jsr    Translate(a6)
  2705.     tst.w    d0
  2706.     bne.s    SayX
  2707.     move.l    #1024,d0
  2708. ISayNn
  2709.     Rbsr    L_Sami_remove
  2710.     lea    TalkIO-MB(a3),a1
  2711.     move.w    #3,28(a1)
  2712.     move.l    d0,36(a1)
  2713.     move.l    Buffer(a5),40(a1)
  2714.     move.l    ExecBase,a6
  2715. ;    tst.w    d7
  2716. ;    bne.s    ISayA
  2717.     jsr    DoIO(a6)
  2718. ;    bra.s    SayX
  2719. ;ISayA    jsr    SendIO(a6)
  2720. SayX    RBsr    L_Sami_install
  2721.     movem.l    (sp)+,a3/a6
  2722.     moveq    #%1111,d0
  2723.     Rbsr    L_VOnOf
  2724.     rts
  2725. ******* SET TALK sex,mode,pitch,rate
  2726. L_ITalk        equ    8
  2727. L8    Rbsr    L_OpNar
  2728.     move.l    #EntNul,d0
  2729.     Dlea    TalkIO,a1
  2730.     move.l    (a3)+,d1
  2731.     cmp.l    d0,d1
  2732.     beq.s    IRd1
  2733.     cmp.w    #40,d1
  2734.     Rbcs    L_IFonc
  2735.     cmp.w    #400,d1
  2736.     Rbhi    L_IFonc
  2737.     move.w    d1,48(a1)
  2738. IRd1    move.l    (a3)+,d1
  2739.     cmp.l    d0,d1
  2740.     beq.s    IRd2
  2741.     cmp.w    #65,d1
  2742.     Rbcs    L_IFonc
  2743.     cmp.w    #320,d1
  2744.     Rbhi    L_IFonc
  2745.     move.w    d1,50(a1)
  2746. IRd2    move.l    (a3)+,d1
  2747.     cmp.l    d0,d1
  2748.     beq.s    IRd3
  2749.     and.w    #$0001,d1
  2750.     move.w    d1,52(a1)
  2751. IRd3    move.l    (a3)+,d1
  2752.     cmp.l    d0,d1
  2753.     beq.s    IRd4
  2754.     and.w    #$0001,d1
  2755.     move.w    d1,54(a1)
  2756. IRd4    rts
  2757.  
  2758. L9
  2759. L10
  2760.  
  2761. ***********************************************************
  2762. *    MUSIC INSTRUCTION
  2763.  
  2764. *******    BELL
  2765. L_Bell0        equ    11
  2766. L11    moveq    #0,d3
  2767.     moveq    #70,d2
  2768.     moveq    #%1111,d1
  2769.     moveq    #1,d5
  2770.     Dlea    EnvBell,a0
  2771.     move.l    a0,d6
  2772.     Rbra    L_GoBel
  2773. L_Bell1        equ    12
  2774. L12    moveq    #0,d3
  2775.     move.l    (a3)+,d2
  2776.     moveq    #%1111,d1
  2777.     moveq    #1,d5
  2778.     Dlea    EnvBell,a0
  2779.     move.l    a0,d6
  2780.     Rbra    L_GoBel
  2781. ******* BOOM
  2782. L_Boom        equ    13
  2783. L13    moveq    #0,d3
  2784.     moveq    #36,d2
  2785.     moveq    #0,d5
  2786.     Dlea    EnvBoom,a0
  2787.     move.l    a0,d6
  2788.     Rbra    L_Shout
  2789. ******* SHOOT
  2790. L_Shoot        equ    14
  2791. L14    moveq    #0,d3
  2792.     moveq    #60,d2
  2793.     moveq    #0,d5
  2794.     Dlea    EnvShoot,a0
  2795.     move.l    a0,d6
  2796.     Rbra    L_Shout
  2797. * Gives a stereo effect
  2798. L_Shout:    equ    15
  2799. L15    moveq    #%0000,d0
  2800.     Rbsr    L_StopDma
  2801.     Rbsr    L_VOnOf
  2802.     moveq    #%1000,d1
  2803. Shot    movem.l    d0-d7,-(sp)
  2804.     Rbsr    L_GoShot
  2805.     movem.l    (sp)+,d0-d7
  2806.     addq.w    #1,d2
  2807.     lsr.w    #1,d1
  2808.     bcc.s    Shot
  2809.     rts
  2810.  
  2811. *******    VOLUME n
  2812. L_IVol1        equ    16
  2813. L16    move.l    (a3)+,d0
  2814.     moveq    #%1111,d1
  2815.     Rbsr    L_Vol
  2816.     Rbsr    L_MVol
  2817.     rts
  2818. ******* VOLUME voice,n
  2819. L_IVol2        equ    17
  2820. L17    move.l    (a3)+,d0
  2821.     move.l    (a3)+,d1
  2822.     Rbra    L_Vol
  2823. * Set voices volume level
  2824. L_Vol        equ    18
  2825. L18    cmp.l    #64,d0
  2826.     Rbcc    L_IFonc
  2827.     moveq    #0,d2
  2828.     Dlea    EnvBase,a0
  2829.     Dlea    Sami_int,a1
  2830. Vol1    btst    d2,d1
  2831.     beq.s    Vol2
  2832.     move.w    d0,EnvDVol(a0)
  2833.     tst.w    Sami_dvol(a1)
  2834.     bmi.s    Vol2
  2835.     move.w    d0,Sami_dvol(a1)
  2836. Vol2    lea    EnvLong(a0),a0
  2837.     lea    Sami_intl(a1),a1
  2838.     addq.w    #1,d2
  2839.     cmp.w    #4,d2
  2840.     bcs.s    Vol1
  2841.     rts
  2842.  
  2843. L19
  2844.  
  2845. *******    PLAY note,length
  2846. L_IPlay2    equ    20
  2847. L20    move.l    (a3)+,d3
  2848.     Rbmi    L_IFonc
  2849.     move.l    (a3)+,d2
  2850.     moveq    #%1111,d1
  2851.     moveq    #-1,d5
  2852.     moveq    #0,d6
  2853.     Rbra    L_GoBel
  2854. ******* Play voice,note,length
  2855. L_IPlay3    equ    21
  2856. L21    move.l    (a3)+,d3
  2857.     Rbmi    L_IFonc
  2858.     move.l    (a3)+,d2
  2859.     move.l    (a3)+,d1
  2860.     moveq    #-1,d5
  2861.     moveq    #0,d6
  2862.     Rbra    L_GoBel
  2863. L_GoBel        equ    22
  2864. L22    cmp.l    #96,d2            * <96?
  2865.     Rbhi    L_IFonc
  2866.     move.w    d1,d0            * Stop voices
  2867.     eor.w    #$000F,d0
  2868.     Rbsr    L_StopDma
  2869.     Rbsr    L_VOnOf
  2870.     Rbra    L_GoShot
  2871. L_GoShot    equ    23
  2872. L23    move.l    a3,-(sp)
  2873.     lea    Circuits,a2
  2874.     Dload    a3
  2875.     move.w    EnvOn-MB(a3),d7
  2876.     clr.w    EnvOn-MB(a3)
  2877.     move.w    #$8000,Sami_Bits-MB(a3)
  2878. * Explores all 4 voices
  2879.     moveq    #0,d0
  2880.     move.w    d1,d4
  2881.     moveq    #3,d1
  2882. IPl1    btst    d1,d4
  2883.     beq.s    IPl2
  2884.     Rbsr    L_VPlay
  2885. IPl2    dbra    d1,IPl1
  2886. ******* Start!
  2887. IPlX    Rbsr    L_DmaWait
  2888.     bset    #15,d0
  2889.     move.w    d0,DmaCon(a2)
  2890.     move.w    Sami_bits-MB(a3),IntEna(a2)
  2891.     move.w    d7,EnvOn-MB(a3)
  2892.     move.l    (sp)+,a3
  2893. * Wait?
  2894.     tst.l    d3
  2895.     beq.s    IPlX1
  2896.     Rjsr    L_WaitRout
  2897. IPlX1    rts
  2898.  
  2899. ******* Play voice D1: WAVE orSAMPLE
  2900. L_VPlay        equ    24
  2901. L24    movem.l    d0-d6/a0-a2,-(sp)
  2902.  
  2903.     moveq    #0,d3
  2904.     bset    d1,d3
  2905.     move.w    d3,DmaCon(a2)        * Stop voice
  2906.     lsl.w    #7,d3
  2907.     move.w    d3,IntEna(a2)        * Stop interrupts
  2908.     bclr    d1,Noise-MB(a3)        * No more random
  2909.     
  2910.     tst.w    d2
  2911.     beq    VSil
  2912.     addq.w    #3,d2
  2913.     move.w    d5,d0            * Forced wave? (bell)
  2914.     bpl.s    VPl0
  2915.     move.w    d1,d0            * Wave or Sample?
  2916.     lsl.w    #1,d0
  2917.     lea    Waves-MB(a3),a0
  2918.     move.w    0(a0,d0.w),d0
  2919.     bmi    VPl2
  2920.  
  2921. * Play WAVE!
  2922. VPl0    beq    VPl4
  2923.     lea    $a0(a2),a2
  2924.     move.w    d1,d3
  2925.     lsl.w    #4,d3
  2926.     add.w    d3,a2            * a2-> I/O
  2927.     movem.l    d1-d3/a2,-(sp)
  2928.     move.w    d0,d1
  2929.     Rbsr    L_WaveAd
  2930.     Rbeq    L_WNDef
  2931.     move.l    a2,a1
  2932.     movem.l    (sp)+,d1-d3/a2
  2933.     pea    WaveEnv(a1)
  2934.     lea    WaveDeb(a1),a1
  2935.     subq.w    #1,d2
  2936.     move.w    d2,d3
  2937.     ext.l    d3
  2938.     divu    #12,d3
  2939.     lsl.w    #2,d3
  2940.     lea    TFreq-MB(a3),a0
  2941.     add.w    d3,a0
  2942.     add.w    (a0)+,a1
  2943.     move.l    a1,(a2)            * AudAd
  2944.     move.w    (a0)+,d3
  2945.     move.w    d3,4(a2)        * AudLen
  2946.     lsl.w    #1,d3
  2947.     lea    TNotes-MB(a3),a1
  2948.     lsl.w    #1,d2
  2949.     mulu    0(a1,d2.w),d3
  2950.     move.l    MusClock-MB(a3),d2
  2951.     divu    d3,d2
  2952.     cmp.w    #124,d2
  2953.     bcc.s    VPl1
  2954.     moveq    #124,d2
  2955. VPl1:    move.w    d2,6(a2)        * AudPer
  2956. * Start enveloppe 
  2957.     move.l    (sp)+,d5
  2958.     tst.l    d6            * Fixed enveloppe? (bell / shoot)
  2959.     bne.s    VPl1a
  2960.     move.l    d5,d6
  2961. VPl1a    lea    EnvBase-MB(a3),a0    
  2962.     move.w    d1,d0
  2963.     mulu    #EnvLong,d0
  2964.     add.w    d0,a0
  2965.     move.l    d6,EnvAd(a0)
  2966.     move.l    d6,EnvDeb(a0)
  2967.     clr.w    EnvVol(a0)
  2968.     Rbsr    L_MuIntE
  2969.     movem.l    (sp)+,a0-a2/d0-d6
  2970.     bset    d1,d0
  2971.     bset    d1,d7
  2972.     rts
  2973. ******* Silence!
  2974. VSil    moveq    #0,d0
  2975.     bset    d1,d0
  2976.     move.w    d0,DmaCon(a2)
  2977.     movem.l    (sp)+,a0-a2/d0-d6
  2978.     bclr    d1,d7
  2979.     rts
  2980. ******* Play SAMPLE
  2981. VPl2    move.l    a2,-(sp)
  2982.     move.w    d2,-(sp)
  2983.     neg.w    d0
  2984.     Rbsr    L_GetSam
  2985.     move.w    (sp)+,d0
  2986.     move.l    (sp)+,a2
  2987.     moveq    #0,d6
  2988. VPl3    lea    TNotes-MB(a3),a0
  2989.     lsl.w    #1,d0
  2990.     mulu    -2(a0,d0.w),d3
  2991.     divu    #440,d3
  2992.     and.l    #$0000FFFF,d3
  2993.     Rbra    L_SPl0
  2994. ******* Play NOISE
  2995. VPl4    bset    d1,Noise-MB(a3)
  2996.     move.w    d2,d0
  2997.     move.l    WaveBase-MB(a3),a1
  2998.     lea    WaveEnv(a1),a0
  2999.     lea    WaveDeb(a1),a1
  3000.     move.l    #LNoise,d2
  3001.     move.l    #2000,d3
  3002.     tst.l    d6
  3003.     bne.s    VPl3
  3004.     move.l    a0,d6
  3005.     bset    #0,d6
  3006.     bra.s    VPl3
  3007.  
  3008. ******* PLAY OFF (voice)
  3009. L_IPlOf0    equ    25
  3010. L25    moveq    #%1111,d0
  3011.     Rbra    L_PlOf
  3012. L_IPlOf1    equ    26
  3013. L26    move.l    (a3)+,d0
  3014.     Rbra    L_Plof
  3015. L_PlOf        equ    27
  3016. L27    move.l    a3,-(sp)
  3017.     Dload    a3
  3018.     Rbsr    L_EnvOff
  3019.     move.l    (sp)+,a3
  3020.     rts
  3021.  
  3022. ******* Attente DMA
  3023. L_DmaWait    equ    28
  3024. L28    movem.l    d2-d3,-(sp)
  3025.  
  3026. ; A modifier!!! Demander les caracteristiques du DMA!!!
  3027. ;    move.w    #$200,d0
  3028. ;.loop    nop
  3029. ;    dbra    d0,.loop
  3030.  
  3031. .wait    moveq    #4,d3        
  3032. .wai2    move.b    $dff006,d2    
  3033. .wai3    cmp.b    $dff006,d2    
  3034.     beq.s    .wai3
  3035.     dbf    d3,.wai2    
  3036.     moveq    #8,d2
  3037. .wai4    dbf    d2,.wai4
  3038.  
  3039.     movem.l    (sp)+,d2-d3
  3040.     rts
  3041.  
  3042. ***********************************************************
  3043. *    SAMPLE INSTRUCTIONS
  3044.  
  3045. *******    SAM BANK n
  3046. L_ISBank    equ    29
  3047. L29    move.l    (a3)+,d0
  3048.     Rbls    L_IFonc
  3049.     cmp.l    #16,d0
  3050.     Rbhi    L_IFonc
  3051.     Dlea    SamBank,a0
  3052.     move.w    d0,(a0)
  3053.     rts
  3054. ******* SAMLOOP ON
  3055. L_ISLOn1    equ    30
  3056. L30    moveq    #0,d0
  3057.     move.l    (a3)+,d1
  3058.     Rbra    L_Sl0
  3059.  
  3060. ******* STOP DMA / INTERUPTS
  3061. *    D0= value
  3062. L_StopDma    equ    31
  3063. L31    move.w    d0,-(sp)
  3064.     eor.w    #%1111,d0
  3065.     move.w    d0,Circuits+DmaCon
  3066.     lsl.w    #7,d0
  3067.     move.w    d0,Circuits+IntEna
  3068.     move.w    (sp)+,d0
  3069.     RBra    L_DmaWait
  3070.  
  3071. L_ISLOn0    equ    32
  3072. L32    moveq    #0,d0
  3073.     moveq    #%1111,d1
  3074.     Rbra    L_Sl0
  3075.  
  3076. ******* SAMLOOP OFF
  3077. L_ISLOf1    equ    33
  3078. L33    moveq    #-1,d0
  3079.     move.l    (a3)+,d1
  3080.     Rbra    L_Sl0
  3081. L_ISLOf0    equ    34
  3082. L34    moveq    #-1,d0
  3083.     moveq    #%1111,d1
  3084.     Rbra    L_SL0
  3085. L_SL0        equ    35
  3086. L35    moveq    #0,d2
  3087.     Dlea    Sami_int,a0
  3088. Sl1    btst    d2,d1
  3089.     beq.s    Sl2
  3090.     bclr    d2,SamLoops+1-MB(a3)
  3091.     move.l    d0,Sami_rpos(a0)
  3092.     bmi.s    Sl2
  3093.     bset    d2,SamLoops+1-MB(a3)
  3094. Sl2    lea    Sami_intl(a0),a0
  3095.     addq.w    #1,d2
  3096.     cmp.w    #4,d2
  3097.     bcs.s    Sl1
  3098.     rts
  3099.  
  3100. ******* NOISE TO voice
  3101. L_INoTo        equ    36
  3102. L36    move.l    (a3)+,d1
  3103.     moveq    #0,d0
  3104.     Rbra    L_ISmt
  3105. ******* SAMPLE n TO voice
  3106. L_ISamTo    equ    37
  3107. L37    move.l    4(a3),d0
  3108.     Rbsr    L_GetSam
  3109.     move.l    (a3)+,d1
  3110.     move.l    (a3)+,d0
  3111.     neg.w    d0
  3112.     Rbra    L_Ismt
  3113. * Poke D1-> waves
  3114. L_ISmt        equ    38
  3115. L38    Dlea    Waves,a0
  3116.     moveq    #0,d2
  3117. ISmt1    btst    d2,d1
  3118.     beq.s    ISmt2
  3119.     move.w    d0,(a0)
  3120. ISmt2    addq.l    #2,a0
  3121.     addq.w    #1,d2
  3122.     cmp.w    #4,d2
  3123.     bcs.s    ISmt1
  3124.     rts
  3125.  
  3126. ******* SAM PLAY number
  3127. L_ISam1        equ    39
  3128. L39    move.l    (a3)+,d0
  3129.     Rbsr    L_GetSam
  3130.     moveq    #%1111,d1
  3131.     Rbra    L_GoSam
  3132. ******* SAM PLAY voix,number
  3133. L_ISam2        equ    40
  3134. L40    move.l    (a3)+,d0
  3135.     Rbsr    L_GetSam
  3136.     move.l    (a3)+,d1
  3137.     Rbra    L_GoSam
  3138. ******* SAM PLAY voix,number,frequence
  3139. L_ISam3        equ    41
  3140. L41    move.l    4(a3),d0
  3141.     Rbsr    L_GetSam
  3142.     move.l    (a3)+,d3
  3143.     cmp.l    #500,d3
  3144.     Rble    L_IFonc
  3145.     addq.l    #4,a3
  3146.     move.l    (a3)+,d1    
  3147.     Rbra    L_GoSam
  3148. ******* SAM RAW voice,ad,length,freq
  3149. L_ISamR        equ    42
  3150. L42    move.l    (a3)+,d3
  3151.     cmp.l    #500,d3
  3152.     Rble    L_IFonc
  3153.     move.l    (a3)+,d2
  3154.     cmp.l    #256,d2
  3155.     Rble    L_IFonc
  3156.     move.l    (a3)+,a1
  3157.     move.l    (a3)+,d1
  3158.     Rbra    L_GoSam
  3159. L_GoSam:    equ    43
  3160. L43    move.l    a3,-(sp)
  3161.     Dload    a3
  3162.  
  3163.     move.w    d1,d0
  3164.     eor.w    #$000F,d0
  3165.     Rbsr    L_StopDma
  3166.     Rbsr    L_VOnOf    
  3167.  
  3168.     lea    Circuits,a2
  3169.     move.w    EnvOn-MB(a3),d7
  3170.     clr.w    EnvOn-MB(a3)
  3171.     move.w    #$8000,Sami_bits-MB(a3)
  3172. * Do all voices
  3173.     moveq    #0,d0
  3174.     move.w    d1,d4
  3175.     moveq    #3,d1
  3176. ISp2b    btst    d1,d4
  3177.     beq.s    ISp2c
  3178.     Rbsr    L_SPlay
  3179. ISp2c    dbra    d1,ISp2b
  3180. * Start!
  3181. ISpX    
  3182.     Rbsr    L_DmaWait
  3183.     bset    #15,d0
  3184.     move.w    d0,DmaCon(a2)
  3185.     move.w    Sami_bits-MB(a3),IntEna(a2)
  3186.     move.w    d7,EnvOn-MB(a3)
  3187.     move.l    (sp)+,a3
  3188.     rts
  3189.     
  3190. ******* Find a sample -> A0
  3191. L_GetSam    equ    44
  3192. L44    move.l    d0,-(sp)
  3193.     Dload    a0
  3194.     move.w    SamBank-MB(a0),d3
  3195.     ext.l    d3
  3196.     Rbeq    L_IFonc
  3197.     Rjsr    L_BkAd
  3198.     move.l    -8(a0),d0
  3199.     cmp.l    #"Samp",d0
  3200.     Rbne    L_BNSam
  3201. * Get sample characteristics1
  3202.     move.l    (sp)+,d0
  3203.     Rbls    L_IFonc
  3204.     cmp.w    (a0),d0
  3205.     Rbhi    L_SNDef
  3206.     lsl.w    #2,d0
  3207.     move.l    2-4(a0,d0.w),d0
  3208.     Rbeq    L_SNDef
  3209.     add.l    d0,a0
  3210.     moveq    #0,d3
  3211.     move.w    8(a0),d3
  3212.     move.l    10(a0),d2
  3213.     lea    14(a0),a1
  3214.     rts
  3215.  
  3216. *********************************************************************
  3217. *    SLOAD fichier,adresse,longueur
  3218. L_Sload        equ    45
  3219. L45    move.l    (a3)+,d4
  3220.     RBmi    L_IFonc
  3221.     RJsr    L_AdOuBank
  3222.     move.l    (a3)+,d0
  3223.     cmp.l    #10,d0
  3224.     Rbcc    L_IFonc
  3225.     subq.l    #1,d0
  3226.     Rbmi    L_IFonc
  3227.     mulu    #TFiche,d0
  3228.     lea    Fichiers(a5),a2
  3229.     add.w    d0,a2
  3230.     move.l    Fha(a2),d1
  3231.     btst    #2,FhT(a2)
  3232.     Rbne    L_IFonc
  3233. * Load the data
  3234.     move.l    d3,d2
  3235.     move.l    d4,d3
  3236.     move.l    a6,-(sp)
  3237.     move.l    DosBase(a5),a6
  3238.     jsr    -42(a6)            DosRead
  3239.     move.l    (sp)+,a6
  3240.     tst.l    d0
  3241.     RBmi    L_IDError
  3242.     rts
  3243.  
  3244. ******* SAMPLAY routine
  3245. *    A1= Sample
  3246. *    D3= Freq
  3247. *    D2= Long
  3248. *    D1= Voice
  3249. L_SPlay:    equ    46
  3250. L46    movem.l    d0-d6/a0-a2,-(sp)
  3251.     bclr    d1,Noise-MB(a3)
  3252.     moveq    #0,d6
  3253.     Rbra    L_SPl0
  3254.  
  3255. L_SPl0        equ    47
  3256. L47
  3257.     movem.l    a4,-(sp)
  3258.  
  3259.     moveq    #0,d0
  3260.     bset    d1,d0            * Stop voice
  3261.     move.w    d0,DmaCon(a2)
  3262.  
  3263.     lea    Sami_int-MB(a3),a4
  3264.     move.w    #Sami_intl,d0
  3265.     mulu    d1,d0
  3266.     add.w    d0,a4            * a4-> Sami interrupts
  3267.     move.w    Sami_bit(a4),IntEna(a2)    * No more interrupts
  3268.  
  3269.     lea    EnvBase-MB(a3),a0    * Enveloppe
  3270.     move.w    d1,d0
  3271.     mulu    #EnvLong,d0
  3272.     add.w    d0,a0
  3273.  
  3274.     lea    $a0(a2),a2
  3275.     move.w    d1,d4
  3276.     lsl.w    #4,d4
  3277.     add.w    d4,a2            * a2-> I/O
  3278.  
  3279.     move.w    #1,$4(a2)
  3280.     move.l    a1,Sami_adr(a4)            * Adresse
  3281.     move.l    d2,Sami_long(a4)        * Longueur
  3282.     clr.l    Sami_pos(a4)            * Position
  3283.     clr.l    Sami_rpos(a4)            * Sam loop on?
  3284.     btst    d1,SamLoops+1-MB(a3)
  3285.     bne.s    .skipa
  3286.     subq.l    #1,Sami_rpos(a4)
  3287. .skipa    clr.l    Sami_radr(a4)            * Pas de double buffer
  3288.     
  3289.     move.l    d6,d5
  3290.     move.l    MusClock-MB(a3),d6
  3291.     bsr    Div32
  3292.     cmp.l    #124,d0
  3293.     bcc.s    .skip0
  3294.     moveq    #124,d0
  3295. .skip0    move.w    d0,6(a2)            * AudPer
  3296.  
  3297.     bclr    d1,d7
  3298.     move.w    EnvDVol(a0),Sami_dvol(a4)    * Volume, sauf si 
  3299.     tst.l    d5                  une enveloppe est
  3300.     beq.s    .skip1                  definie
  3301.     clr.l    Sami_rpos(a4)
  3302.     bclr    #0,d5
  3303.     bne.s    .skipb
  3304.     subq.l    #1,Sami_rpos(a4)
  3305. .skipb    bset    d1,d7
  3306.     move.w    #-1,Sami_dvol(a4)
  3307.     move.l    d5,EnvAd(a0)
  3308.     move.l    d5,EnvDeb(a0)
  3309.     clr.w    EnvVol(a0)
  3310.     Rbsr    L_MuIntE
  3311.  
  3312. .skip1    move.w    Sami_bit(a4),d0
  3313.     or.w    d0,Sami_bits-MB(a3)
  3314.  
  3315. * Va demarrer le son...
  3316.     lea    Circuits,a0
  3317.     move.l    a4,a1
  3318.     move.l    Sami_Handad-MB(a3),a2
  3319.     jsr    (a2)
  3320. * Fini!
  3321.     move.l    (sp)+,a4
  3322.     movem.l    (sp)+,d0-d6/a0-a2
  3323.     bset    d1,d0
  3324.     rts
  3325.  
  3326. * Division 32 bits
  3327. * D6/D3 -> D0
  3328. Div32    movem.l    d1/d3/d4/d5/d6,-(sp)
  3329.     moveq     #31,d5
  3330.         moveq     #-1,d4
  3331.         clr.l     d1
  3332. dv2:    lsl.l     #1,d6
  3333.         roxl.l     #1,d1
  3334.         cmp.l     d3,d1
  3335.         bcs.s     dv1
  3336.         sub.l     d3,d1
  3337.         lsr     #1,d4
  3338. dv1:    roxl.l     #1,d0
  3339.         dbra     d5,dv2
  3340.     movem.l    (sp)+,d1/d3/d4/d5/d6
  3341.     rts
  3342.  
  3343. ***********************************************************
  3344. *    WAVE INSTRUCTION SET
  3345.  
  3346. *******    WAVE n TO n
  3347. L_IWave:    equ    48
  3348. L48    move.l    4(a3),d1
  3349.     Rbmi    L_IFonc
  3350.     Rbsr    L_WaveAd
  3351.     Rbeq    L_WNDef
  3352.     move.l    (a3)+,d1
  3353.     move.l    (a3)+,d0
  3354.     Rbra    L_ISmt
  3355. *******    SET WAVE n,a$
  3356. L_ISWave:    equ    49
  3357. L49    move.l    (a3)+,a1
  3358.     move.w    (a1)+,d1
  3359.     cmp.w    #256,d1
  3360.     Rbcs    L_STSho
  3361.     move.l    (a3)+,d1
  3362.     Rbls    L_IFonc
  3363.     move.l    a3,-(sp)
  3364.     Dload    a3
  3365.     Rbsr    L_NeWave
  3366.     Rbne    L_IOOMem
  3367.     move.l    (sp)+,a3
  3368.     rts
  3369. *******    DEL WAVE 
  3370. L_IDWave1    equ    50
  3371. L50    move.l    (a3)+,d1
  3372.     Rbmi    L_IFonc
  3373.     Rbeq    L_W0Res
  3374.     cmp.l    #1,d1
  3375.     Rbeq    L_W0Res
  3376.     move.l    a3,-(sp)
  3377.     DLoad    a3
  3378.     moveq    #%1111,d0
  3379.     Rbsr    L_EnvOff
  3380.     Rbsr    L_WaveAd
  3381.     Rbeq    L_WNDef
  3382.     Rbsr    L_WaveDel
  3383.     Rbsr    L_NoWave
  3384.     move.l    (sp)+,a3
  3385.     rts
  3386. *******    SET ENVEL n,n TO n,v
  3387. L_ISEnv        equ    51
  3388. L51    move.l    (a3)+,d4
  3389.     cmp.l    #64,d4
  3390.     Rbcc    L_IFonc
  3391.     move.l    (a3)+,d3
  3392.     move.l    (a3)+,d5
  3393.     Rbmi    L_IFonc
  3394.     cmp.l    #7,d5
  3395.     Rbcc    L_IFonc
  3396.     move.l    (a3)+,d1
  3397.     Rbmi    L_IFonc
  3398.     tst.w    d5
  3399.     bne.s    ISe1
  3400.     tst.w    d3
  3401.     Rbls    L_IFonc
  3402. ISe1    move.l    a3,-(sp)
  3403.     Dload    a3
  3404.     Rbsr    L_WaveAd
  3405.     Rbeq    L_WNDef
  3406.     lsl.w    #2,d5
  3407.     lea    WaveEnv(a2,d5.w),a2
  3408.     move.w    d3,(a2)+
  3409.     move.w    d4,(a2)+
  3410.     clr.w    (a2)
  3411.     move.l    (sp)+,a3
  3412.     rts
  3413. ******* RAZ WAVES
  3414. L_RazWave    equ    52
  3415. L52    movem.l    a2/d0-d2,-(sp)
  3416.     moveq    #%1111,d0
  3417.     Rbsr    L_EnvOff        * Stop all voices
  3418.     lea    WaveBase-MB(a3),a2    * Erase all instruments
  3419.     move.l    a2,d2
  3420. RzW1    move.l    d2,a2
  3421.     move.l    (a2),d0
  3422.     beq.s    RzW2
  3423.     move.l    d0,a2
  3424.     Rbsr    L_WaveDel
  3425.     bra.s    RzW1
  3426. RzW2    Rbsr    L_NoWave
  3427.     movem.l    (sp)+,a2/d0-d2
  3428.     rts
  3429. * Plus de Waves speciales
  3430. L_NoWave    equ    53
  3431. L53    Dlea    Waves,a0        * Default waves
  3432.     move.w    #1,(a0)+
  3433.     move.w    #1,(a0)+
  3434.     move.w    #1,(a0)+
  3435.     move.w    #1,(a0)+
  3436.     rts
  3437.  
  3438. ******* NEW WAVES
  3439. *    A1= Array address
  3440. *    D1= # to create
  3441. L_NeWave:    equ    54
  3442. L54    movem.l    d1-d7/a1-a2,-(sp)
  3443. NeW0    Rbsr    L_WaveAd
  3444.     beq.s    NeW1
  3445.     moveq    #%1111,d0
  3446.     Rbsr    L_EnvOff
  3447.     Rbsr    L_WaveDel
  3448.     bra.s    NeW0
  3449. NeW1    move.l    #WaveLong,d0
  3450.     RJsr    L_RamChip
  3451.     beq.s    NeWE
  3452.     move.l    d0,(a2)
  3453.     move.l    d0,a2
  3454.     move.w    d1,WaveNb(a2)
  3455. * Copy default ADSR
  3456.     move.l    a1,-(sp)
  3457.     lea    EnvDef-MB(a3),a0
  3458.     lea    WaveEnv(a2),a1
  3459. NeW3    move.l    (a0)+,(a1)+
  3460.     bne.s    NeW3
  3461.     move.l    (sp)+,a1
  3462. * Full wave: 256 bytes
  3463.     lea    WaveDeb(a2),a2
  3464.     move.l    a2,a0
  3465.     moveq    #256/4-1,d0
  3466. NeW2    move.l    (a1)+,(a0)+
  3467.     dbra    d0,NeW2
  3468. * 1/2
  3469.     move.l    a2,a1
  3470.     move.l    a0,a2
  3471.     moveq    #127,d0
  3472.     bsr    NewRout
  3473. * 1/4
  3474.     move.l    a2,a1
  3475.     move.l    a0,a2
  3476.     moveq    #63,d0
  3477.     bsr    NewRout
  3478. * 1/8
  3479.     move.l    a2,a1    
  3480.     move.l    a0,a2
  3481.     moveq    #31,d0
  3482.     bsr    NewRout
  3483. * 1/16
  3484.     move.l    a2,a1
  3485.     move.l    a0,a2
  3486.     moveq    #15,d0
  3487.     bsr    NewRout
  3488. * 1/32
  3489.     move.l    a2,a1
  3490.     move.l    a0,a2
  3491.     moveq    #7,d0
  3492.     bsr    NewRout
  3493. * 1/64
  3494.     move.l    a2,a1
  3495.     move.l    a0,a2
  3496.     moveq    #3,d0
  3497.     bsr    NewRout
  3498. ******* No error
  3499.     moveq    #0,d0
  3500. NeWx    movem.l    (sp)+,d1-d7/a1-a2
  3501.     rts
  3502. ******* Out of mem
  3503. NeWE    moveq    #-1,d0
  3504.     bra.s    NeWx
  3505. ******* Divide a sample by 2
  3506. NewRout    move.b    (a1)+,d1
  3507.     ext.w    d1
  3508.     move.b    (a1)+,d2
  3509.     ext.w    d2
  3510.     add.w    d2,d1
  3511.     asr.w    #1,d1
  3512.     move.b    d1,(a0)+
  3513.     dbra    d0,NewRout
  3514.     rts
  3515.  
  3516. ******* Get a wave address
  3517. L_WaveAd:    equ    55
  3518. L55    moveq    #0,d2
  3519.     Dlea    WaveBase,a2
  3520.     move.l    (a2),d0
  3521.     beq.s    WAd2
  3522. WAd1    move.l    a2,d2
  3523.     move.l    d0,a2
  3524.     cmp.w    WaveNb(a2),d1
  3525.     beq.s    WAd3
  3526.     move.l    (a2),d0
  3527.     bne.s    WAd1
  3528. WAd2    moveq    #0,d0
  3529.     rts
  3530. WAd3    moveq    #-1,d0
  3531.     rts
  3532.  
  3533. ******* Deletion of a WAVE (A2)-D2
  3534. L_WaveDel    equ    56
  3535. L56    movem.l    a0-a2/d0-d2,-(sp)
  3536.     move.w    WaveNb(a2),d1
  3537.     move.l    d2,a0
  3538.     move.l    (a2),(a0)
  3539.     move.l    #WaveLong,d0
  3540.     move.l    a2,a1
  3541.     Rjsr    L_RamFree
  3542.     movem.l    (sp)+,a0-a2/d0-d2
  3543.     rts
  3544.  
  3545. ***********************************************************
  3546. *    STOP SAMPLES INTERRUPTS
  3547. L_Sami_stop    equ    57
  3548. L57    move.w    #%0000011110000000,d0
  3549.     move.w    d0,Circuits+IntEna
  3550.     move.w    d0,Circuits+IntReq
  3551.     rts
  3552.  
  3553. ***********************************************************
  3554. *    ENVELOPPES 
  3555.  
  3556. ***********************************************************
  3557. *    STOP ENVELOPPE D0
  3558. L_EnvOff    equ    58
  3559. L58    movem.l    d0-d3/a0,-(sp)
  3560.     move.w    EnvOn-MB(a3),d1
  3561.     clr.w    EnvOn-MB(a3)
  3562.     moveq    #0,d3
  3563.     lea    Circuits,a0
  3564.     moveq    #0,d2
  3565. EOf1    btst    d2,d0
  3566.     beq.s    EOf2
  3567.     bclr    d2,d1
  3568.     beq.s    EOf2
  3569.     bset    d2,d3
  3570.     move.w    #2,$a4(a0)
  3571.     clr.w    $a8(a0)
  3572. EOf2    lea    $10(a0),a0
  3573.     addq.w    #1,d2
  3574.     cmp.w    #4,d2
  3575.     bcs.s    EOf1
  3576.     move.w    d1,EnvOn-MB(a3)
  3577.     move.w    d3,MuReStart-MB(a3)
  3578.     movem.l    (sp)+,d0-d3/a0
  3579.     rts
  3580.     
  3581. ******* Next enveloppe
  3582. L_MuIntE    equ    59
  3583. L59    move.l    EnvAd(a0),a1
  3584. MuIe0    move.w    (a1)+,d3
  3585.     beq.s    MuIntS
  3586.     bmi.s    MuIe1
  3587.     move.w    d3,EnvNb(a0)
  3588.     move.w    EnvDVol(a0),d4
  3589.     mulu    (a1)+,d4
  3590.     lsr.w    #6,d4
  3591.     sub.w    EnvVol(a0),d4
  3592.     ext.l    d4
  3593.     lsl.w    #8,d4
  3594.     divs    d3,d4
  3595.     ext.l    d4
  3596.     lsl.l    #8,d4
  3597.     move.l    d4,EnvDelta(a0)
  3598.     clr.w    EnvVol+2(a0)
  3599.     move.l    a1,EnvAd(a0)
  3600.     rts
  3601. * Loop
  3602. MuIe1    move.l    EnvDeb(a0),a1
  3603.     bra.s    MuIe0
  3604. * End of a voice
  3605. MuIntS    bset    d1,d5
  3606.     bclr    d1,d0
  3607.     bclr    d1,Noise-MB(a3)
  3608. * Restarts the music
  3609.     bset    d1,MuReStart+1-MB(a3)
  3610.     rts
  3611.  
  3612. ******************************************************************
  3613. *    MUSIC
  3614.  
  3615. ******* Music initialisation
  3616. L_MuInit:    equ    60
  3617. L60    clr.l    MuBase-MB(a3)
  3618.     clr.w    MuNumber-MB(a3)
  3619.     move.l    #$DFF0A0,MuChip0-MB(a3)
  3620.     move.l    #$DFF0B0,MuChip1-MB(a3)
  3621.     move.l    #$DFF0C0,MuChip2-MB(a3)
  3622.     move.l    #$DFF0D0,MuChip3-MB(a3)
  3623.     move.w    #$000F,MuDMAsk-MB(a3)
  3624.     clr.w    MuReStart-MB(a3)
  3625.     Rbra    L_MOff
  3626.  
  3627. ******* MUSIC OFF-> Stops all musics
  3628. L_IMuSOff    equ    61
  3629. L61    movem.l    a0-a3/d0-d1,-(sp)
  3630.     Dload    a3
  3631.     clr.l    MuBase-MB(a3)
  3632.     clr.w    MuNumber-MB(a3)
  3633.     Rbsr    L_MOff
  3634.     movem.l    (sp)+,a0-a3/d0-d1
  3635.     rts
  3636.  
  3637. ******* MUSIC STOP-> Stops current music
  3638. L_IMuStop    equ    62
  3639. L62    movem.l    a0-a3/d0-d1,-(sp)
  3640.     Dload    a3
  3641.     move.l    MuBase-MB(a3),d0
  3642.     beq.s    IStp
  3643.     clr.w    MuBase-MB(a3)
  3644.     move.l    d0,a0
  3645.     clr.w    VoiCpt0(a0)
  3646.     clr.w    VoiCpt1(a0)
  3647.     clr.w    VoiCpt2(a0)
  3648.     clr.w    VoiCpt3(a0)
  3649.     move.l    d0,MuBase-MB(a3)
  3650. IStp    movem.l    (sp)+,a0-a3/d0-d1
  3651.     rts
  3652.  
  3653. ******* MUSIC VOLUME
  3654. L_IMVol        equ    63
  3655. L63    move.l    (a3)+,d0
  3656.     cmp.l    #64,d0
  3657.     Rbcs    L_MVol
  3658.     Rbcc    L_IFonc
  3659. * Set volume
  3660. L_MVol        equ    64
  3661. L64    and.w    #63,d0
  3662.     Dload    a0
  3663.     move.w    d0,MuVolume-MB(a0)
  3664.     move.l    MuBase-MB(a0),d4
  3665.     beq.s    MVol3
  3666.     clr.l    MuBase-MB(a0)
  3667.     lea    MuBuffer-MB(a0),a1
  3668.     move.w    MuNumber-MB(a0),d1
  3669. MVol0    move.l    a1,a2
  3670.     moveq    #3,d2
  3671. MVol1    move.w    VoiDVol(a2),d3
  3672.     mulu    d0,d3
  3673.     lsr.w    #6,d3
  3674.     move.w    d3,VoiVol(a2)
  3675.     lea    VoiLong(a2),a2
  3676.     dbra    d2,MVol1
  3677. MVol2    lea    MuLong(a1),a1
  3678.     subq.w    #1,d1
  3679.     bne.s    MVol0
  3680.     move.l    d4,MuBase-MB(a0)
  3681. MVol3    rts
  3682.  
  3683. ******* VOICE ON/OFF Voices
  3684. L_IVoice    equ    65
  3685. L65    move.l    (a3)+,d0
  3686.     and.w    #$000F,d0
  3687.     move.l    a3,-(sp)
  3688.     Dload    a3
  3689.     Rbsr    L_VOnOf
  3690.     movem.l    (sp)+,a3
  3691.     rts
  3692.  
  3693. ******* Start / Stop voices D0
  3694. L_VOnOf        equ    66
  3695. L66    movem.l    d0-d5/a0-a3,-(sp)
  3696.     move.w    d0,d4
  3697.     Dload    a3
  3698.     move.l    MuBase-MB(a3),d1
  3699.     beq.s    VooX
  3700.     clr.l    MuBase-MB(a3)
  3701.     move.l    d1,a1
  3702.     move.l    d1,a2
  3703.     move.w    MuDMAsk-MB(a3),d1
  3704.     move.w    d0,MuDMAsk-MB(a3)
  3705.     move.l    WaveBase-MB(a3),a0
  3706.     lea    WaveDeb(a0),a0
  3707.     move.l    a0,d3
  3708.     lea    MuChip0-MB(a3),a0
  3709.     moveq    #0,d2
  3710.     moveq    #0,d4
  3711. * Exploration loop
  3712. Voo1    btst    d2,d0
  3713.     bne.s    Voo2
  3714. * Stop a voice!
  3715.     btst    d2,d1            * Already stopped?
  3716.     beq.s    VooN
  3717.     bset    d2,d4
  3718.     move.l    d3,(a0)
  3719.     bclr    d2,MuStart+1(a2)
  3720.     bclr    d2,MuStop+1(a2)
  3721.     bra.s    VooN
  3722. * Re start a voice
  3723. Voo2    btst    d2,d1            * Already on?
  3724.     bne.s    VooN
  3725.     bset    d2,MuReStart+1-MB(a3)
  3726. * Next
  3727. VooN    addq.l    #4,a0
  3728.     lea    VoiLong(a1),a1
  3729.     addq.w    #1,d2
  3730.     cmp.w    #4,d2
  3731.     bcs.s    Voo1
  3732. * Stop them!
  3733.     move.l    a2,MuBase-MB(a3)
  3734.     move.w    d4,Circuits+DmaCon
  3735. VooX    movem.l    (sp)+,d0-d5/a0-a3
  3736.     rts
  3737.  
  3738. ******* MUSIC n
  3739. L_IMusic    equ    67
  3740. L67    move.l    (a3)+,d3
  3741.     Rbls    L_IFonc
  3742. * Points to the SONG
  3743.     move.l    a3,-(sp)
  3744.     Dload    a3
  3745.     tst.l    MusBank-MB(a3)
  3746.     Rbeq    L_MnRes
  3747.     move.l    BankSong-MB(a3),a1
  3748.     cmp.w    (a1),d3
  3749.     Rbhi    L_MNDef
  3750.     lsl.w    #2,d3
  3751.     add.l    2-4(a1,d3.w),a1
  3752. * Still room?
  3753.     cmp.w    #3,MuNumber-MB(a3)
  3754.     bcc    IMusX
  3755.     clr.l    MuBase-MB(a3)
  3756. * Buffer address
  3757.     move.w    MuNumber-MB(a3),d0
  3758.     move.w    d0,d1
  3759.     addq.w    #1,MuNumber-MB(a3)
  3760.     mulu    #MuLong,d0
  3761.     lea    MuBuffer-MB(a3),a2
  3762.     add.w    d0,a2
  3763. * Init datas
  3764.     moveq    #(VoiLong*4)/2-1,d0
  3765.     move.l    a2,a0
  3766. IMus1    clr.w    (a0)+
  3767.     dbra    d0,IMus1
  3768.     clr.w    MuStop(a2)
  3769.     clr.w    MuStart(a2)
  3770. * Init parameters
  3771.     move.l    a2,d2
  3772.     move.w    TempoBase-MB(a3),MuCpt(a2)
  3773.     move.w    #17,MuTempo(a2)            *XXX
  3774.     moveq    #0,d0
  3775. IMus2    move.w    #1,VoiCpt(a2)
  3776.     lea    FoEnd-MB(a3),a0
  3777.     move.l    a0,VoiAdr(a2)
  3778.     move.l    a1,a0
  3779.     add.w    0(a0,d0.w),a0
  3780.     move.l    a0,VoiPat(a2)
  3781.     move.l    a0,VoiDPat(a2)
  3782.     lea    NoEffect2(pc),a0
  3783.     move.l    a0,VoiEffect(a2)
  3784.     lea    VoiLong(a2),a2
  3785.     addq.w    #2,d0
  3786.     cmp.w    #8,d0
  3787.     bne.s    IMus2
  3788. * No more samples
  3789.     move.w    #%0000011110000000,Circuits+IntEna
  3790. * Starts music
  3791.     move.l    d2,MuBase-MB(a3)
  3792. IMusX    move.l    (sp)+,a3
  3793.     rts
  3794. NoEffect2
  3795.     move.w    VoiNote(a4),$06(a6)
  3796.     rts
  3797.  
  3798. ******* Tempo T
  3799. L_ITempo    equ    68
  3800. L68    move.l    (a3)+,d0
  3801.     cmp.l    #100,d0
  3802.     Rbhi    L_IFonc
  3803.     Dload    a0
  3804.     move.l    MuBase-MB(a0),d1
  3805.     beq.s    ITemp
  3806.     move.l    d1,a0
  3807.     move.w    d0,MuTempo(a0)
  3808. ITemp    rts
  3809.  
  3810. ***********************************************************
  3811. *    =VU METRE(v)
  3812. L_FVu        equ    69
  3813. L69    move.l    (a3)+,d0
  3814.     cmp.l    #4,d0
  3815.     Rbcc    L_IFonc
  3816.     Dload    a0
  3817.     moveq    #0,d3
  3818.     move.b    0(a0,d0.w),d3
  3819.     clr.b    0(a0,d0.w)
  3820.     moveq    #0,d2
  3821.     rts
  3822.  
  3823. ***********************************************************
  3824. *    =MU BASE
  3825. L_FMB        equ    70
  3826. L70    Dload    a0
  3827.     move.l    a0,d3
  3828.     moveq    #0,d2
  3829.     rts
  3830.  
  3831. ***********************************************************
  3832. *    LED INSTRUCTION
  3833. L_LedOn        equ    71
  3834. L71    bclr    #1,$BFE001
  3835.     rts
  3836. L_LedOf        equ    72
  3837. L72    bset    #1,$BFE001
  3838.     rts
  3839.  
  3840. ***********************************************************
  3841. *    INSTALL THE SAMPLE HANDLER
  3842. L_Sami_install    equ    73
  3843. L73    tst.w    Sami_flag-MB(a3)
  3844.     bne.s    .skip
  3845.     movem.l    d0-d2/a0-a2/a6,-(sp)
  3846.     move.l    $4.w,a6
  3847. ; Save state of interrupts
  3848.     move.w    Circuits+IntEnaR,d0
  3849.     and.w    #%0000011110000000,d0
  3850.     move.w    d0,Sami_OldEna-MB(a3)
  3851.     Rbsr    L_Sami_stop
  3852. ; Install 4 voices
  3853.     lea    Sami_int-MB(a3),a1
  3854.     moveq    #7,d0
  3855. .loop    bsr.s    Sami_start
  3856.     lea    Sami_intl(a1),a1
  3857.     addq.w    #1,d0
  3858.     cmp.w    #11,d0
  3859.     bne.s    .loop
  3860.     subq.w    #1,Sami_flag-MB(a3)
  3861.     movem.l    (sp)+,d0-d2/a0-a2/a6
  3862. .skip    rts
  3863. Sami_start
  3864.     move.l    a1,is_data(a1)
  3865.     move.l    Sami_handad-MB(a3),is_code(a1)
  3866.     move.b    #2,ln_type(a1)
  3867.     move.b    #0,ln_pri(a1)
  3868.     move.l    $4.w,a6    
  3869.     movem.l    d0/a1,-(sp)
  3870.     jsr    -162(a6)        SetIntVector
  3871.     move.l    d0,d1
  3872.     movem.l    (sp)+,d0/a1
  3873.     move.l    d1,Sami_old(a1)
  3874.     rts
  3875.  
  3876. ***********************************************************
  3877. *    REMOVE THE SAMPLE HANDLER
  3878. L_Sami_remove    equ    74
  3879. L74    tst.w    Sami_flag-MB(a3)
  3880.     beq.s    .skip
  3881.     movem.l    a0-a2/a6/d0-d2,-(sp)
  3882.     Rbsr    L_Sami_Stop
  3883.     move.l    $4.w,a6
  3884.     moveq    #7,d2
  3885.     lea    Sami_Int-MB(a3),a2
  3886. .loop    move.l    Sami_old(a2),a1
  3887.     move.l    d2,d0
  3888.     jsr    -162(a6)        SetIntVector
  3889.     lea    Sami_intl(a2),a2
  3890.     addq.w    #1,d2    
  3891.     cmp.w    #11,d2
  3892.     bne.s    .loop
  3893.     lea    Circuits,a0
  3894.     move.w    #$000F,DmaCon(a0)
  3895.     move.w    Sami_oldena-MB(a3),IntEna(a0)
  3896.     clr.w    Sami_flag-MB(a3)
  3897.     movem.l    (sp)+,a0-a2/a6/d0-d2
  3898. .skip    rts
  3899.  
  3900. ***********************************************************
  3901. *    Normal error messages
  3902. ; This routines performs jump to the normal AMOS error messages:
  3903. ; Load in D0 the number of the error, and do a RJmp to L_Error.
  3904. L_IOOMem    equ    75
  3905. L75    
  3906.     moveq    #24,d0
  3907.     Rjmp    L_Error
  3908. L_IFonc        equ    76
  3909. L76    moveq    #23,d0
  3910.     Rjmp    L_Error
  3911.  
  3912. ***********************************************************
  3913. *     Customized error messages
  3914. ; This list of routines just load in D0 the number of the error message in
  3915. ; the extension error-list, and call the error handling routine.
  3916.  
  3917. L_WNDef        equ    77
  3918. L77    moveq    #0,d0    
  3919.     Rbra    L_Custom
  3920. L_SNDef        equ    78
  3921. L78    moveq    #1,d0
  3922.     Rbra    L_Custom
  3923. L_BNSam        equ    79
  3924. L79    moveq    #2,d0
  3925.     Rbra    L_Custom
  3926. L_STSho        equ    80
  3927. L80    moveq    #3,d0
  3928.     Rbra    L_Custom
  3929. L_W0Res        equ    81
  3930. L81    moveq    #4,d0
  3931.     Rbra    L_Custom
  3932. L_MnRes        equ    82
  3933. L82    moveq    #5,d0
  3934.     Rbra    L_Custom
  3935. L_MNDef        equ    83
  3936. L83    moveq    #6,d0
  3937.     Rbra    L_Custom
  3938.  
  3939.  
  3940. ********************************************************************
  3941. *    =SAM SWAPPED(V)
  3942. L_Samswapped    equ    84
  3943. L84    move.l    (a3)+,d0
  3944.     moveq    #0,d2
  3945.     moveq    #0,d3
  3946.     cmp.l    #3,d0
  3947.     Rbhi    L_IFonc
  3948.     move.w    Circuits+IntEnaR,d1
  3949.     lsr.w    #7,d1
  3950.     btst    d0,d1
  3951.     beq.s    .stop
  3952.     Dlea    Sami_int,a0
  3953.     mulu    #Sami_intl,d0
  3954.     tst.l    Sami_radr(a0,d0.l)
  3955.     bne.s    .skip
  3956.     move.l    Sami_pos(a0,d0.l),d1
  3957.     cmp.l    #Sami_lplay,d1
  3958.     beq.s    .skip
  3959.     moveq    #-1,d3
  3960. .skip    rts
  3961. .stop    moveq    #1,d3
  3962.     rts
  3963. *********************************************************************
  3964. *    SAM SWAP
  3965. L_SamSwap    equ    85
  3966. L85    move.l    (a3)+,d4
  3967.     Rbmi    L_IFonc
  3968.     Rjsr    L_AdOuBank
  3969.     move.l    (a3)+,d2
  3970.     moveq    #0,d1
  3971.     Dlea    Sami_int,a0
  3972. .loop    btst    d1,d2
  3973.     beq.s    .skip
  3974.     move.l    d3,Sami_radr(a0)
  3975.     move.l    d4,Sami_rlong(a0)
  3976. .skip    lea    Sami_intl(a0),a0
  3977.     addq.w    #1,d1
  3978.     cmp.w    #4,d1
  3979.     bne.s    .loop
  3980.     rts
  3981. *********************************************************************
  3982. *    SAM STOP
  3983. L_SamStop0    equ    86
  3984. L86    move.l    #$f,-(a3)
  3985.     RBra    L_SamStop1
  3986. L_SamStop1    equ    87
  3987. L87    move.l    (a3)+,d1
  3988.     and.l    #$F,d1
  3989.     move.w    d1,Circuits+DmaCon
  3990.     lsl.w    #7,d1    
  3991.     move.w    d1,Circuits+IntEna
  3992.     rts
  3993.  
  3994. *********************************************************************
  3995. *    TRACKER instructions
  3996.  
  3997. *******    TRACK LOAD "nom",banque
  3998. L_Trackload    equ    88
  3999. L88
  4000.     move.l    (a3)+,d3
  4001.     subq.l    #1,d3
  4002.     cmp.l    #16,d3
  4003.     Rbcc    L_IFonc
  4004.     Dload    a0
  4005.     cmp.w    Track_Bank-MB(a0),d3
  4006.     bne.s    .kkk
  4007.     tst.b    mt_on-MB(a0)
  4008.     beq.s    .kkk
  4009.     RBsr    L_TrackStop
  4010. .kkk    move.w    d3,Track_Bank-MB(a0)    * Numero de la banque
  4011.     RJsr    L_EffBank
  4012.     lsl.w    #3,d3
  4013.     move.l    ABanks(a5),a0
  4014.     add.w    d3,a0
  4015.     move.l    a0,-(sp)
  4016. * Get name to load
  4017.     move.l    (a3)+,a0
  4018.     move.w    (a0)+,d0
  4019.     subq.w    #1,d0    
  4020.     cmp.w    #128,d0
  4021.     Rbcc    L_IFonc
  4022.     move.l    Buffer(a5),a1
  4023.     lea    128(a1),a2
  4024.     move.l    a1,d1
  4025. .loop    move.b    (a0),(a1)+
  4026.     move.b    (a0)+,(a2)+
  4027.     dbra    d0,.loop
  4028.     clr.b    (a1)
  4029.     move.b    #".",(a2)+
  4030.     move.b    #"N",(a2)+
  4031.     move.b    #"T",(a2)+
  4032.     clr.b    (a2)
  4033.     move.l    #1005,d2
  4034.     move.l    a6,-(sp)
  4035.     move.l    DosBase(a5),a6
  4036.     jsr    -30(a6)            DosOpen, fichier sons
  4037.     move.l    (sp)+,a6
  4038.     move.l    d0,d7
  4039.     Rbeq    L_IDError
  4040.     move.l    d7,d1            Trouve la taille
  4041.     bsr    .taille
  4042.     move.l    d0,d6
  4043. * Fichier des instruments
  4044.     moveq    #0,d5
  4045.     moveq    #0,d4
  4046.     move.l    Buffer(a5),d1
  4047.     add.l    #128,d1
  4048.     move.l    #1005,d2
  4049.     move.l    a6,-(sp)
  4050.     move.l    DosBase(a5),a6
  4051.     jsr    -30(a6)            DosOpen,
  4052.     move.l    (sp)+,a6
  4053.     move.l    d0,d5
  4054.     beq.s    .noins
  4055.     move.l    d5,d1            Trouve la taille
  4056.     bsr    .taille
  4057.     move.l    d0,d4
  4058. .noins
  4059. * Reserve la banque
  4060.     move.l    (sp)+,a1
  4061.     move.l    d6,d0
  4062.     add.l    d4,d0
  4063.     add.l    #16,d0
  4064.     move.l    d0,d1
  4065.     Rjsr    L_RamChip
  4066.     beq    .mem
  4067.     move.l    d0,(a1)+
  4068.     bset    #31,d1
  4069.     bset    #30,d1
  4070.     move.l    d1,(a1)+
  4071.     move.l    d0,a1
  4072.     move.l    #"Trac",(a1)+
  4073.     move.l    #"ker ",(a1)+
  4074. * Charge les instruments
  4075.     move.l    d5,d1
  4076.     beq.s    .noins2
  4077.     move.l    a1,d2
  4078.     move.l    d4,d3
  4079.     movem.l    a6/a1,-(sp)
  4080.     move.l    DosBase(a5),a6
  4081.     jsr    -42(a6)            Read
  4082.     movem.l    (sp)+,a6/a1
  4083.     move.l    d0,d2
  4084.     move.l    d5,d1
  4085.     bsr    .clo
  4086.     cmp.l    d2,d3
  4087.     Rbne    L_IFonc
  4088.     move.l    #$03011992,(a1)
  4089.     addq.l    #1,d4
  4090.     and.w    #$FFFE,d4
  4091.     move.l    d4,4(a1)
  4092.     add.l    d4,a1
  4093. .noins2
  4094. * Charge la musique
  4095.     move.l    d7,d1
  4096.     move.l    a1,d2
  4097.     move.l    d6,d3
  4098.     move.l    a6,-(sp)
  4099.     move.l    DosBase(a5),a6
  4100.     jsr    -42(a6)            Read
  4101.     move.l    (sp)+,a6
  4102.     move.l    d0,d2
  4103.     move.l    d7,d1
  4104.     bsr    .clo
  4105.     cmp.l    d2,d3
  4106.     Rbne    L_IFonc
  4107.     rts
  4108. * Ferme le fichier
  4109. .clo    movem.l    a6/a0/a1,-(sp)
  4110.     move.l    DosBase(a5),a6
  4111.     jsr    -36(a6)            Close
  4112.     movem.l    (sp)+,a6/a0/a1
  4113.     rts
  4114. * Out of memory
  4115. .mem    move.l    d5,d1
  4116.     beq.s    .xx
  4117.     bsr.s    .clo
  4118. .xx    move.l    d7,d1
  4119.     bsr.s    .clo
  4120.     RBra    L_IOOMem
  4121. * Routine, trouve la taille d'un fichier
  4122. .taille    move.l    a6,-(sp)
  4123.     move.l    d1,-(sp)
  4124.     moveq    #0,d2
  4125.     moveq    #1,d3
  4126.     move.l    DosBase(a5),a6
  4127.     jsr    -66(a6)            DosSeek
  4128.     move.l    (sp)+,d1
  4129.     move.l    d0,d2
  4130.     moveq    #-1,d3
  4131.     move.l    DosBase(a5),a6
  4132.     jsr    -66(a6)            DosSeek
  4133.     move.l    (sp)+,a6
  4134.     rts
  4135.  
  4136. ******* TRACK CHECK, arrete la musique si pas banque...
  4137. L_TrackCheck    equ    89
  4138. L89    movem.l    a0-a1,-(sp)
  4139.     DLoad    a1
  4140.     tst.b    mt_on-MB(a1)
  4141.     beq.s    .skip
  4142.     move.l    mt_data-MB(a1),a0
  4143.     cmp.l    #"ker ",-(a0)
  4144.     bne.s    .stop
  4145.     cmp.l    #"Trac",-(a0)
  4146.     beq.s    .skip
  4147. .stop    RBsr    L_TrackStop
  4148. .skip    movem.l    (sp)+,a0-a1
  4149.     rts
  4150.  
  4151. ******* TRACK STOP
  4152. L_TrackStop    equ    90
  4153. L90
  4154.     move.l    a3,-(sp)
  4155.     Dload    a3
  4156.     clr.b    mt_on-MB(a3)
  4157.     clr.w    $dff0a8
  4158.     clr.w    $dff0b8
  4159.     clr.w    $dff0c8
  4160.     clr.w    $dff0d8
  4161.     move.w    #$f,$dff096
  4162.     move.l    (sp)+,a3
  4163.     rts
  4164.  
  4165. ******* TRACK LOOP ON/OFF
  4166. L_TrackLoopon    equ    91
  4167. L91    DLea    sorploop,a0
  4168.     move.b    #1,(a0)
  4169.     rts
  4170. L_TrackLoopof    equ    92
  4171. L92    DLea    sorploop,a0
  4172.     clr.b    (a0)
  4173.     rts
  4174.  
  4175. ******* TRACK PLAY [Bank],[Pattern]
  4176.  
  4177. L_TrackPlay0    equ    93
  4178. L93
  4179.     move.l    #Entnul,-(a3)
  4180.     Rbra    94
  4181.  
  4182. L_TrackPlay1    equ    94
  4183. L94    
  4184.     clr.l    -(a3)
  4185.     Rbra    95
  4186.  
  4187. L_TrackPlay2    equ    95
  4188. L95    
  4189.     move.l    (a3)+,d7
  4190.     cmp.l    #Entnul,(a3)
  4191.     bne.s    .skip
  4192.     Dload    a0
  4193.     moveq    #0,d0
  4194.     move.w    Track_Bank-MB(a0),d0
  4195.     addq.w    #1,d0
  4196.     move.l    d0,(a3)
  4197. .skip    
  4198.     Rjsr    L_Adoubank
  4199.     move.l    d3,a2
  4200.     cmp.l    #"Trac",-8(a2)    
  4201.     bne    .nobank
  4202.     cmp.l    #"ker ",-4(a2)
  4203.     bne    .nobank
  4204.     
  4205.     Rbsr    L_SamStop0
  4206.     Rbsr    L_TrackStop
  4207.     
  4208.     move.l    a3,-(sp)
  4209.     Dload    a3
  4210.  
  4211.     moveq    #0,d1
  4212.     and.b    #$7f,d7
  4213.     move.b    d7,mt_songpos-MB(a3)
  4214.     move.b    d7,omt_songpos-MB(a3)
  4215.     beq.s    .skp
  4216.     moveq    #1,d1
  4217. .skp    move.b    d1,sorp-MB(a3)
  4218.     clr.b    sorpend-MB(a3)
  4219.     clr.w    mt_pattpos-MB(a3)        * Position dans pattern
  4220.  
  4221.     move.l    a2,a1
  4222.     clr.l    mt_data2-MB(a3)
  4223.     cmp.l    #$03011992,(a2)        Des instruments?
  4224.     bne.s    .skd
  4225.     move.l    4(a2),d0        Prend l'adresse
  4226.     lea    0(a2,d0.l),a1
  4227.     lea    24(a2),a2
  4228.     move.l    a2,mt_data2-MB(a3)
  4229. .skd
  4230.     move.l    a1,mt_data-MB(a3)
  4231.     lea    (a1),a0
  4232.     lea    $3b8(a0),a1
  4233.     moveq    #$7f,d0
  4234.     moveq    #0,d2
  4235.     moveq    #0,d1
  4236. .mt_lop2:
  4237.     move.b    (a1)+,d1
  4238.     cmp.b    d2,d1
  4239.     ble.s    .mt_lop
  4240.     move.l    d1,d2
  4241. .mt_lop:    
  4242.     dbf    d0,.mt_lop2
  4243.     addq.b    #1,d2
  4244.     asl.l    #8,d2
  4245.     asl.l    #2,d2
  4246.     lea    4(a1,d2.l),a2
  4247.     lea    mt_samplestarts-MB(a3),a1
  4248.     add.w    #42,a0
  4249.     moveq    #$1e,d0
  4250. .mt_lop3:
  4251.     clr.l    (a2)
  4252.     move.l    a2,(a1)+
  4253.     moveq    #0,d1
  4254.     move.w    (a0),d1
  4255.     clr.b    2(a0)
  4256.     asl.l    #1,d1
  4257.     add.l    d1,a2
  4258.     add.l    #30,a0
  4259.     dbf    d0,.mt_lop3
  4260.     or.b    #2,$bfe001
  4261.     moveq    #0,d0
  4262.     lea    $dff000,a0
  4263.     move.w    d0,$a8(a0)
  4264.     move.w    d0,$b8(a0)
  4265.     move.w    d0,$c8(a0)
  4266.     move.w    d0,$d8(a0)
  4267.  
  4268.     move.w    TempoBase-MB(a3),d0
  4269.     divu    #16,d0
  4270.     move.b    d0,mt_speed-MB(a3)
  4271.     clr.b    mt_counter-MB(a3)
  4272.     move.b    #1,mt_on-MB(a3)
  4273.     move.l    (sp)+,a3    
  4274.     rts
  4275. * Pas un module tracker
  4276. .nobank    moveq    #8,d0
  4277.     Rbra    L_Custom
  4278.  
  4279. ******* Erreur disque
  4280. L_IDError    equ    96
  4281. L96    move.w    #DEBase+15,d0
  4282.     Rjmp    L_Error
  4283.  
  4284. L97
  4285. L98
  4286. L99
  4287.  
  4288.  
  4289. *********************************************************************
  4290. *    ERROR MESSAGES...
  4291. ;
  4292. ; You know that the compiler have a -E1 option (with errors) and a 
  4293. ; a -E0 (without errors). To achieve that, the compiler copies one of
  4294. ; the two next routines, depending on the -E flag. If errors are to be
  4295. ; copied along with the program, then the next next routine is used. If not,
  4296. ; then the next one is copied.
  4297. ; The compiler assumes that the two last routines in the library handles
  4298. ; the errors: the previous last is WITH errors, the last is WITHOUT. So,
  4299. ; remember:
  4300. ;
  4301. ; THESE ROUTINES MUST BE THE LAST ONES IN THE LIBRARY
  4302. ;
  4303. ; The AMOS interpretor always needs errors. So make all your custom errors
  4304. ; calls point to the L_Custom routine, and everything will work fine...
  4305. ;
  4306. ******* "With messages" routine.
  4307. ; The following routine is the one your program must call to output
  4308. ; a extension error message. It will be used under interpretor and under
  4309. ; compiled program with -E1
  4310.  
  4311. L_Custom    equ    100
  4312. L100    lea    ErrMess(pc),a0
  4313.     moveq    #0,d1            * Can be trapped
  4314.     moveq    #ExtNb,d2        * Number of extension
  4315.     moveq    #0,d3            * IMPORTANT!!!
  4316.     RJmp    L_ErrorExt        * Jump to routine...
  4317. * Messages...
  4318. ErrMess    dc.b    "Wave not defined",0            *0
  4319.     dc.b     "Sample not defined",0            *1
  4320.     dc.b     "Sample bank not found",0        *2
  4321.     dc.b    "256 characters for a wave",0        *3
  4322.     dc.b    "Wave 0 and 1 are reserved",0        *4
  4323.     dc.b    "Music bank not found",0        *5
  4324.     dc.b     "Music not defined",0            *6
  4325.     dc.b    "Can't open narrator",0            *7
  4326.     dc.b    "Not a tracker module",0        *8
  4327. * IMPORTANT! Always EVEN!
  4328.     even
  4329.  
  4330. ******* "No errors" routine
  4331. ; If you compile with -E0, the compiler will replace the previous
  4332. ; routine by this one. This one just sets D3 to -1, and does not
  4333. ; load messages in A0. Anyway, values in D1 and D2 must be valid.
  4334. ;    
  4335. ; THIS ROUTINE MUST BE THE LAST ONE IN THE LIBRARY!
  4336. ;
  4337.  
  4338. L101    moveq    #0,d1
  4339.     moveq    #ExtNb,d2
  4340.     moveq    #-1,d3
  4341.     RJmp    L_ErrorExt
  4342.  
  4343. ; Do not forget the last label to delimit the last library routine!
  4344. L102
  4345.  
  4346. *********************************************************************
  4347. ; Now the title of the extension. If you come from V1.23 note that
  4348. ; the cursor is no more located on the screen, instead a CDOWN (31)
  4349. ; control code is used...
  4350.  
  4351. ******* TITLE MESSAGE
  4352. C_Title    dc.b    31,"Music extension V1.53",0
  4353.     Even
  4354.  
  4355. ******* END OF THE EXTENSION
  4356. C_End    dc.w    0
  4357.     even
  4358.  
  4359.  
  4360.