home *** CD-ROM | disk | FTP | other *** search
/ rtsi.com / 2014.01.www.rtsi.com.tar / www.rtsi.com / UNIFLEX / UNIFLEX / UniFLEX_Std.Utils1.tar.Z / UniFLEX_Std.Utils1.tar / utils1 / link < prev    next >
Text File  |  1981-09-01  |  1KB  |  83 lines
  1.  opt pag,nol
  2.  ttl Link Utility
  3.  lib sysdef
  4.  opt lis
  5.  pag
  6.  info UniFLEX link
  7.  info Version 1, Released August 25, 1980
  8.  info Copyright, (C) 1980, by
  9.  info Technical Systems Consultants, Inc.
  10.  info All rights reserved.
  11. * program starts here
  12.  
  13.  org 0
  14.  
  15. lnk ldd 0,s get arg count
  16.  cmpd #3 it should be 2
  17.  lbne synerr if not, error!
  18.  ldd 4,s get arg 1
  19.  std ilnk2
  20.  ldd 6,s get arg 2
  21.  std ilnk3
  22.  sys ind,ilnk
  23.  bes prter
  24.  ldd #0 set return status
  25.  sys term terminate task
  26.  
  27.  
  28. *
  29. * prter
  30. *
  31. * Print error message.
  32. *
  33.  
  34. prter pshs d save error
  35.  cmpd #8 no file?
  36.  bne prter2
  37.  ldd #2 set file desc
  38.  sys write,nfms,NFSZ output error
  39.  bra prter8
  40. prter2 cmpd #11 file exists?
  41.  bne prter4
  42.  ldd #2 set file desc
  43.  sys write,fems,FESZ output error
  44.  bra prter8
  45. prter4 cmpd #14 cross device?
  46.  bne prter6
  47.  ldd #2 set file desc
  48.  sys write,xdms,XDSZ output error
  49.  bra prter8
  50. prter6 ldd #2 set file desc
  51.  sys write,clms,CLSZ output error
  52. prter8 puls d get error
  53.  sys term exit - error
  54.  
  55. *
  56. * synerr
  57. *
  58. * Report syntax error.
  59. *
  60.  
  61. synerr ldd #2 set file desc
  62.  sys write,synmsg,SYSZ output message
  63.  ldd #$ff set status
  64.  sys term term task
  65.  
  66. synmsg fcc 'Command syntax error.',$d
  67. SYSZ equ *-synmsg
  68. nfms fcc 'The file specified does not exist.',$d
  69. NFSZ equ *-nfms
  70. fems fcc 'The file specified already exists.',$d
  71. FESZ equ *-fems
  72. xdms fcc "Can't link - files not on same device.",$d
  73. XDSZ equ *-xdms
  74. clms fcc "Can't link file.",$d
  75. CLSZ equ *-clms
  76.  
  77.  
  78. ilnk fcb link
  79. ilnk2 fdb 0
  80. ilnk3 fdb 0
  81.  
  82.  end lnk
  83.