home *** CD-ROM | disk | FTP | other *** search
/ tusportal.tus.k12.pa.us / tusportal.tus.k12.pa.us.tar / tusportal.tus.k12.pa.us / Wyse / latest-image.raw / 0.img / usr / sbin / update-alternatives < prev    next >
Text File  |  2009-02-20  |  24KB  |  751 lines
  1. #!/usr/bin/perl --
  2.  
  3. use strict;
  4. use warnings;
  5.  
  6. use POSIX qw(:errno_h);
  7. # use Dpkg;
  8. our ($progname) = $0 =~ m#(?:.*/)?([^/]*)#;
  9. our $version = "1.14";
  10. our $admindir = "/var/lib/rpm";
  11. #use Dpkg::Gettext;
  12. eval 'use Locale::gettext';
  13. if ($@) {
  14.         eval q{
  15.                 sub _g {
  16.                         return shift;
  17.                 }
  18.                 sub textdomain {
  19.                 }
  20.                 sub ngettext {
  21.                         if ($_[2] == 1) {
  22.                                 return $_[0];
  23.                         } else {
  24.                                 return $_[1];
  25.                         }
  26.                 }
  27.         };
  28. } else {
  29.         eval q{
  30.                 sub _g {
  31.                         return gettext(shift);
  32.                 }
  33.         };
  34. }
  35.  
  36. textdomain("rpm");
  37.  
  38. # Global variables:
  39.  
  40. my $altdir = '/etc/alternatives';
  41. # FIXME: this should not override the previous assignment.
  42. $admindir = $admindir . '/alternatives';
  43.  
  44. my $verbosemode = 0;
  45.  
  46. my $action = '';      # Action to perform (display / install / remove / display / auto / config)
  47. my $mode = 'auto';    # Update mode for alternative (manual / auto)
  48. my $state;            # State of alternative:
  49.                       #   expected: alternative with highest priority is the active alternative
  50.                       #   expected-inprogress: busy selecting alternative with highest priority
  51.                       #   unexpected: alternative another alternative is active / error during readlink
  52.                       #   nonexistent: alternative-symlink does not exist
  53.  
  54. my %versionnum;       # Map from currently available versions into @versions and @priorities
  55. my @versions;         # List of available versions for alternative
  56. my @priorities;       # Map from @version-index to priority
  57.  
  58. my $best;
  59. my $bestpri;
  60. my $bestnum;
  61.  
  62. my $link;             # Link we are working with
  63. my $linkname;
  64.  
  65. my $alink;            # Alternative we are managing (ie the symlink we're making/removing) (install only)
  66. my $name;             # Name of the alternative (the symlink) we are processing
  67. my $apath;            # Path of alternative we are offering
  68. my $apriority;        # Priority of link (only when we are installing an alternative)
  69. my %aslavelink;
  70. my %aslavepath;
  71. my %aslavelinkcount;
  72.  
  73. my $slink;
  74. my $sname;
  75. my $spath;
  76. my @slavenames;       # List with names of slavelinks
  77. my %slavenum;         # Map from name of slavelink to slave-index (into @slavelinks)
  78. my @slavelinks;       # List of slavelinks (indexed by slave-index)
  79. my %slavepath;        # Map from (@version-index,slavename) to slave-path
  80. my %slavelinkcount;
  81.  
  82. sub version {
  83.     printf _g("SUSE %s version %s.\n"), $progname, $version;
  84.  
  85.     printf _g("
  86. Copyright (C) 1995 Ian Jackson.
  87. Copyright (C) 2000-2002 Wichert Akkerman.");
  88.  
  89.     printf _g("
  90. This is free software; see the GNU General Public Licence version 2 or
  91. later for copying conditions. There is NO warranty.
  92. ");
  93. }
  94.  
  95. sub usage {
  96.     printf _g(
  97. "Usage: %s [<option> ...] <command>
  98.  
  99. Commands:
  100.   --install <link> <name> <path> <priority>
  101.     [--slave <link> <name> <path>] ...
  102.                            add a group of alternatives to the system.
  103.   --remove <name> <path>   remove <path> from the <name> group alternative.
  104.   --remove-all <name>      remove <name> group from the alternatives system.
  105.   --auto <name>            switch the master link <name> to automatic mode.
  106.   --display <name>         display information about the <name> group.
  107.   --list <name>            display all targets of the <name> group.
  108.   --config <name>          show alternatives for the <name> group and ask the
  109.                            user to select which one to use.
  110.   --set <name> <path>      set <path> as alternative for <name>.
  111.   --all                    call --config on all alternatives.
  112.  
  113. <link> is the symlink pointing to %s/<name>.
  114.   (e.g. /usr/bin/pager)
  115. <name> is the master name for this link group.
  116.   (e.g. pager)
  117. <path> is the location of one of the alternative target files.
  118.   (e.g. /usr/bin/less)
  119. <priority> is an integer; options with higher numbers have higher priority in
  120.   automatic mode.
  121.  
  122. Options:
  123.   --altdir <directory>     change the alternatives directory.
  124.   --admindir <directory>   change the administrative directory.
  125.   --verbose                verbose operation, more output.
  126.   --quiet                  quiet operation, minimal output.
  127.   --help                   show this help message.
  128.   --version                show the version.
  129. "), $progname, $altdir;
  130. }
  131.  
  132. sub quit
  133. {
  134.     printf STDERR "%s: %s\n", $progname, "@_";
  135.     exit(2);
  136. }
  137.  
  138. sub badusage
  139. {
  140.     printf STDERR "%s: %s\n\n", $progname, "@_";
  141.     &usage;
  142.     exit(2);
  143. }
  144.  
  145. sub read_link_group
  146. {
  147.     if (open(AF, "$admindir/$name")) {
  148.     $mode = gl("update_mode");
  149.     $mode eq 'auto' || $mode eq 'manual' || badfmt(_g("invalid update mode"));
  150.     $link = gl("link");
  151.     while (($sname = gl("sname")) ne '') {
  152.         push(@slavenames, $sname);
  153.         defined($slavenum{$sname}) && badfmt(sprintf(_g("duplicate slave %s"), $sname));
  154.         $slavenum{$sname} = $#slavenames;
  155.         $slink = gl("slink");
  156.         $slink eq $link && badfmt(sprintf(_g("slave link same as main link %s"), $link));
  157.         $slavelinkcount{$slink}++ && badfmt(sprintf(_g("duplicate slave link %s"), $slink));
  158.         push(@slavelinks, $slink);
  159.     }
  160.     while (($version = gl("version")) ne '') {
  161.         defined($versionnum{$version}) && badfmt(sprintf(_g("duplicate path %s"), $version));
  162.         if (-r $version || $mode eq 'remove' && $apath eq $version) {
  163.         push(@versions, $version);
  164.         my $i;
  165.         $versionnum{$version} = $i = $#versions;
  166.         my $priority = gl("priority");
  167.         $priority =~ m/^[-+]?\d+$/ || badfmt(sprintf(_g("priority %s %s"), $version, $priority));
  168.         $priorities[$i] = $priority;
  169.         for (my $j = 0; $j <= $#slavenames; $j++) {
  170.             $slavepath{$i,$j} = gl("spath");
  171.         }
  172.         } else {
  173.         # File not found - remove
  174.         pr(sprintf(_g("Alternative for %s points to %s - which wasn't found.  Removing from list of alternatives."), $name, $version))
  175.             if $verbosemode > 0;
  176.         gl("priority");
  177.         for (my $j = 0; $j <= $#slavenames; $j++) {
  178.             gl("spath");
  179.         }
  180.         }
  181.     }
  182.     close(AF);
  183.     return 0;
  184.     } elsif ($! != ENOENT) {
  185.     quit(sprintf(_g("unable to open %s: %s"), "$admindir/$name", $!));
  186.     } elsif ($! == ENOENT) {
  187.     return 1;
  188.     }
  189. }
  190.  
  191. sub fill_missing_slavepaths()
  192. {
  193.     for (my $j = 0; $j <= $#slavenames; $j++) {
  194.     for (my $i = 0; $i <= $#versions; $i++) {
  195.         $slavepath{$i,$j} ||= '';
  196.     }
  197.     }
  198. }
  199.  
  200. sub find_best_version
  201. {
  202.     $best = '';
  203.     for (my $i = 0; $i <= $#versions; $i++) {
  204.     if ($best eq '' || $priorities[$i] > $bestpri) {
  205.         $best = $versions[$i];
  206.         $bestpri = $priorities[$i];
  207.         $bestnum = $i;
  208.     }
  209.     }
  210. }
  211.  
  212. sub display_link_group
  213. {
  214.     pr(sprintf(_g("%s - status is %s."), $name, $mode));
  215.     $linkname = readlink("$altdir/$name");
  216.  
  217.     if (defined($linkname)) {
  218.     pr(sprintf(_g(" link currently points to %s"), $linkname));
  219.     } elsif ($! == ENOENT) {
  220.     pr(_g(" link currently absent"));
  221.     } else {
  222.     pr(sprintf(_g(" link unreadable - %s"), $!));
  223.     }
  224.  
  225.     for (my $i = 0; $i <= $#versions; $i++) {
  226.     pr(sprintf(_g("%s - priority %s"), $versions[$i], $priorities[$i]));
  227.     for (my $j = 0; $j <= $#slavenames; $j++) {
  228.         my $tspath = $slavepath{$i, $j};
  229.         next unless length($tspath);
  230.         pr(sprintf(_g(" slave %s: %s"), $slavenames[$j], $tspath));
  231.     }
  232.     }
  233.  
  234.     if ($best eq '') {
  235.     pr(_g("No versions available."));
  236.     } else {
  237.     pr(sprintf(_g("Current \`best' version is %s."), $best));
  238.     }
  239. }
  240.  
  241. sub list_link_group
  242. {
  243.     for (my $i = 0; $i <= $#versions; $i++) {
  244.     pr("$versions[$i]");
  245.     }
  246. }
  247.  
  248. sub checked_alternative($$$)
  249. {
  250.     my ($name, $link, $path) = @_;
  251.  
  252.     $linkname = readlink($link);
  253.     if (!defined($linkname) && $! != ENOENT) {
  254.     pr(sprintf(_g("warning: %s is supposed to be a symlink to %s, \n".
  255.                   "or nonexistent; however, readlink failed: %s"),
  256.                $link, "$altdir/$name", $!))
  257.         if $verbosemode > 0;
  258.     } elsif (!defined($linkname) ||
  259.             (defined($linkname) && $linkname ne "$altdir/$name")) {
  260.     checked_rm("$link.rpm-tmp");
  261.     checked_symlink("$altdir/$name", "$link.rpm-tmp");
  262.     checked_mv("$link.rpm-tmp", $link);
  263.     }
  264.     $linkname = readlink("$altdir/$name");
  265.     if (defined($linkname) && $linkname eq $path) {
  266.     pr(sprintf(_g("Leaving %s (%s) pointing to %s."), $name, $link, $path))
  267.         if $verbosemode > 0;
  268.     } else {
  269.     pr(sprintf(_g("Updating %s (%s) to point to %s."), $name, $link, $path))
  270.         if $verbosemode > 0;
  271.     }
  272. }
  273.  
  274. sub set_links($$)
  275. {
  276.     my ($spath, $preferred) = (@_);
  277.  
  278.     printf STDOUT _g("Using '%s' to provide '%s'.") . "\n", $spath, $name;
  279.     checked_symlink("$spath","$altdir/$name.rpm-tmp");
  280.     checked_mv("$altdir/$name.rpm-tmp", "$altdir/$name");
  281.  
  282.     # Link slaves...
  283.     for (my $slnum = 0; $slnum < @slavenames; $slnum++) {
  284.     my $slave = $slavenames[$slnum];
  285.     if ($slavepath{$preferred, $slnum} ne '') {
  286.         checked_alternative($slave, $slavelinks[$slnum],
  287.                       $slavepath{$preferred, $slnum});
  288.         checked_symlink($slavepath{$preferred, $slnum},
  289.                         "$altdir/$slave.rpm-tmp");
  290.         checked_mv("$altdir/$slave.rpm-tmp", "$altdir/$slave");
  291.     } else {
  292.         pr(sprintf(_g("Removing %s (%s), not appropriate with %s."), $slave,
  293.                    $slavelinks[$slnum], $versions[$preferred]))
  294.             if $verbosemode > 0;
  295.         checked_rm("$altdir/$slave");
  296.     }
  297.     }
  298. }
  299.  
  300. sub check_many_actions()
  301. {
  302.     return unless $action;
  303.     badusage(sprintf(_g("two commands specified: %s and --%s"), $_, $action));
  304. }
  305.  
  306. sub checked_rm($)
  307. {
  308.     my ($f) = @_;
  309.     unlink($f) || $! == ENOENT ||
  310.         quit(sprintf(_g("unable to remove %s: %s"), $f, $!));
  311. }
  312.  
  313. #
  314. # Main program
  315. #
  316.  
  317. $| = 1;
  318.  
  319. while (@ARGV) {
  320.     $_= shift(@ARGV);
  321.     last if m/^--$/;
  322.     if (!m/^--/) {
  323.         &quit(sprintf(_g("unknown argument \`%s'"), $_));
  324.     } elsif (m/^--help$/) {
  325.         &usage; exit(0);
  326.     } elsif (m/^--version$/) {
  327.         &version; exit(0);
  328.     } elsif (m/^--verbose$/) {
  329.         $verbosemode= +1;
  330.     } elsif (m/^--quiet$/) {
  331.         $verbosemode= -1;
  332.     } elsif (m/^--install$/) {
  333.     check_many_actions();
  334.         @ARGV >= 4 || &badusage(_g("--install needs <link> <name> <path> <priority>"));
  335.         ($alink,$name,$apath,$apriority,@ARGV) = @ARGV;
  336.         $apriority =~ m/^[-+]?\d+/ || &badusage(_g("priority must be an integer"));
  337.     $action = 'install';
  338.     } elsif (m/^--(remove|set)$/) {
  339.     check_many_actions();
  340.         @ARGV >= 2 || &badusage(sprintf(_g("--%s needs <name> <path>"), $1));
  341.         ($name,$apath,@ARGV) = @ARGV;
  342.     $action = $1;
  343.     } elsif (m/^--(display|auto|config|list|remove-all)$/) {
  344.     check_many_actions();
  345.         @ARGV || &badusage(sprintf(_g("--%s needs <name>"), $1));
  346.     $action = $1;
  347.         $name= shift(@ARGV);
  348.     } elsif (m/^--slave$/) {
  349.         @ARGV >= 3 || &badusage(_g("--slave needs <link> <name> <path>"));
  350.         ($slink,$sname,$spath,@ARGV) = @ARGV;
  351.         defined($aslavelink{$sname}) && &badusage(sprintf(_g("slave name %s duplicated"), $sname));
  352.         $aslavelinkcount{$slink}++ && &badusage(sprintf(_g("slave link %s duplicated"), $slink));
  353.         $aslavelink{$sname}= $slink;
  354.         $aslavepath{$sname}= $spath;
  355.     } elsif (m/^--altdir$/) {
  356.         @ARGV || &badusage(sprintf(_g("--%s needs a <directory> argument"), "altdir"));
  357.         $altdir= shift(@ARGV);
  358.     } elsif (m/^--admindir$/) {
  359.         @ARGV || &badusage(sprintf(_g("--%s needs a <directory> argument"), "admindir"));
  360.         $admindir= shift(@ARGV);
  361.     } elsif (m/^--all$/) {
  362.     $action = 'all';
  363.     } else {
  364.         &badusage(sprintf(_g("unknown option \`%s'"), $_));
  365.     }
  366. }
  367.  
  368. defined($name) && defined($aslavelink{$name}) &&
  369.   badusage(sprintf(_g("name %s is both primary and slave"), $name));
  370. defined($alink) && $aslavelinkcount{$alink} &&
  371.   badusage(sprintf(_g("link %s is both primary and slave"), $alink));
  372.  
  373. $action ||
  374.   badusage(_g("need --display, --config, --set, --install, --remove, --all, --remove-all or --auto"));
  375. $action eq 'install' || !%aslavelink ||
  376.   badusage(_g("--slave only allowed with --install"));
  377.  
  378. if ($action eq 'all') {
  379.     &config_all();
  380.     exit 0;
  381. }
  382.  
  383. if (read_link_group()) {
  384.     if ($action eq 'remove') {
  385.     # FIXME: Be consistent for now with the case when we try to remove a
  386.     # non-existing path from an existing link group file.
  387.     exit 0;
  388.     } elsif ($action ne 'install') {
  389.     pr(sprintf(_g("No alternatives for %s."), $name));
  390.     exit 1;
  391.     }
  392. }
  393.  
  394. if ($action eq 'display') {
  395.     find_best_version();
  396.     display_link_group();
  397.     exit 0;
  398. }
  399.  
  400. if ($action eq 'list') {
  401.     list_link_group();
  402.     exit 0;
  403. }
  404.  
  405. find_best_version();
  406.  
  407. if ($action eq 'config') {
  408.     config_alternatives($name);
  409. }
  410.  
  411. if ($action eq 'set') {
  412.     set_alternatives($name);
  413. }
  414.  
  415. if (defined($linkname= readlink("$altdir/$name"))) {
  416.     if (! -e $linkname) { # handle broken links as nonexistent
  417.         $state= 'nonexistent';
  418.     } elsif ($linkname eq $best) {
  419.         $state= 'expected';
  420.     } elsif (defined(readlink("$altdir/$name.rpm-tmp"))) {
  421.         $state= 'expected-inprogress';
  422.     } else {
  423.         $state= 'unexpected';
  424.     }
  425. } elsif ($! == &ENOENT) {
  426.     $state= 'nonexistent';
  427. } else {
  428.     $state= 'unexpected';
  429. }
  430.  
  431. # Possible values for:
  432. #   $mode        manual, auto
  433. #   $state       expected, expected-inprogress, unexpected, nonexistent
  434. #   $action      auto, install, remove, remove-all
  435. # all independent
  436.  
  437. if ($action eq 'auto') {
  438.     &pr(sprintf(_g("Setting up automatic selection of %s."), $name))
  439.       if $verbosemode > 0;
  440.     checked_rm("$altdir/$name.rpm-tmp");
  441.     checked_rm("$altdir/$name");
  442.     $state= 'nonexistent';
  443.     $mode = 'auto';
  444. }
  445.  
  446. #   $mode        manual, auto
  447. #   $state       expected, expected-inprogress, unexpected, nonexistent
  448. #   $action      auto, install, remove
  449. # action=auto <=> state=nonexistent
  450.  
  451. if ($state eq 'unexpected' && $mode eq 'auto') {
  452.     &pr(sprintf(_g("%s has been changed (manually or by a script).\n".
  453.                    "Switching to manual updates only."), "$altdir/$name"))
  454.       if $verbosemode > 0;
  455.     $mode = 'manual';
  456. }
  457.  
  458. #   $mode        manual, auto
  459. #   $state       expected, expected-inprogress, unexpected, nonexistent
  460. #   $action      auto, install, remove
  461. # action=auto <=> state=nonexistent
  462. # state=unexpected => mode=manual
  463.  
  464. &pr(sprintf(_g("Checking available versions of %s, updating links in %s ...\n".
  465.     "(You may modify the symlinks there yourself if desired - see \`man ln'.)"), $name, $altdir))
  466.   if $verbosemode > 0;
  467.  
  468. if ($action eq 'install') {
  469.     if (defined($link) && $link ne $alink) {
  470.         &pr(sprintf(_g("Renaming %s link from %s to %s."), $name, $link, $alink))
  471.           if $verbosemode > 0;
  472.         rename_mv($link,$alink) || $! == &ENOENT ||
  473.             &quit(sprintf(_g("unable to rename %s to %s: %s"), $link, $alink, $!));
  474.     }
  475.     $link= $alink;
  476.     my $i;
  477.     if (!defined($i= $versionnum{$apath})) {
  478.         push(@versions,$apath);
  479.         $versionnum{$apath}= $i= $#versions;
  480.     }
  481.     $priorities[$i]= $apriority;
  482.     for $sname (keys %aslavelink) {
  483.         my $j;
  484.         if (!defined($j= $slavenum{$sname})) {
  485.             push(@slavenames,$sname);
  486.             $slavenum{$sname}= $j= $#slavenames;
  487.         }
  488.         my $oldslavelink = $slavelinks[$j];
  489.         my $newslavelink = $aslavelink{$sname};
  490.     $slavelinkcount{$oldslavelink}-- if defined($oldslavelink);
  491.         $slavelinkcount{$newslavelink}++ &&
  492.             &quit(sprintf(_g("slave link name %s duplicated"), $newslavelink));
  493.     if (defined($oldslavelink) && $newslavelink ne $oldslavelink) {
  494.             &pr(sprintf(_g("Renaming %s slave link from %s to %s."), $sname, $oldslavelink, $newslavelink))
  495.               if $verbosemode > 0;
  496.             rename_mv($oldslavelink,$newslavelink) || $! == &ENOENT ||
  497.                 &quit(sprintf(_g("unable to rename %s to %s: %s"), $oldslavelink, $newslavelink, $!));
  498.         }
  499.         $slavelinks[$j]= $newslavelink;
  500.     }
  501.     for (my $j = 0; $j <= $#slavenames; $j++) {
  502.         $slavepath{$i,$j}= $aslavepath{$slavenames[$j]};
  503.     }
  504.  
  505.     fill_missing_slavepaths();
  506. }
  507.  
  508. if ($action eq 'remove') {
  509.     my $hits = 0;
  510.     if ($mode eq "manual" and $state ne "expected" and (map { $hits += $apath eq $_ } @versions) and $hits and $linkname eq $apath) {
  511.     &pr(_g("Removing manually selected alternative - switching to auto mode"));
  512.     $mode = "auto";
  513.     }
  514.     if (defined(my $i = $versionnum{$apath})) {
  515.         my $k = $#versions;
  516.         $versionnum{$versions[$k]}= $i;
  517.         delete $versionnum{$versions[$i]};
  518.         $versions[$i]= $versions[$k]; $#versions--;
  519.         $priorities[$i]= $priorities[$k]; $#priorities--;
  520.         for (my $j = 0; $j <= $#slavenames; $j++) {
  521.             $slavepath{$i,$j}= $slavepath{$k,$j};
  522.             delete $slavepath{$k,$j};
  523.         }
  524.     } else {
  525.         &pr(sprintf(_g("Alternative %s for %s not registered, not removing."), $apath, $name))
  526.           if $verbosemode > 0;
  527.     }
  528. }
  529.  
  530. if ($action eq 'remove-all') {
  531.    $mode = "auto";
  532.    my $k = $#versions;
  533.    for (my $i = 0; $i <= $#versions; $i++) {
  534.         $k--;
  535.         delete $versionnum{$versions[$i]};
  536.     $#priorities--;
  537.         for (my $j = 0; $j <= $#slavenames; $j++) {
  538.             $slavepath{$i,$j}= $slavepath{$k,$j};
  539.             delete $slavepath{$k,$j};
  540.         }
  541.       }
  542.    $#versions=$k;
  543.  }
  544.  
  545.  
  546. for (my $j = 0; $j <= $#slavenames; $j++) {
  547.     my $i;
  548.     for ($i = 0; $i <= $#versions; $i++) {
  549.         last if $slavepath{$i,$j} ne '';
  550.     }
  551.     if ($i > $#versions) {
  552.         &pr(sprintf(_g("Discarding obsolete slave link %s (%s)."), $slavenames[$j], $slavelinks[$j]))
  553.           if $verbosemode > 0;
  554.         checked_rm("$altdir/$slavenames[$j]");
  555.         checked_rm($slavelinks[$j]);
  556.         my $k = $#slavenames;
  557.         $slavenum{$slavenames[$k]}= $j;
  558.         delete $slavenum{$slavenames[$j]};
  559.         $slavelinkcount{$slavelinks[$j]}--;
  560.         $slavenames[$j]= $slavenames[$k]; $#slavenames--;
  561.         $slavelinks[$j]= $slavelinks[$k]; $#slavelinks--;
  562.         for (my $i = 0; $i <= $#versions; $i++) {
  563.             $slavepath{$i,$j}= $slavepath{$i,$k};
  564.             delete $slavepath{$i,$k};
  565.         }
  566.         $j--;
  567.     }
  568. }
  569.         
  570. if ($mode eq 'manual') {
  571.     &pr(sprintf(_g("Automatic updates of %s are disabled, leaving it alone."), "$altdir/$name"))
  572.       if $verbosemode > 0;
  573.     &pr(sprintf(_g("To return to automatic updates use \`update-alternatives --auto %s'."), $name))
  574.       if $verbosemode > 0;
  575. } else {
  576.     if ($state eq 'expected-inprogress') {
  577.         &pr(sprintf(_g("Recovering from previous failed update of %s ..."), $name));
  578.     checked_mv("$altdir/$name.rpm-tmp", "$altdir/$name");
  579.         $state= 'expected';
  580.     }
  581. }
  582.  
  583. #   $mode        manual, auto
  584. #   $state       expected, expected-inprogress, unexpected, nonexistent
  585. #   $action      auto, install, remove
  586. # action=auto <=> state=nonexistent
  587. # state=unexpected => mode=manual
  588. # mode=auto => state!=expected-inprogress && state!=unexpected
  589.  
  590. open(AF,">$admindir/$name.rpm-new") ||
  591.     &quit(sprintf(_g("unable to open %s for write: %s"), "$admindir/$name.rpm-new", $!));
  592. paf($mode);
  593. &paf($link);
  594. for (my $j = 0; $j <= $#slavenames; $j++) {
  595.     &paf($slavenames[$j]);
  596.     &paf($slavelinks[$j]);
  597. }
  598.  
  599. find_best_version();
  600.  
  601. &paf('');
  602. for (my $i = 0; $i <= $#versions; $i++) {
  603.     &paf($versions[$i]);
  604.     &paf($priorities[$i]);
  605.     for (my $j = 0; $j <= $#slavenames; $j++) {
  606.         &paf($slavepath{$i,$j});
  607.     }
  608. }
  609. &paf('');
  610. close(AF) || &quit(sprintf(_g("unable to close %s: %s"), "$admindir/$name.rpm-new", $!));
  611.  
  612. if ($mode eq 'auto') {
  613.     if ($best eq '') {
  614.         &pr(sprintf(_g("Last package providing %s (%s) removed, deleting it."), $name, $link))
  615.           if $verbosemode > 0;
  616.         checked_rm("$altdir/$name");
  617.         checked_rm("$link");
  618.         checked_rm("$admindir/$name.rpm-new");
  619.         checked_rm("$admindir/$name");
  620.         exit(0);
  621.     } else {
  622.     checked_alternative($name, $link, $best);
  623.         checked_rm("$altdir/$name.rpm-tmp");
  624.         symlink($best,"$altdir/$name.rpm-tmp");
  625.     }
  626. }
  627.  
  628. checked_mv("$admindir/$name.rpm-new", "$admindir/$name");
  629.  
  630. if ($mode eq 'auto') {
  631.     checked_mv("$altdir/$name.rpm-tmp", "$altdir/$name");
  632.     for (my $j = 0; $j <= $#slavenames; $j++) {
  633.         $sname= $slavenames[$j];
  634.         $slink= $slavelinks[$j];
  635.         $spath= $slavepath{$bestnum,$j};
  636.         checked_rm("$altdir/$sname.rpm-tmp");
  637.         if ($spath eq '') {
  638.             &pr(sprintf(_g("Removing %s (%s), not appropriate with %s."), $sname, $slink, $best))
  639.               if $verbosemode > 0;
  640.             checked_rm("$altdir/$sname");
  641.             checked_rm("$slink");
  642.         } else {
  643.         checked_alternative($sname, $slink, $spath);
  644.         checked_symlink("$spath", "$altdir/$sname.rpm-tmp");
  645.         checked_mv("$altdir/$sname.rpm-tmp", "$altdir/$sname");
  646.         }
  647.     }
  648. }
  649.  
  650. sub config_message {
  651.     if ($#versions < 0) {
  652.     print "\n";
  653.     printf _g("There is no program which provides %s.\n".
  654.               "Nothing to configure.\n"), $name;
  655.     return -1;
  656.     }
  657.     if ($#versions == 0) {
  658.     print "\n";
  659.     printf _g("There is only 1 program which provides %s\n".
  660.               "(%s). Nothing to configure.\n"), $name, $versions[0];
  661.     return -1;
  662.     }
  663.     print STDOUT "\n";
  664.     printf(STDOUT _g("There are %s alternatives which provide \`%s'.\n\n".
  665.                      "  Selection    Alternative\n".
  666.                      "-----------------------------------------------\n"),
  667.                   $#versions+1, $name);
  668.     for (my $i = 0; $i <= $#versions; $i++) {
  669.     printf(STDOUT "%s%s %8s    %s\n",
  670.         (readlink("$altdir/$name") eq $versions[$i]) ? '*' : ' ',
  671.         ($best eq $versions[$i]) ? '+' : ' ',
  672.         $i+1, $versions[$i]);
  673.     }
  674.     printf(STDOUT "\n"._g("Press enter to keep the default[*], or type selection number: "));
  675.     return 0;
  676. }
  677.  
  678. sub config_alternatives {
  679.     my $preferred;
  680.     do {
  681.     return if config_message() < 0;
  682.     $preferred=<STDIN>;
  683.     chop($preferred);
  684.     } until $preferred eq '' || $preferred>=1 && $preferred<=$#versions+1 &&
  685.     ($preferred =~ m/[0-9]*/);
  686.     if ($preferred ne '') {
  687.     $mode = "manual";
  688.     $preferred--;
  689.     my $spath = $versions[$preferred];
  690.  
  691.     set_links($spath, $preferred);
  692.     }
  693. }
  694.  
  695. sub set_alternatives {
  696.    $mode = "manual";
  697.    # Get prefered number
  698.    my $preferred = -1;
  699.    for (my $i = 0; $i <= $#versions; $i++) {
  700.      if($versions[$i] eq $apath) {
  701.        $preferred = $i;
  702.        last;
  703.      }
  704.    }
  705.    if($preferred == -1){
  706.      &quit(sprintf(_g("Cannot find alternative `%s'."), $apath)."\n")
  707.    }
  708.    set_links($apath, $preferred);
  709. }
  710.  
  711. sub pr { print(STDOUT "@_\n") || &quit(sprintf(_g("error writing stdout: %s"), $!)); }
  712. sub paf {
  713.     $_[0] =~ m/\n/ && &quit(sprintf(_g("newlines prohibited in update-alternatives files (%s)"), $_[0]));
  714.     print(AF "$_[0]\n") || &quit(sprintf(_g("error writing stdout: %s"), $!));
  715. }
  716. sub gl {
  717.     $!=0; $_= <AF>;
  718.     defined($_) || quit(sprintf(_g("error or eof reading %s for %s (%s)"),
  719.                                 "$admindir/$name", $_[0], $!));
  720.     s/\n$// || &badfmt(sprintf(_g("missing newline after %s"), $_[0]));
  721.     $_;
  722. }
  723. sub badfmt {
  724.     &quit(sprintf(_g("internal error: %s corrupt: %s"), "$admindir/$name", $_[0]));
  725. }
  726. sub rename_mv {
  727.     return (rename($_[0], $_[1]) || (system(("mv", $_[0], $_[1])) == 0));
  728. }
  729. sub checked_symlink {
  730.     my ($filename, $linkname) = @_;
  731.     symlink($filename, $linkname) ||
  732.     &quit(sprintf(_g("unable to make %s a symlink to %s: %s"), $linkname, $filename, $!));
  733. }
  734. sub checked_mv {
  735.     my ($source, $dest) = @_;
  736.     rename_mv($source, $dest) ||
  737.     &quit(sprintf(_g("unable to install %s as %s: %s"), $source, $dest, $!));
  738. }
  739. sub config_all {
  740.     opendir ADMINDIR, $admindir or die sprintf(_g("Serious problem: %s"), $!);
  741.     my @filenames = grep !/^\.\.?$/, readdir ADMINDIR;
  742.     close ADMINDIR;
  743.     foreach my $name (@filenames) {
  744.         system "$0 --config $name";
  745.         exit $? if $?;
  746.     }
  747. }
  748. exit(0);
  749.  
  750. # vim: nowrap ts=8 sw=4
  751.