home
***
CD-ROM
|
disk
|
FTP
|
other
***
search
/
rtsi.com
/
2014.01.www.rtsi.com.tar
/
www.rtsi.com
/
OS9
/
OSK
/
APPS
/
DVI_MGR
/
dvimgr_s.lzh
/
dvi_fbi_hh
/
DVIDECW
/
texview.com
< prev
Wrap
Text File
|
1993-07-27
|
2KB
|
68 lines
$ !-----------------------------------------------------------------------!
$ ! Filename: TEXVIEW.COM !
$ ! Function: This is the interface between DECWindows FILEVIEW and the !
$ ! DVIDECW Tex Preview driver which runs in the DECWindows !
$ ! environment. Fileview selections are scanned and passed !
$ ! in the command line. !
$ ! (c) 28-06-90 by Christian MARKUS !
$ !-----------------------------------------------------------------------!
$ !
$ ! These definitions supersede global definitions and have to be corrected
$ ! in other environments
$ !
$ define/nolog TEX_FONTS $DISK0:[TEX29.DVI.CM.] ! path for fonts
$ define/nolog TEX_INPUTS $disk2:[1050101.dvi_fbi_hh.dvidecw] ! path for .UID file
$ dvidecw := $$disk2:[1050101.dvi_fbi_hh.dvidecw]dvidecw ! path for .EXE file
$ !
$ ! Check if files are selected in FileView
$ !
$ vue$get_selection_count
$ vue$read count
$ !
$ ! If files are selected then go on processing
$ !
$ if count .ne. 0 then goto get_file
$ !
$ ! Ask for filename
$ !
$ vue$inquire_symbol "VUE$TEXVIEW_DVI Filename:"
$ vue$read selection
$ !
$ ! Check for valid filename
$ !
$ if "''selection'".eqs. "" then goto end
$ goto do_dvi
$ !
$ ! Get Filename from FileView selection
$ !
$get_file:
$ vue$get_next_selection
$ vue$read selection
$ !
$ ! Start DVIDECW with filename argument
$ !
$do_dvi:
$ !
$ ! Extract the filename from selection
$ !
$ filename= "''f$parse(selection,,,"NAME")'"
$ !
$ ! Check if file exists
$ !
$ if f$search("''filename'"+".dvi") .eqs. "" then goto end
$ !
$ ! Ask for processing parameter
$ !
$ vue$inquire_symbol "VUE$TEXVIEW Parameter:"
$ vue$read parameter
$ !
$ ! Write info box
$ !
$ vue$set_task_label "DVIDECW ''filename'"
$ vue$popup_progress_box
$ !
$ dvidecw 'filename' 'parameter'
$ !
$end:
$ exit