home *** CD-ROM | disk | FTP | other *** search
/ ftp.eri.u-tokyo.ac.jp / 2014.03.ftp.eri.u-tokyo.ac.jp.zip / ftp.eri.u-tokyo.ac.jp / pub / SUN / www / showaudio < prev   
Text File  |  1995-03-24  |  6KB  |  188 lines
  1. #!/bin/csh -f
  2. # Copyright (c) 1991 Bell Communications Research, Inc. (Bellcore)
  3. # 
  4. # Permission to use, copy, modify, and distribute this material 
  5. # for any purpose and without fee is hereby granted, provided 
  6. # that the above copyright notice and this permission notice 
  7. # appear in all copies, and that the name of Bellcore not be 
  8. # used in advertising or publicity pertaining to this 
  9. # material without the specific, prior written permission 
  10. # of an authorized representative of Bellcore.  BELLCORE 
  11. # MAKES NO REPRESENTATIONS ABOUT THE ACCURACY OR SUITABILITY 
  12. # OF THIS MATERIAL FOR ANY PURPOSE.  IT IS PROVIDED "AS IS", 
  13. # WITHOUT ANY EXPRESS OR IMPLIED WARRANTIES.
  14. #
  15. # First, figure out which machine to play it on!
  16. set thishost=`hostname`
  17.  
  18. # Note that there are some special lines in here that only work at Bellcore,
  19. # Specifically involving phone playback from the machine "greenbush".
  20. # Everything should work fine at other sites, though
  21. set AUDIOBINDIR=/u/andrew/phone-sau/bin
  22. set AUDIOPHONEHOST=greenbush
  23. set AUDIOPHONEHOSTLONG=greenbush.bellcore.com
  24. set AUDIOLOGMAIL=andrew@thumper.bellcore.com
  25. set ORG="Bellcore"
  26. if ($1 == "-p") then
  27.     set AUDIOPHONE=$2
  28.     shift
  29.     shift
  30. endif
  31. if ($1 == "-s") then
  32.     set AUDIOSPEAKERFORCE = 1
  33.     shift
  34. endif
  35. if ($?AUDIOPHONE || $?AUDIOPHONEFORCE) then
  36.     goto playphone
  37. endif
  38. if (! -d $AUDIOBINDIR) then
  39.     set AUDIOSPEAKERFORCE=1
  40. endif
  41.     
  42. if (! $?AUDIOSPEAKERFORCE && ! $?AUDIOPHONEFORCE) then
  43.     if ($?MM_NOTTTY) then
  44.     if ($MM_NOTTTY == 1) then
  45.         setenv MM_NOTTTY 0
  46.         xterm -e showaudio $*
  47.         exit 0
  48.     endif
  49.     endif
  50. choosehardware:
  51.     echo This program can display audio on the speakers of some workstations, 
  52.     echo "or (at some sites) it can call you on the telephone.  Please choose one:"
  53.     echo ""
  54.     echo "1 -- Use the computer's speaker"
  55.     echo "2 -- Call me on the telephone"
  56.     echo ""
  57.     echo -n "Which do you prefer (1 or 2)? "
  58.     set ans=$<
  59.     if ($ans == 2)  then
  60.     echo "OK, we'll use the telephone..."
  61.     set AUDIOPHONEFORCE=1
  62.     echo "In the future, you can avoid this question by setting the environment variable"
  63.     echo "AUDIOPHONEFORCE to 1"
  64.     goto playphone
  65.     else if ($ans == 1) then
  66.         echo "OK, Attempting to play the audio using your computer's speaker.."
  67.         set AUDIOSPEAKERFORCE=1
  68.     echo "In the future, you can avoid this question by setting the environment variable"
  69.     echo "AUDIOSPEAKERFORCE to 1"
  70.     else
  71.     echo "That is NOT one of your choices."
  72.     goto choosehardware
  73.     endif
  74. endif
  75.  
  76. if ($1 == "-") then
  77.     set STDINPUT=1
  78.     shift
  79. endif
  80.  
  81. set audiohost=$thishost
  82. if ($?DISPLAY) then
  83.     set audiohost=`echo $DISPLAY | sed -e 's/:.*//'`
  84.     if ($audiohost == "unix") set audiohost=$thishost
  85.     if ($audiohost == "") set audiohost=$thishost
  86. endif
  87. if ($?AUDIOHOST) then
  88.     set audiohost=$AUDIOHOST
  89. endif
  90.  
  91. if ($audiohost != $thishost) then
  92.     echo Sending audio to $audiohost...
  93.     if ($?MMS_AUDIO) then
  94.         if ($?STDINPUT) then
  95.             cat | mms -host $audiohost "show audio/basic" -
  96.         else
  97.             cat $* | mms -host $audiohost "show audio/basic" -
  98.         endif
  99.         exit 0
  100.     endif
  101.  
  102. # The next two lines are very inefficient, but not everyone has their path right for an rsh
  103.     pushd ~ >& /dev/null
  104.     set thisprog=`which showaudio`
  105.     popd >& /dev/null
  106.     if ($?STDINPUT) then
  107.         cat | rsh $audiohost $thisprog -s -
  108.     else
  109.         cat $* | rsh $audiohost $thisprog  -s -
  110.     endif
  111.     exit 0
  112. endif
  113.  
  114. if (-f /usr/sbin/sfplay) then
  115.     if ($#argv >= 1) then
  116.     exec /usr/sbin/sfplay -i mu-law chan 1 rate 8000 end $*
  117.     else
  118.     cat > /tmp/audio.$$
  119.     /usr/sbin/sfplay -i mu-law chan 1 rate 8000 end /tmp/audio.$$
  120.     rm /tmp/audio.$$
  121.     exit 0
  122.     endif
  123. else if (-d /usr/sony) then
  124.     set dev=/dev/sb0
  125. else
  126.     set dev=/dev/audio
  127. endif
  128.  
  129. if (-w $dev) then
  130. echo Playing audio on $thishost using $dev, one moment please...
  131. if ($#argv >= 1) then
  132.         cat $* > $dev
  133. else
  134.         cat > $dev
  135. endif
  136. exit 0
  137. endif
  138.  
  139. playphone:
  140. if (-d $AUDIOBINDIR) then
  141.               set thisprog=`which showaudio`
  142.     if (! $?AUDIOPHONE) then
  143.         if ($?MM_NOTTTY) then
  144.         if ($MM_NOTTTY == 1) then
  145.             setenv MM_NOTTTY 0
  146.             xterm -e $thisprog $*
  147.             exit 0
  148.         endif
  149.         endif
  150.         echo This message contains audio, which can be sent to your telephone.
  151.         echo Please enter the telephone number at which you would like to hear this
  152.         echo -n "audio message as you would dial it from INSIDE ${ORG}:  "
  153.         set AUDIOPHONE=$<
  154.     endif
  155.     if ($thishost == $AUDIOPHONEHOST || $thishost == $AUDIOPHONEHOSTLONG) then
  156.         echo Calling Phone number $AUDIOPHONE
  157.         echo "You MUST SAY HELLO when you answer the phone, or you will not hear the message."
  158.         mail -s "showaudio: `whoami` called $AUDIOPHONE" $AUDIOLOGMAIL < /dev/null
  159.         if ($?STDINPUT) then
  160.             cat $AUDIOBINDIR/../GREET.au $* - | $AUDIOBINDIR/play -\# $AUDIOPHONE -
  161.         else
  162.             cat $AUDIOBINDIR/../GREET.au $* | $AUDIOBINDIR/play -\# $AUDIOPHONE -
  163.         endif
  164.         echo All done
  165.         exit 0
  166.     else
  167.         echo Trying to rsh to $AUDIOPHONEHOST to send audio via telephone
  168.         cat $* | rsh $AUDIOPHONEHOST $thisprog -p $AUDIOPHONE -
  169.         exit 0
  170.     endif
  171. endif
  172. echo ""
  173. echo This message contains an audio mesage, which can not currently be
  174. echo played on this type of workstation.   If you log into an appropriate 
  175. echo "machine (currently a SPARCstations or Sony News workstation)"
  176. echo and read this message there, you should be able to hear the audio
  177. echo message.  
  178. echo ""
  179. echo -n "Do you want to write the audio out to a file [y] ? "
  180. set ANS=$<
  181. if ("$ANS" =~ n* ||  "$ANS" =~ N* ) exit 0
  182. echo -n "File name:"
  183. set fname=$<
  184. cp $1 $fname
  185. if ($status == 0) echo Wrote file $fname
  186. exit 0
  187.  
  188.