home *** CD-ROM | disk | FTP | other *** search
/ rtsi.com / 2014.01.www.rtsi.com.tar / www.rtsi.com / UNIFLEX / UNIFLEX / UniFLEX_Std.Utils1.tar.Z / UniFLEX_Std.Utils1.tar / utils1 / mount < prev    next >
Text File  |  1982-05-18  |  2KB  |  114 lines
  1.  opt pag,nol
  2.  ttl Mount Utility
  3.  pag
  4.  lib sysdef
  5.  opt lis
  6.  pag
  7.  
  8.  info UniFLEX mount
  9.  info Version 1.03, Released June 1, 1982
  10.  info Copyright, (C) 1981, by
  11.  info Technical Systems Consultants, Inc.
  12.  info All rights reserved.
  13.  
  14. * program starts here
  15.  
  16.  org 0
  17.  
  18. mnt sys update do a quick sys update for safety!
  19.  ldd 0,s get arg count
  20.  cmpd #3 is it 2?
  21.  lblo synerr error?
  22.  beq mnt4
  23.  cmpd #4
  24.  lbhi synerr
  25.  ldx 8,s get arg ptr
  26.  ldd 0,x get the arg
  27.  cmpa #'r is it read only?
  28.  lbne synerr
  29.  tstb null term?
  30.  lbne synerr
  31.  ldd #1 set read only mode
  32.  std imnt4
  33. mnt4 ldd 4,s get arg 1
  34.  std imnt2
  35.  ldd 6,s get arg 2
  36.  std imnt3
  37.  sys ind,imnt
  38.  bes prter
  39.  ldd #0 set status
  40.  sys term terminate task
  41.  
  42. *
  43. * prter
  44. *
  45. * Print error message.
  46. *
  47.  
  48. prter pshs d save error
  49.  cmpd #16 device busy?
  50.  bne prter2
  51.  ldd #2 set file desc
  52.  sys write,dbms,DBSZ output error
  53.  bra prter8
  54. prter2 cmpd #15 not a block device?
  55.  bne prter4
  56.  ldd #2 set file desc
  57.  sys write,nbms,NBSZ output error
  58.  bra prter8
  59. prter4 cmpd #8 no file?
  60.  bne prter5
  61.  ldd #2 set file desc
  62.  sys write,nfms,NFSZ output error
  63.  bra prter8
  64.  
  65. prter5 cmpd #1
  66.  bne prter6 if not "I/O error"
  67.  ldd #2
  68.  sys write,ioms,IOSZ output "i/o error" message
  69.  bra prter8
  70.  
  71. prter6 cmpd #11
  72.  bne prter7 if not "file exists"
  73.  ldd #2
  74.  sys write,allmnt,ALSZ output "A device is already mounted on that directory"
  75.  bra prter8
  76.  
  77. prter7 ldd #2 set file desc
  78.  sys write,cmms,CMSZ output error
  79. prter8 puls d get error
  80.  sys term exit - error
  81.  
  82. *
  83. * synerr
  84. *
  85. * Report syntax error.
  86. *
  87.  
  88. synerr ldd #2 set file desc
  89.  sys write,synmsg,SYSZ output message
  90.  ldd #$ff set status
  91.  sys term term task
  92.  
  93. synmsg fcc 'Command syntax error.',$d
  94. SYSZ equ *-synmsg
  95. cmms fcc "Can't mount - permissions.",$d
  96. CMSZ equ *-cmms
  97. nfms fcc 'The specified directory or device does not exist.',$d
  98. NFSZ equ *-nfms
  99. dbms fcc 'The specified device is already mounted.',$d
  100. DBSZ equ *-dbms
  101. nbms fcc 'The specified device is not a block device.',$d
  102. NBSZ equ *-nbms
  103. ioms fcc 'Cannot open or read the device',$d
  104. IOSZ equ *-ioms
  105. allmnt fcc 'A device is already mounted on that directory',$d
  106. ALSZ equ *-allmnt
  107.  
  108. imnt fcb mount
  109. imnt2 fdb 0
  110. imnt3 fdb 0
  111. imnt4 fdb 0
  112.  
  113.  end mnt
  114.