home *** CD-ROM | disk | FTP | other *** search
/ Atari FTP / ATARI_FTP_0693.zip / ATARI_FTP_0693 / Tex / mf_three.arc / OLDDIG.MF < prev    next >
Text File  |  1988-11-22  |  15KB  |  315 lines
  1. % This file contains the ten digits in so-called old style.
  2. % Character codes \0060 through \0071 are generated.
  3.  
  4. cmchar "Oldstyle numeral 0";
  5. beginchar("0",9u#,x_height#,0);
  6. italcorr .7x_height#*slant-max(.2u#,.95u#-.5curve#);
  7. adjust_fit(0,0);
  8. penpos1(vair,90); penpos3(vair,-90); penpos2(curve,180); penpos4(curve,0);
  9. if not monospace: interim superness:=sqrt(more_super*hein_super); fi
  10. x2r=hround max(.7u,1.45u-.5curve);
  11. x4r=w-x2r; x1=x3=.5w; y1r=h+o; y3r=-o;
  12. y2=y4=.5h-vair_corr; y2l:=y4l:=.52h;
  13. penstroke pulled_arc.e(1,2) & pulled_arc.e(2,3)
  14.  & pulled_arc.e(3,4) & pulled_arc.e(4,1) & cycle;  % bowl
  15. penlabels(1,2,3,4); endchar;
  16.  
  17. cmchar "Oldstyle numeral 1";
  18. beginchar("1",9u#,x_height#,0);
  19. italcorr x_height#*slant+.5cap_stem#-4.25u#;
  20. adjust_fit(0,0);
  21. numeric light_stem; light_stem=hround .4[stem',cap_stem'];
  22. pickup tiny.nib;
  23. pos1(light_stem,0); pos2(light_stem,0);
  24. lft x1l=lft x2l=hround(.5(w+.5u)-.5cap_stem'); top y1=h+apex_o; bot y2=0;
  25. filldraw stroke z1e--z2e;  % stem
  26. if not serifs: save slab; slab=bar; fi
  27. dish_serif(2,1,a,1/3,min(2.25u,lft x2l-1.5u),
  28.   b,1/3,min(2.25u,w-1.25u-rt x2r)); % serif
  29. pickup crisp.nib; pos3(slab,-90); pos4(bar,-90);
  30. top y3l=h+apex_o; top y4l=if monospace: .8 else: .9 fi\\ h+apex_o;
  31. lft x4=max(1.25u,tiny.lft x1l-2.35u);
  32. tiny.rt x1r=lft x3+.25[tiny,hair];
  33. erase fill z3l{x4l-x3l,3(y4l-y3l)}...z4l{left}
  34.  --(x4l,h+apex_o+1)--(x3l,h+apex_o+1)--cycle; % erase excess at top
  35. filldraw stroke z3e{x4e-x3e,3(y4e-y3e)}..z4e{left};  % point
  36. penlabels(1,2,3,4); endchar;
  37.  
  38. cmchar "Oldstyle numeral 2";
  39. beginchar("2",9u#,x_height#,0);
  40. italcorr .8x_height#*slant-.4u#;
  41. adjust_fit(0,0);
  42. numeric arm_thickness, hair_vair; hair_vair=.25[vair,hair];
  43. arm_thickness=Vround(if hefty:slab+2stem_corr else:.75[vair,cap_stem] fi);
  44. pickup crisp.nib; pos7(arm_thickness,-90); pos8(hair,0);
  45. bot y7r=0; lft x7=hround .8u; rt x8r=hround(w-.9u); y8=good.y(y7l+beak/3)+eps;
  46. arm(7,8,a,.3beak_darkness,beak_jut);  % arm and beak
  47. pickup fine.nib; pos2(slab,90); pos3(.4[curve,cap_curve],0);
  48. top y2r=h+o; x2=.5(w-.5u); rt x3r=hround(w-.9u); y3+.5vair=.75h;
  49. if serifs: numeric bulb_diam; bulb_diam=hround .8[hair,flare];
  50.  pos0(bulb_diam,180); pos1(cap_hair,180);
  51.  lft x1r=hround u; y1-.5bulb_diam=2/3h;
  52.  (x,y2l)=whatever[z1l,z2r]; x2l:=x; bulb(2,1,0);  % bulb and arc
  53. else: x2l:=x2l-.25u; pos1(flare,angle(-9u,h));
  54.  lft x1r=hround .75u; bot y1l=vround .7h; y1r:=good.y y1r+eps; x1l:=good.x x1l;
  55.  filldraw stroke term.e(2,1,left,.9,4); fi  % terminal and arc
  56. pos4(.25[hair_vair,cap_stem],0);
  57. pos5(hair_vair,0); pos6(hair_vair,0);
  58. y5=arm_thickness; y4=.3[y5,y3]; top y6=min(y5,slab,top y7l);
  59. lft x6l=crisp.lft x7; z4l=whatever[z6l,(x3l,bot .58h)]; z5l=whatever[z6l,z4l];
  60. erase fill z4l--z6l--lft z6l--(lft x6l,y4l)--cycle;  % erase excess at left
  61. filldraw stroke z2e{right}..tension atleast .9 and atleast 1
  62.  ..z3e{down}.. z4e---z5e--z6e;  % stroke
  63. penlabels(0,1,2,3,4,5,6,7,8); endchar;
  64.  
  65. cmchar "Oldstyle numeral 3";
  66. beginchar("3",9u#,x_height#,desc_depth#);
  67. italcorr .8x_height#*slant-.4u#;
  68. adjust_fit(0,0);
  69. numeric top_thickness,mid_thickness,bot_thickness;
  70. top_thickness=max(fine.breadth,vround(slab-2vair_corr));
  71. mid_thickness=max(fine.breadth,vround 2/3vair);
  72. bot_thickness=max(fine.breadth,vround(slab-vair_corr));
  73. pickup fine.nib; pos2(top_thickness,90); top y2r=h+o;
  74. pos3(max(fine.breadth,.6[curve,cap_curve]-stem_corr),0);
  75. rt x3r=hround(w-1.25u);
  76. pos4(vair,-90); pos5(vair,-90);
  77. pos6(mid_thickness,90); x2=x6=x8=.5[1.5u,x7];
  78. pos7(cap_curve,0); rt x7r=hround(w-.75u); lft x5=min(hround 3u,lft x6);
  79. pos8(bot_thickness,-90); bot y8r=-d-o;
  80. y3=.6[top y4l,bot y2l]; y7=.5[bot y6l,top y8l];
  81. top y5l=vround(.54[-d,h]+.5vair); y5r=y6l;
  82. x4=1/3[x5,x3l]; z4=z5+whatever*(150u,h+d);
  83. filldraw stroke pulled_super_arc.e(2,3)(.5superpull)
  84.  & z3e{down}...z4e---z5e;  % upper bowl
  85. filldraw z5r--z6l--z6r--z5l---cycle;  % middle tip
  86. filldraw stroke pulled_super_arc.e(6,7)(.5superpull)
  87.  & pulled_super_arc.e(7,8)(.5superpull);  % lower bowl
  88. if serifs: numeric bulb_diam[];
  89.  bulb_diam1=flare+.5(cap_stem-stem); bulb_diam2=flare+cap_stem-stem;
  90.  pos0(bulb_diam1,180); pos1(hair,180);
  91.  lft x0r=hround 1.25u; y0=min(.9[-d,h]-.5bulb_diam1,.75[-d,h]+.5bulb_diam1);
  92.  bulb(2,1,0);  % upper bulb
  93.  pos10(bulb_diam2,-180); pos9(cap_hair,-180);
  94.  lft x10r=hround .75u; y10=max(.1[-d,h]+.5bulb_diam2,.3[-d,h]-.5bulb_diam2);
  95.  bulb(8,9,10);  % lower bulb
  96. else: pos1(.5[vair,flare],angle(-8u,h+d)); lft x1r=hround u;
  97.  bot y1l=(vround .75[-d,h])+o; y1r:=good.y y1r+eps; x1l:=good.x x1l;
  98.  pos9(bot_thickness,angle(-2u,-h-d));
  99.  lft x9r=hround .75u; top y9l=(vround .25[-d,h])-o;
  100.  y9r:=good.y y9r-eps; x9l:=good.x x9l;
  101.  filldraw stroke term.e(2,1,left,1,4);  % upper terminal
  102.  filldraw stroke term.e(8,9,left,1,4); fi  % lower terminal
  103. penlabels(0,1,2,3,4,5,6,7,8,9,10); endchar;
  104.  
  105. cmchar "Oldstyle numeral 4";
  106. beginchar("4",9u#,x_height#,desc_depth#);
  107. italcorr x_height#*slant+.5stem#-2.5u#;
  108. adjust_fit(0,0);
  109. numeric light_stem, light_stem', diag_stem, alpha, cut; cut=.75notch_cut;
  110. light_stem=hround .4[fudged.stem,fudged.cap_stem];
  111. light_stem'=hround max(tiny.breadth,light_stem-2stem_corr);
  112. diag_stem=max(tiny.breadth,.4[vair,fudged.hair]);
  113. pickup crisp.nib; pos5(cap_bar,90); pos6(cap_bar,90);
  114. lft x5=hround .5u; rt x6=hround(w-.5u); bot y5l=0;
  115. z4l=top lft z5r; y2=y2'=y5=y6; x1r=x2r=hround(w-3u+.5light_stem);
  116. penpos1(light_stem',0); penpos2(light_stem',0); y1=y3=h+apex_o+apex_oo;
  117. x3r+apex_corr=x1r; alpha=diag_ratio(1,diag_stem,y3-y4l,x3r-x4l);
  118. penpos3(alpha*diag_stem,0); penpos4(alpha*diag_stem,0);
  119. x0=x1l; z0=whatever[z3r,z4r];
  120. x5'=x5; z5''=z5'+penoffset z4-z3 of currentpen=whatever[z4l,z3l];
  121. fill diag_end(2r,1r,1,.5,3l,4l)---z5''...lft z5'
  122.  ---lft z5l -- (x4r,y5l) -- z4r
  123.  if y0<h-cut:{z3r-z4r}...{up}(x1l-1,h-cut)
  124.   --(x1l,h-cut) else: -- z0 fi
  125.  --z2l--z2r--cycle;  % diagonal and upper stem
  126. filldraw stroke z5e--z6e;  % bar
  127. pickup tiny.nib; pos7(light_stem,0); pos2'(light_stem,0); x2'=x7;
  128. rt x7r=x1r; bot y7=-d if not serifs:-o fi;
  129. filldraw stroke z2'e--z7e;  % lower stem
  130. if serifs: dish_serif(7,2',a,1/3,1.75u,
  131.   b,1/3,min(1.75u,w-.5u-rt x7r)); fi  % serif
  132. penlabels(0,1,2,3,4,5,6,7); endchar;
  133.  
  134. cmchar "Oldstyle numeral 5";
  135. beginchar("5",9u#,x_height#,desc_depth#);
  136. italcorr x_height#*slant-u#;
  137. adjust_fit(0,0);
  138. numeric bot_thickness,light_hair;
  139. bot_thickness=max(fine.breadth,vround(slab-vair_corr));
  140. light_hair=hround(cap_hair if hefty: -2stem_corr fi);
  141. pickup tiny.nib; pos5(vair,180); pos6(vair,90);
  142. bot y5=vround(.53[-d,h]-vair);
  143. top y6r=max((vround .61803[-d,h])+o,top y6r+y5+eps-y6l);
  144. pos3(light_hair,0); pos4(light_hair,0);
  145. lft x3l=max(1.35u,2.1u-.5light_hair); x3=x4=x5; y4=y5;
  146. top y3=h if not hefty: +o fi;
  147. filldraw stroke z3e--z4e;  % thin stem
  148. penpos7(cap_stem-fine,0); penpos8(bot_thickness-fine,-90);
  149. fine.rt x7r=hround(w-.9u); x8=.5[u,x7]; x6=.5[x5,x7];
  150. erase fill z5--bot z5--(x6,bot y5)--z6{left}
  151.  ..tension .9 and 1..{x5-x6,3(y5-y6)}cycle; % erase excess in middle
  152. filldraw stroke z6e{left}..tension .9 and 1..{x5-x6,3(y5-y6)}z5e;  % link
  153. pickup fine.nib; pos6'(vair,90); z6'=z6;
  154. y7=.5[y6,y8]; bot y8r=-d-o;
  155. filldraw stroke pulled_arc.e(6',7) & pulled_arc.e(7,8);  % bowl
  156. if serifs: pos9(hair,-180); y9=.5[-d,y5]; lft x9r=hround .9u;
  157.  pos10(flare+1/3(cap_stem-stem),-180); bulb(8,9,10);  % bulb
  158. else: pos9(3/7[bot_thickness,flare],angle(-7u,-h-d));
  159.  lft x9r=hround .9u; bot y9r=(vround .15[-d,h])-o;
  160.  x9l:=good.x x9l; y9l:=good.y y9l;
  161.  filldraw stroke term.e(8,9,left,1,4); fi  % terminal
  162. if hefty: pickup crisp.nib; pos1(slab,90); pos2(hair,0);
  163.  top y1r=h; x1=x4; rt x2r=hround(w-1.5u);
  164.  y2=y1l-eps; arm(1,2,a,0,0);  % arm
  165. else: numeric flag_breadth; flag_breadth=7/8[vair,cap_curve];
  166.  pos1(flag_breadth,90); pos2(flag_breadth,60);
  167.  pos0(vair,90); top y1r=tiny.top y3; top y2r=(vround .95[-d,h])+o; y0r=y1r;
  168.  lft x1=tiny.lft x3l; x2r=.5[x1,x0]; rt x0=hround(w-1.6u);
  169.  erase fill top z1r--z1r...{right}z2r
  170.   --(x2r,top y1r)--cycle; % erase excess at top
  171.  filldraw stroke z1e...{right}z2e...z0e; fi  % flag
  172. penlabels(0,1,2,3,4,5,6,7,8,9,10); endchar;
  173.  
  174. cmchar "Oldstyle numeral 6";
  175. beginchar("6",9u#,fig_height#,0);
  176. italcorr fig_height#*slant-u#;
  177. adjust_fit(0,0);
  178. numeric top_thickness,bot_thickness,side_thickness,pull;
  179. top_thickness=max(fine.breadth,vround(slab-2vair_corr));
  180. bot_thickness=max(fine.breadth,vround(slab-vair_corr));
  181. side_thickness=max(fine.breadth,hround 1/3[curve,cap_curve]);
  182. pull=min(.25,1.5superpull);
  183. pickup fine.nib; pos2(top_thickness,-270);
  184. pos3(side_thickness,-180); pos4(bot_thickness,-90);
  185. pos5(side_thickness,0); pos6(vair,90);
  186. lft x3r=w-rt x5r=hround max(.75u,1.5u-.5side_thickness);
  187. x4=x6-.1u=x2-u=.5w;
  188. top y2r=h+o; y3=.5[y2,y4]; bot y4r=-o;
  189. y5=.5[y4,y6]; top y6=vround 5/8h+o;
  190. path p; p=pulled_super_arc.l(3,4)(pull);
  191. numeric t; t=xpart(p intersectiontimes((x3r,y5)--(x4,y5)));
  192. pos7(thin_join,180); z7l=point t of p;
  193. (x,y6r)=whatever[z7l,z6l]; x6r:=min(x,.5[x5r,x6]);
  194. filldraw stroke pulled_super_arc.e(2,3)(pull)
  195.  & {{interim superness:=more_super; pulled_super_arc.e(3,4)(pull)}}
  196.  & {{less_tense; pulled_super_arc.e(4,5)(pull) & pulled_super_arc.e(5,6)(pull)}}
  197.  & z6e{left}...{direction t of p}z7e;  % arc and bowl
  198. if serifs: pos1(hair,-360); pos0(flare,-360);
  199.  rt x0r=max(rt x2+eps,hround(w-1.2u));
  200.  y0=vround min(.9h-.5flare,.85h+.5flare)+o;
  201.  {{less_tense; bulb(2,1,0)}};  % arc and bulb
  202. else: pos1(vround .1[top_thickness,flare],90);
  203.  top y1r=vround .97h+o; rt x1=hround(x5-.5);
  204.  filldraw stroke term.e(2,1,right,.9,4); fi  % terminal
  205. penlabels(0,1,2,3,4,5,6,7); endchar;
  206.  
  207. cmchar "Oldstyle numeral 7";
  208. beginchar("7",9u#,x_height#,desc_depth#);
  209. italcorr x_height#*slant;
  210. adjust_fit(0,0);
  211. numeric arm_thickness, bot_width, top_shift, top_hair;
  212. if hefty: arm_thickness=Vround(slab+2stem_corr); top_shift=0;
  213.  bot_width=hround .51[curve,cap_curve]; top_hair=.4[thin_join,bot_width];
  214. else: arm_thickness=Vround .4[stem,cap_stem]; top_shift=.5u;
  215.  bot_width=flare; top_hair=cap_hair; fi
  216. if top_hair<tiny.breadth: top_hair:=tiny.breadth; fi
  217. pickup crisp.nib; pos2(arm_thickness,90); pos1(hair,180);
  218. top y2r=h; rt x2=hround(w-.75u+top_shift);
  219. lft x1r=hround(.75u+.5top_shift); y1=good.y(y2l-beak/2)-eps;
  220. arm(2,1,a,.3beak_darkness,-beak_jut);  % arm and beak
  221. pos3(hair,180); y3=good.y(y2r+beak/6)+eps; z3r=whatever[z1r,z.a0];
  222. penpos2'(2epsilon,-90); z2'=z2r;
  223. arm(2',3,b,beak_darkness,x3r-x.a0);  % upward extension of beak
  224. pickup tiny.nib; pos4(top_hair,0); pos6(bot_width,0);
  225. bot y4=max(h-arm_thickness,h-slab,bot y2l); rt x4r=crisp.rt x2;
  226. lft x6l=hround(3.5u+top_shift-.5bot_width);
  227. if serifs: y6-.5bot_width=-d-o; filldraw z6l{down}..{up}z6r--cycle;  % bulb
  228. else: bot y6=-d-oo; fi
  229. if hefty: erase fill rt z4r--z4r...{down}z6r
  230.   --(rt x4r,y6)--cycle;  % erase excess at top
  231.  filldraw stroke z4e...{down}z6e;  % stroke
  232. else: pos5(top_hair,0); y5=2/3[-d,h]; z5=whatever[z4,(.75u,y6)];
  233.  erase fill rt z4r--z4r--z5r--(rt x4r,y5)--cycle;  % erase excess at top
  234.  filldraw stroke z4e---z5e...{down}z6e; fi  % stroke
  235. penlabels(1,2,3,4,5,6); endchar;
  236.  
  237. cmchar "Oldstyle numeral 8";
  238. beginchar("8",9u#,fig_height#,0);
  239. italcorr fig_height#*slant-u#;
  240. adjust_fit(0,0);
  241. numeric top_thickness,mid_thickness,bot_thickness,upper_side,lower_side,theta;
  242. top_thickness=max(fine.breadth,vround(slab-2vair_corr));
  243. bot_thickness=max(fine.breadth,vround(slab-vair_corr));
  244. x0=.5w; y0=.54h;
  245. if hefty: mid_thickness=vround 2/3vair; upper_side=hround(stem-3stem_corr);
  246.  lower_side=hround min(.5[curve,cap_curve]-stem_corr,upper_side+.25u);
  247.  penpos1(top_thickness,90); penpos2(upper_side,180);
  248.  penpos3(mid_thickness,270); penpos8(upper_side,360);
  249.  penpos4(mid_thickness,90); penpos7(lower_side,180);
  250.  penpos6(bot_thickness,270); penpos5(lower_side,360);
  251.  penpos0(vair,90); z3l=z0r; z4l=z0l;
  252.  x1=x6=.5w; x2r=w-x8r=hround u; x7r=w-x5r=hround .75u;
  253.  top y1r=h+o; bot y6r=-o; y2=y8=.5[y1l,y3l]; y7=y5=.5[y4l,y6l];
  254.  filldraw stroke pulled_arc.e(1,2)
  255.   & pulled_arc.e(2,3);  % left half of upper bowl
  256.  filldraw stroke pulled_arc.e(4,5)
  257.   & pulled_arc.e(5,6);  % right half of lower bowl
  258.  filldraw stroke pulled_arc.e(6,7)
  259.   & pulled_arc.e(7,4);  % left half of lower bowl
  260.  filldraw stroke pulled_arc.e(3,8)
  261.   & pulled_arc.e(8,1);  % right half of upper bowl
  262. else: pickup fine.nib; theta=90-angle(18u,h); slope:=-h/18u;
  263.  upper_side=max(fine.breadth,hround(.5[hair,stem]-stem_corr));
  264.  lower_side=hround(.5[hair,stem]+stem_corr);
  265.  if lower_side>1.2upper_side: upper_side:=lower_side; fi
  266.  pos1(top_thickness,-90); pos6(bot_thickness,-90);
  267.  x1=x6=.5w; top y1l=h+o; bot y6r=-o; pos0(cap_stem,theta);
  268.  lft x2l=w-rt x8l=hround 1.25u; lft x7r=w-rt x5r=hround .75u;
  269.  x2r-x2l=upper_side-fine; x5r-x5l=lower_side-fine;
  270.  ellipse_set(1l,2l,3l,0l); ellipse_set(1r,2r,3r,0r);
  271.  ellipse_set(6l,5l,4l,0l); ellipse_set(6r,5r,4r,0r);
  272.  numeric tau; tau=max(.8,.20710678/(superness-.5));
  273.  filldraw stroke z1e{left}..tension atleast tau..z2e{down}
  274.   ..z3e---z4e..z5e{down}..tension atleast tau..z6e{left};  % S stroke
  275.  pos7(lower_side,180); pos8(upper_side,180);
  276.  y7=.5[y5l,y5r]; y8=.5[y2l,y2r]; pos9(vair,90); z9=z0;
  277.  filldraw stroke z1e{right}..tension atleast tau..z8e{down}
  278.   ..tension atleast tau and atleast 1..{-18u,-.618h}z9e; % upper right stroke
  279.  filldraw stroke z6e{left}..tension atleast tau..z7e{up}
  280.   ..tension atleast tau and atleast 1..{18u,.5h}z9e; fi % lower left stroke
  281. penlabels(0,1,2,3,4,5,6,7,8,9); endchar;
  282.  
  283. cmchar "Oldstyle numeral 9";
  284. beginchar("9",9u#,x_height#,desc_depth#);
  285. italcorr x_height#*slant-u#;
  286. adjust_fit(0,0);
  287. numeric top_thickness,bot_thickness,side_thickness,pull;
  288. top_thickness=max(fine.breadth,vround(slab-2vair_corr));
  289. bot_thickness=max(fine.breadth,vround(slab-vair_corr));
  290. side_thickness=max(fine.breadth,hround 1/3[curve,cap_curve]);
  291. pull=min(.25,1.5superpull);
  292. pickup fine.nib; pos2(bot_thickness,-90);
  293. pos3(side_thickness,0); pos4(top_thickness,90);
  294. pos5(side_thickness,180); pos6(vair,270);
  295. w-rt x3r=lft x5r=hround max(.75u,1.5u-.5side_thickness);
  296. x4-.1u=x6+.1u=x2+.75u=.5w;
  297. bot y2r=-d-o; y3=.5[y2,y4]; top y4r=h+o;
  298. y5=.5[y4,y6]; bot y6=(vround 3/8[-d,h])-o;
  299. path p; p=pulled_super_arc.l(3,4)(pull);
  300. numeric t; t=xpart(p intersectiontimes((x3r,y5)--(x4,y5)));
  301. pos7(thin_join,360); z7l=point t of p;
  302. (x,y6r)=whatever[z7l,z6l]; x6r:=max(x,.5[x5r,x6]);
  303. filldraw stroke pulled_super_arc.e(2,3)(pull)
  304.  & {{interim superness:=more_super; pulled_super_arc.e(3,4)(pull)}}
  305.  & {{less_tense; pulled_super_arc.e(4,5)(pull) & pulled_super_arc.e(5,6)(pull)}}
  306.  & z6e{right}...{direction t of p}z7e;  % arc and bowl
  307. if serifs: pos1(hair,-180); pos0(flare,-180);
  308.  lft x0r=min(lft x2-eps,hround 1.2u);
  309.  y0=vround max(.1[-d,h]+.5flare,.15[-d,h]-.5flare)-o;
  310.  {{less_tense; bulb(2,1,0)}};  % arc and bulb
  311. else: pos1(.1[bot_thickness,flare],-120);
  312.  bot y1r=(vround .07[-d,h])-o; lft x1r=hround 1.3u;
  313.  filldraw stroke term.e(2,1,left,.9,4); fi  % terminal
  314. penlabels(0,1,2,3,4,5,6,7); endchar;
  315.