home *** CD-ROM | disk | FTP | other *** search
/ Atari FTP / ATARI_FTP_0693.zip / ATARI_FTP_0693 / Tex / mf_three.arc / ROMLIG.MF < prev    next >
Text File  |  1988-11-22  |  8KB  |  164 lines
  1. % This file describes five roman ligatures that begin with `f'
  2. % and puts them in code positions \0013--\0017.
  3.  
  4. numeric itc#; % modified italic correction on `f' and `ff'
  5. itc#=if serifs: max(0,flare#-.25u#) else: 1.25u# fi;
  6.  
  7. ligtable "f": "i"=:oct"014", "f"=:oct"013", "l"=:oct"015",
  8.  "'" kern itc#, "?" kern itc#, "!" kern itc#, ")" kern itc#, "]" kern itc#;
  9. ligtable oct"013": "i"=:oct"016", "l"=:oct"017",
  10.  "'" kern itc#, "?" kern itc#, "!" kern itc#, ")" kern itc#, "]" kern itc#;
  11.  
  12. cmchar "The ligature ff";
  13. beginchar(oct"013",10.5u#+2letter_fit#,asc_height#,0);
  14. italcorr asc_height#*slant+if serifs:flare#-.25u# else: 1.25u# fi;
  15. adjust_fit(0,0);
  16. pickup tiny.nib; pos1(stem',0); lft x1l=hround(2.5u-.5stem');
  17. pos11(stem',0); rt x11r=hround(w-3u+.5stem');
  18. pickup fine.nib; numeric bulb_diam, inner_jut;
  19. if serifs: bulb_diam=hround .8[stem,flare];
  20.  pos2(bulb_diam,0); pos12(bulb_diam,0);
  21.  rt x2r=hround(rt x11r-stem_corr); lft x12l=hround(w-.75u+.5);
  22.  y2+.5bulb_diam=.85[x_height,h+oo]; y12+.5bulb_diam=.9[x_height,h+oo];
  23.  if rt x1r+jut+.5u+2<=lft x11l-jut: inner_jut=jut;
  24.  else: rt x1r+inner_jut+.5u+2=lft x11l-inner_jut; fi
  25. else: pos2(5/7[vair,flare],90); top y2r=h; rt x2=hround 6.25u;
  26.  pos12(5/7[vair,flare],90); y12=y2; rt x12=hround(w+.75u); fi
  27. f_stroke(1,2,a,b,c,jut,inner_jut); % left stem, arc, terminal, serif
  28. f_stroke(11,12,d,e,f,inner_jut,1.25jut); % right stem, arc, terminal, serif
  29. pickup crisp.nib; top y3r=top y4r=x_height; lft x3=hround .5u-1;
  30. pos3(bar,90); pos4(bar,90);
  31. rt x4=hround(w-1/3u);
  32. if hefty: pos3'(bar,90); x3'-x1=x4-x11; y3'=y3;
  33.  pos4'(bar,90); x4'=x11; y4'=y4;
  34.  filldraw stroke z3e--z3'e; filldraw stroke z4'e--z4e;  % bars
  35. else: filldraw stroke z3e--z4e; fi  % bar
  36. penlabels(1,2,3,4,11,12); endchar;
  37.  
  38. cmchar "The ligature fi";
  39. beginchar(oct"014",10u#+2letter_fit#,asc_height#,0);
  40. italcorr asc_height#*slant-serif_fit#+.5if serifs:stem# else:dot_size# fi-2u#;
  41. adjust_fit(0,serif_fit#);
  42. pickup tiny.nib; pos1(stem',0); lft x1l=hround(2.5u-.5stem');
  43. pos11(stem',0); rt x11r=hround(w-2.5u+.5stem');
  44. pos12(stem',0); x11=x12; bot y12=0;
  45. pickup fine.nib; numeric bulb_diam, inner_jut;
  46. if serifs: bulb_diam=hround 1/4[.8[stem,flare],dot_size];
  47.  pos2(bulb_diam,0); x2r=x12r;
  48.  y2+.5bulb_diam=.8[x_height,h+oo]; top y11=x_height+min(oo,serif_drop);
  49.  if rt x1r+jut+.5u+2<=lft x11l-jut: inner_jut=jut;
  50.  else: rt x1r+inner_jut+.5u+2=lft x11l-inner_jut; fi
  51. else: bulb_diam=max(stem,dot_size);
  52.  pos2(6/7[vair,flare],90); top y2r=h; rt x2=hround 5.3u;
  53.  pickup tiny.nib; pos13(bulb_diam,0); pos14(bulb_diam,90);
  54.  x13=x11-.5; top y14r=min(2x_height,h+1); top y11=x_height;
  55.  if bot y14l-x_height<tiny: y14l:=min(y14r-eps,y11+2tiny); fi
  56.  x13=x14; y13=.5[y14l,y14r]; dot(13,14);  % dot
  57. fi;  % this is the ligature we're drawing
  58. f_stroke(1,2,a,b,c,jut,inner_jut); % left stem, arc, terminal, serif
  59. pickup tiny.nib; filldraw stroke z11e--z12e;  % right stem
  60. pickup crisp.nib; top y3r=top y4r=x_height; lft x3=hround .5u-1;
  61. pos3(bar,90); pos4(bar,90);
  62. if serifs: x4=x11;  % bar will overlap upper right serif
  63.  sloped_serif.l(11,12,d,1/3,jut,min(oo,serif_drop));  % upper right serif
  64.  dish_serif(12,11,e,1/3,inner_jut,f,1/3,jut);  % lower right serif
  65. else: rt x4= hround 5.3u; fi
  66. pickup crisp.nib; filldraw stroke z3e--z4e;  % bar
  67. penlabels(1,2,3,4,11,12,13,14); endchar;
  68.  
  69. cmchar "The ligature fl";
  70. beginchar(oct"015",10u#+2letter_fit#,asc_height#,0);
  71. italcorr asc_height#*slant-serif_fit#+.5stem#-2u#;
  72. adjust_fit(0,serif_fit#);
  73. pickup tiny.nib; pos1(stem',0); lft x1l=hround(2.5u-.5stem');
  74. pos11(stem',0); rt x11r=hround(w-2.5u+.5stem');
  75. pos12(stem',0); x11=x12; bot y12=0; top y11=h;
  76. filldraw stroke z11e--z12e;  % right stem
  77. pickup fine.nib; numeric bulb_diam, inner_jut;
  78. if serifs: bulb_diam=hround .8[stem,flare];
  79.  pos2(bulb_diam,0); x2r=x11r-stem_corr;
  80.  y2+.5bulb_diam=.9[x_height,h+oo];
  81.  sloped_serif.l(11,12,d,1/3,eps,max(serif_drop,oo)); % erase excess at top
  82.  if rt x1r+jut+.5u+2<=lft x11l-jut: inner_jut=jut;
  83.  else: rt x1r+inner_jut+.5u+2=lft x11l-inner_jut; fi
  84. else: pos2(5/7[vair,flare],90); top y2r=h; rt x2=hround 5.3u; fi
  85. f_stroke(1,2,a,b,c,jut,inner_jut); % left stem, arc, terminal, serif
  86. pickup crisp.nib; top y3r=top y4r=x_height; lft x3=hround .5u-1;
  87. pos3(bar,90); pos4(bar,90);
  88. if serifs: x4=x11;
  89.  dish_serif(12,11,e,1/3,inner_jut,f,1/3,jut);  % lower right serif
  90. else: rt x4= hround 5.3u; fi
  91. pickup crisp.nib; filldraw stroke z3e--z4e;  % bar
  92. penlabels(1,2,3,4,11,12); endchar;
  93.  
  94. cmchar "The ligature ffi";
  95. beginchar(oct"016",15u#+4letter_fit#,asc_height#,0);
  96. italcorr asc_height#*slant-serif_fit#+.5if serifs:stem# else:dot_size# fi-2u#;
  97. adjust_fit(0,serif_fit#);
  98. pickup tiny.nib; pos1(stem',0); lft x1l=hround(2.5u-.5stem');
  99. pos11(stem',0); lft x11l=hround(.5w-.5stem');
  100. pos21(stem',0); rt x21r=hround(w-2.5u+.5stem');
  101. pos22(stem',0); x21=x22; bot y22=0;
  102. pickup fine.nib; numeric bulb_diam, inner_jut;
  103. if serifs: bulb_diam=hround 1/4[.8[stem,flare],dot_size];
  104.  pos2(bulb_diam,0); x2r=x11r-stem_corr;
  105.  pos12(bulb_diam,0); x12r=x21r;
  106.  top y21=x_height+min(oo,serif_drop);
  107.  y2+.5bulb_diam=.8[x_height,h+oo]; y12=y2;
  108.  if rt x1r+jut+.5u+2<=lft x11l-jut: inner_jut=jut;
  109.  else: rt x1r+inner_jut+.5u+2=lft x11l-inner_jut; fi
  110. else: bulb_diam=max(stem,dot_size);
  111.  pos2(5/7[vair,flare],90); top y2r=h; rt x2=hround 5.75u;
  112.  pos12(6/7[vair,flare],90); y12=y2; rt x12=hround(.5w+2.8u);
  113.  pickup tiny.nib; pos23(bulb_diam,0); pos24(bulb_diam,90);
  114.  x23=x21-.5; top y24r=min(2x_height,h+1); top y21=x_height;
  115.  if bot y24l-x_height<tiny: y24l:=min(y24r-eps,y21+2tiny); fi
  116.  x23=x24; y23=.5[y24l,y24r]; dot(23,24); fi  % dot
  117. f_stroke(1,2,a,b,c,jut,inner_jut); % left stem, arc, terminal, serif
  118. f_stroke(11,12,d,e,f,inner_jut,inner_jut); % middle ditto
  119. pickup tiny.nib; filldraw stroke z21e--z22e;  % right stem
  120. pickup crisp.nib; top y3r=top y4r=x_height; lft x3=hround.5u-1;
  121. pos3(bar,90); pos4(bar,90);
  122. if serifs: x4=x21;  % bar will overlap upper right serif
  123.  sloped_serif.l(21,22,g,1/3,jut,min(oo,serif_drop));  % upper right serif
  124.  dish_serif(22,21,h,1/3,inner_jut,i,1/3,jut);  % lower right serif
  125. else: rt x4=hround(.5w+2.8u); fi
  126. pickup crisp.nib;
  127. if hefty: pos3'(bar,90); x3'-x1=x4-x11; y3'=y3;
  128.  pos4'(bar,90); x4'=x11; y4'=y4;
  129.  filldraw stroke z3e--z3'e; filldraw stroke z4'e--z4e;  % bars
  130. else: filldraw stroke z3e--z4e; fi  % bar
  131. penlabels(1,2,3,4,11,12,21,22,23,24); endchar;
  132.  
  133. cmchar "The ligature ffl";
  134. beginchar(oct"017",15u#+4letter_fit#,asc_height#,0);
  135. italcorr asc_height#*slant-serif_fit#+.5stem#-2u#;
  136. adjust_fit(0,serif_fit#);
  137. pickup tiny.nib; pos1(stem',0); lft x1l=hround(2.5u-.5stem');
  138. pos11(stem',0); lft x11l=hround(.5w-.5stem');
  139. pos21(stem',0); rt x21r=hround(w-2.5u+.5stem');
  140. pos22(stem',0); x21=x22; bot y22=0; top y21=h;
  141. filldraw stroke z21e--z22e;  % right stem
  142. pickup fine.nib; numeric bulb_diam, inner_jut;
  143. if serifs: bulb_diam=hround .8[stem,flare];
  144.  pos2(bulb_diam,0); x2r=x11r-stem_corr;
  145.  pos12(bulb_diam,0); x12r=x21r-stem_corr;
  146.  y2+.5bulb_diam=.85[x_height,h+oo]; y12+.5bulb_diam=.9[x_height,h+oo];
  147.  sloped_serif.l(21,22,g,1/3,eps,max(serif_drop,oo)); % erase excess at top
  148.  if rt x1r+jut+.5u+2<=lft x11l-jut: inner_jut=jut;
  149.  else: rt x1r+inner_jut+.5u+2=lft x11l-inner_jut; fi
  150. else: pos2(5/7[vair,flare],90); top y2r=h; rt x2=hround 5.75u;
  151.  pos12(5/7[vair,flare],90); y12=y2; rt x12=hround(.5w+2.8u); fi
  152. f_stroke(1,2,a,b,c,jut,inner_jut); % left stem, arc, terminal, serif
  153. f_stroke(11,12,d,e,f,inner_jut,inner_jut); % middle ditto
  154. pickup crisp.nib; top y3r=top y4r=x_height; lft x3=hround.5u-1;
  155. pos3(bar,90); pos4(bar,90);
  156. if serifs: dish_serif(22,21,h,1/3,inner_jut,i,1/3,jut);  % lower right serif
  157.  pickup crisp.nib; x4=x21;
  158. else: rt x4=hround(.5w+2.8u); fi
  159. if hefty: pos3'(bar,90); x3'-x1=x4-x11; y3'=y3;
  160.  pos4'(bar,90); x4'=x11; y4'=y4;
  161.  filldraw stroke z3e--z3'e; filldraw stroke z4'e--z4e;  % bars
  162. else: filldraw stroke z3e--z4e; fi  % bar
  163. penlabels(1,2,3,4,11,12,21,22); endchar;
  164.