home
***
CD-ROM
|
disk
|
FTP
|
other
***
search
/
rtsi.com
/
2014.01.www.rtsi.com.tar
/
www.rtsi.com
/
UNIFLEX
/
UNIFLEX
/
UniFLEX_Std.Utils1.tar.Z
/
UniFLEX_Std.Utils1.tar
/
utils1
/
link
< prev
next >
Wrap
Text File
|
1981-09-01
|
1KB
|
83 lines
opt pag,nol
ttl Link Utility
lib sysdef
opt lis
pag
info UniFLEX link
info Version 1, Released August 25, 1980
info Copyright, (C) 1980, by
info Technical Systems Consultants, Inc.
info All rights reserved.
* program starts here
org 0
lnk ldd 0,s get arg count
cmpd #3 it should be 2
lbne synerr if not, error!
ldd 4,s get arg 1
std ilnk2
ldd 6,s get arg 2
std ilnk3
sys ind,ilnk
bes prter
ldd #0 set return status
sys term terminate task
*
* prter
*
* Print error message.
*
prter pshs d save error
cmpd #8 no file?
bne prter2
ldd #2 set file desc
sys write,nfms,NFSZ output error
bra prter8
prter2 cmpd #11 file exists?
bne prter4
ldd #2 set file desc
sys write,fems,FESZ output error
bra prter8
prter4 cmpd #14 cross device?
bne prter6
ldd #2 set file desc
sys write,xdms,XDSZ output error
bra prter8
prter6 ldd #2 set file desc
sys write,clms,CLSZ output error
prter8 puls d get error
sys term exit - error
*
* synerr
*
* Report syntax error.
*
synerr ldd #2 set file desc
sys write,synmsg,SYSZ output message
ldd #$ff set status
sys term term task
synmsg fcc 'Command syntax error.',$d
SYSZ equ *-synmsg
nfms fcc 'The file specified does not exist.',$d
NFSZ equ *-nfms
fems fcc 'The file specified already exists.',$d
FESZ equ *-fems
xdms fcc "Can't link - files not on same device.",$d
XDSZ equ *-xdms
clms fcc "Can't link file.",$d
CLSZ equ *-clms
ilnk fcb link
ilnk2 fdb 0
ilnk3 fdb 0
end lnk