home *** CD-ROM | disk | FTP | other *** search
/ Atari FTP / ATARI_FTP_0693.zip / ATARI_FTP_0693 / Tex / mf_two.arc / GRAYF.MF < prev    next >
Text File  |  1988-11-22  |  3KB  |  83 lines
  1. % More-or-less general gray font generator
  2. % See Appendix H of The METAFONTbook for how to use it
  3.  
  4. forsuffixes m = mag,rep:
  5.  if unknown m: m := 1;
  6.  elseif (m<1) or (m<>floor m):
  7.   errmessage "Sorry, " & str m & " must be a positive integer";
  8.   m := 1; fi endfor
  9.  
  10. mg := mag; mag := 1; mode_setup;
  11. if mg>1: hppp := hppp*mg; vppp := vppp*mg;
  12.  extra_endchar:=
  13.   "if charcode>0:currentpicture:=currentpicture scaled mg;fi"
  14.   & extra_endchar; fi;
  15.  
  16. if picture pix_picture: rep := 1;
  17.  cull pix_picture keeping (1,infinity);
  18. else: for z=(0,2),(1,0),(2,3),(3,1):
  19.   fill unitsquare shifted z; endfor
  20.  if not boolean lightweight: addto currentpicture also
  21.   currentpicture rotated 90 xscaled -1; fi
  22.  if unknown scale: scale := max(1,round(pixels_per_inch/300)); fi
  23.  pix_wd := pix_ht := 4scale;
  24.  if rep>1: picture pix;
  25.    currentpicture := currentpicture shifted-(1,1); pix := currentpicture;
  26.    for r=1 upto rep-1: addto currentpicture also pix shifted(4r,0); endfor
  27.    cullit; pix := currentpicture;
  28.    for r=1 upto rep-1: addto currentpicture also pix shifted(0,4r); endfor
  29.    unfill unitsquare xscaled 4rep yscaled 2 shifted-(1,1);
  30.    unfill unitsquare yscaled 4rep xscaled 2 shifted-(1,1); cullit; fi
  31.  picture pix_picture; pix_picture := currentpicture scaled scale;
  32.  pix_wd := pix_ht := 4scale*rep; fi
  33.  
  34. def # = *72.27/pixels_per_inch enddef;
  35. if unknown dotsize: dotsize := 2.5pix_wd/rep; fi
  36.  
  37. beginchar(0,1.2dotsize#,1.2dotsize#,0);
  38. fill fullcircle scaled dotsize scaled mg; endchar;
  39.  
  40. numeric a[]; newinternal b,k;
  41. def next_binary =
  42.  k := 0; forever: if k>b: a[incr b] := 0; fi
  43.   exitif a[k]=0; a[k] := 0; k := k+1; endfor
  44.  a[k] := 1 enddef;
  45. def next_special_binary =
  46.  if a[0]=1: for k=0 upto b: a[k] := 0; endfor a[incr b]
  47.  else: k := 0; forever: exitif a[incr k]=1; endfor
  48.   a[k-1] fi := 1 enddef;
  49.  
  50. def make_char =
  51.  clearit; next_binary;
  52.  for k=0 upto b: if a[k]=1:
  53.   addto currentpicture also pix_picture shifted(0,-k*pix_ht); fi endfor
  54.  charcode := charcode+1; chardp := b*charht;
  55.  scantokens extra_endchar; shipout currentpicture enddef;
  56.  
  57. charwd := pix_wd#; charht := pix_ht#; chardx := pix_wd*mg;
  58. b := -1;
  59.  
  60. if boolean large_pixels:
  61.  for k=1 upto 7: make_char; charlist k:k+120; endfor
  62.  charcode := 120; b := -1;
  63.  addto pix_picture also pix_picture shifted (chardx,0);
  64.  charwd := 2charwd; chardx := 2chardx;
  65.  for k=1 upto 7: make_char; endfor
  66. else: for k=1 upto 63: make_char; endfor
  67.  let next_binary = next_special_binary;
  68.  for k=64 upto 120: make_char; endfor
  69.  for k=121,122: charcode := k;
  70.   addto currentpicture also currentpicture shifted (chardx,0);
  71.   charwd := 2charwd; chardx := 2chardx;
  72.   scantokens extra_endchar; shipout currentpicture; endfor
  73.  charlist 120:121:122; fi
  74.  
  75. font_coding_scheme "GFGRAY";
  76. font_size 8(pix_wd#);
  77. font_normal_space pix_wd#;
  78. font_x_height pix_ht#;
  79. font_quad pix_wd#;
  80. fontdimen 8: if known rulethickness: rulethickness
  81.  else: pix_wd#/(2rep) fi;
  82. bye.
  83.