home *** CD-ROM | disk | FTP | other *** search
/ Atari FTP / ATARI_FTP_0693.zip / ATARI_FTP_0693 / Tex / mf_three.arc / SYMBOL.MF < prev    next >
Text File  |  1988-11-22  |  43KB  |  1,036 lines
  1. % This file defines the symbols of a \TeX\ math symbol font.
  2. % Character codes \0000--\00100 and \0133--\0177 are generated.
  3.  
  4. % (Improvements to the author's original characters were worked out in 1982
  5. % by Ronald F. Whitney and other members of
  6. % the American Mathematical Society.)
  7.  
  8. % Italic corrections have not been computed for most of these characters,
  9. % since they are generally not slanted.
  10.  
  11. minus=oct"000"; cdot=oct"001"; diamond=oct"005";
  12. plus_minus=oct"006"; o_plus=oct"010"; o_times=oct"012";
  13. eqv=oct"021"; leq=oct"024"; geq=oct"025";
  14. subset=oct"032"; superset=oct"033";
  15. left_arrow=oct"040"; right_arrow=oct"041";
  16. up_arrow=oct"042"; down_arrow=oct"043"; double_arrow=oct"044";
  17. infty=oct"061"; elt=oct"062";
  18. for_all=oct"070"; there_exists=oct"071"; false_that=oct"072";
  19. cup=oct"133"; cap=oct"134"; meet=oct"136"; join=oct"137";
  20. left_brace=oct"146"; right_brace=oct"147"; vertical=oct"152";
  21. backslash=oct"156"; integral=oct"163";
  22.  
  23. input sym;  % symbols common to other fonts
  24.  
  25. cmchar "Times operator";
  26. beginarithchar(oct"002"); pickup rule.nib;
  27. x1=good.x(1/sqrt2)[.5w,rt u]; y1=good.y(1/sqrt2)[math_axis,bot h];
  28. x2=x3=w-x1; x4=x1; .5[y1,y2]=.5[y3,y4]=math_axis; y2=y4;
  29. draw z1--z2; draw z3--z4;  % diagonals
  30. labels(1,2,3,4); endchar;
  31.  
  32. cmchar "Asterisk at the axis";
  33. beginchar(oct"003",9u#,v_center(x_height#));
  34. adjust_fit(0,0);
  35. numeric ast_flare; ast_flare=hround .7[thin_join,stem];
  36. x0=.5w; y0=h-.5x_height;
  37. for d=-150 step 60 until 150: z[d]=z0+.5dir d xscaled 7.5u yscaled x_height;
  38.  numeric theta; theta=angle(z[d]-z0);
  39.  fill z0+.5(0,-thin_join)rotated theta
  40.   ---z[d]+.5(-ast_flare,-ast_flare)rotated theta
  41.   ..z[d]..z[d]+.5(-ast_flare,ast_flare)rotated theta
  42.   ---z0+.5(0,thin_join)rotated theta--cycle; endfor  % diagonal at angle |d|
  43. labels(0,[-150],[-90],[-30],30,90,150); endchar;
  44.  
  45. cmchar "Elementary division operator";
  46. beginarithchar(oct"004"); pickup rule.nib;
  47. x3-.5dot_size=hround(.5w-.5dot_size); w:=r:=2x3;
  48. y3+.5dot_size=vround(math_axis+math_spread[.5x_height,.6x_height]+.5dot_size);
  49. lft x1=hround u-eps; x2=w-x1; y1=y2=math_axis;
  50. draw z1--z2;  % bar
  51. pos3(dot_size,0); pos4(dot_size,90); z3=z4;
  52. pos5(dot_size,0); pos6(dot_size,90); z5=z6; x5=x3; .5[y3,y5]=math_axis;
  53. dot(3,4); dot(5,6);  % dots
  54. penlabels(1,2,3,4,5,6); endchar;
  55.  
  56. cmchar "Minus-or-plus sign";
  57. beginarithchar(oct"007"); pickup rule.nib;
  58. numeric shiftup; shiftup=-vround 1.5u;
  59. x1=x2=.5w; lft x3=lft x5=hround u-eps; x4=x6=w-x3;
  60. .5[y1,y2]=y3=y4=math_axis+shiftup; top y1=h+shiftup; y5=y6=y1;
  61. draw z1--z2;  % stem
  62. draw z3--z4;  % plus bar
  63. draw z5--z6;  % minus bar
  64. labels(1,2,3,4,5,6); endchar;
  65.  
  66. cmchar "Circle-minus operator";
  67. beginarithchar(oct"011"); pickup light_rule.nib; autorounded;
  68. lft x6=hround u; x2=w-x6; y2=math_axis; top y8=h;
  69. circle_points; draw_circle;  % circle
  70. draw z2--z6;  % bar
  71. labels(1,2,3,4,5,6,7,8); endchar;
  72.  
  73. cmchar "Circle-divide operator";
  74. beginarithchar(oct"013"); pickup light_rule.nib; autorounded;
  75. lft x6=hround u; x2=w-x6; y2=math_axis; top y8=h;
  76. circle_points; draw_circle;  % circle
  77. draw z1--z5;  % diagonal
  78. labels(1,2,3,4,5,6,7,8); endchar;
  79.  
  80. cmchar "Circle-dot operator";
  81. beginarithchar(oct"014"); pickup light_rule.nib; autorounded;
  82. lft x6=hround u; x2=w-x6; y2=math_axis; top y8=h;
  83. circle_points; draw_circle;  % circle
  84. fill fullcircle scaled(1.3dot_size+eps) shifted(.5[z4,z8]);  % dot
  85. labels(1,2,3,4,5,6,7,8); endchar;
  86.  
  87. cmchar "Circle for copyright, etc.";
  88. beginchar(oct"015",18u#,asc_height#,desc_depth#); autorounded;
  89. adjust_fit(if monospace:-3u#,-3u# else: 0,0 fi); pickup rule.nib;
  90. lft x6=hround u; x2=w-x6; top y8=h+o; bot y4=-d-o;
  91. circle_points; draw_circle;  % circle
  92. labels(1,2,3,4,5,6,7,8); endchar;
  93.  
  94. cmchar "Circle operator";
  95. beginchar(oct"016",9u#,v_center(7u#));
  96. adjust_fit(0,0); pickup rule.nib; autorounded;
  97. lft x6=hround u; x2=w-x6; top y8=h; y2=math_axis;
  98. circle_points; draw_circle;  % circle
  99. labels(1,2,3,4,5,6,7,8); endchar;
  100.  
  101. cmchar "Bullet";
  102. beginchar(oct"017",9u#,v_center(7u#));
  103. adjust_fit(0,0); pickup rule.nib; autorounded;
  104. lft x6=hround u; x2=w-x6; top y8=h; y2=math_axis; circle_points;
  105. filldraw z8{right}...z1{z2-z8}...z2{down}...z3{z4-z2}...z4{left}
  106.   ...z5{z6-z4}...z6{up}...z7{z8-z6}...cycle;  % circle and interior
  107. labels(1,2,3,4,5,6,7,8); endchar;
  108.  
  109. cmchar "Hardy's asymptotic equivalence sign";
  110. compute_spread(.45x_height#,.55x_height#);
  111. beginchar(oct"020",14u#,v_center(2spread#+rule_thickness#));
  112. adjust_fit(0,0); pickup rule.nib; autorounded;
  113. lft x1=hround u-eps; x3=x1; x2=x4=w-x1; x5=x6=.5w;
  114. y1=y2=good.y h; y3=y4; .5[y1,y3]=.5[y5,y6]=math_axis;
  115. y5=good.y .3[y1,y3];
  116. draw z1{x5-x1,2(y5-y1)}...z5{right}...z2{x2-x5,2(y2-y5)};  % upper bar
  117. draw z3{x6-x3,2(y6-y3)}...z6{right}...z4{x4-x6,2(y4-y6)};  % lower bar
  118. labels(1,2,3,4); endchar;
  119.  
  120. cmchar "Subset or equal to sign";
  121. compute_spread(.45x_height#,.55x_height#);
  122. spread#':=spread#; spread':=spread; % the spread of `$=$'
  123. compute_spread(5/4x_height#,3/2x_height#);
  124. beginchar(oct"022",14u#,v_center(spread#'+spread#+rule_thickness#));
  125. adjust_fit(0,0); pickup rule.nib; autorounded;
  126. lft x2=hround 1.5u-eps; x1=x3=w-x2;
  127. y1-y3=spread; y2=.5[y1,y3]; top y1=h;
  128. x4=x5=.5w; y4=y1; y5=y3;
  129. draw z1---z4...z2{down}...z5---z3;  % arc and bars
  130. x8=x1; lft x9=x2; y8=y9; y3-y9=spread'; draw z8--z9;  % lower bar
  131. labels(1,2,3,4,5,8,9); endchar;
  132.  
  133. cmchar "Superset or equal to sign";
  134. compute_spread(.45x_height#,.55x_height#);
  135. spread#':=spread#; spread':=spread; % the spread of `$=$'
  136. compute_spread(5/4x_height#,3/2x_height#);
  137. beginchar(oct"023",14u#,v_center(spread#'+spread#+rule_thickness#));
  138. adjust_fit(0,0); pickup rule.nib; autorounded;
  139. lft x1=hround 1.5u-eps; x2=w-x1; x3=x1;
  140. y1-y3=spread; y2=.5[y1,y3]; top y1=h;
  141. x4=x5=.5w; y4=y1; y5=y3;
  142. draw z1---z4...z2{down}...z5---z3;  % arc and bars
  143. x8=x1; rt x9=x2; y8=y9; y3-y9=spread'; draw z8--z9;  % lower bar
  144. labels(1,2,3,4,5,8,9); endchar;
  145.  
  146. cmchar "Precedes or equals sign";
  147. compute_spread(.45x_height#,.55x_height#);
  148. spread#':=spread#; spread':=spread; % the spread of `$=$'
  149. compute_spread(5/4x_height#,3/2x_height#);
  150. beginchar(oct"026",14u#,v_center(spread#'+spread#+rule_thickness#));
  151. adjust_fit(0,0); pickup rule.nib; autorounded;
  152. lft x2=hround 1.5u-eps; x1=x3=w-x2;
  153. y1-y3=spread; y2=.5[y1,y3]; top y1=h;
  154. draw z1{-u,-spread}...{left}z2;  % upper diagonal
  155. draw z3{-u,spread}...{left}z2;  % lower diagonal
  156. x8=x1; x9=x2; y8=y9; y3-y9=spread'; draw z8--z9;  % bar
  157. labels(1,2,3,8,9); endchar;
  158.  
  159. cmchar "Follows or equals sign";
  160. compute_spread(.45x_height#,.55x_height#);
  161. spread#':=spread#; spread':=spread; % the spread of `$=$'
  162. compute_spread(5/4x_height#,3/2x_height#);
  163. beginchar(oct"027",14u#,v_center(spread#'+spread#+rule_thickness#));
  164. adjust_fit(0,0); pickup rule.nib; autorounded;
  165. lft x1=hround 1.5u-eps; x2=w-x1; x3=x1;
  166. y1-y3=spread; y2=.5[y1,y3]; top y1=h;
  167. draw z1{u,-spread}...{right}z2;  % upper diagonal
  168. draw z3{u,spread}...{right}z2;  % lower diagonal
  169. x8=x1; x9=x2; y8=y9; y3-y9=spread'; draw z8--z9;  % bar
  170. labels(1,2,3,8,9); endchar;
  171.  
  172. cmchar "Similarity sign";
  173. compute_spread(.45x_height#,.55x_height#);
  174. beginchar(oct"030",14u#,v_center(spread#+rule_thickness#));
  175. adjust_fit(0,0);
  176. pickup pencircle xscaled .7rule_thickness yscaled 1.4rule_thickness;
  177. if vair#>.8curve#: pickup rule.nib; autorounded; fi % monoline
  178. lft x1=hround u; x2=4u; x3=w-x2; x4=w-x1;
  179. bot y1=bot y3=-d; top y2=top y4=h;
  180. draw z1{up}...z2{right}..{right}z3...{up}z4;  % stroke
  181. labels(1,2,3,4); endchar;
  182.  
  183. cmchar "Approximate equality sign";
  184. compute_spread(.45x_height#,.55x_height#);
  185. spread#':=spread#; spread':=spread; % the spread of `$=$'
  186. compute_spread(.54x_height#,.66x_height#);
  187. beginchar(oct"031",14u#,v_center(spread#'+spread#+rule_thickness#));
  188. adjust_fit(0,0);
  189. pickup pencircle xscaled .7rule_thickness yscaled 1.4rule_thickness;
  190. if vair#>.8curve#: pickup rule.nib; autorounded; fi % monoline
  191. lft x1=hround u; x2=4u; x3=w-x2; x4=w-x1;
  192. y1=y3; top y2=top y4=h; top y2-bot y1=spread';
  193. draw z1{up}...z2{right}..{right}z3...{up}z4;  % upper stroke
  194. z1-z5=z2-z6=z3-z7=z4-z8=(0,spread);
  195. draw z5{up}...z6{right}..{right}z7...{up}z8;  % lower stroke
  196. labels(1,2,3,4,5,6,7,8); endchar;
  197.  
  198. cmchar "Much less sign";
  199. compute_spread(5/4x_height#,3/2x_height#);
  200. beginchar(oct"034",18u#,v_center(spread#+rule_thickness#));
  201. adjust_fit(if monospace:-u#,-u# else: 0,0 fi); pickup rule.nib;
  202. lft x2=hround u-epsilon; x1=x3=hround 12.5u-x2;
  203. y1-y3=ceiling 1.1spread; y2=.5[y1,y3]=math_axis;
  204. draw z1--z2--z3;  % left diagonals
  205. z4-z1=z5-z2=z6-z3; x4=w-x2; y4=y1;
  206. draw z4--z5--z6;  % right diagonals
  207. labels(1,2,3,4,5,6); endchar;
  208.  
  209. cmchar "Much greater sign";
  210. compute_spread(5/4x_height#,3/2x_height#);
  211. beginchar(oct"035",18u#,v_center(spread#+rule_thickness#));
  212. adjust_fit(if monospace:-u#,-u# else: 0,0 fi); pickup rule.nib;
  213. lft x1=hround u-epsilon; x2=hround 12.5u-x1; x3=x1;
  214. y1-y3=ceiling 1.1spread; y2=.5[y1,y3]=math_axis;
  215. draw z1--z2--z3;  % left diagonals
  216. z4-z1=z5-z2=z6-z3; x4=w-x2; y4=y1;
  217. draw z4--z5--z6;  % right diagonals
  218. labels(1,2,3,4,5,6); endchar;
  219.  
  220. cmchar "Precedes sign";
  221. compute_spread(5/4x_height#,3/2x_height#);
  222. beginchar(oct"036",14u#,v_center(spread#+rule_thickness#));
  223. adjust_fit(0,0); pickup rule.nib; autorounded;
  224. lft x2=hround 1.5u-epsilon; x1=x3=w-x2;
  225. y1-y3=spread; y2=.5[y1,y3]; top y1=h;
  226. draw z1{-u,-spread}...{left}z2;  % upper diagonal
  227. draw z3{-u,spread}...{left}z2;  % lower diagonal
  228. labels(1,2,3); endchar;
  229.  
  230. cmchar "Follows sign";
  231. compute_spread(5/4x_height#,3/2x_height#);
  232. beginchar(oct"037",14u#,v_center(spread#+rule_thickness#));
  233. adjust_fit(0,0); pickup rule.nib; autorounded;
  234. lft x1=hround 1.5u-epsilon; x2=w-x1; x3=x1;
  235. y1-y3=spread; y2=.5[y1,y3]; top y1=h;
  236. draw z1{u,-spread}...{right}z2;  % upper diagonal
  237. draw z3{u,spread}...{right}z2;  % lower diagonal
  238. labels(1,2,3); endchar;
  239.  
  240. cmchar "Northeast arrow";
  241. beginchar(oct"045",18u#,asc_height#,asc_depth#);
  242. adjust_fit(0,0); pickup crisp.nib;
  243. x1-.5rule_thickness=hround u; rt x0=hround(w-u);
  244. y1-.5rule_thickness=-d; top y0=h;
  245. numeric theta,delta; theta=angle(z0-z1); delta=3u++.24asc_height;
  246. if abs(theta-45)<2.5: theta:=45; y1:=y0+x1-x0; fi % near-45$^\circ$ angle
  247. pos1(rule_thickness,90+theta); pos2(rule_thickness,90+theta);
  248. pos3(bar,theta); pos4(bar,theta);
  249. y3=y0; x4=x0; x0-x3=y0-y4=delta+eps;
  250. pos5(bar,-90); z5l=z0; pos6(bar,-180); z6l=z0;
  251. z9=.381966[.5[z3,z4],z0];
  252. numeric t; path p; p=z4l{z9-z4}..z6r;
  253. t=xpart(p intersectiontimes (z1l--(z1l+2(z0-z1)))); z2l=point t of p;
  254. filldraw z0..{z4-z9}z4r--subpath (0,t) of\\(z4l{z9-z4}..z6r)
  255.  --z2l---z1l..z1r---z2r--subpath (t,0) of\\(z3l{z9-z3}..z5r)
  256.  --z3r{z9-z3}..z0 & cycle;  % arrowhead and stem
  257. penlabels(0,1,2,3,4,5,6,9); endchar;
  258.  
  259. cmchar "Southeast arrow";
  260. beginchar(oct"046",18u#,asc_height#,asc_depth#);
  261. adjust_fit(0,0); pickup crisp.nib;
  262. x1-.5rule_thickness=hround u; rt x0=hround(w-u);
  263. y1+.5rule_thickness=h; bot y0=-d;
  264. numeric theta,delta; theta=angle(z0-z1); delta=3u++.24asc_height;
  265. if abs(theta+45)<2.5: theta:=-45; y1:=y0+x0-x1; fi % near-45$^\circ$ angle
  266. pos1(rule_thickness,90+theta); pos2(rule_thickness,90+theta);
  267. pos3(bar,theta); pos4(bar,theta);
  268. x3=x0; y4=y0; y3-y0=x0-x4=delta+eps;
  269. pos5(bar,180); z5l=z0; pos6(bar,90); z6l=z0;
  270. z9=.381966[.5[z3,z4],z0];
  271. numeric t; path p; p=z4l{z9-z4}..z6r;
  272. t=xpart(p intersectiontimes (z1l--(z1l+2(z0-z1)))); z2l=point t of p;
  273. filldraw z0..{z4-z9}z4r
  274.  --subpath (0,t) of\\(z4l{z9-z4}..z6r)
  275.  --z2l---z1l..z1r---z2r
  276.  --subpath (t,0) of\\(z3l{z9-z3}..z5r)
  277.  --z3r{z9-z3}..z0 & cycle;  % arrowhead and stem
  278. penlabels(0,1,2,3,4,5,6,9); endchar;
  279.  
  280. cmchar "Similar or equal sign";
  281. compute_spread(.45x_height#,.55x_height#);
  282. beginchar(oct"047",14u#,v_center(2spread#+rule_thickness#));
  283. adjust_fit(0,0);
  284. pickup pencircle xscaled .7rule_thickness yscaled 1.4rule_thickness;
  285. if vair#>.8curve#: pickup rule.nib; autorounded; fi % monoline
  286. lft x1=hround u; x2=4u; x3=w-x2; x4=w-x1;
  287. bot y1=bot y3=floor math_axis; top y2=top y4=h;
  288. draw z1{up}...z2{right}..{right}z3...{up}z4;  % stroke
  289. pickup rule.nib; lft x5=hround u-eps; x6=w-x5; y5=y6=math_axis-spread;
  290. draw z5--z6;  % bar
  291. labels(1,2,3,4,5,6); endchar;
  292.  
  293. cmchar "Double leftward arrow";
  294. compute_spread(.45x_height#,.55x_height#);
  295. beginchar(oct"050",18u#,v_center(spread#+rule_thickness#));
  296. adjust_fit(0,0); pickup rule.nib;
  297. lft x7=hround u-eps; x8=x7; x1=x2=w-x7;
  298. y1=y7; y2=y8; y1-y2=spread; .5[y1,y2]=math_axis;
  299. draw z1--z7; draw z2--z8;  % bars
  300. pickup crisp.nib; lft x0=hround u-eps; y0=good.y math_axis;
  301. pos3(rule_thickness,0); pos4(rule_thickness,0);
  302. y3-y1=y2-y4=.24asc_height+eps; x3=x4=x0+6u+eps;
  303. pos5(rule_thickness,angle(z4-z0)); z5l=z0;
  304. pos6(rule_thickness,angle(z3-z0)); z6l=z0;
  305. z9=.381966[.5[z3,z4],z0];
  306. erase filldraw z0..{z3-z9}z3--(0,y3)
  307.  --(0,y4)--z4{z9-z4}..z0 & cycle;  % erase excess
  308. numeric t; path p; p=z4r{z9-z4}..z6r;
  309. t=xpart(p intersectiontimes((0,y0)--(w,y0)));
  310. filldraw z0..{z4-z9}z4l--subpath (0,t) of\\(z4r{z9-z4}..z6r)
  311.  --subpath (t,0) of\\(z3r{z9-z3}..z5r)--z3l{z9-z3}..z0 & cycle;  % arrowhead
  312. penlabels(0,1,2,3,4,5,6,7,8,9); endchar;
  313.  
  314. cmchar "Double rightward arrow";
  315. compute_spread(.45x_height#,.55x_height#);
  316. beginchar(oct"051",18u#,v_center(spread#+rule_thickness#));
  317. adjust_fit(0,0); pickup rule.nib;
  318. lft x1=hround u-eps; x2=x1; x7=x8=w-x1;
  319. y1=y7; y2=y8; y1-y2=spread; .5[y1,y2]=math_axis;
  320. draw z1--z7; draw z2--z8;  % bars
  321. pickup crisp.nib; rt x0=hround(w-u)+eps; y0=good.y math_axis;
  322. pos3(rule_thickness,0); pos4(rule_thickness,0);
  323. y3-y1=y2-y4=.24asc_height+eps; x3=x4=x0-6u-eps;
  324. pos5(rule_thickness,angle(z4-z0)); z5l=z0;
  325. pos6(rule_thickness,angle(z3-z0)); z6l=z0;
  326. z9=.381966[.5[z3,z4],z0];
  327. erase filldraw z0..{z3-z9}z3--(w,y3)
  328.  --(w,y4)--z4{z9-z4}..z0 & cycle;  % erase excess
  329. numeric t; path p; p=z4l{z9-z4}..z6r;
  330. t=xpart(p intersectiontimes((0,y0)--(w,y0)));
  331. filldraw z0..{z4-z9}z4r--subpath (0,t) of\\(z4l{z9-z4}..z6r)
  332.  --subpath (t,0) of\\(z3l{z9-z3}..z5r)--z3r{z9-z3}..z0 & cycle;  % arrowhead
  333. penlabels(0,1,2,3,4,5,6,7,8,9); endchar;
  334.  
  335. cmchar "Double upward arrow";
  336. beginchar(oct"052",11u#,asc_height#,asc_depth#);
  337. adjust_fit(0,0); pickup rule.nib;
  338. compute_spread(.45x_height#,.55x_height#);
  339. bot y1=bot y2=-d-eps; top y7=h; y8=y7;
  340. x1=x7; x2=x8; x1-x2=spread; .5[x1,x2]=crisp.lft hround(crisp.rt .5w);
  341. draw z1--z7; draw z2--z8;  % bars
  342. pickup crisp.nib; top y0=h+eps; x0=good.x .5w;
  343. pos3(rule_thickness,90); pos4(rule_thickness,90);
  344. x2-x3=x4-x1=3u+eps; y3=y4=y0-.48asc_height-eps;
  345. pos5(rule_thickness,angle(z4-z0)); z5l=z0;
  346. pos6(rule_thickness,angle(z3-z0)); z6l=z0;
  347. z9=.381966[.5[z3,z4],z0];
  348. erase filldraw z0..{z3-z9}z3--(x3,h)
  349.  --(x4,h)--z4{z9-z4}..z0 & cycle;  % erase excess
  350. numeric t; path p; p=z4l{z9-z4}..z6r;
  351. t=xpart(p intersectiontimes((x0,-d)--(x0,h)));
  352. filldraw z0..{z4-z9}z4r--subpath (0,t) of\\(z4l{z9-z4}..z6r)
  353.  --subpath (t,0) of\\(z3l{z9-z3}..z5r)--z3r{z9-z3}..z0 & cycle;  % arrowhead
  354. penlabels(0,1,2,3,4,5,6,7,8,9); endchar;
  355.  
  356. cmchar "Double downward arrow";
  357. beginchar(oct"053",11u#,asc_height#,asc_depth#);
  358. adjust_fit(0,0); pickup rule.nib;
  359. compute_spread(.45x_height#,.55x_height#);
  360. top y1=top y2=h+eps; bot y7=-d; y8=y7;
  361. x1=x7; x2=x8; x1-x2=spread; .5[x1,x2]=crisp.lft hround(crisp.rt .5w);
  362. draw z1--z7; draw z2--z8;  % bars
  363. pickup crisp.nib; bot y0=-d-eps; x0=good.x .5w;
  364. pos3(rule_thickness,90); pos4(rule_thickness,90);
  365. x2-x3=x4-x1=3u+eps; y3=y4=y0+.48asc_height-eps;
  366. pos5(rule_thickness,angle(z4-z0)); z5l=z0;
  367. pos6(rule_thickness,angle(z3-z0)); z6l=z0;
  368. z9=.381966[.5[z3,z4],z0];
  369. erase filldraw z0..{z3-z9}z3--(x3,-d)
  370.  --(x4,-d)--z4{z9-z4}..z0 & cycle;  % erase excess
  371. numeric t; path p; p=z4r{z9-z4}..z6r;
  372. t=xpart(p intersectiontimes((x0,-d)--(x0,h)));
  373. filldraw z0..{z4-z9}z4l--subpath (0,t) of\\(z4r{z9-z4}..z6r)
  374.  --subpath (t,0) of\\(z3r{z9-z3}..z5r)--z3l{z9-z3}..z0 & cycle;  % arrowhead
  375. penlabels(0,1,2,3,4,5,6,7,8,9); endchar;
  376.  
  377. cmchar "Double left-and-right arrow";
  378. compute_spread(.45x_height#,.55x_height#);
  379. beginchar(oct"054",18u#,v_center(spread#+rule_thickness#));
  380. adjust_fit(if monospace: -u#,-u# else: 0,0 fi); pickup rule.nib;
  381. lft x7=hround u-eps; x8=x7; x1=x2=w-x7;
  382. y1=y7; y2=y8; y1-y2=spread; .5[y1,y2]=math_axis;
  383. draw z1--z7; draw z2--z8;  % bars
  384. pickup crisp.nib; lft x0=hround u-o; y0=good.y math_axis;
  385. pos3(rule_thickness,0); pos4(rule_thickness,0);
  386. y3-y1=y2-y4=.24asc_height+eps; x3=x4=x0+5u+eps;
  387. pos5(rule_thickness,angle(z4-z0)); z5l=z0;
  388. pos6(rule_thickness,angle(z3-z0)); z6l=z0;
  389. z9=.381966[.5[z3,z4],z0];
  390. erase filldraw z0..{z3-z9}z3--(0,y3)
  391.  --(0,y4)--z4{z9-z4}..z0 & cycle;  % erase excess at left
  392. numeric t; path p; p=z4r{z9-z4}..z6r;
  393. t=xpart(p intersectiontimes((0,y0)--(w,y0)));
  394. filldraw z0..{z4-z9}z4l--subpath (0,t) of\\(z4r{z9-z4}..z6r)
  395.  --subpath (t,0) of\\(z3r{z9-z3}..z5r)
  396.  --z3l{z9-z3}..z0 & cycle;  % left arrowhead
  397. rt x10=hround(w-u)+o; y10=good.y math_axis;
  398. pos13(rule_thickness,0); pos14(rule_thickness,0);
  399. y13=y3; y14=y4; x13=x14=x10-5u-eps;
  400. pos15(rule_thickness,angle(z14-z10)); z15l=z10;
  401. pos16(rule_thickness,angle(z13-z10)); z16l=z10;
  402. z19=.381966[.5[z13,z14],z10];
  403. erase filldraw z10..{z13-z19}z13--(w,y13)
  404.  --(w,y14)--z14{z19-z14}..z10 & cycle;  % erase excess at right
  405. numeric t; path p; p=z14l{z19-z14}..z16r;
  406. t=xpart(p intersectiontimes((0,y10)--(w,y10)));
  407. filldraw z10..{z14-z19}z14r--subpath (0,t) of\\(z14l{z19-z14}..z16r)
  408.  --subpath (t,0) of\\(z13l{z19-z13}..z15r)
  409.  --z13r{z19-z13}..z10 & cycle; % right arrowhead
  410. penlabels(0,1,2,3,4,5,6,7,8,9,10,13,14,15,16,19); endchar;
  411.  
  412. cmchar "Northwest arrow";
  413. beginchar(oct"055",18u#,asc_height#,asc_depth#);
  414. adjust_fit(0,0); pickup crisp.nib;
  415. x1+.5rule_thickness=hround(w-u); lft x0=hround u;
  416. y1-.5rule_thickness=-d; top y0=h;
  417. numeric theta,delta; theta=angle(z1-z0); delta=3u++.24asc_height;
  418. if abs(theta+45)<2.5: theta:=-45; y1:=y0+x0-x1; fi % near-45$^\circ$ angle
  419. pos1(rule_thickness,-90+theta); pos2(rule_thickness,-90+theta);
  420. pos3(bar,-180+theta); pos4(bar,-180+theta);
  421. x3=x0; y4=y0; x4-x0=y0-y3=delta+eps;
  422. pos5(bar,0); z5l=z0; pos6(bar,-90); z6l=z0;
  423. z9=.381966[.5[z3,z4],z0];
  424. numeric t; path p; p=z4l{z9-z4}..z6r;
  425. t=xpart(p intersectiontimes (z1l--(z1l+2(z0-z1)))); z2l=point t of p;
  426. filldraw z0..{z4-z9}z4r--subpath (0,t) of\\(z4l{z9-z4}..z6r)
  427.  --z2l---z1l..z1r---z2r--subpath (t,0) of\\(z3l{z9-z3}..z5r)
  428.  --z3r{z9-z3}..z0 & cycle;  % arrowhead and stem
  429. penlabels(0,1,2,3,4,5,6,9); endchar;
  430.  
  431. cmchar "Southwest arrow";
  432. beginchar(oct"056",18u#,asc_height#,asc_depth#);
  433. adjust_fit(0,0); pickup crisp.nib;
  434. x1+.5rule_thickness=hround(w-u); lft x0=hround u;
  435. y1+.5rule_thickness=h; bot y0=-d;
  436. numeric theta,delta; theta=angle(z1-z0); delta=3u++.24asc_height;
  437. if abs(theta-45)<2.5: theta:=45; y1:=y0+x1-x0; fi % near-45$^\circ$ angle
  438. pos1(rule_thickness,-90+theta); pos2(rule_thickness,-90+theta);
  439. pos3(bar,-180+theta); pos4(bar,-180+theta);
  440. y3=y0; x4=x0; x3-x0=y4-y0=delta+eps;
  441. pos5(bar,90); z5l=z0; pos6(bar,0); z6l=z0;
  442. z9=.381966[.5[z3,z4],z0];
  443. numeric t; path p; p=z4l{z9-z4}..z6r;
  444. t=xpart(p intersectiontimes (z1l--(z1l+2(z0-z1)))); z2l=point t of p;
  445. filldraw z0..{z4-z9}z4r
  446.  --subpath (0,t) of\\(z4l{z9-z4}..z6r)
  447.  --z2l---z1l..z1r---z2r
  448.  --subpath (t,0) of\\(z3l{z9-z3}..z5r)
  449.  --z3r{z9-z3}..z0 & cycle;  % arrowhead and stem
  450. penlabels(0,1,2,3,4,5,6,9); endchar;
  451.  
  452. cmchar "Proportionality sign";
  453. beginchar(oct"057",16.5u#,x_height#,0);
  454. italcorr x_height#*slant-.5u#;
  455. adjust_fit(0,-2.5u#); pickup fine.nib;
  456. numeric theta,phi; phi=angle(3u,h); theta=angle(5u,-h);
  457. pos1(vair,180); pos2(.5[vair,stem],90+.5theta); pos3(stem,90+theta);
  458. pos4(stem,90+theta); pos5(.5[vair,stem],90+.5theta);
  459. pos6(vair,180); pos7(.2[vair,stem],270+.5phi);
  460. pos8(.3[vair,stem],270+phi); pos9(.2[vair,stem],270+.5phi);
  461. lft x1r=w-rt x6l=hround u; x2=x9=.4[x1,x8]; x5=x7=.6[x8,x6];
  462. if monospace: x2l:=x2r; x5r:=x5l; x7r:=x7l; x9l:=x9r; fi
  463. y1=y6=.5h; top y2r=top y7l=h+oo; bot y5l=bot y9r=-oo;
  464. x8=.5[x3,x4]=.5w; y8=.5[y3,y4]=.5h;
  465. y3-y4=h/3; z3-z4=whatever*dir theta;
  466. filldraw stroke z1e{up}...z2e{right}...z3e---z4e...z5e{right}...z6e{up}
  467.  ...z7e{left}...{-dir phi}z8e...{left}z9e...z1e{up}; % `infinity' bowls
  468. erase fill (w-3.5u,h+o)--(w,h+o)
  469.  --(w,-o)--(w-3.5u,-o)--cycle; % erase excess
  470. penlabels(1,2,3,4,5,6,7,8,9); endchar;
  471.  
  472. cmchar "Prime symbol (intended as superscript only)";
  473. beginchar(oct"060",3u#+max(1.75u#,curve#+2(curve#-stem#)),
  474.  .8asc_height#,0);
  475. adjust_fit(0,0); pickup fine.nib;
  476. numeric light_stem,heavy_stem;
  477. light_stem=hround .5[vair,stem]; heavy_stem=hround(bold+2dw);
  478. x1+.5heavy_stem=hround(w-.25u); y1+.5heavy_stem=h;
  479. x2-.5light_stem=hround .5u; y2=1/12asc_height;
  480. numeric theta; theta=angle(z1-z2)-90;
  481. pos1(heavy_stem,theta); pos2(light_stem,theta);
  482. filldraw circ_stroke z1e--z2e;  % diagonal
  483. penlabels(1,2); endchar;
  484.  
  485. cmchar "Ownership sign";
  486. compute_spread(5/4x_height#,3/2x_height#);
  487. beginchar(oct"063",12u#,v_center(spread#+rule_thickness#));
  488. adjust_fit(0,0); pickup rule.nib; autorounded;
  489. lft x1=hround 1.5u-eps; x1=x3=x6=w-x2;
  490. y1-y3=spread; y2=y6=.5[y1,y3]=math_axis;
  491. x4=x5=.5w-u; y4=y1; y5=y3;
  492. draw z1---z4...z2{down}...z5---z3;  % arc and bars
  493. draw z2--z6;  % middle bar
  494. labels(1,2,3,4,5,6); endchar;
  495.  
  496. cmchar "Large triangle";
  497. beginchar(oct"064",16u#,asc_height#,desc_depth#);
  498. adjust_fit(0,0); pickup rule.nib;
  499. bot y1=0; y2=y1; top y3=h+o;
  500. .5[x1,x2]=x3=good.x .5w; w:=r:=2x3; lft x1=hround(.5w-u*sqrt48);
  501. draw z1--z2--z3--cycle;  % stroke
  502. labels(1,2,3); endchar;
  503.  
  504. cmchar "Large inverted triangle";
  505. beginchar(oct"065",16u#,asc_height#,desc_depth#);
  506. adjust_fit(0,0); pickup rule.nib;
  507. top y1=h-d; y2=y1; bot y3=-d-o;
  508. .5[x1,x2]=x3=good.x .5w; w:=r:=2x3; lft x1=hround(.5w-u*sqrt48);
  509. draw z1--z2--z3--cycle;  % stroke
  510. labels(1,2,3); endchar;
  511.  
  512. cmchar "Zero-width slash to negate a relation";
  513. beginchar(oct"066",14u#,asc_height#,asc_depth#);
  514. adjust_fit(0,0); pickup rule.nib;
  515. rt x5=hround(w-2.5u)-eps; lft x6=hround 2.5u+eps;
  516. top y5=h+o; .5[y5,y6]=math_axis;
  517. draw z5--z6;  % diagonal
  518. labels(1,2); zero_width; endchar;
  519.  
  520. cmchar "Maps-to relation";
  521. compute_spread(.45x_height#,.55x_height#);
  522. beginchar(oct"067",14u#,v_center(spread#+rule_thickness#));
  523. % this character should be followed immediately by minus or rightarrow
  524. adjust_fit(0,0); pickup rule.nib;
  525. lft x1=hround u; x2=x1+.5u; x3=x4=x1;
  526. y1=y2=math_axis; y1-y3=y4-y1=.24asc_height+eps;
  527. draw z3--z4;  % stem
  528. draw z1--z2;  % bar stub
  529. labels(1,2,3,4); zero_width; endchar;
  530.  
  531. cmchar "Empty set symbol";
  532. beginchar(oct"073",9u#,body_height#,body_height#-asc_height#);
  533. adjust_fit(0,0);
  534. penpos1(vair,90); penpos3(vair,-90); penpos2(stem,180); penpos4(stem,0);
  535. if not monospace: interim superness:=sqrt(more_super*hein_super); fi
  536. x2r=hround max(.7u,1.45u-.5stem);
  537. x4r=w-x2r; x1=x3=.5w; y1r=asc_height+o; y3r=-o;
  538. y2=y4=.5asc_height-vair_corr; y2l:=y4l:=.52asc_height;
  539. penstroke pulled_arc.e(1,2) & pulled_arc.e(2,3)
  540.  & pulled_arc.e(3,4) & pulled_arc.e(4,1) & cycle;  % bowl
  541. pickup rule.nib; lft x6=hround 2u-eps; x5=w-x6; top y5=h+o; bot y6=-d-o;
  542. draw z5--z6;  % diagonal
  543. penlabels(1,2,3,4,5,6); endchar;
  544.  
  545. cmchar "Uppercase Fraktur R";
  546. beginchar(oct"074",13u#,asc_height#,0);
  547. adjust_fit(0,0); pickup fine.nib;
  548. pos1(hair,0); pos2(vair,90); pos3(1/6[hair,stem],190);
  549. pos4(1/4[hair,stem],210); pos5(1/8[hair,stem],190);
  550. pos6(vair,90); pos7(cap_stem,0); pos8(cap_stem,0);
  551. pos9(vair,-90); pos10(hair,-135); pos11(hair,-135);
  552. pos12(vair,135); pos13(vair,135);
  553. lft x1l=lft x5r=hround u; x2=.4[x1,x3]; rt x3l=hround 3.5u; x4=.6[x3,x5];
  554. x6=3u; lft x7=hround(6u-.5cap_stem); x8=x7;
  555. x9=3.5u; x10=5/3u; x11=4/3u; x12=u; x13=2u;
  556. y1=.47h; bot y2l=vround.35h; y3=1/3[y2,y6]; y5=3/4[y2,y6]; y4=.6[y3,y5];
  557. top y6r=h+oo; y7=.64h; y8=.57y7; bot y9r=-o;
  558. y10=1/6y7; y12=1/5y7; y13=1/4y7;
  559. z11-z10=whatever*(z13-z12) rotated 90;
  560. filldraw stroke z1e{down}...z2e{right}...z3e{up}..z4e..z5e{up}
  561.  ...pulled_arc.e(6,7)..pulled_arc.e(8,9)
  562.  ...z10e---z11e;  % flourish and left stem
  563. filldraw stroke z12e--z13e;  % cross
  564. pos20(cap_bar,180); pos21(cap_bar,90);
  565. x20=x7; y20=.75h; rt x21=hround(w-3.5u+.5cap_stem); top y21r=h+o;
  566. filldraw stroke z20e{up}...{right}z21e;  % top of bowl
  567. rt x22r=hround(w-.1u); y22r=good.y .64h;
  568. numeric theta; theta=angle(z21r-z22r);
  569. pos22(cap_stem,theta-90); pos23(cap_bar,theta); z22l=z23l;
  570. path p; p=z20{up}...(z21--(w,y21));
  571. z=p intersectionpoint(z22l--z22l+(h,0) rotated theta);
  572. filldraw z--z21r--z22r--z22l--cycle;  % diagonal of bowl
  573. pos24(cap_bar,90); pos25(cap_bar,90); x24=w-4u; x25=x7;
  574. y24=y25; top y24r=vround(.52h+.5cap_bar);
  575. filldraw stroke z23e{dir(theta+90)}...z24e---z25e;  % bottom of bowl
  576. pos26(cap_stem,0); pos27(cap_stem,0); pos28(cap_stem,0);
  577. x26=x24; x27=x26+.25u; x28l=w-2.5u; y26=y24r; y27=1/3y26; bot y28=-o;
  578. filldraw stroke z26e--z27e...{right}z28e;  % lower diagonal
  579. pos29(cap_bar,0); pos30(cap_bar,-30); z29l=z28l;
  580. x30r=good.x(w-.5u); y30r=good.y .09h;
  581. erase filldraw z29r--z28r--z30r--cycle;  % erase excess
  582. filldraw stroke z29e--z30e;  % serif of lower diagonal
  583. %% \begingroup\thinmuskip=3mu
  584. penlabels(1,2,3,4,5,6,7,8,9,10,11,12,13,20,21,22,23,24,25,26,27,28,29,30);
  585. %% \endgroup
  586. endchar;
  587.  
  588. cmchar "Uppercase Fraktur I";
  589. beginchar(oct"075",13u#,asc_height#,0);
  590. adjust_fit(0,0); pickup fine.nib;
  591. pos1(vair,270); pos2(cap_hair,180); pos3(vair,90);
  592. pos4(cap_stem,0); pos5(vair,90); pos6(cap_hair,180);
  593. x1=5u; lft x2r=hround u; x3=.5[x2,x4l]; x4r=x5-.75u;
  594. x5=.5[x4l,x6l]; rt x6l=hround(w-.5u);
  595. top y1l=vround.5h; y2=.5[y1,y3]; top y3r=h+oo;
  596. y4=.2[y5,y3]; y6=.3[y5,y3]; bot y5l=ceiling(1/6[x_height,h]);
  597. filldraw stroke z1e{left}...z2e{up}...z3e{right}
  598.  ..z4e..z5e{right}...{up}z6e;  % upper stroke
  599. pos7(vair,90); pos8(cap_stem,0); pos9(cap_stem,0);
  600. lft x7=hround u; z7r=z8l; x9=.5w+u; y8=good.y .25h; bot y9=-oo;
  601. filldraw z8l---z8r..{right}z9r+(0,eps)
  602.  --z9r---z9l..{left}z7l--cycle;  % lower left stroke
  603. pos10(cap_stem,0); pos11(cap_stem,0); pos12(vair,-90); pos13(cap_hair,-180);
  604. x10=w-2.5u; x11r=x12-u; x12=x5; x13=x6;
  605. y10=1/3y12; y11=3/4y12; top y12l=x_height; y13=4/5y12;
  606. filldraw z9l+(0,eps){right}...{up}z10l
  607.  --z10r{down}...z9r---z9l--cycle;  % lower link
  608. filldraw stroke z10e{up}...z11e{up}
  609.  ...z12e{right}...{down}z13e;  % lower right stroke
  610. penlabels(1,2,3,4,5,6,7,8,9,10,11,12,13); endchar;
  611.  
  612. cmchar "Lattice top";
  613. beginchar(oct"076",14u#,asc_height#,0);
  614. adjust_fit(0,0); pickup rule.nib;
  615. x1=x2=good.x .5w; w:=r:=2x1; lft x3=hround u; x4=r-x3;
  616. bot y1=0; y2-y1=x4-x3;
  617. if top y2>h: y2:=bot h; fi
  618. y3=y4=y2;
  619. draw z1--z2;  % stem
  620. draw z3--z4;  % bar
  621. labels(1,2,3,4); endchar;
  622.  
  623. cmchar "Perpendicular sign or lattice bottom";
  624. beginchar(oct"077",14u#,asc_height#,0);
  625. adjust_fit(0,0); pickup rule.nib;
  626. x1=x2=good.x .5w; w:=r:=2x1; lft x3=hround u; x4=r-x3;
  627. bot y1=0; y2-y1=x4-x3;
  628. if top y2>h: y2:=bot h; fi
  629. y3=y4=y1;
  630. draw z1--z2;  % stem
  631. draw z3--z4;  % bar
  632. labels(1,2,3,4); endchar;
  633.  
  634. cmchar "Hebrew letter aleph";
  635. beginchar(oct"100",11u#,asc_height#,0);
  636. adjust_fit(0,0); pickup fine.nib;
  637. pos1(cap_stem,75); pos2(cap_stem,90); pos3(cap_stem,90); pos4(cap_stem,75);
  638. lft x1l=hround u-eps; x2=2.5u=w-x3; rt x4r=hround(w-u)+eps;
  639. top y1r=h; bot y4l=0; z2=whatever[z1l,z4r]; z3=whatever[z1l,z4r];
  640. filldraw z1r{4(x1l-x1r),y1l-y1r}...{down}z1l...z2l
  641.  ---z3l...{down}z4l{4(x4r-x4l),y4r-y4l}...{up}z4r...z3r
  642.  ---z2r...{up}cycle; % long diagonal
  643. pos5(cap_stem,75); pos6(cap_stem,90); pos7(cap_stem,75);
  644. lft x5l=hround(w-4u)-eps; x6=.5[x5,x7]; x7=x4;
  645. y5=y1; bot y7l=x_height-o; z6=whatever[z5l,z7r];
  646. filldraw z5r{4(x5l-x5r),y5l-y5r}...{down}z5l
  647.  ...z6l{z7r-z5l}...{down}z7l{4(x7r-x7l),y7r-y7l}...{up}z7r
  648.  ...z6r{z5l-z7l}...{up}cycle; % short diagonal
  649. pos8(cap_hair,0); pos9(cap_hair,0); z8=z6; x9=x8-.75u; z9=whatever[z2,z3];
  650. filldraw stroke z8e{down}..{down}z9e;  % right stem
  651. pos10(cap_hair,-30); pos11(stem,0);
  652. pos12(cap_curve,0); pos13(cap_curve,0); pos14(vair,90);
  653. lft x11l=hround 1.5u; x10=x12=.4[x11,.5w]; z10=whatever[z2,z3];
  654. lft x13l=hround u; z13l=z14l; y11=.5y10; y12=.2[y14r,y11]; bot y13=0;
  655. filldraw stroke z10e{2(x11-x10),y11-y10}
  656.  ...z11e{down}..{down}z12e; % left stem
  657. filldraw z12r{down}...z13r---z13l--z14r{right}...{up}z12l--cycle; % flourish
  658. penlabels(1,2,3,4,5,6,7,8,9,10,11,12,13,14); endchar;
  659.  
  660. cmchar "Multiset union sign";
  661. beginchar(oct"135",12u#,.8asc_height#,0); autorounded;
  662. adjust_fit(if monospace:-.5u#,-.5u# else: 0,0 fi); pickup rule.nib;
  663. lft x1=hround u; x2=x1; x3=w-x3; x4=x5=w-x1;
  664. y1=good.y h+o; bot y3=-o; y2=y4=2/3[y1,y3]; y5=y1;
  665. draw z1---z2...z3...z4---z5;  % stems and cup
  666. y8=y9=.47[y1,y3]; x8=w-x9=x1+2rule_thickness+eps;
  667. x6=x7=x3; .5[y6,y7]=y8; y7-y6=x9-x8;
  668. draw z8--z9; draw z6--z7;  % enclosed plus sign
  669. labels(1,2,3,4,5,6,7,8,9); endchar;
  670.  
  671. cmchar "Left turnstile";
  672. beginchar(oct"140",11u#,asc_height#,0);
  673. adjust_fit(0,0); pickup rule.nib;
  674. .5[y1,y2]=y3=y4; x1=x2=x3;
  675. lft x3=hround u; x4=w-x3; top y1=h; bot y2=0;
  676. draw z1--z2;  % stem
  677. draw z3--z4;  % bar
  678. labels(1,2,3,4); endchar;
  679.  
  680. cmchar "Right turnstile";
  681. beginchar(oct"141",11u#,asc_height#,0);
  682. adjust_fit(0,0); pickup rule.nib;
  683. .5[y1,y2]=y3=y4; x1=x2=x4;
  684. lft x3=hround u; x4=w-x3; top y1=h; bot y2=0;
  685. draw z1--z2;  % stem
  686. draw z3--z4;  % bar
  687. labels(1,2,3,4); endchar;
  688.  
  689. cmchar "Left floor bracket";
  690. beginchar(oct"142",8u#,body_height#,paren_depth#);
  691. adjust_fit(0,0); pickup rule.nib;
  692. x1=x2=good.x 3.5u; x3=x1+3.75u+eps;
  693. top y1=h; .5[y1,y2]=math_axis; y3=y2;
  694. draw z1--z2--z3;  % stem and bar
  695. labels(1,2,3); endchar;
  696.  
  697. cmchar "Right floor bracket";
  698. beginchar(oct"143",8u#,body_height#,paren_depth#);
  699. adjust_fit(0,0); pickup rule.nib;
  700. x1=x2=good.x(w-3.5u); x3=x1-3.75u-eps;
  701. top y1=h; .5[y1,y2]=math_axis; y3=y2;
  702. draw z1--z2--z3;  % stem and bar
  703. labels(1,2,3); endchar;
  704.  
  705. cmchar "Left ceiling bracket";
  706. beginchar(oct"144",8u#,body_height#,paren_depth#);
  707. adjust_fit(0,0); pickup rule.nib;
  708. x1=x2=good.x 3.5u; x3=x1+3.75u+eps;
  709. top y1=h; .5[y1,y2]=math_axis; y3=y1;
  710. draw z3--z1--z2;  % stem and bar
  711. labels(1,2,3); endchar;
  712.  
  713. cmchar "Right ceiling bracket";
  714. beginchar(oct"145",8u#,body_height#,paren_depth#);
  715. adjust_fit(0,0); pickup rule.nib;
  716. x1=x2=good.x(w-3.5u); x3=x1-3.75u-eps;
  717. top y1=h; .5[y1,y2]=math_axis; y3=y1;
  718. draw z3--z1--z2;  % stem and bar
  719. labels(1,2,3); endchar;
  720.  
  721. cmchar "Left angle bracket";
  722. beginchar(oct"150",7u#,body_height#,paren_depth#);
  723. adjust_fit(0,0); pickup rule.nib;
  724. rt x1=hround(w-u)+eps; x1=x3; lft x2=hround 2u-1-eps;
  725. top y1=h+eps; .5[y1,y3]=y2=math_axis;
  726. draw z1--z2--z3;  % diagonals
  727. labels(1,2,3); endchar;
  728.  
  729. cmchar "Right angle bracket";
  730. beginchar(oct"151",7u#,body_height#,paren_depth#);
  731. adjust_fit(0,0); pickup rule.nib;
  732. rt(w-x1)=hround(w-u)+eps; x1=x3; lft(w-x2)=hround 2u-1-eps;
  733. top y1=h+eps; .5[y1,y3]=y2=math_axis;
  734. draw z1--z2--z3;  % diagonals
  735. labels(1,2,3); endchar;
  736.  
  737. cmchar "Double vertical line (norm or cardinality)";
  738. beginchar(oct"153",9u#,body_height#,paren_depth#);
  739. adjust_fit(0,0); pickup rule.nib;
  740. x1=x2; top y1=h; .5[y1,y2]=math_axis;
  741. x3=x4=w-x1; y3=y1; y4=y2;
  742. compute_spread(.45x_height#,.55x_height#); x3-x1=spread;
  743. draw z1--z2; draw z3--z4;  % stems
  744. labels(1,2,3,4); endchar;
  745.  
  746. cmchar "Up-and-down arrow";
  747. beginchar(oct"154",9u#,body_height#,paren_depth#);
  748. adjust_fit(0,0); pickup crisp.nib;
  749. pos1(rule_thickness,0); pos2(rule_thickness,0);
  750. pos3(bar,90); pos4(bar,90);
  751. lft x1l=hround(.5w-.5rule_thickness); y1=.5[-d,h];
  752. x0=x1=x2; bot y0=-d-o; x0-x3=x4-x0=3u+eps;
  753. y3=y4=y0+.24asc_height+eps;
  754. pos5(bar,angle(z4-z0)); z5l=z0; pos6(bar,angle(z3-z0)); z6l=z0;
  755. z9=.381966[.5[z3,z4],z0];
  756. numeric t; path p; p=z4r{z9-z4}..z6r;
  757. t=xpart(p intersectiontimes((x2r,-d)--(x2r,h))); y2=ypart point t of p;
  758. filldraw z0..{z4-z9}z4l--subpath (0,t) of\\(z4r{z9-z4}..z6r)
  759.  --z2r---z1r..z1l---z2l--subpath (t,0) of\\(z3r{z9-z3}..z5r)
  760.  --z3l{z9-z3}..z0 & cycle;  % lower arrowhead and stem
  761. pos11(rule_thickness,0); pos12(rule_thickness,0); z11=z1;
  762. pos13(bar,90); pos14(bar,90);
  763. x10=x11=x12; top y10=h+o; x10-x13=x14-x10=3u+eps;
  764. y13=y14=y10-.24asc_height-eps;
  765. pos15(bar,angle(z14-z10)); z15l=z10; pos16(bar,angle(z13-z10)); z16l=z10;
  766. z19=.381966[.5[z13,z14],z10];
  767. numeric t; path p; p=z14l{z19-z14}..z16r;
  768. t=xpart(p intersectiontimes((x12r,-d)--(x12r,h))); y12=ypart point t of p;
  769. filldraw z10..{z14-z19}z14r--subpath (0,t) of\\(z14l{z19-z14}..z16r)
  770.  --z12r---z11r..z11l---z12l--subpath (t,0) of\\(z13l{z19-z13}..z15r)
  771.  --z13r{z19-z13}..z10 & cycle;  % upper arrowhead and stem
  772. penlabels(0,1,2,3,4,5,6,9,10,11,12,13,14,15,16,19); endchar;
  773.  
  774. cmchar "Double up-and-down arrow";
  775. beginchar(oct"155",11u#,body_height#,paren_depth#);
  776. adjust_fit(0,0); pickup rule.nib;
  777. compute_spread(.45x_height#,.55x_height#);
  778. bot y1=bot y2=-d-eps; top y7=h; y8=y7;
  779. x1=x7; x2=x8; x1-x2=spread; .5[x1,x2]=crisp.lft hround(crisp.rt .5w);
  780. draw z1--z7; draw z2--z8;  % bars
  781. pickup crisp.nib; top y0=h+o; x0=good.x .5w;
  782. pos3(rule_thickness,90); pos4(rule_thickness,90);
  783. x2-x3=x4-x1=3u+eps; y3=y4=y0-.4asc_height-eps;
  784. pos5(rule_thickness,angle(z4-z0)); z5l=z0;
  785. pos6(rule_thickness,angle(z3-z0)); z6l=z0;
  786. z9=.381966[.5[z3,z4],z0];
  787. erase filldraw z0..{z3-z9}z3--(x3,h)
  788.  --(x4,h)--z4{z9-z4}..z0 & cycle;  % erase excess at top
  789. numeric t; path p; p=z4l{z9-z4}..z6r;
  790. t=xpart(p intersectiontimes((x0,-d)--(x0,h)));
  791. filldraw z0..{z4-z9}z4r--subpath (0,t) of\\(z4l{z9-z4}..z6r)
  792.  --subpath (t,0) of\\(z3l{z9-z3}..z5r)
  793.  --z3r{z9-z3}..z0 & cycle;  % top arrowhead
  794. bot y10=-d-o; x10=good.x .5w;
  795. pos13(rule_thickness,90); pos14(rule_thickness,90);
  796. x13=x3; x14=x4; y13=y14=y10+.4asc_height-eps;
  797. pos15(rule_thickness,angle(z14-z10)); z15l=z10;
  798. pos16(rule_thickness,angle(z13-z10)); z16l=z10;
  799. z19=.381966[.5[z13,z14],z10];
  800. erase filldraw z10..{z13-z19}z13--(x13,-d)
  801.  --(x14,-d)--z14{z19-z14}..z10 & cycle;  % erase excess at bottom
  802. numeric t; path p; p=z14r{z19-z14}..z16r;
  803. t=xpart(p intersectiontimes((x10,-d)--(x10,h)));
  804. filldraw z10..{z14-z19}z14l--subpath (0,t) of\\(z14r{z19-z14}..z16r)
  805.  --subpath (t,0) of\\(z13r{z19-z13}..z15r)
  806.  --z13l{z19-z13}..z10 & cycle;  % bottom arrowhead
  807. penlabels(0,1,2,3,4,5,6,7,8,9,13,14,15,16,19); endchar;
  808.  
  809. cmchar "Wreath product";
  810. beginchar(oct"157",5u#,asc_height#,asc_depth#);
  811. adjust_fit(if monospace: u#,u# else: 0,0 fi);
  812. pickup pencircle yscaled .7rule_thickness xscaled 1.4rule_thickness;
  813. if vair#>.8curve#: pickup rule.nib; autorounded; fi % monoline
  814. lft x1=lft x3=hround u; x2=x4=w-x1;
  815. top y1=vround .75[math_axis,h];
  816. .5[y1,y4]=.5[y2,y3]=math_axis; y1-y2=1/4(y1-y4);
  817. draw z1{right}...z2{down}..{down}z3...{right}z4;  % stroke
  818. labels(1,2,3,4); endchar;
  819.  
  820. cmchar "Radical sign";
  821. beginchar(oct"160",15u#,rule_thickness#,
  822.  body_height#+paren_depth#-rule_thickness#);
  823. big_sqrt; endchar;
  824.  
  825. cmchar "Amalgamation symbol or coproduct symbol";
  826. beginchar(oct"161",13u#+width_adj#,cap_height#,0);
  827. italcorr cap_height#*slant-cap_serif_fit#+cap_jut#-2.5u#+min(.5cap_stem#,u#);
  828. adjust_fit(cap_serif_fit#,cap_serif_fit#);
  829. pickup tiny.nib; pos1(cap_stem,0); pos2(cap_stem,0);
  830. pos3(cap_stem,0); pos4(cap_stem,0);
  831. lft x1l=lft x2l=hround max(2u,3u-.5cap_stem); x3=x4=w-x1;
  832. top y1=top y3=h; bot y2=bot y4=0;
  833. filldraw stroke z1e--z2e; % left stem
  834. filldraw stroke z3e--z4e; % right stem
  835. penpos5(cap_bar,90); penpos6(cap_bar,90);
  836. x5=x1; x6=x3; y5=y6; y5l=0;
  837. fill stroke z5e--z6e;  % bar
  838. if serifs: numeric inner_jut;
  839.  if rt x1r+cap_jut+u+2<=lft x3l-cap_jut: inner_jut=cap_jut;
  840.  else: rt x1r+inner_jut+u+2=lft x3l-inner_jut; fi
  841.  dish_serif(1,2,a,1/3,cap_jut,b,1/3,inner_jut);  % upper left serif
  842.  nodish_serif(2,1,c,1/3,cap_jut,d,1/3,eps); % lower left serif
  843.  dish_serif(3,4,e,1/3,inner_jut,f,1/3,cap_jut);  % upper right serif
  844.  nodish_serif(4,3,g,1/3,eps,h,1/3,cap_jut); fi  % lower right serif
  845. math_fit(0,.5ic#); penlabels(1,2,3,4,5,6); endchar;
  846.  
  847. cmchar "Nabla or backwards-difference operator";
  848. beginchar(oct"162",15u#,cap_height#,0);
  849. adjust_fit(0,0);
  850. numeric right_stem,alpha;
  851. right_stem=cap_hair if hefty: -3stem_corr fi;
  852. x1l=w-x4r=.75u; y1=y4=h;
  853. x2-x1=x4-x3; x3l=x2l+apex_corr; y2=y3=-apex_o-apex_oo;
  854. alpha=diag_ratio(2,right_stem,y1-y2,x4r-x1l-apex_corr);
  855. penpos1(alpha*cap_stem,0); penpos2(alpha*cap_stem,0);
  856. penpos3(alpha*right_stem,0); penpos4(alpha*right_stem,0);
  857. fill diag_end(2l,1l,1,1,4r,3r)--diag_end(4r,3r,1,1,2l,1l)--cycle;  % triangle
  858. z0=whatever[z1r,z2r]=whatever[z3l,z4l];
  859. y5=y6=h-cap_vstem; z5=whatever[z1r,z2r]; z6=whatever[z3l,z4l];
  860. if y0>cap_notch_cut: y0:=cap_notch_cut;
  861.  unfill z0+.5right{up}...{z4-z3}z6--z5{z2-z1}
  862.   ...{down}z0+.5left--cycle; % counter
  863. else: unfill z0--z5--z6--cycle; fi  % counter
  864. penlabels(0,1,2,3,4,5,6); endchar;
  865.  
  866. cmchar "Square set union sign (Scott lub)";
  867. beginchar(oct"164",12u#,.8asc_height#,0);
  868. adjust_fit(0,0); pickup rule.nib;
  869. lft x1=hround 1.1u; x2=x1; x4=x5=w-x1;
  870. y1=good.y h+o; bot y2=0; y4=y2; y5=y1;
  871. draw z1---z2---z4---z5;  % stems and bar
  872. labels(1,2,4,5); endchar;
  873.  
  874. cmchar "Square set intersection sign (Scott glb)";
  875. beginchar(oct"165",12u#,.8asc_height#,0);
  876. adjust_fit(0,0); pickup rule.nib;
  877. lft x1=hround 1.1u; x2=x1; x4=x5=w-x1;
  878. y2=good.y h+o; bot y1=0; y4=y2; y5=y1;
  879. draw z1---z2---z4---z5;  % stems and bar
  880. labels(1,2,4,5); endchar;
  881.  
  882. cmchar "Square subset or equal to sign";
  883. compute_spread(.45x_height#,.55x_height#);
  884. spread#':=spread#; spread':=spread; % the spread of `$=$'
  885. compute_spread(5/4x_height#,3/2x_height#);
  886. beginchar(oct"166",14u#,v_center(spread#'+spread#+rule_thickness#));
  887. adjust_fit(0,0); pickup rule.nib;
  888. lft x2=hround(1.5u+oo); x1=x4=hround(w-1.5u)+eps; x3=x2;
  889. y1-y4=spread; y2=y1; y3=y4; top y1=h;
  890. draw z1--z2--z3--z4;  % bars and stem
  891. x8=x1; x9=x2-oo-eps; y8=y9; y4-y9=spread';
  892. draw z8--z9;  % lower bar
  893. labels(1,2,3,4,8,9); endchar;
  894.  
  895. cmchar "Square superset or equal to sign";
  896. compute_spread(.45x_height#,.55x_height#);
  897. spread#':=spread#; spread':=spread; % the spread of `$=$'
  898. compute_spread(5/4x_height#,3/2x_height#);
  899. beginchar(oct"167",14u#,v_center(spread#'+spread#+rule_thickness#));
  900. adjust_fit(0,0); pickup rule.nib;
  901. x1=x4=hround 1.5u-eps; rt x2=hround(w-1.5u-oo); x3=x2;
  902. y1-y4=spread; y2=y1; y3=y4; top y1=h;
  903. draw z1--z2--z3--z4;  % bars and stem
  904. x8=x1; x9=x2+oo+eps; y8=y9; y4-y9=spread';
  905. draw z8--z9;  % lower bar
  906. labels(1,2,3,4,8,9); endchar;
  907.  
  908. cmchar "Section sign";
  909. beginchar(oct"170",6.5u#+max(1.5u#,stem#),asc_height#,desc_depth#);
  910. adjust_fit(0,0); pickup fine.nib;
  911. numeric sstem; sstem=hround .75[hair,stem];
  912. pos0(stem,0); pos1(hair,0); pos2(vair,90); pos3(sstem,180); pos4(vair,270);
  913. pos5'(sstem,0); pos5(sstem,180);
  914. pos6(vair,90); pos7(sstem,0); pos8(vair,-90); pos9(hair,-180); pos10(stem,-180);
  915. top y2r=h+oo; bot y8r=-d-oo; y2-y1=y9-y8=(y2-y8)/8;
  916. y3=.52[y4,y2]; y5=.52[y4,y6]; y7=.52[y6,y8]; y5'=.52[y6,y4];
  917. y2-y4=y4-y6=y6-y8;
  918. rt x1r=hround(w-1.5u); lft x3r=hround 1.25u;
  919. x2=x4=x6=x8=.5w; x5=x7=w-x3; x5'=x3; x9=w-x1;
  920. bulb(2,1,0); bulb(8,9,10);  % bulbs
  921. filldraw stroke z2e{left}...z3e{down}...z4e{3(x5-x3),y5-y3}
  922.  ...z5e{down}...{left}z6e;  % upper stroke
  923. filldraw stroke z4e{left}...z5'e{down}...z6e{3(x7-x5'),y7-y5'}
  924.  ...z7e{down}...{left}z8e;  % upper stroke
  925. penlabels(0,1,2,3,4,5,6,7,8,9,10); endchar;
  926.  
  927. cmchar "Dagger mark";
  928. beginchar(oct"171",8u#,asc_height#,desc_depth#);
  929. adjust_fit(0,0); pickup fine.nib;
  930. pos1(stem,0); pos2(thin_join,0); pos3(stem,0); pos4(hair,0);
  931. pos5(stem,90); pos2'(thin_join,90); pos6(stem,90); z2'=z2;
  932. x1=x2=x3=x4; x1-.5stem=hround(.5w-.5stem); w:=r:=2x1;
  933. x5-.5stem=hround u; x6=w-x5;
  934. y1+.5stem=h+oo; y2=y5=y6; y3=.57y2; bot y4=-d-o;
  935. y5+.5stem=floor(x_height+.5stem);
  936. filldraw circ_stroke z1e{down}..z2e{down}..z3e{down}..z4e;  % stem
  937. filldraw circ_stroke z5e{right}..{right}z2'e;  % left bulb
  938. filldraw circ_stroke z6e{left}..{left}z2'e;  % right bulb
  939. penlabels(1,2,3,4,5,6); endchar;
  940.  
  941. cmchar "Double dagger mark";
  942. beginchar(oct"172",8u#,asc_height#,desc_depth#);
  943. adjust_fit(0,0); pickup fine.nib;
  944. pos1(stem,0); pos2(thin_join,0); pos3(stem,0);
  945. pos4(stem,90); pos2'(thin_join,90); pos5(stem,90); z2'=z2;
  946. x1=x2=x3; x1-.5stem=hround(.5w-.5stem); w:=r:=2x1;
  947. x4-.5stem=hround u; x5=w-x4;
  948. y1+.5stem=h+oo; y2=y4=y5=.5[y1,y3]; y3-.5stem=ceiling(.5[-d,h]);
  949. filldraw circ_stroke z1e{down}..{down}z2e;  % top stem
  950. filldraw circ_stroke z3e{up}..{up}z2e;    % upper middle stem
  951. filldraw circ_stroke z4e{right}..{right}z2'e;  % top left bulb
  952. filldraw circ_stroke z5e{left}..{left}z2'e;  % top right bulb
  953. pos6(stem,0); pos7(thin_join,0); pos8(stem,0);
  954. pos9(stem,90); pos7'(thin_join,90); pos0(stem,90); z7'=z7;
  955. x6=x7=x8=x1; x9=x4; x0=x5;
  956. y6=y3-stem-1; y7=y9=y0=.5[y6,y8]; y8-.5stem=-d-oo;
  957. filldraw circ_stroke z6e{down}..{down}z7e;  % lower middle stem
  958. filldraw circ_stroke z8e{up}..{up}z7e;    % bottom stem
  959. filldraw circ_stroke z9e{right}..{right}z7'e;  % bottom left bulb
  960. filldraw circ_stroke z0e{left}..{left}z7'e;  % bottom right bulb
  961. penlabels(1,2,3,4,5,6,7,8,9,0); endchar;
  962.  
  963. cmchar "Paragraph mark";
  964. beginchar(oct"173",11u#,asc_height#,desc_depth#);
  965. adjust_fit(0,0); pickup rule.nib; autorounded;
  966. top y1=h; bot y6=-d-eps; y4=y7=y9=y1;
  967. y8=y6; y3=y5=good.y .5[y1,y6];
  968. x7-x4=ceiling(rule_thickness+1.25u);
  969. lft x2=hround u; y2=.5[y1,y3]; x4=x5=x6; rt x9=hround(w-.5u);
  970. x7=x8=good.x(x9-1.5u); x1=x3=min(.5w,x4);
  971. filldraw z4..z1{left}...z2{down}...{right}z5--cycle;  % filled bowl
  972. draw z9--z4--z6;  % left stem and upper serif
  973. draw z7--z8;  % right stem
  974. labels(1,2,3,4,5,6,7,8,9); endchar;
  975.  
  976. cmchar "Club suit";
  977. beginchar(oct"174",14u#,asc_height#,2/3desc_depth#);
  978. adjust_fit(0,0); pickup rule.nib; autorounded;
  979. x1=x4=x30=x33=good.x .5w; w:=r:=2x1;
  980. x2=good.x(x1-.5u)-eps; lft x1-rt x10=hround .5pt; lft x12=hround .5u;
  981. x11=.6[x12,x10]; x13=.5[x12,x10]=x5; x32-x31=x1-.5u-x12;
  982. x2+x3=x5+x6=x10+x20=x11+x21=x12+x22=x13+x23=x31+x32=2x1;
  983. top y30=h+o+oo; bot y11=bot y21=-o; top y13=top y23=vround .53h;
  984. y30-y33=y13-y11; y31=y32=y4=.5[y30,y33]; y12=y22=.5[y11,y13];
  985. y1=y10=y20=good.y .1h; bot y5=bot y6=y1+.75; bot y2=bot y3=-d;
  986. filldraw z30{left}...z31{down}...z33{right}...z32{up}...cycle;  % top bowl
  987. filldraw z13{left}...z12{down}...z11{right}...z10{up}...cycle;  % left bowl
  988. filldraw z23{left}...z20{down}...z21{right}...z22{up}...cycle;  % right bowl
  989. filldraw z1{down}...{2(x2-x1),y2-y1}z2--z3{2(x1-x3),y1-y3}
  990.  ...{up}cycle;  % stem
  991. filldraw z4--z5--z6--cycle;  % filling
  992. labels(1,2,3,4,5,6,10,11,12,13,20,21,22,23,30,31,32,33); endchar;
  993.  
  994. cmchar "Diamond suit";
  995. beginchar(oct"175",14u#,asc_height#,2/3desc_depth#);
  996. adjust_fit(0,0); pickup rule.nib; autorounded;
  997. x1=x4=good.x .5w; w:=r:=2x1;
  998. lft x2=hround u; x3=w-x2;
  999. top y1=h+o+oo; bot y4=-d-o-oo; y2=y3=.5[y1,y4];
  1000. draw z1{x3-x1,1.5(y3-y1)}...z3{1.5(x3-x1),y3-y1};  % upper right diagonal
  1001. draw z1{x2-x1,1.5(y2-y1)}...z2{1.5(x2-x1),y2-y1};  % upper left diagonal
  1002. draw z4{x2-x4,1.5(y2-y4)}...z2{1.5(x2-x4),y2-y4};  % lower left diagonal
  1003. draw z4{x3-x4,1.5(y3-y4)}...z3{1.5(x3-x4),y3-y4};  % lower right diagonal
  1004. labels(1,2,3,4); endchar;
  1005.  
  1006. cmchar "Heart suit";
  1007. beginchar(oct"176",14u#,asc_height#,2/3desc_depth#);
  1008. adjust_fit(0,0); pickup rule.nib; autorounded;
  1009. x1=x5=good.x .5w; w:=r:=2x1;
  1010. lft x7=hround u; x8=4u; x2+x8=x3+x7=x4+x6=w;
  1011. y1=good.y .77h; top y2=h+o; y3=.7h; y4=.2h; bot y5=-o-oo;
  1012. y2=y8; y3=y7; y4=y6; z4=whatever[z3,z5];
  1013. x0=x9=w; y0=1.5h; y9=.6h;
  1014. draw z1{x2-x1,8(y2-y1)}...z2{right}....z3{down}...{z4-z9}z4
  1015.  ...{z5-z0}z5;  % right half bowl
  1016. draw z1{x8-x1,8(y8-y1)}...z8{left}....z7{down}...{(z4-z9)xscaled-1}z6
  1017.  ...{(z5-z0)xscaled-1}z5;  % left half bowl
  1018. labels(0,1,2,3,4,5,6,7,8,9); endchar;
  1019.  
  1020. cmchar "Spade suit";
  1021. beginchar(oct"177",14u#,asc_height#,2/3desc_depth#);
  1022. adjust_fit(0,0); pickup rule.nib; autorounded;
  1023. x1=x10=good.x .5w; w:=r:=2x1;
  1024. x2=good.x(x1-.5u)-eps; lft x1-rt x6=hround .5pt; x5=x6;
  1025. x7=.5[x8,x6]; lft x8=hround u;
  1026. x2+x3=x5+x15=x6+x14=x7+x13=x8+x12=x9+x11=2x10;
  1027. top y10=h+o+oo; y9=y11=.7h; y8=y12=.3h;
  1028. y1=y6=y14=good.y .1h; bot y5=bot y15=y1+.75;
  1029. bot y7=bot y13=-o; bot y2=bot y3=-d; z9=whatever[z8,z10];
  1030. filldraw z10{-w,-3h}...z9{-w,-h}...z8{down}...z7{right}...z6---z5
  1031.  --z15---z14...{right}z13...{up}z12...{-w,h}z11
  1032.  ...{-w,3h}cycle;  % filled bowl
  1033. filldraw z1{down}...{2(x2-x1),y2-y1}z2--z3{2(x1-x3),y1-y3}
  1034.  ...{up}cycle;  % stem
  1035. labels(1,2,3,5,6,10,11,12,13,14,15); endchar;
  1036.