home *** CD-ROM | disk | FTP | other *** search
/ 17 Bit Software 1: Collection A / 17Bit_Collection_A.iso / files / 290.dms / 290.adf / quickrif.source / unvscomp.asm < prev    next >
Assembly Source File  |  1989-01-31  |  5KB  |  145 lines
  1.  
  2. ; unvscomp.asm  Copyright 1987 Dancing Flame all rights reserved.
  3. ;
  4. ; This file contains a single function which is set up to be called from
  5. ; C.  Ie the parameters are on the stack instead of registers.
  6. ;       decode_vkplane(in, out, linebytes)
  7. ; where in is a bit-plane's worth of vertical-byte-run-with-skips data
  8. ; and out is a bit-plane that STILL has the image from last frame on it.
  9. ; Linebytes is the number of bytes-per-line in the out bitplane, and it
  10. ; should certainly be noted that the external pointer variable ytable
  11. ; must be initialized to point to a multiplication table of
  12. ; 0*linebytes, 1*linebytes ... n*linebytes  before this routine is called.
  13. ; 
  14. ; The format of "in":
  15. ;   Each column of the bitplane is compressed separately.  A 320x200
  16. ;   bitplane would have 40 columns of 200 bytes each.  The linebytes
  17. ;   parameter is used to count through the columns, it is not in the
  18. ;   "in" data, which is simply a concatenation of columns.
  19. ;
  20. ;   Each columns is an op-count followed by a number of ops.
  21. ;   If the op-count is zero, that's ok, it just means there's no change
  22. ;   in this column from the last frame.
  23. ;   The ops are of three classes, and followed by a varying amount of
  24. ;   data depending on which class.
  25. ;       1. Skip ops - this is a byte with the hi bit clear that says how many
  26. ;          rows to move the "dest" pointer forward, ie to skip. It is non-
  27. ;          zero
  28. ;       2. Uniq ops - this is a byte with the hi bit set.  The hi bit is
  29. ;          masked down and the remainder is a count of the number of bytes
  30. ;          of data to copy literally.  It's of course followed by the
  31. ;          data to copy.
  32. ;       3. Same ops - this is a 0 byte followed by a count byte, followed
  33. ;          by a byte value to repeat count times.
  34. ;   Do bear in mind that the data is compressed vertically rather than
  35. ;   horizontally, so to get to the next byte in the destination (out)
  36. ;   we add linebytes instead of one!
  37. ;
  38.  
  39.     public _decode_vkplane
  40.  
  41. firstp    set    16
  42. in    set    4+firstp
  43. out    set    8+firstp
  44. linebytes    set    14+firstp
  45.  
  46. _decode_vkplane
  47.     movem.l    a2/a3/d4/d5,-(sp)  ; save registers for Aztec C
  48.     move.l    in(sp),a0
  49.     move.l    out(sp),a2
  50.     move.w    linebytes(sp),d2
  51.     move.l    _ytable,a3
  52.     move.w    d2,d4    ; make a copy of linebytes to use as a counter
  53.     bra    zdcp    ; And go to the "columns" loop
  54.  
  55. dcp
  56.     move.l    a2,a1     ; get copy of dest pointer
  57.     clr.w    d0    ; clear hi byte of op_count
  58.     move.b    (a0)+,d0  ; fetch number of ops in this column
  59.     bra    zdcvclp   ; and branch to the "op" loop.
  60.  
  61. dcvclp    clr.w    d1    ; clear hi byte of op
  62.     move.b    (a0)+,d1    ; fetch next op
  63.     bmi    dcvskuniq ; if hi-bit set branch to "uniq" decoder
  64.     beq dcvsame    ; if it's zero branch to "same" decoder
  65.  
  66. skip            ; otherwise it's just a skip
  67.     add.w    d1,d1    ; use amount to skip as index into word-table
  68.     adda.w    0(a3,d1),a1
  69.     dbra    d0,dcvclp ; go back to top of op loop
  70.     bra    z1dcp     ; go back to column loop
  71.  
  72. dcvsame            ;here we decode a "vertical same run"
  73.     move.b    (a0)+,d1    ;fetch the count
  74.     move.b    (a0)+,d3  ; fetch the value to repeat
  75.     move.w    d1,d5     ; and do what it takes to fall into a "tower"
  76.     asr.w    #3,d5     ; d5 holds # of times to loop through tower
  77.     and.w    #7,d1     ; d1 is the remainder
  78.     add.w    d1,d1
  79.     add.w    d1,d1
  80.     neg.w    d1
  81.     jmp    34+same_tower(pc,d1) ; why 34?  8*size of tower
  82.                                          ;instruction pair, but the extra 2's
  83.                                          ;pure voodoo.
  84. same_tower
  85.     move.b    d3,(a1)
  86.     adda.w    d2,a1
  87.     move.b    d3,(a1)
  88.     adda.w    d2,a1
  89.     move.b    d3,(a1)
  90.     adda.w    d2,a1
  91.     move.b    d3,(a1)
  92.     adda.w    d2,a1
  93.     move.b    d3,(a1)
  94.     adda.w    d2,a1
  95.     move.b    d3,(a1)
  96.     adda.w    d2,a1
  97.     move.b    d3,(a1)
  98.     adda.w    d2,a1
  99.     move.b    d3,(a1)
  100.     adda.w    d2,a1
  101.     dbra    d5,same_tower
  102.     dbra    d0,dcvclp
  103.     bra    z1dcp
  104.  
  105. dcvskuniq                     ; here we decode a "unique" run
  106.     and.b    #$7f,d1   ; setting up a tower as above....
  107.     move.w    d1,d5
  108.     asr.w    #3,d5
  109.     and.w    #7,d1
  110.     add.w    d1,d1
  111.     add.w    d1,d1
  112.     neg.w    d1
  113.     jmp    34+uniq_tower(pc,d1)
  114. uniq_tower
  115.     move.b    (a0)+,(a1)
  116.     adda.w    d2,a1
  117.     move.b    (a0)+,(a1)
  118.     adda.w    d2,a1
  119.     move.b    (a0)+,(a1)
  120.     adda.w    d2,a1
  121.     move.b    (a0)+,(a1)
  122.     adda.w    d2,a1
  123.     move.b    (a0)+,(a1)
  124.     adda.w    d2,a1
  125.     move.b    (a0)+,(a1)
  126.     adda.w    d2,a1
  127.     move.b    (a0)+,(a1)
  128.     adda.w    d2,a1
  129.     move.b    (a0)+,(a1)
  130.     adda.w    d2,a1
  131.     dbra    d5,uniq_tower  ; branch back up to "op" loop
  132. zdcvclp dbra    d0,dcvclp      ; branch back up to "column loop"
  133.  
  134.     ; now we've finished decoding a single column
  135. z1dcp    addq.l    #1,a2  ; so move the dest pointer to next column
  136. zdcp    dbra    d4,dcp ; and go do it again what say?
  137.     movem.l    (sp)+,a2/a3/d4/d5
  138.     rts
  139.  
  140.     dseg
  141.     public _ytable ; saves me 8 cycles/op ... a lookup table
  142.                    ; on the y addresses.
  143.  
  144.  
  145.