17 Bit Software 4: Phase Four/17Bit_Phase_Four.iso/files/3082b.dms/3082b.adf/Code/Barebones.AMOS/Barebones.amosSourceCode

AMOS Source Code | 1993-02-25 | 43.3 KB | 1,585 lines

Set Buffer 17
'                    -------- Ant Wars ---------
'
'                              V 1.1
'
'  You are allowed to use (small) parts of this program in your own
'     games , as long as you give me credit for it , all right ?
'   Chris Gregan , Sheaf o' Wheat , Dunboyne , Co. Meath , Ireland
'  Just because you're Paranoid , don't mean they're not after you !
'
Bob Update On
Hide On : Change Mouse 1
Screen Open 0,640,512,2,Hires+Laced : Cls 0
Screen Hide 0
Load Iff "df0:nemesis"
Colour 1,$0 : Screen Show 0
For N=1 To 14
Read A : Colour 1,A : Wait 3 : Next N
Data $111,$222,$333,$444,$555,$666,$777,$888,$999,$AAA,$BBB,$CCC,$DDD,$EEE
Do
   N=N+1
   If Mouse Key or Fire(1)=-1 Then Exit
   If Inkey$<>"" Then Exit
   If N=10000 Then Exit
Loop
Fade 2 : Wait 30
Screen Close 0 : Wait Vbl
Screen Open 0,320,256,2,Lowres : Cls 0 : Ink 1 : Curs Off
Screen Hide 0
Unpack 8 To 0
Screen Display 0,135,60,320,200
Wait Vbl
Screen Show 0
Do
   N=N+1
   If Mouse Key or Fire(1)=-1 Then Exit
   If Inkey$<>"" Then Exit
   If N=25000 Then Exit
Loop
Unpack 9 To 0
Close Editor
ROOT$="df0:code/groundmap4" : Rem Directory of Map
GRAPHIC$="Ant_War2:graphics/bobbank(blocks).abk"
Global CF1
MX=1000
Dim MOBX(MX),MOBY(MX),MOBN(MX)
ANTS#=40 : ANT=1 : MP=1 : AC=0 : GOS=10 : Rem AC=ant colour
Dim X(ANTS#),Y(ANTS#),DINC(ANTS#),ACTIVE(ANTS#)
Global BLX,BLY,GGG,FLAGKILL
Global Z,X(),Y(),DINC(),ANT,ANTS#,ACTIVE(),MP,ESC,AC,GOS,XX,YY,HN,B$
Global MOBX(),MOBY(),MOBN(),MOB,OFFSX,OFFSY,A$,ROOT$,GRAPHIC$,SX,SY
Global CT1,CT2,SXR,SYR,SXB,SYB,XXA,YYA,DDA,XM,BASX,BASY,BASX2,BASY2
Global B1,B2,CAN1,CAN2
Global R#,B#
B1=2
B2=2
Global BUG,EX
BX#=100 : BY#=100
Global BX#,BY#,ANGLE#,F
Dim HX(2),HY(2),HDINC(2),HP(2)
HD1=0 : HD2=0
HDINC(1)=102 : HDINC(2)=102 : HC=0
Global HX(),HY(),HDINC(),HC,FRAME,HP(),HD1,HD2,Q
Dim SMF(23),SML(23)
Global SMF(),SML(),OFF
TITLE
Show
GRAPHIX
ESCAPE
_SCROLL
SETAMAL
HELI
1
Do
   BUTTONS
Loop
Procedure SOUNDS
   Load "df0:basicsounds.abk",5
   If Chip Free>512000
      CF1=1
      Screen 1 : Centre "...1 Mb Chip Mem allocated..."
      Print : Print : Centre "Loading Enhanced Samples !"
      Load "df0:sounds.abk",6
      Cls 0
   End If
End Proc
Procedure TITLE
   ST:
   Rainbow Del
   Sam Loop On
   Load "Ant_War2:tunes.abk",5
   Sam Bank 5
   Sam Play 1
   Fade 2 : Wait 30
   Erase 8
   Erase 9
   Show On
   Screen Open 0,320,200,16,Lowres
   Cls 0
   Restore
   Read A
   Screen Open 0,320,208,4,Lowres : Curs Off
   Screen Display 0,,50,,
   Set Rainbow 0,1,30,"(1,1,15)(1,-1,15)","",""
   Rainbow 0,0,49,212 : Rem - Thanks to whoever programmed this bit ! -
   Channel 0 To Rainbow 0
   Amal 0,"Loop: For RA=0 To 29; Let X=RA; P;P;P;P;P; Next RA; Jump Loop"
   Amal On
   Curs Off : Flash Off
   Paper 0 : Ink 0
   Bar 100,20 To 222,180
   Ink 2 : Box 101,21 To 221,179
   Print : Print : Print
   Centre "Select A Level"
   Print : Print
   Reserve Zone A
   For N=1 To A
      Read B$
      X$=Zone$(B$,N)
      Centre X$
      Print
   Next N
   Locate 14,20
   Print "Choice :";
   Do
      If Mouse Key=1 and Mouse Zone>0 Then K=Mouse Zone : Exit
      MZ=Mouse Zone
      If MZ<>MZZ
         Locate 22,20
         Print "    "
         Locate 22,20
      End If
      If Mouse Zone>0 Then Locate 22,20 : Print Mouse Zone
      MZZ=MZ
   Loop
   Curs Off : Sam Stop : Sam Loop Off : Amal Off
   Erase 5
   Data 13
   Data "1:Care Bear"
   Data "2:Hair Bear"
   Data "3:Rockies  "
   Data "4:Radland  "
   Data "5:Muck     "
   Data "6:Wooly    "
   Data "7:Mud      "
   Data "8:Mess     "
   Data "9:The Pit  "
   Data "10:A bugger"
   Data "11:Fortress"
   Data "12:Strange "
   Data "13:Random  "
   If K=1
      ROOT$="Ant_War2:maps/cloudmap1"
      GRAPHIC$="Ant_War2:graphics/bobbank(cloud).abk"
   End If
   If K=2
      ROOT$="Ant_War2:maps/cloudmap2"
      GRAPHIC$="Ant_War2:graphics/bobbank(cloud).abk"
   End If
   If K=3
      ROOT$="Ant_War2:maps/rockmap"
      GRAPHIC$="Ant_War2:graphics/bobbank(blocks).abk"
   End If
   If K=4
      ROOT$="Ant_War2:maps/rockmap2"
      GRAPHIC$="Ant_War2:graphics/bobbank(blocks).abk"
   End If
   If K=5
      ROOT$="Ant_War2:maps/groundmap2"
      GRAPHIC$="Ant_War2:graphics/bobbank(blocks).abk"
   End If
   If K=6
      ROOT$="Ant_War2:maps/tablemap1"
      GRAPHIC$="Ant_War2:graphics/bobbank(cloud).abk"
   End If
   If K=7
      ROOT$="Ant_War2:maps/tablemap2"
      GRAPHIC$="Ant_War2:graphics/bobbank(special).abk"
   End If
   If K=8
      ROOT$="Ant_War2:maps/tablemap3"
      GRAPHIC$="Ant_War2:graphics/bobbank(special).abk"
   End If
   If K=9
      ROOT$="Ant_War2:maps/thepit"
      GRAPHIC$="Ant_War2:graphics/bobbank(blocks).abk"
   End If
   '
   If K=10
      ROOT$="Ant_War2:maps/bugger"
      GRAPHIC$="Ant_War2:graphics/bobbank(cloud).abk"
   End If
   If K=11
      ROOT$="Ant_War2:maps/surreal#1"
      GRAPHIC$="Ant_War2:graphics/bobbank(blocks).abk"
   End If
   If K=12
      ROOT$="Ant_War2:maps/surreal#2"
      GRAPHIC$="Ant_War2:graphics/bobbank(special).abk"
   End If
   For N=ANTS#/2 To ANTS#
      DINC(N)=4
   Next N
   If K=13
      SX=1008 : SY=200
      Load "Ant_War2:graphics/bobbank(ants).abk"
      SCREEOPEN
      RANMAP
      Stop
   End If
End Proc
Procedure SCREEOPEN
   Fade 2 : Wait 15*2
   Screen Open 1,320,62,16,Lowres : Curs Off : Paper 0 : Flash Off : Cls
   Rainbow Del
   Screen Open 0,SX,200,16,Lowres : Paper 0 : Cls : Curs Off : Flash Off
   Screen Display 0,135,113,320,196
   Screen Hide 0
   Autoback 0
   Limit Mouse 128,105-55 To 447,300
   Get Sprite Palette
End Proc
Procedure GRAPHIX
   Load GRAPHIC$
End Proc
Procedure GRAPHICS
   Load "Ant_War2:graphics/bobbank(ants).abk"
   Get Sprite Palette
   Double Buffer : Wait Vbl
   Bob 49,BASX,BASY,124
   Bob 50,BASX2,BASY2,123
   Screen Show 0
   SOUNDS
   Screen 1 : Get Sprite Palette : Screen 0
   Wait Vbl
End Proc
Procedure RANMAP
   3
   SOUNDS : Screen 0
   Screen Show 0 : Screen Offset 0,0,0
   Get Sprite Palette
   Cls 0 : Wait 5
   X=60 : Y#=100 : I#=0.3 : D=-1
   Ink 5 : Bar 0,100-25 To X,200
   Repeat
      Ink 5
      If Y#-25>3 Then Draw X,200 To X,Y#-25 Else Draw X,200 To X,3
      If Y#-25>3 Then Ink 4 : Draw X,Y#-25 To X,Y#-27 Else Ink 4 : Draw X,5 To X,3
      If X>180 and X<846 Then Screen Offset 0,X-180,
      Y#=Y#+I#
      If D=1 Then I#=I#+0.05
      If D=-1 Then I#=I#-0.05
      If I#>1 and D=1 Then D=-1 : I#=0
      If I#>1 and D=-1 Then D=1 : I#=0
      If Rnd(2)=2 Then D=D*-1
      If Y#>170 Then D=-1
      If Y#<60 Then D=1
      If X>700 and Y#<90 Then D=1 : I#=I#+0.1
      X=X+1
   Until X=938
   Ink 5
   Bar X,Y#-27 To 1008,200
   Double Buffer
   Bob 49,-2,35,124
   Bob 50,935,Y#-70,123
   BASX=-2 : BASY=35
   SXB=BASX+35 : SYB=BASY-5 : HX(2)=90 : HY(2)=15
   BASX2=935 : BASY2=Y#-70
   SXR=BASX2+35 : SYR=BASY2-5 : HX(1)=910 : HY(1)=20
   For N=1 To ANTS#/2
      X(N)=SXR : Y(N)=SYR : DINC(N)=0 : ACTIVE(N)=2
   Next N
   For N=(ANTS#/2)+1 To ANTS#
      X(N)=SXB : Y(N)=SYB : DINC(N)=0 : ACTIVE(N)=2
   Next N
   Bob 62,,,108
   Bob 63,,,105
   HELI
   Wait Vbl
   _SCROLL
   SETAMAL
   Screen Offset 0,1008-320,
   Screen 1 : Cls
   Ink 0 : Bar 0,0 To 1008,3
   Ink 1
   Centre "Is this O.K  ? ("
   Reserve Zone 2
   Print Zone$("Y",1);
   Print "/";
   Print Zone$("N",2);
   Print ") ";
   Do
      A$=Inkey$
      If A$="y" Then Print "Y" : Goto 2
      If Mouse Zone=1 and Mouse Key=1 Then Print "Y" : Goto 2
      If A$="n" Then Print "N" : Bob Off : SCREEOPEN : Goto 3
      If Mouse Zone=2 and Mouse Key=1 Then Print "N" : Bob Off : SCREEOPEN : Goto 3
      If MZ<>Mouse Zone and Mouse Zone=1 Then Locate 33,0 : Print "  " : Locate 33,0 : Print "Y" : MZ=Mouse Zone
      If MZ<>Mouse Zone and Mouse Zone=2 Then Locate 33,0 : Print "  " : Locate 33,0 : Print "N" : MZ=Mouse Zone
      If Mouse Zone=0 Then Locate 33,0 : Print "  " : Locate 33,0 : MZ=0
      Locate 33,0
   Loop
   2
   Do
      BUTTONS
   Loop
End Proc
Procedure ESCAPE
   Open In 1,ROOT$
   Input #1,SX
   Input #1,SY
   Input #1,T : MOB=T
   For N=1 To MOB
      Input #1,A
      Input #1,B
      Input #1,C
      MOBX(N)=A
      MOBY(N)=B
      MOBN(N)=C
   Next N
   Input #1,HX(2)
   Input #1,HY(2)
   Input #1,HX(1)
   Input #1,HY(1)
   Input #1,BASX
   Input #1,BASY
   Input #1,BASX2
   Input #1,BASY2
   Input #1,SXB
   Input #1,SYB
   Input #1,SXR
   Input #1,SYR
   Close 1
   For N=1 To ANTS#/2
      X(N)=SXR : Y(N)=SYR : DINC(N)=0 : ACTIVE(N)=2
   Next N
   For N=(ANTS#/2)+1 To ANTS#
      X(N)=SXB : Y(N)=SYB : DINC(N)=0 : ACTIVE(N)=2
   Next N
   SCREEOPEN
   For N=1 To MOB
      Paste Bob MOBX(N),MOBY(N),MOBN(N)
   Next N
   Ink 0 : Bar 0,0 To 1008,3
   GRAPHICS
End Proc
Procedure _SCROLL
   Channel 3 To Screen Offset 0
   A$=A$+"Loop:"
   A$=A$+""
   A$=A$+"I: If YM=50 then Jump E"
   A$=A$+"J: If YM=300 then Jump F"
   A$=A$+"K: If XM=128 then Jump G"
   A$=A$+"M: If XM=447 then Jump H"
   A$=A$+"Jump Loop"
   A$=A$+"E: If Y>0 then Jump A Jump J"
   A$=A$+"F: If Y<7 then Jump B Jump K"
   A$=A$+"G: If X>0 then Jump C Jump M"
   A$=A$+"H: If X<688 then Jump D Jump I"
   A$=A$+"A: Let Y=Y-1 Jump Loop"
   A$=A$+"B: Let Y=Y+1 Jump Loop"
   A$=A$+"C: Let X=X-1 Jump Loop"
   A$=A$+"D: Let X=X+1 Jump Loop"
   Amal 3,A$
   Amal On 3
End Proc
Procedure MOVE
   Screen 1 : Fade 2 : Wait 2*15 : Cls 0 : Get Sprite Palette
   Paste Bob 0,0,51
   SELECTANT
   If ANT=>666 Then GOS=GOS+1 : Pop Proc
   Screen 0
   Bob Update On : Amal On
   QUOTA=35
   A$=""
   XM=X(ANT)
   Screen 1 : Locate 12,5
   Print "Space Bar to end move."
   Do
      A$=Inkey$
      Screen 0
      If Mouse Key=1 Then XM=X Screen(X Mouse) : SAMLAY[8]
      If Point(X(ANT),Y(ANT)+1)=0 Then FALL
      If ACTIVE(ANT)=1 and XM<X(ANT)-2 Then DINC(ANT)=4 : FRAMES : QUOTA=QUOTA-1
      If ACTIVE(ANT)=1 and XM>X(ANT)+2 Then DINC(ANT)=0 : FRAMES : QUOTA=QUOTA-1
      MESSMOUSE
      If A$=" " Then QUOTA=0
      If DUM<>QUOTA
         Screen 1
         Locate 22,3 : Print "Steps :     ";
         Locate 30,3 : Print QUOTA : Screen 0
      End If
      DUM=QUOTA
      If QUOTA=0 Then Exit
      If QUOTA=38 Then AAANT=ANT : GRAVITY : ANT=AAANT
   Loop
End Proc
Procedure FALL
   Screen 0
   Repeat
      FAL=FAL+1
      Y(ANT)=Y(ANT)+1
      If FAL>4 and ACTIVE(ANT)=1 Then Bob ANT,X(ANT),Y(ANT),9+AC
      If FAL<4 and ACTIVE(ANT)=1 Then Bob ANT,X(ANT),Y(ANT),DINC(ANT)+1+AC
      If X(ANT)>SX or X(ANT)<0 or Y(ANT)>200 Then DEAD
      For N=1 To 10 : Next N
   Until Point(X(ANT),Y(ANT)+1)>0
   If ACTIVE(ANT)=1 Then Bob ANT,X(ANT),Y(ANT),DINC(ANT)+1+AC : Wait Vbl
   If Point(X(ANT),Y(ANT)+1)>0 and FAL>80 Then SPLAT
End Proc
Procedure CHECKPOS
   If Point(X(ANT),Y(ANT))>0 Then LIFT
   If X(ANT)>SX or X(ANT)<0 or Y(ANT)>SY Then DEAD
End Proc
Procedure LIFT
   Repeat
      If Point(X(ANT),Y(ANT))>0 Then Y(ANT)=Y(ANT)-1 : RI=RI+1
      If RI=15
         X(ANT)=XXA
         Y(ANT)=YYA
         DINC(ANT)=DDA
         XM=X(ANT)
         Exit
      End If
   Until Point(X(ANT),Y(ANT))=0 or Y(ANT)<=0
End Proc
Procedure SPLAT
   SAMLAY[1]
   For N=41 To 46
      Bob ANT,X(ANT),Y(ANT),N
      Wait Vbl
   Next N
   Bob Off ANT : Wait Vbl
   Paste Bob X(ANT)-11,Y(ANT)-4,46
   If ANT<20 Then R#=R#+1 Else B#=B#+1
   DEAD
End Proc
Procedure FRAMES
   For N=2 To 4
      If ACTIVE(ANT)=1 Then Bob ANT,X(ANT),Y(ANT),N+DINC(ANT)+AC : Wait Vbl
   Next N
   XXA=X(ANT) : YYA=Y(ANT) : DDA=DINC(ANT)
   For D=1 To 5
      If DINC(ANT)=0 Then X(ANT)=X(ANT)+1
      If DINC(ANT)=4 Then X(ANT)=X(ANT)-1
      CHECKPOS
   Next D
   If ACTIVE(ANT)=1 Then Bob ANT,X(ANT),Y(ANT),1+DINC(ANT)+AC : Wait Vbl
End Proc
Procedure DEAD
   ACTIVE(ANT)=0
   Bob Off ANT : ANTSORT : Wait Vbl
End Proc
Procedure BAZOOKROUTINE
   Do
      Screen 1 : Fade 2 : Wait 2*15 : Cls 0 : Get Sprite Palette
      Paste Bob 0,0,54
      SELECTANT
      If ANT=>666 Then GOS=GOS+1 : Pop Proc
      Screen 1
      Ink 1
      E=0
      Locate 15,5 : Print "Enter X to Esc"
      Curs Off
      Locate 15,3 : Print "Angle :(0-180)"; : Input AN$
      Curs Off
      If AN$="x" Then GOS=GOS+1 : Pop Proc
      If AN$="X" Then GOS=GOS+1 : Pop Proc
      Curs Off
      Locate 15,3 : Print " Force :(1-50)     "; : Locate 15+14,3 : Input F$
      Curs Off
      If F$="x" Then GOS=GOS+1 : Pop Proc
      If F$="X" Then GOS=GOS+1 : Pop Proc
      If Val(AN$)=>0 and Val(AN$)<=180 Then ANGLE#=Val(AN$) : E=1
      If Val(F$)=>1 and Val(F$)<=50 Then F=Val(F$) : E=E+1
      If E=2 Then Exit
   Loop
   Locate 15,5 : Print "              "
   SAMLAY[21] : Wait 50
   Curs Off
   Screen 0
   Bob Update On : Amal On
   BAZOOKA
   Bob Off 0 : Wait Vbl
   Screen 1
End Proc
Procedure BAZOOKA
   If ANGLE#>90 and DINC(ANT)=4 Then DINC(ANT)=0 : Goto DF
   If ANGLE#>90 and DINC(ANT)=0 Then DINC(ANT)=4
   DF:
   If ANGLE#>90 Then ANGLE#=180-ANGLE#
   ANGLE#=ANGLE#/57.3
   If DINC(ANT)=0 Then S=10 : T=15 Else S=16 : T=21
   For N=S To T
      Bob ANT,X(ANT),Y(ANT),N+AC
      Wait 4
   Next N
   BX#=X(ANT)+14
   If DINC(ANT)=4 Then BX#=X(ANT)-14
   BY#=Y(ANT)-24 : Shoot
   BAZOOKASHOOT
   BLAST
   If ACTIVE(ANT)<>1 Then Pop Proc
   For N=T To S Step -1
      Bob ANT,X(ANT),Y(ANT),N+AC
      Wait 4
   Next N
End Proc
Procedure BAZOOKASHOOT
   Screen 0
   Sam Stop
   SAMLAY[4]
   F#=F/10
   FX#=F#*Cos(ANGLE#)
   FY#=F#*Sin(ANGLE#)
   If DINC(ANT)=4 Then FX#=FX#*-1
   XX#=X(ANT)+5 : YY#=Y(ANT)-12
   If DINC(ANT)=4 Then XX#=X(ANT)-5 : Goto LEFT
   ANGLE=ANGLE#*57.3
   TX#=XX# : TY#=YY# : TFY#=FY#
   For N=1 To 200
      TX#=TX#+FX# : TY#=TY#-TFY#
      TFY#=TFY#-0.1
      If Point(TX#,TY#)>0 Then Exit
   Next N
   For N=1 To 200
      XX#=XX#+FX# : YY#=YY#-FY#
      FY#=FY#-0.1
      If FY#=>1 Then Bob 0,XX#,YY#,Vrev(145)
      If FY#<1 and FY#>-1 Then Bob 0,XX#,YY#,146
      If FY#<=-1 Then Bob 0,XX#,YY#,145
      If FY#=>0 and ANGLE=>86 Then Bob 0,XX#,YY#,Vrev(144)
      If FY#<0 and ANGLE=>86 Then Bob 0,XX#,YY#,144
      Wait 3
      If XX#=TX# and YY#=TY# Then Exit
   Next N
   Goto RIGHT
   LEFT:
   ANGLE=ANGLE#*57.3
   TX#=XX# : TY#=YY# : TFY#=FY#
   For N=1 To 150
      TX#=TX#+FX# : TY#=TY#-TFY#
      TFY#=TFY#-0.1
      If Point(TX#,TY#)>0 Then Exit
   Next N
   For N=1 To 150
      XX#=XX#+FX# : YY#=YY#-FY#
      FY#=FY#-0.1
      If FY#=>1 Then Bob 0,XX#,YY#,Hrev(Vrev(145))
      If FY#<1 and FY#>-1 Then Bob 0,XX#,YY#,Hrev(146)
      If FY#<=-1 Then Bob 0,XX#,YY#,Hrev(145)
      If FY#=>0 and ANGLE=>85 Then Bob 0,XX#,YY#,Vrev(144)
      If FY#<0 and ANGLE=>85 Then Bob 0,XX#,YY#,144
      Wait 3
      If XX#=TX# and YY#=TY# Then Exit
   Next N
   RIGHT:
   BLX=XX# : BLY=YY#
End Proc
Procedure BLAST
   Bob Off 0
   FLAGKILL=0
   SAMLAY[7]
   Bob 0,BLX,BLY,97 : Wait 10
   Bob 0,BLX,BLY,97 : Wait Vbl
   HITS
   If FLAGKILL=1 Then Bob Off 0 : Wait 3 : Pop Proc
   Bob Off 0 : Wait 3
End Proc
Procedure HITS
   AANT=ANT
   ANTKILL
   HELIKILL
   NESTKILL
   ANT=AANT
End Proc
Procedure ANTKILL
   Priority Reverse Off
   Bob 0,BLX,BLY,97
   Wait 10
   For ANT=1 To ANTS#
      If Bob Col(0,ANT To ANT)=-1 and ANT<20 Then R#=R#+1
      If Bob Col(0,ANT To ANT)=-1 and ANT>20 Then B#=B#+1
      If Bob Col(0,ANT To ANT)=-1
         Priority Reverse Off
         SAMLAY[1]
         For N=41 To 45
            Bob ANT,,,N
            Wait Vbl
         Next N
         DEAD
      End If
   Next ANT
End Proc
Procedure KILBAR
   If R#+B#=0 Then P#=50 : Goto DIV
   If R#=0 and B#=1 Then P#=1 : Goto DIV
   If R#=1 and B#=0 Then P#=99 : Goto DIV
   P#=(R#/(R#+B#))*100
   DIV:
   X=50 : Y=50
   Ink 1
   Box X-1,Y To X+200+3,Y+10
   If P#<1 Then P#=1
   Colour 2,$D00
   Ink 1 : Box X+1,Y+2 To X+1+(P#*2),Y+8
   If P#=99 Then P#=98 : JACK=1
   Ink 2 : Bar X+1+(P#*2)+2,Y+2 To X+200+1,Y+8
   Ink 1 : Box X+1+(P#*2)+2,Y+2 To X+200+1,Y+8
   If JACK=1 Then P#=99 : JACK=0
   Ink 1,0
   P#=Int(P#)
   ST$=Str$(P#)+"%"
   Text 38-Text Length(ST$),Y+10,ST$
   ST$=Str$(100-P#)+"%"
   Text X+207,Y+10,ST$
   Ink 0,1
End Proc
Procedure CRATER
   Screen 0
   Bob Off 0
   Paste Bob BLX-17,BLY-15,97
   Ink 0 : Circle BLX,BLY,15 : Boom :
   PD=0
   If Point(BLX,BLY)=8 Then Paint BLX,BLY : Wait Vbl
   If Point(BLX+6,BLY)=8 Then Paint BLX,BLY+6 : Wait Vbl
   If Point(BLX-6,BLY)=8 Then Paint BLX,BLY-6 : Wait Vbl
   If Point(BLX,BLY-3)=8 Then Paint BLX,BLY-3 : Wait Vbl
   FLAGKILL=1 : Bob Off 0 : Wait 5
End Proc
Procedure HELIKILL
   If Bob Col(0,63 To 63)=-1
      Screen 1 : Cls : Paste Bob 0,0,54 : Locate 15,1
      Pen 1 : Print "Red Heli Destroyed !"
      XB=X Bob(0) : YB=Y Bob(0) : Bob Off 0
      HN=1 : Screen 0 : XPLODE
      Bob Off 63 : Wait Vbl
      HD1=1 : FLAGKILL=1
      Bob 0,XB,YB,97
      Wait 5
      'Bob 63,100,220, : HX(1)=100 : HY(1)=220 : Wait 20
      Wait Vbl
   End If
   If Bob Col(0,62 To 62)=-1
      Screen 1 : Cls : Paste Bob 0,0,54 : Locate 15,1
      Pen 1 : Print "Black Heli Destroyed !"
      XB=X Bob(0) : YB=Y Bob(0) : Bob Off 0
      HN=2 : Screen 0 : XPLODE
      Bob Off 62
      HD2=1 : FLAGKILL=1
      Bob 0,XB,YB,97
      Wait 5
   End If
End Proc
Procedure NESTKILL
   If Bob Col(0,50 To 50)=-1
      Bob Off 0 : Wait Vbl
      Z=1 : BXPLODE : GOS=1 : Goto JOMP
   End If
   If Bob Col(0,49 To 49)=-1
      Bob Off 0 : Wait Vbl
      Z=2 : BXPLODE : GOS=1 : Goto JOMP
   End If
   CRATER
   JOMP:
End Proc
Procedure XPLODE
   XP=HX(HN) : YP=HY(HN)
   C$="Anim 0,(127,4)(128,4)(129,4)(130,4)(131,4)(132,4)"
   D$="Anim 0,(129,4)(130,4)(131,4)(132,4)(127,4)(128,4)"
   E$="Anim 0,(131,4)(132,4)(127,4)(128,4)(129,4)(131,4)"
   Channel 4 To Bob 55
   Channel 5 To Bob 56
   Channel 6 To Bob 57
   For N=1 To 5
      Priority Reverse On
      Bob 55,XP+(Rnd(40)-80)+65,YP+(Rnd(40)-80)+65,
      Bob 56,XP+(Rnd(40)-80)+65,YP+(Rnd(40)-80)+65,
      Bob 57,XP+(Rnd(40)-80)+65,YP+(Rnd(40)-80)+65,
      Amal 4,C$
      Amal 5,D$
      Amal 6,E$
      Amal On 4
      Amal On 5
      Amal On 6
      For Z=1 To 4
         SAMLAY[7] : Wait Rnd(15)+1
      Next Z
   Next N
   Amal Off 4 : Bob Off 55
   Amal Off 5 : Bob Off 56
   Amal Off 6 : Bob Off 57
End Proc
Procedure BXPLODE
   Screen 1
   Cls 0 : Paste Bob 0,0,54
   Pen 1
   Locate 17,1
   If Z=2 Then XP=BASX : YP=BASY : Print "Black Nest Hit !" : Locate 18,3 : Print "Lives left :";B2-1
   If Z=1 Then XP=BASX2 : YP=BASY2 : Print "Red Nest Hit !" : Locate 18,3 : Print "Lives Left :";B1-1
   Screen 0
   C$="Anim 0,(127,4)(128,4)(129,4)(130,4)(131,4)(132,4)"
   D$="Anim 0,(129,4)(130,4)(131,4)(132,4)(127,4)(128,4)"
   E$="Anim 0,(131,4)(132,4)(127,4)(128,4)(129,4)(131,4)"
   Channel 4 To Bob 55
   Channel 5 To Bob 56
   Channel 6 To Bob 57
   For N=1 To 5
      If Z=0 Then Priority Reverse On : Z=1 Else Z=0 : Priority Reverse Off
      Bob 55,XP+(Rnd(40)-80)+95,YP+(Rnd(40)-80)+95,
      Bob 56,XP+(Rnd(40)-80)+95,YP+(Rnd(40)-80)+95,
      Bob 57,XP+(Rnd(40)-80)+95,YP+(Rnd(40)-80)+95,
      Amal 4,C$
      Amal 5,D$
      Amal 6,E$
      Amal On 4
      Amal On 5
      Amal On 6
      For Z=1 To 4
         SAMLAY[7] : Wait Rnd(15)+1
      Next Z
   Next N
   Amal Off 4 : Bob Off 55
   Amal Off 5 : Bob Off 56
   Amal Off 6 : Bob Off 57
   If XP=BASX2 Then B1=B1-1
   If XP=BASX Then B2=B2-1
   If B1=0
      Screen 1 : Fade 1 : Wait 15 : Cls 0
      Get Sprite Palette
      Ink 1
      Home : Centre "Game Over !"
      Print : Centre "BLACK is the winner !" : Print : Print
      T$="Black Ants Dead :"+Str$(B#) : Centre T$
      Print
      T$="  Red Ants Dead :"+Str$(R#) : Centre T$
      KILBAR : Screen 0
      BAS2FLAG
      Screen 0 : Fade 2 : Screen 1 : Fade 2 : Wait 30
      Screen Close 0 : Screen Close 1
      Command Line$="black" : Sam Bank 5
      Hide : Run "Ant_War2:code/endbit.amos"
   End If
   If B2=0
      Screen 1 : Fade 1 : Wait 15 : Cls 0
      Get Sprite Palette
      Ink 1
      Home : Centre "Game Over !"
      Print : Centre "RED is the winner !" : Print : Print
      T$="Black Ants Dead :"+Str$(B#) : Centre T$
      Print
      T$="  Red Ants Dead :"+Str$(R#) : Centre T$
      KILBAR : Screen 0
      BAS1FLAG
      Screen Close 0 : Screen Close 1
      Command Line$="red" : Sam Bank 5
      Hide : Run "Ant_War2:code/endbit.amos"
   End If
   Curs Off
End Proc
Procedure BAS1FLAG
   SD=147
   Do
      Bob 55,BASX+35,BASY+6,SD : Wait 5
      If SD<155 Then SD=SD+1 Else SD=147
      If A$<>"" or Mouse Key>0 Then Pop Proc
   Loop
End Proc
Procedure BAS2FLAG
   SD=147
   Do
      A$=Inkey$
      Bob 55,BASX2+35,BASY2+6,SD : Wait 5
      If SD<155 Then SD=SD+1 Else SD=147
      If A$<>"" or Mouse Key>0 Then Pop Proc
   Loop
End Proc
Procedure DIGROUTINE
   Screen 1 : Fade 2 : Wait 2*15 : Cls 0 : Get Sprite Palette
   Paste Bob 0,0,56
   SELECTANT
   If ANT=>666 Then GOS=GOS+1 : Pop Proc
   Screen 1
   Ink 1 : Locate 15,1 : Print "Select a mine type"
   Paste Bob 143,34,31
   Paste Bob 169,34,36
   Paste Bob 194,32,37
   Paste Bob 215,32,38
   Set Zone 1,150-10,20-10+20 To 150+10,20+10+20
   Set Zone 2,175-10,20-10+20 To 175+10,20+10+20
   Set Zone 3,200-10,20-10+20 To 200+10,20+10+20
   Set Zone 4,225-10,20-10+20 To 225+10,20+10+20
   Z=0
   Do
      If Mouse Zone=1 Then Box 150-10,20-10+20 To 150+10,20+10+20 : Z=1
      If Mouse Zone=2 Then Box 175-10,20-10+20 To 175+10,20+10+20 : Z=2
      If Mouse Zone=3 Then Box 200-10,20-10+20 To 200+10,20+10+20 : Z=3
      If Mouse Zone=4 Then Box 225-10,20-10+20 To 225+10,20+10+20 : Z=4
      If Mouse Zone=0 or Z<>ZZ
         Ink 0
         Box 150-10,20-10+20 To 150+10,20+10+20
         Box 175-10,20-10+20 To 175+10,20+10+20
         Box 200-10,20-10+20 To 200+10,20+10+20
         Box 225-10,20-10+20 To 225+10,20+10+20
         Ink 1
      End If
      ZZ=Z
      If Z=1 and Mouse Key=1 Then Exit
      If Z=2 and Mouse Key=1 Then Exit
      If Z=3 and Mouse Key=1 Then Exit
      If Z=4 and Mouse Key=1 Then Exit
      If Mouse Key=2 Then Pop Proc
   Loop
   B$=""
   If Z=1 Then B$="d"
   If Z=2 Then B$="a"
   If Z=3 Then B$="c"
   If Z=4 Then B$="z"
   Screen 0
   Bob Update On : Amal On
   ANTMINE
   B$=""
   If ACTIVE(ANT)=1 Then Bob ANT,X(ANT),Y(ANT),1+DINC(ANT)+AC : Wait Vbl
End Proc
Procedure ANTMINE
   FL=0
   If B$="d" Then FL=1
   If B$="c" Then FL=1
   If FL=1
      For N=27 To 31
         Bob ANT,X(ANT),Y(ANT),N
         Wait 4
      Next N
   End If
   If FL=0
      For N=32 To 36
         Bob ANT,X(ANT),Y(ANT),N
         Wait 4
      Next N
   End If
   SAMLAY[2]
   If B$="d" Then Bob Update Off : DIGR
   If B$="a" Then Bob Update Off : DIGL
   If B$="z" Then Bob ANT,,,38 : Wait Vbl : Bob Update Off : DIGDL
   If B$="c" Then Bob ANT,,,37 : Wait Vbl : Bob Update Off : DIGDR
   Bob Update On
   If FL=1
      For N=31 To 27 Step -1
         Bob ANT,X(ANT),Y(ANT),N
         Wait 4
      Next N
   End If
   If FL=0
      For N=36 To 32 Step -1
         Bob ANT,X(ANT),Y(ANT),N
         Wait 4
      Next N
   End If
End Proc
Procedure DIGDR
   Bob Update Off
   X=X(ANT)+4 : Y=Y(ANT)-5
   For N=-4 To 40
      If N=5 or N=10 or N=15 or N=20 or N=25 or N=30 or N=35
         Ink 7 : Circle X+N,Y+N,4 : SAMLAY[2]
      End If
      Ink 0
      Draw X-4+N,Y+4+N To X+4+N,Y-4+N
      Draw X-4+N,Y+5+N To X+5+N,Y-4+N
   Next N
   For N=1 To 40
      If N=5 or N=10 or N=15 or N=20 or N=25 or N=30 or N=35
         Ink 0 : Circle X+N,Y+N,4
      End If
   Next N
End Proc
Procedure DIGDL
   Bob Update Off
   X=X(ANT) : Y=Y(ANT)-5
   For N=-4 To 40
      If N=5 or N=10 or N=15 or N=20 or N=25 or N=30 or N=35
         Ink 7 : Circle X-N,Y+N,4 : SAMLAY[2]
      End If
      Ink 0
      Draw X+4-N,Y+4+N To X-4-N,Y-4+N
      Draw X+4-N,Y+5+N To X-5-N,Y-4+N
   Next N
   For N=1 To 40
      If N=5 or N=10 or N=15 or N=20 or N=25 or N=30 or N=35
         Ink 0 : Circle X-N,Y+N,4
      End If
   Next N
End Proc
Procedure DIGR
   Bob Update Off
   X=X(ANT) : Y=Y(ANT)-5
   For N=-5 To 55
      If N=10 or N=15 or N=20 or N=25 or N=30 or N=35 or N=40 or N=45 or N=50
         Ink 7 : Circle X+N,Y-2,4 : SAMLAY[2]
      End If
      Ink 0
      Draw X+N,Y-8 To X+N,Y+5
   Next N
   For N=1 To 55
      If N=10 or N=15 or N=20 or N=25 or N=30 or N=35 or N=40 or N=45 or N=50
         Ink 0 : Circle X+N,Y-2,4
      End If
   Next N
   ESC=1
End Proc
Procedure DIGL
   Bob Update Off
   X=X(ANT) : Y=Y(ANT)-5
   For N=-5 To 55
      If N=10 or N=15 or N=20 or N=25 or N=30 or N=35 or N=40 or N=45 or N=50
         Ink 7 : Circle X-N,Y-2,4 : SAMLAY[2]
      End If
      Ink 0
      Draw X-N,Y-8 To X-N,Y+5
   Next N
   For N=1 To 55
      If N=10 or N=15 or N=20 or N=25 or N=30 or N=35 or N=40 or N=45 or N=50
         Ink 0 : Circle X-N,Y-2,4
      End If
   Next N
End Proc
Procedure BRIDGEROUTINE
   Screen 1 : Fade 2 : Wait 2*15 : Cls 0 : Get Sprite Palette
   Paste Bob 0,0,55
   SELECTANT
   If ANT=>666 Then GOS=GOS+1 : Pop Proc
   Screen 1
   Ink 1 : Locate 15,1 : Print "Select a bridge type"
   Paste Bob 140,30,23
   Paste Bob 169,32,24
   Paste Bob 190,35,25
   Paste Bob 205,35,26
   Set Zone 1,150-10,20-10+20 To 150+10,20+10+20
   Set Zone 2,175-10,20-10+20 To 175+10,20+10+20
   Set Zone 3,200-10,20-10+20 To 200+10,20+10+20
   Set Zone 4,225-10,20-10+20 To 225+10,20+10+20
   Z=0
   Do
      If Mouse Zone=1 Then Box 150-10,20-10+20 To 150+10,20+10+20 : Z=1
      If Mouse Zone=2 Then Box 175-10,20-10+20 To 175+10,20+10+20 : Z=2
      If Mouse Zone=3 Then Box 200-10,20-10+20 To 200+10,20+10+20 : Z=3
      If Mouse Zone=4 Then Box 225-10,20-10+20 To 225+10,20+10+20 : Z=4
      If Mouse Zone=0 or Z<>ZZ
         Ink 0
         Box 150-10,20-10+20 To 150+10,20+10+20
         Box 175-10,20-10+20 To 175+10,20+10+20
         Box 200-10,20-10+20 To 200+10,20+10+20
         Box 225-10,20-10+20 To 225+10,20+10+20
         Ink 1
      End If
      ZZ=Z
      If Z=1 and Mouse Key=1 Then Exit
      If Z=2 and Mouse Key=1 Then Exit
      If Z=3 and Mouse Key=1 Then Exit
      If Z=4 and Mouse Key=1 Then Exit
      If Mouse Key=2 Then Pop Proc
   Loop
   If Z=1 Then B$="1"
   If Z=2 Then B$="2"
   If Z=3 Then B$="3"
   If Z=4 Then B$="4"
   Screen 0
   GOS=GOS+1
   BRIDGE
   A$=""
End Proc
Procedure BRIDGE
   If B$="1" and AC=0
      Bob Off ANT
      SAMLAY[11]
      Wait Vbl
      Paste Bob X(ANT)-12,Y(ANT)-15,23+AC : DEAD
   End If
   If B$="1" and AC=56
      SAMLAY[11]
      Bob Off ANT
      Wait Vbl
      Paste Bob X(ANT)-12,Y(ANT)-13,23+AC : DEAD
   End If
   If B$="2" and AC=56
      SAMLAY[11]
      Bob Off ANT
      Wait Vbl
      Paste Bob X(ANT)-1,Y(ANT)-14,24+AC : DEAD
   End If
   If B$="2" and AC=0
      Bob Off ANT
      SAMLAY[11]
      Wait Vbl
      Paste Bob X(ANT)-1,Y(ANT)-13,24+AC : DEAD
   End If
   If B$="3" Then Bob Off ANT : SAMLAY[11] : Wait Vbl : Paste Bob X(ANT)-4,Y(ANT)-4,25+AC : DEAD
   If B$="4" Then Bob Off ANT : SAMLAY[11] : Wait Vbl : Paste Bob X(ANT)-28,Y(ANT)-4,26+AC : DEAD
End Proc
Procedure BUTTONS
   Bob Update On
   Wait Vbl
   Repeat
      If AC=0 Then HN=1 Else HN=2
      Bob Update Off
      If ESC=1 and ESC<2 Then INFANTRY : BUG=1
      If EX=1 Then BUG=2 : EX=0
      If HD1=1 and HN=1 and ESC=2 Then BUG=1
      If HD2=1 and HN=2 and ESC=2 Then BUG=1
      If ESC=2 and BUG<>1 Then HELIBUTTONS
      If ESC=2 and BUG=1 Then ESC=1
   Until ESC=0
   Bob Update Off
   If ESC=0 and AC=0 Then AC=56 : FLAG=1 : HC=6
   If FLAG=0 and ESC=0 and AC=56 Then AC=0 : HC=0 Else FLAG=0
   GOS=5
   Screen 1 : Fade 2 : Wait 2*15 : Cls 0 : Get Sprite Palette
   SAMLAY[9]
   If AC=0
      Paste Bob 130,25,125
      Wait 30
      Cls
      Screen Offset 0,SX-320,0
   End If
   If AC=56
      Paste Bob 100,25,126
      Wait 30
      Cls
      Screen Offset 0,0,0
   End If
   Reserve Zone 6
   Paste Bob 0,0,47
   Paste Bob 110,0,48
   Paste Bob 225,0,49
   Set Zone 1,0,0 To 100,46
   Set Zone 2,100,0 To 215,46
   Set Zone 3,225,0 To 325,46
   KILBAR
   Screen 0
   Screen 1
   Wait 20 : SAMLAY[10]
   Do
      A$=Inkey$
      MESSMOUSE
      SK=Scancode
      If Mouse Zone=1 and Mouse Key=1 Then BUG=1 : Exit
      If Mouse Zone=2 and Mouse Key=1 and HD1=0 and HC=0 Then BUG=2 : Exit
      If Mouse Zone=2 and Mouse Key=1 and HD2=0 and HC=6 Then BUG=2 : Exit
      If Mouse Zone=3 and Mouse Key=1 Then SAMLAY[20] : Exit
      If SK=80 Then BUG=1 : Exit
      If SK=81 and HD1=0 and HC=0 Then BUG=2 : Exit
      If SK=81 and HD2=0 and HC=6 Then BUG=2 : Exit
      If SK=82 Then SAMLAY[20] : Exit
      If SK=69 Then Screen Close 0 : Screen Close 1 : Run "Ant_War2:code/barebones.amos"
   Loop
   If Mouse Zone=1 or SK=80 Then ESC=1 : INFANTRY
   If Mouse Zone=2 or SK=81 Then ESC=2 : HELIBUTTONS
   If Mouse Zone=3 or SK=82 Then ESC=0
End Proc
Procedure INFANTRY
   Screen 1
   Fade 2 : Wait 2*15 : Cls 0 : Get Sprite Palette
   SAMLAY[12]
   Paste Bob 0,-3,133
   Reserve Zone 7
   Set Zone 1,13,10 To 43,29
   Set Zone 2,56,10 To 85,29
   Set Zone 3,196,10 To 226,29
   Set Zone 4,238,10 To 268,29
   Set Zone 5,280,10 To 310,29
   Set Zone 6,109,24 To 173,34
   If HD1=0 and AC=0 Then Set Zone 7,108,8 To 174,16
   If HD2=0 and AC=56 Then Set Zone 7,108,8 To 174,16
   CHANT
   BUG=1
   Ink 0
   If AC=0 Then Text 60,45,Right$(Str$(CAN1),Len(Str$(CAN1))-1) Else Text 60,45,Right$(Str$(CAN2),Len(Str$(CAN2))-1)
   Text 270,44,Right$(Str$(GOS),Len(Str$(GOS))-1)
   Text 125,32,"SKIP"
   Ink 1
   Do
      MESSMOUSE
      CC=0
      A$=Inkey$
      K=Scancode
      If K=69 Then Screen Close 0 : Screen Close 1 : Run "Ant_War2:code/barebones.amos"
      If K=>80 or K<=87 Then CC=K-79
      If HD1=1 and AC=0 and CC=6 Then CC=0
      If HD2=1 and AC=56 and CC=6 Then CC=0
      If Mouse Zone=6 and Mouse Key=1 Then CC=7
      If CC=7 Then GOS=0 : SAMLAY[20] : Exit
      If Mouse Zone=1 and Mouse Key=1 Then CC=1
      If CC=1 Then SAMLAY[13] : DEPLOY : GOS=GOS-1 : Exit
      DS=0
      If AC=0 and CAN1=0 Then DS=1
      If AC=56 and CAN2=0 Then DS=1
      If Mouse Zone=2 and Mouse Key=1 and DS=0 Then CC=2
      If CC=2
         SAMLAY[6]
         MOVE
         GOS=GOS-1
         Exit
      End If
      If Mouse Zone=3 and Mouse Key=1 and DS=0 Then CC=3
      If CC=3
         SAMLAY[14]
         BAZOOKROUTINE
         GOS=GOS-1
         Exit
      End If
      If Mouse Zone=4 and Mouse Key=1 and DS=0 Then CC=4
      If CC=4
         SAMLAY[15]
         DIGROUTINE
         GOS=GOS-1
         Exit
      End If
      If Mouse Zone=5 and Mouse Key=1 and DS=0 Then CC=5
      If CC=5
         SAMLAY[16]
         BRIDGEROUTINE
         GOS=GOS-1
         Exit
      End If
      If Mouse Zone=7 and GOS=5 and Mouse Key=1 Then CC=6
      If CC=6
         ESC=2 : EX=1
         Exit
      End If
      If Mouse Zone=7 and GOS>1 and Mouse Key=1 Then CC=6
      If CC=6
         ESC=2 : EX=1
         GOS=GOS-1
         Exit
      End If
   Loop
   GRAVITY
   If GOS=0 Then ESC=0
End Proc
Procedure CHANT
   CAN1=0 : CAN2=0
   For N=1 To ANTS#/2
      If ACTIVE(N)=1 Then CAN1=CAN1+1
   Next N
   For N=(ANTS#/2)+1 To ANTS#
      If ACTIVE(N)=1 Then CAN2=CAN2+1
   Next N
End Proc
Procedure SELECTANT
   Pen 1
   ANTSORT
   Locate 15,1 : Print "                         "
   Locate 15,1 : Print "Select an ant:";
   Locate 15,3 : Print "Space to cancel."
   Screen 0
   Reserve Zone
   Reserve Zone ANTS#
   If AC=0 Then BINNY
   If AC=56 Then BINNY2
   Screen 1 : Locate 30,1
   A$=""
   Pen 1
   Do
      A$=Inkey$
      Screen 0
      MESSMOUSE
      ZO=Mouse Zone
      Screen 1
      If ZO<>ZOO Then Locate 30,1 : Print "    "
      Locate 30,1
      If AC=56 and ACTIVE(ZO+(ANTS#/2))=1 Then Print ZO
      If AC=0 and ACTIVE(ZO)=1 Then Print ZO
      Locate 30,1
      If AC=56 and ACTIVE(ZO+(ANTS#/2))=1 and Mouse Key=1 Then Exit
      If AC=0 and ACTIVE(ZO)=1 and Mouse Key=1 Then Exit
      If A$=" " Then ZO=666 : Exit
      ZOO=ZO
   Loop
   SAMLAY[5] : XM=X Screen(X Mouse)
   Wait 5
   If AC=56 Then ZO=ZO+(ANTS#/2)
   ANT=ZO
   Locate 15,1 : Print "         "
   Locate 15,3 : Print "                "
   Screen 0
End Proc
Procedure DEPLOY
   Screen 1 : Fade 2 : Wait 2*15 : Cls 0 : Get Sprite Palette
   Paste Bob 0,0,50
   Screen 0
   Bob Update On : Amal On
   ANT=0 : DD=0
   If AC=56 Then ANT=(ANTS#/2) Else DD=4
   Repeat
      ANT=ANT+1
      If ANT=20 or ANT=40 Then Pop Proc
   Until ACTIVE(ANT)=2
   If ACTIVE(ANT)=2 Then ACTIVE(ANT)=1 : DINC(ANT)=DD
   Bob ANT,X(ANT),Y(ANT),9+AC+DINC(ANT) : Wait Vbl
   SAMLAY[3]
   If Point(X(ANT),Y(ANT)+1)=0 Then FALL
End Proc
Procedure BINNY
   For Q=1 To ANTS#/2
      If ACTIVE(Q)=1 and Y(Q)>10 Then Set Zone Q,X(Q)-10,Y(Q)-10 To X(Q)+5,Y(Q)+5
      If ACTIVE(Q)=1 and Y(Q)<=10 Then Set Zone Q,X(Q)-10,0 To X(Q)+5,Y(Q)+5
   Next Q
End Proc
Procedure BINNY2
   For Q=(ANTS#/2)+1 To ANTS#
      If ACTIVE(Q)=1 and Y(Q)>10 Then Set Zone Q-(ANTS#/2),X(Q)-10,Y(Q)-10 To X(Q)+3,Y(Q)+3
      If ACTIVE(Q)=1 and Y(Q)<=10 Then Set Zone Q-(ANTS#/2),X(Q)-10,0 To X(Q)+5,5
   Next Q
End Proc
Procedure ANTSORT
   For N=1 To ANTS#/2
      If ACTIVE(N)=0 Then ACTIVE(N)=2 : X(N)=SXR : Y(N)=SYR
   Next N
   For N=(ANTS#/2)+1 To ANTS#
      If ACTIVE(N)=0 Then ACTIVE(N)=2 : X(N)=SXB : Y(N)=SYB
   Next N
End Proc
Procedure MESSMOUSE
   If MP=1 and Y Mouse>100 Then Change Mouse 2 : MP=2
   If MP=2 and Y Mouse<100 Then Change Mouse 1 : MP=1
End Proc
Procedure SAMLAY[N]
   Sam Bank 5
   If N=1 Then Sam Play 1
   If N=2 Then Sam Play 8
   If N=3 Then Sam Play 6
   If N=4 Then Sam Play 2
   If N=5 Then Sam Play 10
   If N=6 Then Sam Play 5
   If N=7 Then Sam Play 3
   If N=8 Then Sam Play 9
   If N=11 Then Sam Play 4
   If N=22 Then Sam Play 7
   If N=23 Then Sam Play 11
   If CF1=1 Then Goto EXTRA
   If N=14 Then Sam Play 5
   If N=16 Then Sam Play 5
   If N=19 Then Sam Play 5
   If N=18 Then Sam Play 5
   If N=13 Then Sam Play 5
   If N=15 Then Sam Play 5
   If N=20 Then Sam Play 5
   Pop Proc
   EXTRA:
   Sam Bank 6
   If N=14 Then Sam Play 1
   If N=16 Then Sam Play 2
   If N=19 Then Sam Play 3
   If N=13 Then Sam Play 4
   If N=18 Then Sam Play 5
   If N=17 Then Sam Play 6
   If N=12 Then Sam Play 7
   If N=15 Then Sam Play 8
   If N=21 Then Sam Play 9
   If N=20 Then Sam Play 10
   If N=9 Then Sam Play 12
   If N=10 Then Sam Play 11
End Proc
Procedure GRAVITY
   Do
      ZZTOP=0
      Wait Vbl
      For N=1 To ANTS#
         Screen 0
         If ACTIVE(N)=1 and Point(X(N),Y(N)+1)=0 Then ZZTOP=1 : ANT=N : FALL
         Screen 1
      Next N
      If ZZTOP=0 Then Exit
   Loop
End Proc
Procedure HELIBUTTONS
   If BUG=1 Then Pop Proc
   Screen 1
   Fade 2 : Wait 2*15 : Cls 0 : Get Sprite Palette
   SAMLAY[17]
   Bob Update Off
   Paste Bob 0,-3,137
   Set Zone 1,13,10 To 43,30
   Set Zone 2,56,10 To 85,29
   Set Zone 3,236,10 To 266,29
   Set Zone 4,109,24 To 173,34
   Set Zone 5,108,8 To 174,16
   If HC=6 Then HN=2 Else HN=1
   Ink 0
   Text 60,45,Right$(Str$(HP(HN)),Len(Str$(HP(HN)))-1)
   Text 270,44,Right$(Str$(GOS),Len(Str$(GOS))-1)
   Text 125,32,"SKIP"
   CHANT
   Do
      A$=Inkey$
      MESSMOUSE
      SK=Scancode
      If Mouse Zone=4 and Mouse Key=1 Then SAMLAY[20] : GOS=0 : Exit
      If Mouse Zone=1 and Mouse Key=1 and HP(HN)<5 and CAN1>0 and HC=0 Then SAMLAY[19] : HELIROPE : GOS=GOS-1 : Exit
      If Mouse Zone=1 and Mouse Key=1 and HP(HN)<5 and CAN2>0 and HC=6 Then SAMLAY[19] : HELIROPE : GOS=GOS-1 : Exit
      If Mouse Zone=2 and Mouse Key=1 and HP(HN)>0 Then SAMLAY[18] : PARAHELI : GOS=GOS-1 : Exit
      If Mouse Zone=3 and Mouse Key=1 Then SAMLAY[6] : HELIMOUSE : GOS=GOS-1 : Exit
      If Mouse Zone=5 and GOS=5 and Mouse Key=1 Then ESC=1 : Exit
      If Mouse Zone=5 and GOS>1 and GOS<5 and Mouse Key=1 Then GOS=GOS-1 : ESC=1 : Exit
      If SK=84 Then SAMLAY[20] : GOS=0 : Exit
      If SK=80 and HP(HN)<5 and CAN1>0 and HC=0 Then SAMLAY[19] : HELIROPE : GOS=GOS-1 : Exit
      If SK=80 and HP(HN)<5 and CAN2>0 and HC=6 Then SAMLAY[19] : HELIROPE : GOS=GOS-1 : Exit
      If SK=81 and HP(HN)>0 Then SAMLAY[18] : PARAHELI : GOS=GOS-1 : Exit
      If SK=82 Then SAMLAY[6] : HELIMOUSE : GOS=GOS-1 : Exit
      If SK=83 and GOS=5 Then ESC=1 : Exit
      If SK=83 and GOS>1 Then GOS=GOS-1 : ESC=1 : Exit
      If SK=69 Then Screen Close 0 : Screen Close 1 : Run "Ant_War2:code/barebones.amos"
   Loop
   If GOS=0 Then ESC=0
End Proc
Procedure HELIMOUSE
   Screen 1 : Fade 2 : Wait 2*15 : Cls 0 : Get Sprite Palette
   Paste Bob 0,0,117
   Pen 1 : Locate 14,3 : Print "Use joystick to Move."
   Screen 0 : SETAMAL
   If HX(HN)-160>0 and HX(HN)-160<680 Then Screen Offset 0,HX(HN)-160,
   Bob Update On
   HELIMK2
   HN=1
   If HC=6 Then HN=2
   Q=201
End Proc
Procedure HELI
   Bob 62,HX(2),HY(2),
   Bob 63,HX(1),HY(1),
   If HX(HN)>160 and HX(HN)<848 and Joy(1)<>0
      Screen Offset 0,HX(HN)-160,
   End If
End Proc
Procedure TURN
   If HN=2 and HDINC(HN)=105 Then HX(HN)=HX(HN)+28
   If HN=2 and HDINC(HN)=102 Then HX(HN)=HX(HN)-28
   If HN=1 and HDINC(HN)=105 Then HX(HN)=HX(HN)-28
   If HN=1 and HDINC(HN)=102 Then HX(HN)=HX(HN)+28
   If HN=2 Then Bob 62,HX(HN)-3,HY(HN)+10,114
   If HN=1 Then Bob 63,HX(HN)-3,HY(HN)+10,114
   C$="Anim 0,(114,4)(115,4)(116,4)"
   Amal HN,C$
   Amal On HN
   Wait Vbl
   Do
      If Fire(1)=0 Then Exit
   Loop
   If HDINC(HN)=102 Then HDINC(HN)=105 : ZARNIWOOP=1
   If HDINC(HN)=105 and ZARNIWOOP=0 Then HDINC(HN)=102 Else ZARNIWOOP=0
   SETAMAL
   HELI
End Proc
Procedure HELIROPE
   Screen 1 : Fade 2 : Wait 2*15 : Cls 0 : Get Sprite Palette
   Paste Bob 0,0,121
   SELECTANT
   HPSAUCE=HP(HN)
   Bob Update On
   If AC=0 and ANT=0 Then GOS=GOS+1 : Pop Proc
   If AC=56 and ANT=(ANTS#/2) Then GOS=GOS+1 : Pop Proc
   If ANT=666 or ANT=686 Then GOS=GOS+1 : Pop Proc
   If HX(HN)>X(ANT) and HX(HN)-X(ANT)>250 Then GOS=GOS+1 : Pop Proc
   If HX(HN)<X(ANT) and X(ANT)-HX(HN)>250 Then GOS=GOS+1 : Pop Proc
   Screen 0
   If HC=6 Then HN=2 Else HN=1
   If HN=2 and HX(HN)>X(ANT)+50 and HDINC(HN)=102 Then TURN : Wait Vbl
   If HN=2 and HX(HN)<X(ANT)-50 and HDINC(HN)=105 Then TURN : Wait Vbl
   If HN=1 and HX(HN)>X(ANT)+50 and HDINC(HN)=105 Then TURN : Wait Vbl
   If HN=1 and HX(HN)<X(ANT)-50 and HDINC(HN)=102 Then TURN : Wait Vbl
   Repeat
      HELICOL
      If CT1>0
         GOS=GOS+1
         Amal On 1
         Screen 1
         Pen 1
         Cls
         Paste Bob 0,0,121
         Print
         Centre "      Obstacle !"
         Print : Print
         Locate 17,3 : Print "Click Mouse."
         Screen 0
         While Mouse Key=0
         Wend
         Pop Proc
      End If
      If CT2>0
         GOS=GOS+1
         Amal On 2
         Screen 1
         Pen 1
         Cls
         Paste Bob 0,0,121
         Print
         Centre "      Obstacle !"
         Print : Print
         Locate 17,3 : Print "Click Mouse."
         Screen 0
         While Mouse Key=0
         Wend
         Pop Proc
      End If
      If HX(HN)>X(ANT) Then Dec HX(HN)
      If HX(HN)<X(ANT) Then Inc HX(HN)
      If HN=2 Then Bob 62,HX(HN),HY(HN),
      If HN=1 Then Bob 63,HX(HN),HY(HN),
   Until HX(HN)=X(ANT)
   Ink 1
   ROPE
   HP(HN)=HP(HN)+1
   If HP(HN)>HPSAUCE Then DEAD Else GOS=GOS+1
End Proc
Procedure PARAHELI
   Screen 0
   Bob Update On
   ANT=0
   If AC=56 Then ANT=(ANTS#/2)
   Repeat
      ANT=ANT+1
   Until ACTIVE(ANT)=2
   If HC=6 Then HN=2 Else HN=1
   If ACTIVE(ANT)=2 Then X(ANT)=HX(HN) : Y(ANT)=HY(HN)+12
   DEPLOY
   Dec HP(HN)
End Proc
Procedure SETAMAL
   If HDINC(1)=102
      C$="Anim 0,(105,6)(106,6)(107,6)"
   End If
   If HDINC(1)=105
      C$="Anim 0,(102,6)(103,6)(104,6)"
   End If
   If HDINC(2)=102
      C2$="Anim 0,(108,6)(109,6)(110,6)"
   End If
   If HDINC(2)=105
      C2$="Anim 0,(111,6)(112,6)(113,6)"
   End If
   If HD1=0
      Bob 63,,,
      Channel 1 To Bob 63
      Amal 1,C$
      Amal On 1
   End If
   If HD2=0
      Bob 62,,,
      Channel 2 To Bob 62
      Amal 2,C2$
      Amal On 2
   End If
End Proc
Procedure HELICOL
   CT1=0
   If HC=0 and HDINC(1)=105 Then FLAG=1
   While FLAG=1
      If Point(HX(1)+14,HY(1)+11)>0 Then CT1=3 : Rem 3
      If Point(HX(1)-24,HY(1)+11)>0 Then CT1=4 : Rem 4
      If Point(HX(1)-50,HY(1)+2)>0 Then CT1=5 : Rem 5
      If Point(HX(1)-2,HY(1)-20)>0 Then CT1=9 : Rem 9
      FLAG=0
   Wend
   If HC=0 and HDINC(1)=102 Then FLAG=1
   While FLAG=1
      If Point(HX(1)-14,HY(1)+11)>0 Then CT1=3 : Rem 3
      If Point(HX(1)+24,HY(1)+11)>0 Then CT1=4 : Rem 4
      If Point(HX(1)+50,HY(1)+2)>0 Then CT1=5 : Rem 5
      If Point(HX(1)+49,HY(1)-17)>0 Then CT1=6 : Rem 6
      If Point(HX(1)+2,HY(1)-20)>0 Then CT1=9 : Rem 9
      FLAG=0
   Wend
   CT2=0
   If HC=6 and HDINC(2)=102 Then FLAG=1
   While FLAG=1
      If Point(HX(2)+14,HY(2)+11)>0 Then CT2=3 : Rem 3
      If Point(HX(2)-24,HY(2)+11)>0 Then CT2=4 : Rem 4
      If Point(HX(2)-50,HY(2)+2)>0 Then CT2=5 : Rem 5
      If Point(HX(2)-49,HY(2)-17)>0 Then CT2=6 : Rem 6
      If Point(HX(2)-2,HY(2)-20)>0 Then CT2=9 : Rem 9
      FLAG=0
   Wend
   If HC=6 and HDINC(2)=105 Then FLAG=1
   While FLAG=1
      If Point(HX(2)-14,HY(2)+11)>0 Then CT2=3 : Rem 3
      If Point(HX(2)+24,HY(2)+11)>0 Then CT2=4 : Rem 4
      If Point(HX(2)+50,HY(2)+2)>0 Then CT2=5 : Rem 5
      If Point(HX(2)+49,HY(2)-17)>0 Then CT2=6 : Rem 6
      If Point(HX(2)+2,HY(2)-20)>0 Then CT2=9 : Rem 9
      FLAG=0
   Wend
   FLAG=0
End Proc
Procedure HELIMK2
   HN=1
   If HC=6 Then HN=2
   QUOTA=200
   Sam Loop On : SAMLAY[22]
   DK:
   X=HX(HN) : Y=HY(HN) :
   Screen 1 : Locate 14,5 : Print "Space Bar to end move."
   If HDINC(HN)=105 and HN=2 Then Goto RV
   If HDINC(HN)=102 and HN=1 Then Goto RV
   Do
      HELI
      A$=Inkey$
      DUM=QUOTA
      DIE=Joy(1)
      If DIE=1+4 Then DIE=4
      If DIE=2+4 Then DIE=4
      If DIE=1+8 Then DIE=8
      If DIE=2+8 Then DIE=8
      If DIE=1 and HY(HN)>-9 and Point(X-28,Y-15)<=0 and Point(X-2,Y-18)<=0 and Point(X-46,Y-15)<=0 and Point(X+28,Y-16)<=0 Then Y=Y-2 : QUOTA=QUOTA-1
      If DIE=2 and Point(X+16,Y+3)<=0 and Point(X+27,Y-10)<=0 and Point(X-45,Y+1)<=0 and Point(X,Y+10)<=0 and Point(X-20,Y+10)<=0 and Point(X+10,Y+10)<=0 Then Y=Y+2 : QUOTA=QUOTA-1
      If DIE=4 and HX(HN)>25 and Point(X-50,Y)<=0 and Point(X-48,Y-14)<=0 and Point(X-23,Y+8)<=0 Then X=X-2 : QUOTA=QUOTA-1
      If DIE=8 and HX(HN)<999 and Point(X+30,Y-13)<=0 and Point(X+20,Y)<=0 and Point(X+12,Y+9)<=0 Then X=X+2 : QUOTA=QUOTA-1
      If Fire(1)=-1 Then TURN : HX(HN)=HX(HN)+18 : HELI : Exit
      If Y<-9 Then Y=-9
      HX(HN)=X : HY(HN)=Y
      If DUM>QUOTA
         Screen 1 : Pen 1
         Locate 22,1 : Print "Fuel  :     ";
         Locate 30,1 : Print QUOTA : Screen 0
      End If
      If A$=" " or QUOTA=0 Then Sam Loop Off : Pop Proc
   Loop
   Goto DK
   RV:
   Do
      HELI
      A$=Inkey$
      DIE=Joy(1)
      If DIE=1+4 Then DIE=4
      If DIE=2+4 Then DIE=4
      If DIE=1+8 Then DIE=8
      If DIE=2+8 Then DIE=8
      If DIE=1 and HY(HN)>-9 and Point(X-28,Y-15)<=0 and Point(X+2,Y-18)<=0 and Point(X+46,Y-15)<=0 and Point(X+28,Y-16)<=0 Then Y=Y-2 : QUOTA=QUOTA-1
      If DIE=2 and Point(X-16,Y+3)<=0 and Point(X-27,Y-10)<=0 and Point(X+45,Y+1)<=0 and Point(X,Y+10)<=0 and Point(X+20,Y+10)<=0 and Point(X-10,Y+10)<=0 Then Y=Y+2 : QUOTA=QUOTA-1
      If DIE=8 and HX(HN)<999 and Point(X+50,Y)<=0 and Point(X+48,Y-14)<=0 and Point(X+23,Y+8)<=0 Then X=X+2 : QUOTA=QUOTA-1
      If DIE=4 and HX(HN)>25 and Point(X-30,Y-13)<=0 and Point(X-20,Y)<=0 and Point(X-12,Y+9)<=0 Then X=X-2 : QUOTA=QUOTA-1
      If Fire(1)=-1 Then TURN : HX(HN)=HX(HN)-18 : HELI : Exit
      If Y<-9 Then Y=-9
      HX(HN)=X : HY(HN)=Y
      If DUM<>QUOTA
         Screen 1 : Pen 1
         Locate 22,1 : Print "Fuel  :     ";
         Locate 30,1 : Print QUOTA : Screen 0
      End If
      DUM=QUOTA
      If A$=" " or QUOTA=0 Then Sam Loop Off : Pop Proc
   Loop
   Goto DK
   Sam Loop Off
End Proc
Procedure ROPE
   YY=HY(HN) : X=HX(HN)
   Z=0
   Sam Loop On : SAMLAY[23]
   Repeat
      Z=Z+1
      YY=YY+1
   Until Point(X,YY+10)>0
   If YY+10<Y(ANT)-13 Then HP(HN)=HP(HN)-1 : Sam Loop Off : Pop Proc
   Ink 1
   YY=HY(HN)
   For N=1 To Z Step 3
      Draw X,YY+10 To X,YY+10+N
   Next N
   Wait 5
   Ink 0
   For N=Z+10 To Z+5 Step -1
      Plot X,YY+N
      Bob ANT,X,YY+N+5,101
   Next N
   For N=Z+4 To -5 Step -3
      Ink 0
      Draw X,YY+10+N-1 To X,YY+Z
      If YY+N+5<Y Bob(ANT) Then Bob ANT,X,YY+N+5,101
   Next N
   Bob Off ANT
   Plot HX(HN),HY(HN)+10
   Plot HX(HN),HY(HN)+11
   Plot HX(HN),HY(HN)+12
   Sam Loop Off
End Proc