home *** CD-ROM | disk | FTP | other *** search
/ ftp.ee.lbl.gov / 2014.05.ftp.ee.lbl.gov.tar / ftp.ee.lbl.gov / mtrek.shar.Z / mtrek.shar / fill.mac < prev    next >
Text File  |  1990-04-02  |  2KB  |  81 lines
  1.     .ENABL    LC
  2.     .TITLE    FILL
  3.     .IDENT    /MTREK/
  4. ; 
  5. ;    FORTRAN callable routine to do buffered i/o.
  6. ;
  7. ;    Strings are sized and copied to the buffer. If a new string
  8. ;    will not fit in the space left in the buffer, then the
  9. ;    subroutine flush is called to output the buffer and make
  10. ;    room for the new string.
  11. ;
  12. ;    The entry flush is used to output all of the characters
  13. ;    in the buffer.
  14. ;
  15. ;    Calling sequence:
  16. ; 
  17. ;        CALL FILL(STRING[,ICNT])
  18. ; 
  19. ;    STRING    String of text to output (an array or quoted string)
  20. ;    ICNT    Optional character count
  21. ;
  22. ;    Calling sequence:
  23. ; 
  24. ;        CALL FLUSH
  25. ; 
  26.     .MCALL    DIR$,QIOW$
  27.     .GLOBL    FILL,FLUSH,FINIT
  28.  
  29.     LUN = 1            ; LUN FOR QIOS
  30.     MAXSIZ=200        ; SIZE OF BUFFER FOR OUTPUT
  31.     COUNT=QIOW+Q.IOPL+2    ; ADDRESS OF CHARACTER COUNT
  32.  
  33. FILL:    TSTB    @2(R5)        ; SEE IF STRING IS ZERO LENGTH
  34.     BEQ    60$        ; BRANCH IF ZERO LENGTH
  35.     MOV    2(R5),R0    ; ADDRESS OF STRING IN R0
  36.     CMPB    #2,(R5)        ; CHARACTER COUNT INPUT?
  37.     BNE    20$        ; BRANCH IF NOT
  38.     MOV    @4(R5),R1    ; COUNT IN R1
  39.     BLE    60$        ; EXIT IF COUNT IS LE ZERO
  40.     BR    30$        ; NOW GO SEE IF ENOUGH SPACE LEFT
  41. 20$:    MOV    R0,R1        ; COPY ADDRESS TO R1
  42. 10$:    TSTB    (R1)+        ; LOOKING FOR ZERO BYTE
  43.     BNE    10$        ; LOOP UNTIL DONE
  44.     DEC    R1        ; THEN BACK UP ONE
  45.     SUB    R0,R1        ; AND SUBTRACT FOR THE COUNT
  46. 30$:    MOV    #MAXSIZ,R2    ; PUT MAXIMUN NUMBER IN R2
  47.     SUB    COUNT,R2    ; SUBTRACT FOR FREE SPACE
  48.     CMP    R2,R1        ; IS THERE ENOUGH ROOM LEFT?
  49.     BGE    40$        ; BRANCH IF ROOM LEFT
  50.     CALL    FLUSH        ; OUTPUT THE BUFFER
  51. 40$:    MOV    #BASE,R2    ; ADDRESS OF THE BUFFER
  52.     ADD    COUNT,R2    ; CALCULATE TOP OF BUFFER
  53.     ADD    R1,COUNT    ; UPDATE COUNT
  54. 50$:    MOVB    (R0)+,(R2)+    ; COPY CHARS
  55.     SOB    R1,50$        ; LOOP UNTIL DONE
  56. 60$:    RETURN            ; AND RETURN TO MAIN
  57. ;
  58. ;    Entry for flush buffer
  59. ;
  60. FLUSH:    TST    COUNT        ; DO WE HAVE ANY CHARS TO OUTPUT?
  61.     BLE    70$        ; BRANCH IF NOT
  62.     DIR$    #QIOW        ; OUTPUT THE ENTIRE BUFFER
  63.     CLR    COUNT        ; CLEAR THE COUNT
  64. 70$:    RETURN            ; AND RETURN TO CALLER
  65. ;
  66. ;    Here is the entry for initilization
  67. ;
  68. FINIT:    CLR    COUNT        ; ZERO THE COUNT
  69.     RETURN            ; AND RETURN
  70. ;
  71. ;    Here is the qio
  72. ;
  73. QIOW:    QIOW$    IO.WLB!TF.WAL,LUN,1,,,,<BASE,0>
  74. ;
  75. ;    Here is the buffer
  76. ;
  77.     .NLIST    BIN
  78. BASE:    .BLKB    MAXSIZ
  79.     .EVEN
  80.     .END
  81.