home *** CD-ROM | disk | FTP | other *** search
/ The CDPD Public Domain Collection for CDTV 1 / CDPD_Vol1.bin / protracker / pt-play.s < prev    next >
Text File  |  1992-06-24  |  22KB  |  1,126 lines
  1. ;********************************************
  2. ;* ----- Protracker V1.1B Playroutine ----- *
  3. ;* Lars "Zap" Hamre/Amiga Freelancers 1991  *
  4. ;* Bekkeliveien 10, N-2010 STRØMMEN, Norway *
  5. ;********************************************
  6.  
  7. ; VBlank Version 2:
  8. ; Call mt_init to initialize the routine, then call mt_music on
  9. ; each vertical blank (50 Hz). To end the song and turn off all
  10. ; voices, call mt_end.
  11.  
  12. ; This playroutine is not very fast, optimized or well commented,
  13. ; but all the new commands in PT1.1A should work.
  14. ; If it's not good enough, you'll have to change it yourself.
  15. ; We'll try to write a faster routine soon...
  16.  
  17. ; Changes from V1.0C playroutine:
  18. ; - Vibrato depth changed to be compatible with Noisetracker 2.0.
  19. ;   You'll have to double all vib. depths on old PT modules.
  20. ; - Funk Repeat changed to Invert Loop.
  21. ; - Period set back earlier when stopping an effect.
  22.  
  23. DMAWait = 1200 ; Set this as low as possible without losing low notes.
  24.                ; no lower than 1000 for 25mhz 68030
  25.  
  26. n_note        EQU    0  ; W
  27. n_cmd        EQU    2  ; W
  28. n_cmdlo        EQU    3  ; B
  29. n_start        EQU    4  ; L
  30. n_length    EQU    8  ; W
  31. n_loopstart    EQU    10 ; L
  32. n_replen    EQU    14 ; W
  33. n_period    EQU    16 ; W
  34. n_finetune    EQU    18 ; B
  35. n_volume    EQU    19 ; B
  36. n_dmabit    EQU    20 ; W
  37. n_toneportdirec    EQU    22 ; B
  38. n_toneportspeed    EQU    23 ; B
  39. n_wantedperiod    EQU    24 ; W
  40. n_vibratocmd    EQU    26 ; B
  41. n_vibratopos    EQU    27 ; B
  42. n_tremolocmd    EQU    28 ; B
  43. n_tremolopos    EQU    29 ; B
  44. n_wavecontrol    EQU    30 ; B
  45. n_glissfunk    EQU    31 ; B
  46. n_sampleoffset    EQU    32 ; B
  47. n_pattpos    EQU    33 ; B
  48. n_loopcount    EQU    34 ; B
  49. n_funkoffset    EQU    35 ; B
  50. n_wavestart    EQU    36 ; L
  51. n_reallength    EQU    40 ; W
  52.  
  53. mt_init    LEA    mt_data,A0
  54.     MOVE.L    A0,mt_SongDataPtr
  55.     MOVE.L    A0,A1
  56.     LEA    952(A1),A1
  57.     MOVEQ    #127,D0
  58.     MOVEQ    #0,D1
  59. mtloop    MOVE.L    D1,D2
  60.     SUBQ.W    #1,D0
  61. mtloop2    MOVE.B    (A1)+,D1
  62.     CMP.B    D2,D1
  63.     BGT.S    mtloop
  64.     DBRA    D0,mtloop2
  65.     ADDQ.B    #1,D2
  66.             
  67.     LEA    mt_SampleStarts(PC),A1
  68.     ASL.L    #8,D2
  69.     ASL.L    #2,D2
  70.     ADD.L    #1084,D2
  71.     ADD.L    A0,D2
  72.     MOVE.L    D2,A2
  73.     MOVEQ    #30,D0
  74. mtloop3    CLR.L    (A2)
  75.     MOVE.L    A2,(A1)+
  76.     MOVEQ    #0,D1
  77.     MOVE.W    42(A0),D1
  78.     ASL.L    #1,D1
  79.     ADD.L    D1,A2
  80.     ADD.L    #30,A0
  81.     DBRA    D0,mtloop3
  82.  
  83.     OR.B    #2,$BFE001
  84.     MOVE.B    #6,mt_speed
  85.     CLR.B    mt_counter
  86.     CLR.B    mt_SongPos
  87.     CLR.W    mt_PatternPos
  88. mt_end    CLR.W    $DFF0A8
  89.     CLR.W    $DFF0B8
  90.     CLR.W    $DFF0C8
  91.     CLR.W    $DFF0D8
  92.     MOVE.W    #$F,$DFF096
  93.     RTS
  94.  
  95. mt_music
  96.     MOVEM.L    D0-D4/A0-A6,-(SP)
  97.     ADDQ.B    #1,mt_counter
  98.     MOVE.B    mt_counter(PC),D0
  99.     CMP.B    mt_speed(PC),D0
  100.     BLO.S    mt_NoNewNote
  101.     CLR.B    mt_counter
  102.     TST.B    mt_PattDelTime2
  103.     BEQ.S    mt_GetNewNote
  104.     BSR.S    mt_NoNewAllChannels
  105.     BRA    mt_dskip
  106.  
  107. mt_NoNewNote
  108.     BSR.S    mt_NoNewAllChannels
  109.     BRA    mt_NoNewPosYet
  110.  
  111. mt_NoNewAllChannels
  112.     LEA    $DFF0A0,A5
  113.     LEA    mt_chan1temp(PC),A6
  114.     BSR    mt_CheckEfx
  115.     LEA    $DFF0B0,A5
  116.     LEA    mt_chan2temp(PC),A6
  117.     BSR    mt_CheckEfx
  118.     LEA    $DFF0C0,A5
  119.     LEA    mt_chan3temp(PC),A6
  120.     BSR    mt_CheckEfx
  121.     LEA    $DFF0D0,A5
  122.     LEA    mt_chan4temp(PC),A6
  123.     BRA    mt_CheckEfx
  124.  
  125. mt_GetNewNote
  126.     MOVE.L    mt_SongDataPtr(PC),A0
  127.     LEA    12(A0),A3
  128.     LEA    952(A0),A2    ;pattpo
  129.     LEA    1084(A0),A0    ;patterndata
  130.     MOVEQ    #0,D0
  131.     MOVEQ    #0,D1
  132.     MOVE.B    mt_SongPos(PC),D0
  133.     MOVE.B    (A2,D0.W),D1
  134.     ASL.L    #8,D1
  135.     ASL.L    #2,D1
  136.     ADD.W    mt_PatternPos(PC),D1
  137.     CLR.W    mt_DMACONtemp
  138.  
  139.     LEA    $DFF0A0,A5
  140.     LEA    mt_chan1temp(PC),A6
  141.     BSR.S    mt_PlayVoice
  142.     LEA    $DFF0B0,A5
  143.     LEA    mt_chan2temp(PC),A6
  144.     BSR.S    mt_PlayVoice
  145.     LEA    $DFF0C0,A5
  146.     LEA    mt_chan3temp(PC),A6
  147.     BSR.S    mt_PlayVoice
  148.     LEA    $DFF0D0,A5
  149.     LEA    mt_chan4temp(PC),A6
  150.     BSR.S    mt_PlayVoice
  151.     BRA    mt_SetDMA
  152.  
  153. mt_PlayVoice
  154.     TST.L    (A6)
  155.     BNE.S    mt_plvskip
  156.     BSR    mt_PerNop
  157. mt_plvskip
  158.     MOVE.L    (A0,D1.L),(A6)
  159.     ADDQ.L    #4,D1
  160.     MOVEQ    #0,D2
  161.     MOVE.B    n_cmd(A6),D2
  162.     AND.B    #$F0,D2
  163.     LSR.B    #4,D2
  164.     MOVE.B    (A6),D0
  165.     AND.B    #$F0,D0
  166.     OR.B    D0,D2
  167.     TST.B    D2
  168.     BEQ    mt_SetRegs
  169.     MOVEQ    #0,D3
  170.     LEA    mt_SampleStarts(PC),A1
  171.     MOVE    D2,D4
  172.     SUBQ.L    #1,D2
  173.     ASL.L    #2,D2
  174.     MULU    #30,D4
  175.     MOVE.L    (A1,D2.L),n_start(A6)
  176.     MOVE.W    (A3,D4.L),n_length(A6)
  177.     MOVE.W    (A3,D4.L),n_reallength(A6)
  178.     MOVE.B    2(A3,D4.L),n_finetune(A6)
  179.     MOVE.B    3(A3,D4.L),n_volume(A6)
  180.     MOVE.W    4(A3,D4.L),D3 ; Get repeat
  181.     TST.W    D3
  182.     BEQ.S    mt_NoLoop
  183.     MOVE.L    n_start(A6),D2    ; Get start
  184.     ASL.W    #1,D3
  185.     ADD.L    D3,D2        ; Add repeat
  186.     MOVE.L    D2,n_loopstart(A6)
  187.     MOVE.L    D2,n_wavestart(A6)
  188.     MOVE.W    4(A3,D4.L),D0    ; Get repeat
  189.     ADD.W    6(A3,D4.L),D0    ; Add replen
  190.     MOVE.W    D0,n_length(A6)
  191.     MOVE.W    6(A3,D4.L),n_replen(A6)    ; Save replen
  192.     MOVEQ    #0,D0
  193.     MOVE.B    n_volume(A6),D0
  194.     MOVE.W    D0,8(A5)    ; Set volume
  195.     BRA.S    mt_SetRegs
  196.  
  197. mt_NoLoop
  198.     MOVE.L    n_start(A6),D2
  199.     ADD.L    D3,D2
  200.     MOVE.L    D2,n_loopstart(A6)
  201.     MOVE.L    D2,n_wavestart(A6)
  202.     MOVE.W    6(A3,D4.L),n_replen(A6)    ; Save replen
  203.     MOVEQ    #0,D0
  204.     MOVE.B    n_volume(A6),D0
  205.     MOVE.W    D0,8(A5)    ; Set volume
  206. mt_SetRegs
  207.     MOVE.W    (A6),D0
  208.     AND.W    #$0FFF,D0
  209.     BEQ    mt_CheckMoreEfx    ; If no note
  210.     MOVE.W    2(A6),D0
  211.     AND.W    #$0FF0,D0
  212.     CMP.W    #$0E50,D0
  213.     BEQ.S    mt_DoSetFineTune
  214.     MOVE.B    2(A6),D0
  215.     AND.B    #$0F,D0
  216.     CMP.B    #3,D0    ; TonePortamento
  217.     BEQ.S    mt_ChkTonePorta
  218.     CMP.B    #5,D0
  219.     BEQ.S    mt_ChkTonePorta
  220.     CMP.B    #9,D0    ; Sample Offset
  221.     BNE.S    mt_SetPeriod
  222.     BSR    mt_CheckMoreEfx
  223.     BRA.S    mt_SetPeriod
  224.  
  225. mt_DoSetFineTune
  226.     BSR    mt_SetFineTune
  227.     BRA.S    mt_SetPeriod
  228.  
  229. mt_ChkTonePorta
  230.     BSR    mt_SetTonePorta
  231.     BRA    mt_CheckMoreEfx
  232.  
  233. mt_SetPeriod
  234.     MOVEM.L    D0-D1/A0-A1,-(SP)
  235.     MOVE.W    (A6),D1
  236.     AND.W    #$0FFF,D1
  237.     LEA    mt_PeriodTable(PC),A1
  238.     MOVEQ    #0,D0
  239.     MOVEQ    #36,D7
  240. mt_ftuloop
  241.     CMP.W    (A1,D0.W),D1
  242.     BHS.S    mt_ftufound
  243.     ADDQ.L    #2,D0
  244.     DBRA    D7,mt_ftuloop
  245. mt_ftufound
  246.     MOVEQ    #0,D1
  247.     MOVE.B    n_finetune(A6),D1
  248.     MULU    #36*2,D1
  249.     ADD.L    D1,A1
  250.     MOVE.W    (A1,D0.W),n_period(A6)
  251.     MOVEM.L    (SP)+,D0-D1/A0-A1
  252.  
  253.     MOVE.W    2(A6),D0
  254.     AND.W    #$0FF0,D0
  255.     CMP.W    #$0ED0,D0 ; Notedelay
  256.     BEQ    mt_CheckMoreEfx
  257.  
  258.     MOVE.W    n_dmabit(A6),$DFF096
  259.     BTST    #2,n_wavecontrol(A6)
  260.     BNE.S    mt_vibnoc
  261.     CLR.B    n_vibratopos(A6)
  262. mt_vibnoc
  263.     BTST    #6,n_wavecontrol(A6)
  264.     BNE.S    mt_trenoc
  265.     CLR.B    n_tremolopos(A6)
  266. mt_trenoc
  267.     MOVE.L    n_start(A6),(A5)    ; Set start
  268.     MOVE.W    n_length(A6),4(A5)    ; Set length
  269.     MOVE.W    n_period(A6),D0
  270.     MOVE.W    D0,6(A5)        ; Set period
  271.     MOVE.W    n_dmabit(A6),D0
  272.     OR.W    D0,mt_DMACONtemp
  273.     BRA    mt_CheckMoreEfx
  274.  
  275. mt_SetDMA
  276.     MOVE.W    #1200,D0
  277. mt_WaitDMA
  278.     DBRA    D0,mt_WaitDMA
  279.     MOVE.W    mt_DMACONtemp(PC),D0
  280.     OR.W    #$8000,D0
  281.     MOVE.W    D0,$DFF096
  282.     MOVE.W    #1200,D0
  283. mt_WaitDMA2
  284.     DBRA    D0,mt_WaitDMA2
  285.  
  286.     LEA    $DFF000,A5
  287.     LEA    mt_chan4temp(PC),A6
  288.     MOVE.L    n_loopstart(A6),$D0(A5)
  289.     MOVE.W    n_replen(A6),$D4(A5)
  290.     LEA    mt_chan3temp(PC),A6
  291.     MOVE.L    n_loopstart(A6),$C0(A5)
  292.     MOVE.W    n_replen(A6),$C4(A5)
  293.     LEA    mt_chan2temp(PC),A6
  294.     MOVE.L    n_loopstart(A6),$B0(A5)
  295.     MOVE.W    n_replen(A6),$B4(A5)
  296.     LEA    mt_chan1temp(PC),A6
  297.     MOVE.L    n_loopstart(A6),$A0(A5)
  298.     MOVE.W    n_replen(A6),$A4(A5)
  299.  
  300. mt_dskip
  301.     ADD.W    #16,mt_PatternPos
  302.     MOVE.B    mt_PattDelTime,D0
  303.     BEQ.S    mt_dskc
  304.     MOVE.B    D0,mt_PattDelTime2
  305.     CLR.B    mt_PattDelTime
  306. mt_dskc    TST.B    mt_PattDelTime2
  307.     BEQ.S    mt_dska
  308.     SUBQ.B    #1,mt_PattDelTime2
  309.     BEQ.S    mt_dska
  310.     SUB.W    #16,mt_PatternPos
  311. mt_dska    TST.B    mt_PBreakFlag
  312.     BEQ.S    mt_nnpysk
  313.     SF    mt_PBreakFlag
  314.     MOVEQ    #0,D0
  315.     MOVE.B    mt_PBreakPos(PC),D0
  316.     CLR.B    mt_PBreakPos
  317.     LSL.W    #4,D0
  318.     MOVE.W    D0,mt_PatternPos
  319. mt_nnpysk
  320.     CMP.W    #1024,mt_PatternPos
  321.     BLO.S    mt_NoNewPosYet
  322. mt_NextPosition    
  323.     MOVEQ    #0,D0
  324.     MOVE.B    mt_PBreakPos(PC),D0
  325.     LSL.W    #4,D0
  326.     MOVE.W    D0,mt_PatternPos
  327.     CLR.B    mt_PBreakPos
  328.     CLR.B    mt_PosJumpFlag
  329.     ADDQ.B    #1,mt_SongPos
  330.     AND.B    #$7F,mt_SongPos
  331.     MOVE.B    mt_SongPos(PC),D1
  332.     MOVE.L    mt_SongDataPtr(PC),A0
  333.     CMP.B    950(A0),D1
  334.     BLO.S    mt_NoNewPosYet
  335.     CLR.B    mt_SongPos
  336. mt_NoNewPosYet    
  337.     TST.B    mt_PosJumpFlag
  338.     BNE.S    mt_NextPosition
  339.     MOVEM.L    (SP)+,D0-D4/A0-A6
  340.     RTS
  341.  
  342. mt_CheckEfx
  343.     BSR    mt_UpdateFunk
  344.     MOVE.W    n_cmd(A6),D0
  345.     AND.W    #$0FFF,D0
  346.     BEQ.S    mt_PerNop
  347.     MOVE.B    n_cmd(A6),D0
  348.     AND.B    #$0F,D0
  349.     BEQ.S    mt_Arpeggio
  350.     CMP.B    #1,D0
  351.     BEQ    mt_PortaUp
  352.     CMP.B    #2,D0
  353.     BEQ    mt_PortaDown
  354.     CMP.B    #3,D0
  355.     BEQ    mt_TonePortamento
  356.     CMP.B    #4,D0
  357.     BEQ    mt_Vibrato
  358.     CMP.B    #5,D0
  359.     BEQ    mt_TonePlusVolSlide
  360.     CMP.B    #6,D0
  361.     BEQ    mt_VibratoPlusVolSlide
  362.     CMP.B    #$E,D0
  363.     BEQ    mt_E_Commands
  364. SetBack    MOVE.W    n_period(A6),6(A5)
  365.     CMP.B    #7,D0
  366.     BEQ    mt_Tremolo
  367.     CMP.B    #$A,D0
  368.     BEQ    mt_VolumeSlide
  369. mt_Return2
  370.     RTS
  371.  
  372. mt_PerNop
  373.     MOVE.W    n_period(A6),6(A5)
  374.     RTS
  375.  
  376. mt_Arpeggio
  377.     MOVEQ    #0,D0
  378.     MOVE.B    mt_counter(PC),D0
  379.     DIVS    #3,D0
  380.     SWAP    D0
  381.     CMP.W    #0,D0
  382.     BEQ.S    mt_Arpeggio2
  383.     CMP.W    #2,D0
  384.     BEQ.S    mt_Arpeggio1
  385.     MOVEQ    #0,D0
  386.     MOVE.B    n_cmdlo(A6),D0
  387.     LSR.B    #4,D0
  388.     BRA.S    mt_Arpeggio3
  389.  
  390. mt_Arpeggio1
  391.     MOVEQ    #0,D0
  392.     MOVE.B    n_cmdlo(A6),D0
  393.     AND.B    #15,D0
  394.     BRA.S    mt_Arpeggio3
  395.  
  396. mt_Arpeggio2
  397.     MOVE.W    n_period(A6),D2
  398.     BRA.S    mt_Arpeggio4
  399.  
  400. mt_Arpeggio3
  401.     ASL.W    #1,D0
  402.     MOVEQ    #0,D1
  403.     MOVE.B    n_finetune(A6),D1
  404.     MULU    #36*2,D1
  405.     LEA    mt_PeriodTable(PC),A0
  406.     ADD.L    D1,A0
  407.     MOVEQ    #0,D1
  408.     MOVE.W    n_period(A6),D1
  409.     MOVEQ    #36,D7
  410. mt_arploop
  411.     MOVE.W    (A0,D0.W),D2
  412.     CMP.W    (A0),D1
  413.     BHS.S    mt_Arpeggio4
  414.     ADDQ.L    #2,A0
  415.     DBRA    D7,mt_arploop
  416.     RTS
  417.  
  418. mt_Arpeggio4
  419.     MOVE.W    D2,6(A5)
  420.     RTS
  421.  
  422. mt_FinePortaUp
  423.     TST.B    mt_counter
  424.     BNE.S    mt_Return2
  425.     MOVE.B    #$0F,mt_LowMask
  426. mt_PortaUp
  427.     MOVEQ    #0,D0
  428.     MOVE.B    n_cmdlo(A6),D0
  429.     AND.B    mt_LowMask(PC),D0
  430.     MOVE.B    #$FF,mt_LowMask
  431.     SUB.W    D0,n_period(A6)
  432.     MOVE.W    n_period(A6),D0
  433.     AND.W    #$0FFF,D0
  434.     CMP.W    #113,D0
  435.     BPL.S    mt_PortaUskip
  436.     AND.W    #$F000,n_period(A6)
  437.     OR.W    #113,n_period(A6)
  438. mt_PortaUskip
  439.     MOVE.W    n_period(A6),D0
  440.     AND.W    #$0FFF,D0
  441.     MOVE.W    D0,6(A5)
  442.     RTS    
  443.  
  444. mt_FinePortaDown
  445.     TST.B    mt_counter
  446.     BNE    mt_Return2
  447.     MOVE.B    #$0F,mt_LowMask
  448. mt_PortaDown
  449.     CLR.W    D0
  450.     MOVE.B    n_cmdlo(A6),D0
  451.     AND.B    mt_LowMask(PC),D0
  452.     MOVE.B    #$FF,mt_LowMask
  453.     ADD.W    D0,n_period(A6)
  454.     MOVE.W    n_period(A6),D0
  455.     AND.W    #$0FFF,D0
  456.     CMP.W    #856,D0
  457.     BMI.S    mt_PortaDskip
  458.     AND.W    #$F000,n_period(A6)
  459.     OR.W    #856,n_period(A6)
  460. mt_PortaDskip
  461.     MOVE.W    n_period(A6),D0
  462.     AND.W    #$0FFF,D0
  463.     MOVE.W    D0,6(A5)
  464.     RTS
  465.  
  466. mt_SetTonePorta
  467.     MOVE.L    A0,-(SP)
  468.     MOVE.W    (A6),D2
  469.     AND.W    #$0FFF,D2
  470.     MOVEQ    #0,D0
  471.     MOVE.B    n_finetune(A6),D0
  472.     MULU    #37*2,D0
  473.     LEA    mt_PeriodTable(PC),A0
  474.     ADD.L    D0,A0
  475.     MOVEQ    #0,D0
  476. mt_StpLoop
  477.     CMP.W    (A0,D0.W),D2
  478.     BHS.S    mt_StpFound
  479.     ADDQ.W    #2,D0
  480.     CMP.W    #37*2,D0
  481.     BLO.S    mt_StpLoop
  482.     MOVEQ    #35*2,D0
  483. mt_StpFound
  484.     MOVE.B    n_finetune(A6),D2
  485.     AND.B    #8,D2
  486.     BEQ.S    mt_StpGoss
  487.     TST.W    D0
  488.     BEQ.S    mt_StpGoss
  489.     SUBQ.W    #2,D0
  490. mt_StpGoss
  491.     MOVE.W    (A0,D0.W),D2
  492.     MOVE.L    (SP)+,A0
  493.     MOVE.W    D2,n_wantedperiod(A6)
  494.     MOVE.W    n_period(A6),D0
  495.     CLR.B    n_toneportdirec(A6)
  496.     CMP.W    D0,D2
  497.     BEQ.S    mt_ClearTonePorta
  498.     BGE    mt_Return2
  499.     MOVE.B    #1,n_toneportdirec(A6)
  500.     RTS
  501.  
  502. mt_ClearTonePorta
  503.     CLR.W    n_wantedperiod(A6)
  504.     RTS
  505.  
  506. mt_TonePortamento
  507.     MOVE.B    n_cmdlo(A6),D0
  508.     BEQ.S    mt_TonePortNoChange
  509.     MOVE.B    D0,n_toneportspeed(A6)
  510.     CLR.B    n_cmdlo(A6)
  511. mt_TonePortNoChange
  512.     TST.W    n_wantedperiod(A6)
  513.     BEQ    mt_Return2
  514.     MOVEQ    #0,D0
  515.     MOVE.B    n_toneportspeed(A6),D0
  516.     TST.B    n_toneportdirec(A6)
  517.     BNE.S    mt_TonePortaUp
  518. mt_TonePortaDown
  519.     ADD.W    D0,n_period(A6)
  520.     MOVE.W    n_wantedperiod(A6),D0
  521.     CMP.W    n_period(A6),D0
  522.     BGT.S    mt_TonePortaSetPer
  523.     MOVE.W    n_wantedperiod(A6),n_period(A6)
  524.     CLR.W    n_wantedperiod(A6)
  525.     BRA.S    mt_TonePortaSetPer
  526.  
  527. mt_TonePortaUp
  528.     SUB.W    D0,n_period(A6)
  529.     MOVE.W    n_wantedperiod(A6),D0
  530.     CMP.W    n_period(A6),D0
  531.     BLT.S    mt_TonePortaSetPer
  532.     MOVE.W    n_wantedperiod(A6),n_period(A6)
  533.     CLR.W    n_wantedperiod(A6)
  534.  
  535. mt_TonePortaSetPer
  536.     MOVE.W    n_period(A6),D2
  537.     MOVE.B    n_glissfunk(A6),D0
  538.     AND.B    #$0F,D0
  539.     BEQ.S    mt_GlissSkip
  540.     MOVEQ    #0,D0
  541.     MOVE.B    n_finetune(A6),D0
  542.     MULU    #36*2,D0
  543.     LEA    mt_PeriodTable(PC),A0
  544.     ADD.L    D0,A0
  545.     MOVEQ    #0,D0
  546. mt_GlissLoop
  547.     CMP.W    (A0,D0.W),D2
  548.     BHS.S    mt_GlissFound
  549.     ADDQ.W    #2,D0
  550.     CMP.W    #36*2,D0
  551.     BLO.S    mt_GlissLoop
  552.     MOVEQ    #35*2,D0
  553. mt_GlissFound
  554.     MOVE.W    (A0,D0.W),D2
  555. mt_GlissSkip
  556.     MOVE.W    D2,6(A5) ; Set period
  557.     RTS
  558.  
  559. mt_Vibrato
  560.     MOVE.B    n_cmdlo(A6),D0
  561.     BEQ.S    mt_Vibrato2
  562.     MOVE.B    n_vibratocmd(A6),D2
  563.     AND.B    #$0F,D0
  564.     BEQ.S    mt_vibskip
  565.     AND.B    #$F0,D2
  566.     OR.B    D0,D2
  567. mt_vibskip
  568.     MOVE.B    n_cmdlo(A6),D0
  569.     AND.B    #$F0,D0
  570.     BEQ.S    mt_vibskip2
  571.     AND.B    #$0F,D2
  572.     OR.B    D0,D2
  573. mt_vibskip2
  574.     MOVE.B    D2,n_vibratocmd(A6)
  575. mt_Vibrato2
  576.     MOVE.B    n_vibratopos(A6),D0
  577.     LEA    mt_VibratoTable(PC),A4
  578.     LSR.W    #2,D0
  579.     AND.W    #$001F,D0
  580.     MOVEQ    #0,D2
  581.     MOVE.B    n_wavecontrol(A6),D2
  582.     AND.B    #$03,D2
  583.     BEQ.S    mt_vib_sine
  584.     LSL.B    #3,D0
  585.     CMP.B    #1,D2
  586.     BEQ.S    mt_vib_rampdown
  587.     MOVE.B    #255,D2
  588.     BRA.S    mt_vib_set
  589. mt_vib_rampdown
  590.     TST.B    n_vibratopos(A6)
  591.     BPL.S    mt_vib_rampdown2
  592.     MOVE.B    #255,D2
  593.     SUB.B    D0,D2
  594.     BRA.S    mt_vib_set
  595. mt_vib_rampdown2
  596.     MOVE.B    D0,D2
  597.     BRA.S    mt_vib_set
  598. mt_vib_sine
  599.     MOVE.B    0(A4,D0.W),D2
  600. mt_vib_set
  601.     MOVE.B    n_vibratocmd(A6),D0
  602.     AND.W    #15,D0
  603.     MULU    D0,D2
  604.     LSR.W    #7,D2
  605.     MOVE.W    n_period(A6),D0
  606.     TST.B    n_vibratopos(A6)
  607.     BMI.S    mt_VibratoNeg
  608.     ADD.W    D2,D0
  609.     BRA.S    mt_Vibrato3
  610. mt_VibratoNeg
  611.     SUB.W    D2,D0
  612. mt_Vibrato3
  613.     MOVE.W    D0,6(A5)
  614.     MOVE.B    n_vibratocmd(A6),D0
  615.     LSR.W    #2,D0
  616.     AND.W    #$003C,D0
  617.     ADD.B    D0,n_vibratopos(A6)
  618.     RTS
  619.  
  620. mt_TonePlusVolSlide
  621.     BSR    mt_TonePortNoChange
  622.     BRA    mt_VolumeSlide
  623.  
  624. mt_VibratoPlusVolSlide
  625.     BSR.S    mt_Vibrato2
  626.     BRA    mt_VolumeSlide
  627.  
  628. mt_Tremolo
  629.     MOVE.B    n_cmdlo(A6),D0
  630.     BEQ.S    mt_Tremolo2
  631.     MOVE.B    n_tremolocmd(A6),D2
  632.     AND.B    #$0F,D0
  633.     BEQ.S    mt_treskip
  634.     AND.B    #$F0,D2
  635.     OR.B    D0,D2
  636. mt_treskip
  637.     MOVE.B    n_cmdlo(A6),D0
  638.     AND.B    #$F0,D0
  639.     BEQ.S    mt_treskip2
  640.     AND.B    #$0F,D2
  641.     OR.B    D0,D2
  642. mt_treskip2
  643.     MOVE.B    D2,n_tremolocmd(A6)
  644. mt_Tremolo2
  645.     MOVE.B    n_tremolopos(A6),D0
  646.     LEA    mt_VibratoTable(PC),A4
  647.     LSR.W    #2,D0
  648.     AND.W    #$001F,D0
  649.     MOVEQ    #0,D2
  650.     MOVE.B    n_wavecontrol(A6),D2
  651.     LSR.B    #4,D2
  652.     AND.B    #$03,D2
  653.     BEQ.S    mt_tre_sine
  654.     LSL.B    #3,D0
  655.     CMP.B    #1,D2
  656.     BEQ.S    mt_tre_rampdown
  657.     MOVE.B    #255,D2
  658.     BRA.S    mt_tre_set
  659. mt_tre_rampdown
  660.     TST.B    n_vibratopos(A6)
  661.     BPL.S    mt_tre_rampdown2
  662.     MOVE.B    #255,D2
  663.     SUB.B    D0,D2
  664.     BRA.S    mt_tre_set
  665. mt_tre_rampdown2
  666.     MOVE.B    D0,D2
  667.     BRA.S    mt_tre_set
  668. mt_tre_sine
  669.     MOVE.B    0(A4,D0.W),D2
  670. mt_tre_set
  671.     MOVE.B    n_tremolocmd(A6),D0
  672.     AND.W    #15,D0
  673.     MULU    D0,D2
  674.     LSR.W    #6,D2
  675.     MOVEQ    #0,D0
  676.     MOVE.B    n_volume(A6),D0
  677.     TST.B    n_tremolopos(A6)
  678.     BMI.S    mt_TremoloNeg
  679.     ADD.W    D2,D0
  680.     BRA.S    mt_Tremolo3
  681. mt_TremoloNeg
  682.     SUB.W    D2,D0
  683. mt_Tremolo3
  684.     BPL.S    mt_TremoloSkip
  685.     CLR.W    D0
  686. mt_TremoloSkip
  687.     CMP.W    #$40,D0
  688.     BLS.S    mt_TremoloOk
  689.     MOVE.W    #$40,D0
  690. mt_TremoloOk
  691.     MOVE.W    D0,8(A5)
  692.     MOVE.B    n_tremolocmd(A6),D0
  693.     LSR.W    #2,D0
  694.     AND.W    #$003C,D0
  695.     ADD.B    D0,n_tremolopos(A6)
  696.     RTS
  697.  
  698. mt_SampleOffset
  699.     MOVEQ    #0,D0
  700.     MOVE.B    n_cmdlo(A6),D0
  701.     BEQ.S    mt_sononew
  702.     MOVE.B    D0,n_sampleoffset(A6)
  703. mt_sononew
  704.     MOVE.B    n_sampleoffset(A6),D0
  705.     LSL.W    #7,D0
  706.     CMP.W    n_length(A6),D0
  707.     BGE.S    mt_sofskip
  708.     SUB.W    D0,n_length(A6)
  709.     LSL.W    #1,D0
  710.     ADD.L    D0,n_start(A6)
  711.     RTS
  712. mt_sofskip
  713.     MOVE.W    #$0001,n_length(A6)
  714.     RTS
  715.  
  716. mt_VolumeSlide
  717.     MOVEQ    #0,D0
  718.     MOVE.B    n_cmdlo(A6),D0
  719.     LSR.B    #4,D0
  720.     TST.B    D0
  721.     BEQ.S    mt_VolSlideDown
  722. mt_VolSlideUp
  723.     ADD.B    D0,n_volume(A6)
  724.     CMP.B    #$40,n_volume(A6)
  725.     BMI.S    mt_vsuskip
  726.     MOVE.B    #$40,n_volume(A6)
  727. mt_vsuskip
  728.     MOVE.B    n_volume(A6),D0
  729.     MOVE.W    D0,8(A5)
  730.     RTS
  731.  
  732. mt_VolSlideDown
  733.     MOVEQ    #0,D0
  734.     MOVE.B    n_cmdlo(A6),D0
  735.     AND.B    #$0F,D0
  736. mt_VolSlideDown2
  737.     SUB.B    D0,n_volume(A6)
  738.     BPL.S    mt_vsdskip
  739.     CLR.B    n_volume(A6)
  740. mt_vsdskip
  741.     MOVE.B    n_volume(A6),D0
  742.     MOVE.W    D0,8(A5)
  743.     RTS
  744.  
  745. mt_PositionJump
  746.     MOVE.B    n_cmdlo(A6),D0
  747.     SUBQ.B    #1,D0
  748.     MOVE.B    D0,mt_SongPos
  749. mt_pj2    CLR.B    mt_PBreakPos
  750.     ST     mt_PosJumpFlag
  751.     RTS
  752.  
  753. mt_VolumeChange
  754.     MOVEQ    #0,D0
  755.     MOVE.B    n_cmdlo(A6),D0
  756.     CMP.B    #$40,D0
  757.     BLS.S    mt_VolumeOk
  758.     MOVEQ    #$40,D0
  759. mt_VolumeOk
  760.     MOVE.B    D0,n_volume(A6)
  761.     MOVE.W    D0,8(A5)
  762.     RTS
  763.  
  764. mt_PatternBreak
  765.     MOVEQ    #0,D0
  766.     MOVE.B    n_cmdlo(A6),D0
  767.     MOVE.L    D0,D2
  768.     LSR.B    #4,D0
  769.     MULU    #10,D0
  770.     AND.B    #$0F,D2
  771.     ADD.B    D2,D0
  772.     CMP.B    #63,D0
  773.     BHI.S    mt_pj2
  774.     MOVE.B    D0,mt_PBreakPos
  775.     ST    mt_PosJumpFlag
  776.     RTS
  777.  
  778. mt_SetSpeed
  779.     MOVE.B    3(A6),D0
  780.     BEQ    mt_Return2
  781.     CLR.B    mt_counter
  782.     MOVE.B    D0,mt_speed
  783.     RTS
  784.  
  785. mt_CheckMoreEfx
  786.     BSR    mt_UpdateFunk
  787.     MOVE.B    2(A6),D0
  788.     AND.B    #$0F,D0
  789.     CMP.B    #$9,D0
  790.     BEQ    mt_SampleOffset
  791.     CMP.B    #$B,D0
  792.     BEQ    mt_PositionJump
  793.     CMP.B    #$D,D0
  794.     BEQ.S    mt_PatternBreak
  795.     CMP.B    #$E,D0
  796.     BEQ.S    mt_E_Commands
  797.     CMP.B    #$F,D0
  798.     BEQ.S    mt_SetSpeed
  799.     CMP.B    #$C,D0
  800.     BEQ    mt_VolumeChange
  801.     BRA    mt_PerNop
  802.  
  803. mt_E_Commands
  804.     MOVE.B    n_cmdlo(A6),D0
  805.     AND.B    #$F0,D0
  806.     LSR.B    #4,D0
  807.     BEQ.S    mt_FilterOnOff
  808.     CMP.B    #1,D0
  809.     BEQ    mt_FinePortaUp
  810.     CMP.B    #2,D0
  811.     BEQ    mt_FinePortaDown
  812.     CMP.B    #3,D0
  813.     BEQ.S    mt_SetGlissControl
  814.     CMP.B    #4,D0
  815.     BEQ    mt_SetVibratoControl
  816.     CMP.B    #5,D0
  817.     BEQ    mt_SetFineTune
  818.     CMP.B    #6,D0
  819.     BEQ    mt_JumpLoop
  820.     CMP.B    #7,D0
  821.     BEQ    mt_SetTremoloControl
  822.     CMP.B    #9,D0
  823.     BEQ    mt_RetrigNote
  824.     CMP.B    #$A,D0
  825.     BEQ    mt_VolumeFineUp
  826.     CMP.B    #$B,D0
  827.     BEQ    mt_VolumeFineDown
  828.     CMP.B    #$C,D0
  829.     BEQ    mt_NoteCut
  830.     CMP.B    #$D,D0
  831.     BEQ    mt_NoteDelay
  832.     CMP.B    #$E,D0
  833.     BEQ    mt_PatternDelay
  834.     CMP.B    #$F,D0
  835.     BEQ    mt_FunkIt
  836.     RTS
  837.  
  838. mt_FilterOnOff
  839.     MOVE.B    n_cmdlo(A6),D0
  840.     AND.B    #1,D0
  841.     ASL.B    #1,D0
  842.     AND.B    #$FD,$BFE001
  843.     OR.B    D0,$BFE001
  844.     RTS    
  845.  
  846. mt_SetGlissControl
  847.     MOVE.B    n_cmdlo(A6),D0
  848.     AND.B    #$0F,D0
  849.     AND.B    #$F0,n_glissfunk(A6)
  850.     OR.B    D0,n_glissfunk(A6)
  851.     RTS
  852.  
  853. mt_SetVibratoControl
  854.     MOVE.B    n_cmdlo(A6),D0
  855.     AND.B    #$0F,D0
  856.     AND.B    #$F0,n_wavecontrol(A6)
  857.     OR.B    D0,n_wavecontrol(A6)
  858.     RTS
  859.  
  860. mt_SetFineTune
  861.     MOVE.B    n_cmdlo(A6),D0
  862.     AND.B    #$0F,D0
  863.     MOVE.B    D0,n_finetune(A6)
  864.     RTS
  865.  
  866. mt_JumpLoop
  867.     TST.B    mt_counter
  868.     BNE    mt_Return2
  869.     MOVE.B    n_cmdlo(A6),D0
  870.     AND.B    #$0F,D0
  871.     BEQ.S    mt_SetLoop
  872.     TST.B    n_loopcount(A6)
  873.     BEQ.S    mt_jumpcnt
  874.     SUBQ.B    #1,n_loopcount(A6)
  875.     BEQ    mt_Return2
  876. mt_jmploop    MOVE.B    n_pattpos(A6),mt_PBreakPos
  877.     ST    mt_PBreakFlag
  878.     RTS
  879.  
  880. mt_jumpcnt
  881.     MOVE.B    D0,n_loopcount(A6)
  882.     BRA.S    mt_jmploop
  883.  
  884. mt_SetLoop
  885.     MOVE.W    mt_PatternPos(PC),D0
  886.     LSR.W    #4,D0
  887.     MOVE.B    D0,n_pattpos(A6)
  888.     RTS
  889.  
  890. mt_SetTremoloControl
  891.     MOVE.B    n_cmdlo(A6),D0
  892.     AND.B    #$0F,D0
  893.     LSL.B    #4,D0
  894.     AND.B    #$0F,n_wavecontrol(A6)
  895.     OR.B    D0,n_wavecontrol(A6)
  896.     RTS
  897.  
  898. mt_RetrigNote
  899.     MOVE.L    D1,-(SP)
  900.     MOVEQ    #0,D0
  901.     MOVE.B    n_cmdlo(A6),D0
  902.     AND.B    #$0F,D0
  903.     BEQ.S    mt_rtnend
  904.     MOVEQ    #0,D1
  905.     MOVE.B    mt_counter(PC),D1
  906.     BNE.S    mt_rtnskp
  907.     MOVE.W    (A6),D1
  908.     AND.W    #$0FFF,D1
  909.     BNE.S    mt_rtnend
  910.     MOVEQ    #0,D1
  911.     MOVE.B    mt_counter(PC),D1
  912. mt_rtnskp
  913.     DIVU    D0,D1
  914.     SWAP    D1
  915.     TST.W    D1
  916.     BNE.S    mt_rtnend
  917. mt_DoRetrig
  918.     MOVE.W    n_dmabit(A6),$DFF096    ; Channel DMA off
  919.     MOVE.L    n_start(A6),(A5)    ; Set sampledata pointer
  920.     MOVE.W    n_length(A6),4(A5)    ; Set length
  921.     MOVE.W    #1200,D0
  922. mt_rtnloop1
  923.     DBRA    D0,mt_rtnloop1
  924.     MOVE.W    n_dmabit(A6),D0
  925.     BSET    #15,D0
  926.     MOVE.W    D0,$DFF096
  927.     MOVE.W    #1200,D0
  928. mt_rtnloop2
  929.     DBRA    D0,mt_rtnloop2
  930.     MOVE.L    n_loopstart(A6),(A5)
  931.     MOVE.L    n_replen(A6),4(A5)
  932. mt_rtnend
  933.     MOVE.L    (SP)+,D1
  934.     RTS
  935.  
  936. mt_VolumeFineUp
  937.     TST.B    mt_counter
  938.     BNE    mt_Return2
  939.     MOVEQ    #0,D0
  940.     MOVE.B    n_cmdlo(A6),D0
  941.     AND.B    #$F,D0
  942.     BRA    mt_VolSlideUp
  943.  
  944. mt_VolumeFineDown
  945.     TST.B    mt_counter
  946.     BNE    mt_Return2
  947.     MOVEQ    #0,D0
  948.     MOVE.B    n_cmdlo(A6),D0
  949.     AND.B    #$0F,D0
  950.     BRA    mt_VolSlideDown2
  951.  
  952. mt_NoteCut
  953.     MOVEQ    #0,D0
  954.     MOVE.B    n_cmdlo(A6),D0
  955.     AND.B    #$0F,D0
  956.     CMP.B    mt_counter(PC),D0
  957.     BNE    mt_Return2
  958.     CLR.B    n_volume(A6)
  959.     MOVE.W    #0,8(A5)
  960.     RTS
  961.  
  962. mt_NoteDelay
  963.     MOVEQ    #0,D0
  964.     MOVE.B    n_cmdlo(A6),D0
  965.     AND.B    #$0F,D0
  966.     CMP.B    mt_Counter,D0
  967.     BNE    mt_Return2
  968.     MOVE.W    (A6),D0
  969.     BEQ    mt_Return2
  970.     MOVE.L    D1,-(SP)
  971.     BRA    mt_DoRetrig
  972.  
  973. mt_PatternDelay
  974.     TST.B    mt_counter
  975.     BNE    mt_Return2
  976.     MOVEQ    #0,D0
  977.     MOVE.B    n_cmdlo(A6),D0
  978.     AND.B    #$0F,D0
  979.     TST.B    mt_PattDelTime2
  980.     BNE    mt_Return2
  981.     ADDQ.B    #1,D0
  982.     MOVE.B    D0,mt_PattDelTime
  983.     RTS
  984.  
  985. mt_FunkIt
  986.     TST.B    mt_counter
  987.     BNE    mt_Return2
  988.     MOVE.B    n_cmdlo(A6),D0
  989.     AND.B    #$0F,D0
  990.     LSL.B    #4,D0
  991.     AND.B    #$0F,n_glissfunk(A6)
  992.     OR.B    D0,n_glissfunk(A6)
  993.     TST.B    D0
  994.     BEQ    mt_Return2
  995. mt_UpdateFunk
  996.     MOVEM.L    A0/D1,-(SP)
  997.     MOVEQ    #0,D0
  998.     MOVE.B    n_glissfunk(A6),D0
  999.     LSR.B    #4,D0
  1000.     BEQ.S    mt_funkend
  1001.     LEA    mt_FunkTable(PC),A0
  1002.     MOVE.B    (A0,D0.W),D0
  1003.     ADD.B    D0,n_funkoffset(A6)
  1004.     BTST    #7,n_funkoffset(A6)
  1005.     BEQ.S    mt_funkend
  1006.     CLR.B    n_funkoffset(A6)
  1007.  
  1008.     MOVE.L    n_loopstart(A6),D0
  1009.     MOVEQ    #0,D1
  1010.     MOVE.W    n_replen(A6),D1
  1011.     ADD.L    D1,D0
  1012.     ADD.L    D1,D0
  1013.     MOVE.L    n_wavestart(A6),A0
  1014.     ADDQ.L    #1,A0
  1015.     CMP.L    D0,A0
  1016.     BLO.S    mt_funkok
  1017.     MOVE.L    n_loopstart(A6),A0
  1018. mt_funkok
  1019.     MOVE.L    A0,n_wavestart(A6)
  1020.     MOVEQ    #-1,D0
  1021.     SUB.B    (A0),D0
  1022.     MOVE.B    D0,(A0)
  1023. mt_funkend
  1024.     MOVEM.L    (SP)+,A0/D1
  1025.     RTS
  1026.  
  1027.  
  1028. mt_FunkTable dc.b 0,5,6,7,8,10,11,13,16,19,22,26,32,43,64,128
  1029.  
  1030. mt_VibratoTable    
  1031.     dc.b   0, 24, 49, 74, 97,120,141,161
  1032.     dc.b 180,197,212,224,235,244,250,253
  1033.     dc.b 255,253,250,244,235,224,212,197
  1034.     dc.b 180,161,141,120, 97, 74, 49, 24
  1035.  
  1036. mt_PeriodTable
  1037. ; Tuning 0, Normal
  1038.     dc.w    856,808,762,720,678,640,604,570,538,508,480,453
  1039.     dc.w    428,404,381,360,339,320,302,285,269,254,240,226
  1040.     dc.w    214,202,190,180,170,160,151,143,135,127,120,113
  1041. ; Tuning 1
  1042.     dc.w    850,802,757,715,674,637,601,567,535,505,477,450
  1043.     dc.w    425,401,379,357,337,318,300,284,268,253,239,225
  1044.     dc.w    213,201,189,179,169,159,150,142,134,126,119,113
  1045. ; Tuning 2
  1046.     dc.w    844,796,752,709,670,632,597,563,532,502,474,447
  1047.     dc.w    422,398,376,355,335,316,298,282,266,251,237,224
  1048.     dc.w    211,199,188,177,167,158,149,141,133,125,118,112
  1049. ; Tuning 3
  1050.     dc.w    838,791,746,704,665,628,592,559,528,498,470,444
  1051.     dc.w    419,395,373,352,332,314,296,280,264,249,235,222
  1052.     dc.w    209,198,187,176,166,157,148,140,132,125,118,111
  1053. ; Tuning 4
  1054.     dc.w    832,785,741,699,660,623,588,555,524,495,467,441
  1055.     dc.w    416,392,370,350,330,312,294,278,262,247,233,220
  1056.     dc.w    208,196,185,175,165,156,147,139,131,124,117,110
  1057. ; Tuning 5
  1058.     dc.w    826,779,736,694,655,619,584,551,520,491,463,437
  1059.     dc.w    413,390,368,347,328,309,292,276,260,245,232,219
  1060.     dc.w    206,195,184,174,164,155,146,138,130,123,116,109
  1061. ; Tuning 6
  1062.     dc.w    820,774,730,689,651,614,580,547,516,487,460,434
  1063.     dc.w    410,387,365,345,325,307,290,274,258,244,230,217
  1064.     dc.w    205,193,183,172,163,154,145,137,129,122,115,109
  1065. ; Tuning 7
  1066.     dc.w    814,768,725,684,646,610,575,543,513,484,457,431
  1067.     dc.w    407,384,363,342,323,305,288,272,256,242,228,216
  1068.     dc.w    204,192,181,171,161,152,144,136,128,121,114,108
  1069. ; Tuning -8
  1070.     dc.w    907,856,808,762,720,678,640,604,570,538,508,480
  1071.     dc.w    453,428,404,381,360,339,320,302,285,269,254,240
  1072.     dc.w    226,214,202,190,180,170,160,151,143,135,127,120
  1073. ; Tuning -7
  1074.     dc.w    900,850,802,757,715,675,636,601,567,535,505,477
  1075.     dc.w    450,425,401,379,357,337,318,300,284,268,253,238
  1076.     dc.w    225,212,200,189,179,169,159,150,142,134,126,119
  1077. ; Tuning -6
  1078.     dc.w    894,844,796,752,709,670,632,597,563,532,502,474
  1079.     dc.w    447,422,398,376,355,335,316,298,282,266,251,237
  1080.     dc.w    223,211,199,188,177,167,158,149,141,133,125,118
  1081. ; Tuning -5
  1082.     dc.w    887,838,791,746,704,665,628,592,559,528,498,470
  1083.     dc.w    444,419,395,373,352,332,314,296,280,264,249,235
  1084.     dc.w    222,209,198,187,176,166,157,148,140,132,125,118
  1085. ; Tuning -4
  1086.     dc.w    881,832,785,741,699,660,623,588,555,524,494,467
  1087.     dc.w    441,416,392,370,350,330,312,294,278,262,247,233
  1088.     dc.w    220,208,196,185,175,165,156,147,139,131,123,117
  1089. ; Tuning -3
  1090.     dc.w    875,826,779,736,694,655,619,584,551,520,491,463
  1091.     dc.w    437,413,390,368,347,328,309,292,276,260,245,232
  1092.     dc.w    219,206,195,184,174,164,155,146,138,130,123,116
  1093. ; Tuning -2
  1094.     dc.w    868,820,774,730,689,651,614,580,547,516,487,460
  1095.     dc.w    434,410,387,365,345,325,307,290,274,258,244,230
  1096.     dc.w    217,205,193,183,172,163,154,145,137,129,122,115
  1097. ; Tuning -1
  1098.     dc.w    862,814,768,725,684,646,610,575,543,513,484,457
  1099.     dc.w    431,407,384,363,342,323,305,288,272,256,242,228
  1100.     dc.w    216,203,192,181,171,161,152,144,136,128,121,114
  1101.  
  1102. mt_chan1temp    dc.l    0,0,0,0,0,$00010000,0,  0,0,0,0
  1103. mt_chan2temp    dc.l    0,0,0,0,0,$00020000,0,  0,0,0,0
  1104. mt_chan3temp    dc.l    0,0,0,0,0,$00040000,0,  0,0,0,0
  1105. mt_chan4temp    dc.l    0,0,0,0,0,$00080000,0,  0,0,0,0
  1106.  
  1107. mt_SampleStarts    dc.l    0,0,0,0,0,0,0,0,0,0,0,0,0,0,0,0
  1108.         dc.l    0,0,0,0,0,0,0,0,0,0,0,0,0,0,0
  1109.  
  1110. mt_SongDataPtr    dc.l 0
  1111.  
  1112. mt_speed    dc.b 6
  1113. mt_counter    dc.b 0
  1114. mt_SongPos    dc.b 0
  1115. mt_PBreakPos    dc.b 0
  1116. mt_PosJumpFlag    dc.b 0
  1117. mt_PBreakFlag    dc.b 0
  1118. mt_LowMask    dc.b 0
  1119. mt_PattDelTime    dc.b 0
  1120. mt_PattDelTime2    dc.b 0,0
  1121.  
  1122. mt_PatternPos    dc.w 0
  1123. mt_DMACONtemp    dc.w 0
  1124.  
  1125. ;/* End of File */
  1126.