home
***
CD-ROM
|
disk
|
FTP
|
other
***
search
/
Fatal Distractions!
/
fataldistractions.bin
/
appndxa
/
masters
/
pork.agt
< prev
next >
Wrap
Text File
|
1993-08-14
|
139KB
|
5,373 lines
TITLE
COLORS WHITE YELLOW BLACK YELLOW RED
PORK I: The Great Underground Sewer System
Copywronged 1988, Version -4.26
Original author is Unknown
Converted to AGT and greatly expanded by David Malmberg
END_TITLE
INTRODUCTION
This adventure, PORK I, is a parody of ZORK I, THE GREAT UNDERGROUND EMPIRE
which was written by 'Diabolical' Dave Lebling and 'Maniacal' Marc Blank and
originally published by Infocom in 1981. ZORK I has sold more copies than any
other adventure game (and probably more copies than any other program --
period). It is truly a classic! In writing PORK, I have tried to retain some
of the cleverness, low cunning, and humor of ZORK -- while poking a little
good-natured fun at it.
You do not need to have played ZORK to enjoy PORK. However, previous
experience with ZORK may give you some clues for solving some of PORK's
puzzles -- then again, it may not.
END_INTRODUCTION
VERBS
LIGHT BURN
Dummy_Verb1 DESTROY BREAK MAIM DISFIGURE POKE
Dummy_Verb2 GO
Dummy_Verb3 SEARCH FIND
Dummy_Verb4 WAVE
Dummy_Verb5 GIVE
Dummy_Verb6 SWIM
Dummy_Verb7 SWING SLUG HIT SLOG
Dummy_Verb8 COVER
Dummy_Verb9 SMOKE USE INSERT
Dummy_Verb10 FART
Dummy_Verb11 SHOW
Dummy_Verb12 SCRAMBLE
Dummy_Verb13 PEACE HELLO HI LOVE
Dummy_Verb14 DEBUG
Dummy_Verb15 NO
Dummy_Verb16 YES
Dummy_Verb17 ULYSSES ODYSSEY FISH ODYSSEUS
Dummy_Verb18 RUB
Dummy_Verb19 WASH
Dummy_Verb20 PET PAT HUG LOVE BEFRIEND
Dummy_Verb21 KISS
Dummy_Verb22 SAY
Dummy_Verb23 SHAKE RATTLE
Dummy_Verb24 FIX
Dummy_Verb25 CLIMB
Dummy_Verb26 JUMP
Dummy_Verb27 MOVE LIFT
Dummy_Verb28 PRAY SLEEP
Dummy_Verb29 ECHO AHOY PLUGH XYZZY PLOVER AHRIMAN ARTICHOKE ZORK
Dummy_Verb30 DIG
Dummy_Verb31 RING
Dummy_Verb32 OOPS
END_VERBS
VOCABULARY
! This is the default AGT verb list for the "menu-driven" parser for PORK
! AGAIN should be the first A-verb
1 Again
2 Attack
3 Attack With
3 Ask about
2 Befriend
2 Break
3 Break with
1 Brief
2 Burn
2 Close
2 Climb up
2 Climb down
2 Climb through
2 Climb In
2 Cover
! DOWN should be the first D-verb
1 Down
2 Drop
2 Destroy
3 Dig with
2 Drink
! EAST should be the first E-verb
1 East
2 Examine
2 Eat
1 Enter
2 Enter Into
1 Exit
2 Extinguish
1 Fart
3 Feed to
2 Find
2 Fire
3 Fire At
2 Fix
2 Follow
! GET should be the first G-verb
2 Get
2 Get in
3 Give to
2 Go to
2 Go through
! HELP should be the first H-verb
1 Help
2 Hear
1 Hello
2 Hit
3 Hit with
2 Hold
2 Hug
! INVENTORY should be the first I-verb
1 Inventory
2 insert
2 Jump in
2 Jump on
2 Jump over
2 Jump down
2 kick
2 Kill
3 Kill With
2 Kiss
! LOOK AROUND should be the first L-verb
1 Look around
2 Look at
2 Look in
2 Look through
2 Look under
2 Look up
2 Look down
2 Love
1 List Exits
2 Light
3 Light With
1 Listen
2 Listen To
3 Lock with
2 Move
! NORTH should be the first N-verb
1 North
1 Northeast
1 Northwest
! OPEN should be the first O-verb
2 Open
3 Open With
1 ODYSSEY
2 Pat
1 Peace
2 Play
1 Pray
2 Put down
3 Put in
3 Put on
3 Put under
2 Push
3 Push With
2 Pull
! QUIT should be the first Q-verb
1 Quit
! READ should be the first R-verb
2 Read
2 Remove
2 Ring
2 Rub
3 Rub with
1 Restore
! SOUTH should be the first S-verb
1 South
1 Southeast
1 Southwest
1 Score
1 Save
1 Say
2 Scramble
1 Scream
2 Scream At
1 Script
2 Search
2 shake
2 Shoot
3 Shoot At
1 Shout
2 Shout to
3 Show to
1 sleep
2 Slug
2 Smash
2 smoke
1 Swim
2 Swing
2 Switch
! TAKE should be the first T-verb
2 Take
2 Take Off
2 Talk to
3 Talk About
3 Tell about
2 Think about
2 Throw
3 Throw at
3 Throw in
3 Throw through
3 Throw to
2 Touch
2 Turn on
2 Turn off
! UP should be the first U-verb
1 Up
1 ULYSSES
3 Unlock with
2 Unplug
1 Unscript
2 Use
! VERBOSE should be the first V-verb
1 Verbose
1 Version
! WEST should be the first W-verb
1 West
1 Wait
2 Wash
2 Wave
2 Wear
1 Yell
2 Yell At
END_VOCABULARY
#DEFINE [Nowhere] 0
#DEFINE [Carried] 1
#DEFINE [WEST] 4
#DEFINE [Underground?] AtLocationGT [Funeral]
#DEFINE [Total number of treasures] 13
#DEFINE [Is a treasure?] NOUNPointsGT 4
MAXIMUM_SCORE 160
COMMAND SAY
PrintMessage "Go ahead, just spit it out! There is no need to say 'SAY'!"
DoneWithTurn
END_COMMAND
ROOM [Inside House]
Inside House
EAST [East of House]
DOWN [Smelly Cellar]
END_ROOM
ROOM_DESCR [Inside House]
You are inside of the house, which seems very beaten down. There is a smashed
window leading to the east (probably broken by a baseball).
END_ROOM_DESCR
NOUN [Window]
Window
Broken
There is a broken window.
LOCATION [NoWhere]
NOUN_SYNONYMS house peace hello hi
END_NOUN
NOUN [Closed Trapped Door]
Door
Trapped
There is a closed trapped door here.
UNMOVABLE
LOCATION [Inside House]
NOUN_SYNONYMS gate
END_NOUN
NOUN_DESCR [Closed Trapped Door]
The door is trapped and closed.
END_NOUN_DESCR
NOUN [Open Trap Door]
Door
Trap
There is a open trap door here, which leads down to a smelly cellar.
UNMOVABLE
LOCATION [Nowhere]
END_NOUN
NOUN_DESCR [Open Trap Door]
The trap door is open. You can see and smell a cellar below the trap door.
END_NOUN_DESCR
COMMAND DOWN
InRoom [Closed Trapped Door]
PrintMessage "The door is trapped and closed -- so you can't go down."
DoneWithTurn
END_COMMAND
MESSAGE [It slams shut behind you]
You hear the sound of the door slamming shut behind you and the bolt being
locked in place. You are now trapped in the smelly cellar. No wonder, it was
called a 'trapped door'.
END_MESSAGE
COMMAND DOWN
InRoom [Open Trap Door]
PrintMessage [It slams shut behind you]
BlankLine
END_COMMAND
MESSAGE [It is now open]
Oh, sorry about that -- I meant to say 'trap' door! Anyway, it opens revealing
a plush carpeted stairway leading down into a smelly cellar.
END_MESSAGE
COMMAND OPEN DOOR
InRoom [Closed Trapped Door]
SwapLocations [Closed Trapped Door] [Open Trap Door]
PrintMessage [It is now open]
DoneWithTurn
END_COMMAND
COMMAND CLOSE DOOR
InRoom [Open Trap Door]
SwapLocations [Closed Trapped Door] [Open Trap Door]
PrintMessage "The door is now closed and trapped."
DoneWithTurn
END_COMMAND
TREASURE_ROOM [Inside House]
NOUN [Bank Vault]
Vault
Bank
There is an open bank vault here.
SIZE 1000
WEIGHT 1000
UNMOVABLE
LOCATION [Inside House]
CLOSABLE
OPEN
END_NOUN
NOUN_DESCR [Bank Vault]
The bank vault door is open. It looks like it is big enough to hold a lot of
treasures and other goodies (HINT HINT).
END_NOUN_DESCR
NOUN [Pork Guidebook]
Guidebook
PORK
You see a book entitled "PORK Guidebook".
SIZE 10
WEIGHT 10
LOCATION [Bank Vault]
READABLE
NOUN_SYNONYMS book hint hints
END_NOUN
NOUN_DESCR [Pork Guidebook]
The book is titled "PORK Guidebook". It has a subtitle: "The PORKer's Book of
Wit, Wisdom and Hints". It looks like it might be helpful.
END_NOUN_DESCR
FLAG [Has read AGT info]
COMMAND READ GUIDEBOOK
FlagOFF [Has read AGT info]
Present [Pork Guidebook]
PrintMessage [AGT Info]
TurnFlagON [Has read AGT info]
DoneWithTurn
END_COMMAND
COMMAND READ GUIDEBOOK
FlagON [Has read AGT info]
Present [Pork Guidebook]
RandomMessage [Funny Saying #1] [Funny Saying #29]
DoneWithTurn
END_COMMAND
MESSAGE [It is a reverse timelock]
Sorry, but you can't close the bank vault until yesterday morning (a reverse
timelock.) That's about -1000 turns away
END_MESSAGE
COMMAND CLOSE VAULT
InRoom [Bank Vault]
PrintMessage [It is a reverse timelock]
DoneWithTurn
END_COMMAND
NOUN [Table]
Table
Wooden
There is a wooden table against one wall.
UNMOVABLE
LOCATION [Inside House]
END_NOUN
NOUN_DESCR [Table]
The table is about 2 feet wide by about 6 feet long. It has been pushed
against one wall.
END_NOUN_DESCR
NOUN [Handgun]
Gun
Hand
There is a hand gun here.
SIZE 25
WEIGHT 25
LOCATION [Inside House]
CAN_SHOOT
NUM_SHOTS 1000
POSITION On the Table
NOUN_SYNONYMS revolver .22 handgun
END_NOUN
NOUN_DESCR [Handgun]
The hand gun appears to be a small .22, made for defense against evil people
who try to steal things from you (HINT HINT). It is old and dusty too.
A label reads `ACME Gun Company' on the side.
END_NOUN_DESCR
NOUN [Catsup]
Bottle
Catsup
You see a bottle of Catsup (or Ketchup -- if you prefer).
SIZE 10
WEIGHT 10
EDIBLE
DRINKABLE
LOCATION [Inside House]
POSITION On the Table
NOUN_SYNONYMS catsup ketchup
END_NOUN
NOUN_DESCR [Catsup]
The bottle is the giant-economy size. The label on the bottle proclaims:
"Genuine Generic -- Your Guarantee of Cheap Mediocrity".
END_NOUN_DESCR
NOUN [Rabbit's Foot]
Foot
Rabbit's
There is a giant rabbit's foot here.
SIZE 60
WEIGHT 60
LOCATION [Inside House]
POSITION On the Table
NOUN_SYNONYMS feet
END_NOUN
NOUN_DESCR [Rabbit's Foot]
The foot looks like it came from a mighty BIG rabbit. I would sure hate to
run into the sucker who belongs with this foot!
END_NOUN_DESCR
MESSAGE [Rub it]
You $VERB$ the rabbit's foot for a while, but nothing happens.
END_MESSAGE
COMMAND RUB FOOT
Present [Rabbit's Foot]
PrintMessage [Rub it]
DoneWithTurn
END_COMMAND
ROOM [North of House]
North of House
EAST [East of House]
WEST [West of House]
END_ROOM
ROOM_DESCR [North of House]
You are north of the house. There is not much to see here, except maybe for
the house to the south. Paths lead east and west.
END_ROOM_DESCR
ROOM [West of House]
West of House
LOCKED_DOOR
NORTH [North of House]
SOUTH [South of House]
END_ROOM
ROOM_DESCR [West of House]
You are west of the house. The house has a boarded front door. Paths lead
north and south.
END_ROOM_DESCR
STARTING_ROOM [West of House]
NOUN [Mailbox]
Mailbox
Metal
A mailbox without a lid (which probably was take by vandals) is here.
SIZE 1000
WEIGHT 1000
UNMOVABLE
LOCATION [West of House]
CLOSABLE
OPEN
NOUN_SYNONYMS box
END_NOUN
NOUN_DESCR [Mailbox]
The mailbox looks quite ordinary, except for the fact that it is missing
its lid. There is a letter inside addressed to you.
END_NOUN_DESCR
NOUN [Letter]
Letter
small
There is a letter addressed to you.
SIZE 10
WEIGHT 10
LOCATION [Mailbox]
END_NOUN
NOUN_DESCR [Letter]
There is a letter addressed to you.
END_NOUN_DESCR
MESSAGE [It is a letter bomb]
But wait -- it is a letter bomb! It blows up immediately, and you are blasted
to tiny shreds. (Remember, no one said solving this adventure was going to be
easy or painless.)
END_MESSAGE
COMMAND GET LETTER
AtLocation [West of House]
PrintMessage [It is a letter bomb]
BlankLine
GoToRoom [Funeral]
DoneWithTurn
END_COMMAND
COMMAND READ LETTER
AtLocation [West of House]
PrintMessage [It is a letter bomb]
BlankLine
GoToRoom [Funeral]
DoneWithTurn
END_COMMAND
COMMAND GO HOUSE
AtLocation [West of House]
PrintMessage "You follow the path to the east side of the house."
BlankLine
GoToRoom [East of House]
DoneWithTurn
END_COMMAND
COMMAND ENTER HOUSE
AtLocation [West of House]
PrintMessage "You follow the path to the east side of the house."
BlankLine
GoToRoom [East of House]
DoneWithTurn
END_COMMAND
ROOM [East of House]
East of House
NORTH [North of House]
SOUTH [South of House]
EAST [Clearing]
WEST [Inside House]
END_ROOM
ROOM_DESCR [East of House]
You are east of the house. There is a house to the west (with a broken window
smashed by a baseball leading in), and paths to the north, south, and east.
END_ROOM_DESCR
ROOM [South of House]
South of House
EAST [East of House]
WEST [West of House]
SOUTH [Thick Woods]
END_ROOM
ROOM_DESCR [South of House]
You are south of the house. There is nothing of interest here, except for
the house and trails leading east, west and south.
In the distance, you can hear the chirping of a song bird.
END_ROOM_DESCR
ROOM [Thick Woods]
Thick woods
NORTH [South of House]
ROOM_SYNONYMS CHANGE_LOCATION CLIMB GO
KEY [Large trees]
SPECIAL [Top of Tree]
END_ROOM
ROOM_DESCR [Thick Woods]
You are in the midst of a thick woods. The ground is damp with dew. The
air is chilly and you shiver from the cold. The only path leads north --
back the way you came.
END_ROOM_DESCR
NOUN [Large trees]
trees
large
There are large trees here.
LOCATION [Thick Woods]
UNMOVABLE
PLURAL
NOUN_SYNONYMS TREE
END_NOUN
NOUN_DESCR [Large trees]
The trees are mostly large maples.
END_NOUN_DESCR
NOUN [Leaves]
Leaves
Lotsa
There are a lot of leaves on the ground all around you.
LOCATION [Thick Woods]
WEIGHT 2
SIZE 5
PLURAL
NOUN_SYNONYMS leave
END_NOUN
NOUN_DESCR [Leaves]
The leaves are mostly from maple trees. They are showing lots of fall colors.
Were you expecting something else, perhaps?
END_NOUN_DESCR
COMMAND BURN LEAVES
PrintMessage "A voice booms out, 'That would cause air pollution, turkey!!'"
DoneWithTurn
END_COMMAND
COMMAND NO
PrintMessage "You don't need to be so negative, turkey! It's just a game!"
DoneWithTurn
END_COMMAND
COMMAND YES
PrintMessage "You don't say! I wish I could be so positive!"
DoneWithTurn
END_COMMAND
SPECIAL [Top of Tree]
You struggle up branch by branch till you reach the tallest part of the tree.
END_SPECIAL
ROOM [Top of Tree]
Top of Tree
DOWN [Thick Woods]
ROOM_SYNONYMS DOWN CLIMB
END_ROOM
ROOM_DESCR [Top of Tree]
You are perched somewhat precariously on a limb near the top of a tall tree.
END_ROOM_DESCR
COMMAND JUMP
AtLocation [Top of Tree]
OR
AtLocation [Triangular Room]
OR
AtLocation [1st Level]
OR
AtLocation [2nd Level]
OR
AtLocation [3rd Level]
OR
AtLocation [4th Level]
PrintMessage "That is very dangerous. You could get killed doing that. Oops!"
GoToRoom [Funeral]
DoneWithTurn
END_COMMAND
NOUN [Bird's Nest]
Nest
Bird's
There is a bird's nest here.
LOCATION [Top of Tree]
WEIGHT 2
SIZE 5
CLOSABLE
OPEN
END_NOUN
NOUN_DESCR [Bird's Nest]
The nest is made of twigs and is fairly small.
END_NOUN_DESCR
NOUN [Golden Egg]
egg
golden
You see a golden egg.
LOCATION [Bird's Nest]
EDIBLE
POINTS 10
END_NOUN
NOUN_DESCR [Golden Egg]
The egg is made of gold. It is not very heavy, so it must be hollow. When
you shake it, you can hear something inside.
END_NOUN_DESCR
MESSAGE [You shake it]
Shake, rattle and egg roll!!
END_MESSAGE
COMMAND SHAKE EGG
Present [Golden Egg]
PrintMessage [You shake it]
DoneWithTurn
END_COMMAND
MESSAGE [Can't get the egg open]
No matter how hard you try or what tools you use, you can't get the #!$%!@ing
egg open.
END_MESSAGE
COMMAND OPEN EGG
Present [Golden Egg]
PrintMessage [Can't get the egg open]
DoneWithTurn
END_COMMAND
COMMAND UNLOCK EGG
Present [Golden Egg]
PrintMessage [Can't get the egg open]
DoneWithTurn
END_COMMAND
COMMAND BREAK EGG
Present [Golden Egg]
PrintMessage [Can't get the egg open]
DoneWithTurn
END_COMMAND
ROOM [Clearing]
Clearing
SOUTH [Dangerous Cliff]
WEST [East of House]
END_ROOM
ROOM_DESCR [Clearing]
You are in a clearing in a petrified forest. Petrified trees stand all
around. You know, these trees had a wild party this morning, and now they're
all stoned, along with my pet rock. You really should have been there.
END_ROOM_DESCR
MESSAGE [Trees are stoned]
The trees are all too stoned to allow you to go that way.
END_MESSAGE
COMMAND NORTH
AtLocation [Clearing]
PrintMessage [Trees are stoned]
BlankLine
DoneWithTurn
END_COMMAND
COMMAND EAST
AtLocation [Clearing]
PrintMessage [Trees are stoned]
BlankLine
DoneWithTurn
END_COMMAND
COMMAND UP
AtLocation [Clearing]
PrintMessage [Trees are stoned]
BlankLine
DoneWithTurn
END_COMMAND
COMMAND DOWN
AtLocation [Clearing]
PrintMessage [Trees are stoned]
BlankLine
DoneWithTurn
END_COMMAND
ROOM [Dangerous Cliff]
Dangerous Cliff
NORTH [Clearing]
DOWN [Beautiful Canyon]
ROOM_SYNONYMS Down Scramble
END_ROOM
ROOM_DESCR [Dangerous Cliff]
You are at the top of a huge cliff, almost a whole 1000000000*10^.0000000001
feet down! Below, you can see the luscious canyon, with all of its wildlife
dying off because of adventurer pollution. You can go to the north, or
scramble down the cliff with massive effort.
END_ROOM_DESCR
ROOM [Beautiful Canyon]
Beautiful Canyon
NORTH [Rainbow]
UP [Dangerous Cliff]
ROOM_SYNONYMS Up Scramble
END_ROOM
ROOM_DESCR [Beautiful Canyon]
You are at the bottom of the cliff, in a beautiful canyon. However, when you
arrive, all the dead animals flee from your horrid face. This makes you sad,
for you were in the mood for some good cruelty to animals. You can scramble
backup the cliff, or go north to see a rainbow. There is something shining
in the sun light at the end of the rainbow. It looks like a pot of some kind.
END_ROOM_DESCR
MESSAGE [Too far away]
Sorry, but the $NOUN$ is too far away to $VERB$.
END_MESSAGE
COMMAND GET POT
AtLocation [Beautiful Canyon]
NOT Present [Mary Jane]
PrintMessage [Too far away]
DoneWithTurn
END_COMMAND
COMMAND EXAMINE POT
AtLocation [Beautiful Canyon]
NOT Present [Mary Jane]
PrintMessage [Too far away]
DoneWithTurn
END_COMMAND
FLAG [Has Rainbow Bonus]
MESSAGE [Get Rainbow Bonus]
I am really glad you decided to leave the rainbow alone. We all know how
sissy they are (oops - bad choice of words. Sorry if I offended you.)
Anyway, I'm giving you 5 points because you avoided the rainbow!
END_MESSAGE
COMMAND UP
AtLocation [Beautiful Canyon]
NOT FlagON [Has Rainbow Bonus]
PrintMessage [Get Rainbow Bonus]
BlankLine
TurnFlagON [Has Rainbow Bonus]
PlusScore 5
END_COMMAND
COMMAND GO RAINBOW
AtLocation [Beautiful Canyon]
BlankLine
GoToRoom [Rainbow]
DoneWithTurn
END_COMMAND
COMMAND SEARCH RAINBOW
AtLocation [Beautiful Canyon]
BlankLine
GoToRoom [Rainbow]
DoneWithTurn
END_COMMAND
COMMAND EXAMINE RAINBOW
AtLocation [Beautiful Canyon]
BlankLine
GoToRoom [Rainbow]
DoneWithTurn
END_COMMAND
NOUN [Rainbow NOUN]
Rainbow
Pretty
There is rainbow here.
LOCATION [Nowhere]
END_NOUN
NOUN [Mary Jane]
Pot
Fine
There is a pot full of pot here. It looks mighty fine.
SIZE 20
WEIGHT 20
LOCATION [Nowhere]
EDIBLE
POISONOUS
POINTS 10
NOUN_SYNONYMS Drugs drug dope reefer joint
END_NOUN
VARIABLE [Joints Left]
NOUN_DESCR [Mary Jane]
The pot looks real, probably grown in someone's back yard. The pot it is in
used to be used to carry gold, until it got promoted.
There are #VAR[Joints Left]# joints left.
END_NOUN_DESCR
MESSAGE [Wave money message]
As you wave the bill, a man in a trench coat walks up to you and sets down a
pot of pot. He says for you to pay him later. Before you can ask any
questions, he disappears into a crowd (don't ask me how!)
END_MESSAGE
COMMAND WAVE MONEY
Present [$500 bill]
AtLocation [Beautiful Canyon]
PrintMessage [Wave money message]
DropIt [Mary Jane]
DoneWithTurn
END_COMMAND
COMMAND WAVE ANY
PrintMessage "Nothing happens. (Oh well, you know how it is in this business.)"
DoneWithTurn
END_COMMAND
ROOM [Rainbow]
Rainbow
KillPlayer
END_ROOM
ROOM_DESCR [Rainbow]
You decide to climb the rainbow, and avoid the elevator. As you go up, you
feel really happy and are glad you came this way. Then, you even see Ronald
McDonald doing a commercial. But then - Grimace steps on the rainbow! It
collapses!
END_ROOM_DESCR
ROOM [Funeral]
Funeral
KillPlayer
END_ROOM
ROOM_DESCR [Funeral]
You find yourself at a funeral -- yours!!
A giant Grue is talking... 'Dearly behated, we are gathered here today to have
a party, for the so-called adventurer of PORK had died. I'm sure he'll hate
us for celebrating his death, but still it's a good excuse to party.'
END_ROOM_DESCR
ROOM [Smelly Cellar]
Smelly Cellar
NORTH [By Sumo Room]
UP [Inside House]
LOCKED_DOOR
END_ROOM
ROOM_DESCR [Smelly Cellar]
You are in the cellar of the house. It really reeks down here. The walls are
bare. There is a passage leading north (where the reek is coming from).
Besides smelling awful, the northern passage looks quite dark and foreboding.
Stairs lead up to a 'trapped' door.
END_ROOM_DESCR
NOUN [Headache]
Headache
Excedrin
UNMOVABLE
LOCATION [Nowhere]
END_NOUN
NOUN_DESCR [Headache]
Oh .... oh.... your head hurts....oh....
END_NOUN_DESCR
MESSAGE [Use your head]
You race up the stairs at top speed. Using you head as a battering ram, you
finally break open the trap door. However, bashing your head against the door
has given you Excedrin headache #47.
END_MESSAGE
COMMAND BREAK DOOR
AtLocation [Smelly Cellar]
ReDirectTo UP
END_COMMAND
COUNTER [Turns with headache]
COMMAND UP
AtLocation [Smelly Cellar]
PrintMessage [Use your head]
SendToRoom [headache] [carried]
TurnCounterON [Turns with headache]
BlankLine
GoToRoom [Inside House]
DoneWithTurn
END_COMMAND
MESSAGE [You have to be kidding!]
You have to be kidding! That is ridiculous!
END_MESSAGE
COMMAND DROP HEADACHE
IsCarrying [Headache]
PrintMessage [You have to be kidding!]
DoneWithTurn
END_COMMAND
NOUN [Brass unlit lantern]
lantern
brass
There is a shiny brass lamp nearby. It is off.
NOUN_SYNONYMS lamp light
LOCATION [Smelly Cellar]
WEIGHT 10
END_NOUN
NOUN_DESCR [Brass unlit lantern]
The lamp runs on batteries and is currently turned off.
END_NOUN_DESCR
MESSAGE [Batteries don't work]
Sorry, but these batteries are too old and too corroded to be of much use.
END_MESSAGE
COMMAND INSERT BATTERIES
Present [Batteries]
PrintMessage [Batteries don't work]
DoneWithTurn
END_COMMAND
COMMAND PUT BATTERIES IN LANTERN
Present [Batteries]
PrintMessage [Batteries don't work]
DoneWithTurn
END_COMMAND
NOUN [Shining lantern]
lantern
shining
There is a lamp shining nearby.
NOUN_SYNONYMS lamp light
WEIGHT 10
END_NOUN
NOUN_DESCR [Shining lantern]
The lamp runs on batteries and is currently turned on. It is shining
brightly.
END_NOUN_DESCR
MESSAGE [Your lamp is growing weaker]
The batteries in your lamp are growing weaker. They will only last for #VAR[Battery Life]#
more turns!
END_MESSAGE
MESSAGE [Your batteries are dead]
Sorry, but your batteries are dead and there is no way to turn on the lamp.
You could be in real trouble!
END_MESSAGE
MESSAGE [You have no source of light]
Sorry, but you have no source of light!
END_MESSAGE
MESSAGE [Your lamp is now on]
Your lamp is now shining brightly!
END_MESSAGE
MESSAGE [Your lamp is now off]
Your lamp is now off.
END_MESSAGE
MESSAGE [Wrong adventure]
Rubbing the electric lamp is not particularly rewarding. Anyway, nothing
exciting happens. I think you must be thinking about some other adventure.
END_MESSAGE
MESSAGE [Give hint about batteries]
Your lamp is getting dim. You'd best start wrapping this up, unless you can
find some fresh batteries. I seem to recall there's a vending machine in the
maze. Bring some coins with you.
END_MESSAGE
MESSAGE [Your lamp has gone out]
Your lamp has run out of power.
END_MESSAGE
MESSAGE [No light - let's call it a day]
There's not much point in just wandering around aimlessly, and you can't
explore the cave without a working lamp. So let's just call it a day. Better
luck next time!
END_MESSAGE
FLAG [Lamp is ON]
VARIABLE [Battery Life]
;EXTINGUISH
COMMAND EXTINGUISH LAMP
Present [Brass unlit lantern]
PrintMessage [Your lamp is now off]
DoneWithTurn
END_COMMAND
COMMAND EXTINGUISH LAMP
Present [Shining lantern]
PrintMessage [Your lamp is now off]
TurnFlagOFF [Lamp is ON]
SwapLocations [Shining lantern] [Brass unlit lantern]
DoneWithTurn
END_COMMAND
COMMAND RUB LAMP
Present [Shining lantern]
OR
Present [Brass unlit lantern]
PrintMessage [Wrong adventure]
DoneWithTurn
END_COMMAND
;LIGHT
COMMAND LIGHT LAMP
Present [Shining lantern]
PrintMessage [Your lamp is now on]
DoneWithTurn
END_COMMAND
COMMAND LIGHT LAMP
NOT Present [Brass unlit lantern]
PrintMessage [You have no source of light]
DoneWithTurn
END_COMMAND
COMMAND LIGHT LAMP
Present [Brass unlit lantern]
VariableGT [Battery Life] 0
PrintMessage [Your lamp is now on]
TurnFlagON [Lamp is ON]
SwapLocations [Shining lantern] [Brass unlit lantern]
DoneWithTurn
END_COMMAND
COMMAND LIGHT LAMP
Present [Brass unlit lantern]
VariableEquals [Battery Life] 0
PrintMessage [Your batteries are dead]
DoneWithTurn
END_COMMAND
COMMAND TURN OFF LAMP
Present [Shining lantern]
ReDirectTo EXTINGUISH LAMP
END_COMMAND
COMMAND TURN ON LAMP
Present [Brass unlit lantern]
ReDirectTo LIGHT LAMP
END_COMMAND
ROOM [By Sumo Room]
Smelly Corridor
SOUTH [Smelly Cellar]
NORTH [Sumo Room]
LIGHT [Shining lantern]
END_ROOM
ROOM_DESCR [By Sumo Room]
You are in a smelly corridor. You see a faint light behind you to the south.
The passage to the north leads into darkness. A very strong odor is coming
from the north.
END_ROOM_DESCR
ROOM [Sumo Room]
Sumo Room
SOUTH [By Sumo Room]
EAST [E-W Passage]
WEST [Start of Polish Maze]
LIGHT [Shining lantern]
END_ROOM
ROOM_DESCR [Sumo Room]
You are in a large room that has pot holes all over it from a giant's
foot-steps. Besides a horrible reek of you here, there are passages leading
south, east and west.
END_ROOM_DESCR
CREATURE [Live Sumo]
Sumo
huge
There is a huge (10000 pound) sumo wrestler here!
LOCATION [Sumo Room]
HOSTILE
THRESHOLD 1000
TIME_THRESH 1000
MAN
CREATURE_SYNONYMS wrestler
END_CREATURE
CREATURE_DESCR [Live Sumo]
There is a huge (10000 pound) sumo wrestler here! He is (literally) blocking
all exits to the room.
END_CREATURE_DESCR
CREATURE [Dead Sumo]
Sumo
huge
In the corner, the sumo is sitting on himself. He is quite dead.
LOCATION [Nowhere]
MAN
CREATURE_SYNONYMS wrestler body
END_CREATURE
CREATURE_DESCR [Dead Sumo]
The sumo is sitting on himself -- which is quite a feat. He is dead.
END_CREATURE_DESCR
MESSAGE [Sumo blocking exits]
Come on, man -- you expect to do that with a 10000 pound sumo trying to crush
you? Be real!!
END_MESSAGE
COMMAND GET SUMO
Present [Live Sumo]
PrintMessage [You have to be kidding!]
DoneWithTurn
END_COMMAND
ROOM [Start of Polish Maze]
Start of Polish Maze
NORTH [Hippy Room]
SOUTH [Polish Maze]
EAST [Sumo Room]
WEST [Polish Maze]
UP [Polish Maze]
DOWN [Polish Maze]
ENTER [Polish Maze]
EXIT [Polish Maze]
LIGHT [Shining lantern]
END_ROOM
ROOM_DESCR [Start of Polish Maze]
You are in the beginning room in a Polish Maze. There is a passage to the
east (chicken!), a large passage to the north, and small crawlways leading in
all the other directions. A big sign over the north passage says, `Go this
way! Don't go anywhere else! Please! Go this way!'
Also, beyond the sign in the next room is a large greeting party, just waiting
for you to go north!!! Besides, the little crawlways look icky and ugly to
boot.
END_ROOM_DESCR
MESSAGE [Smart move!]
As you wisely decide to travel north, many telegrams from well wishers all over
the planet congratulate you on getting out of the Polish Maze. It's taken more
lives than the Royal Puzzle. Nice job.
END_MESSAGE
COMMAND NORTH
AtLocation [Start of Polish Maze]
PrintMessage [Smart move!]
END_COMMAND
ROOM [Polish Maze]
Polish Maze
NORTH [End of Polish Maze]
SOUTH [Polish Maze]
EAST [Polish Maze]
WEST [Polish Maze]
UP [Polish Maze]
DOWN [Polish Maze]
ENTER [Polish Maze]
EXIT [Polish Maze]
LIGHT [Shining lantern]
END_ROOM
ROOM_DESCR [Polish Maze]
You are in a little room in a Polish Maze. There is a large passageway
leading north. There are little crawlways leading off in all other
directions. It looks like you will never get out of here. (I told you not to
go in here. Maybe next time, you'll listen.)
END_ROOM_DESCR
NOUN [Polish Maze Sign]
Sign
Large
There is a large sign on the wall.
UNMOVABLE
LOCATION [Polish Maze]
READABLE
NOUN_SYNONYMS writing statue berez joel idol idols
END_NOUN
NOUN_DESCR [Polish Maze Sign]
The sign is about 2 feet high by 3 feet wide. The writing is rather sloppy.
END_NOUN_DESCR
COMMAND READ SIGN
AtLocation [Polish Maze]
RandomMessage [Funny Saying #1] [Funny Saying #29]
DoneWithTurn
END_COMMAND
MESSAGE [You wander around for a while]
You wander around in the maze for a while and find yourself...
END_MESSAGE
ROOM [End of Polish Maze]
Escaped from the Polish Maze
NORTH [Hippy Room]
SOUTH [Polish Maze]
EAST [Polish Maze]
WEST [Polish Maze]
UP [Polish Maze]
DOWN [Polish Maze]
ENTER [Polish Maze]
EXIT [Polish Maze]
LIGHT [Shining lantern]
END_ROOM
ROOM_DESCR [End of Polish Maze]
You have escaped from the Polish Maze. There is a large passage to the north,
and small crawlways leading in all the other directions. A big sign over the
north passage says, `Go this way! Don't go anywhere else! Please! Go this
way!'
END_ROOM_DESCR
ROOM [Hippy Room]
Hippy Room
SOUTH [Start of Polish Maze]
UP [Tax Collector's Lair]
LIGHT [Shining lantern]
END_ROOM
ROOM_DESCR [Hippy Room]
You are in a room with wild paintings on the wall, filled with flowers. The
atmosphere is very free and wild. There are stairs leading up, and a passage
that goes south into a huge maze.
END_ROOM_DESCR
CREATURE [Normal Hippy]
Hippy
Peaceful
There is a hippy guarding the stairway, who constantly chants "Peace!"
LOCATION [Hippy Room]
MAN
END_CREATURE
CREATURE_DESCR [Normal Hippy]
The hippy is constantly chanting "Peace!" He has a string of "love beads" and
is holding a bunch of scraggly flowers.
END_CREATURE_DESCR
CREATURE [Wasted Hippy]
Hippy
Wasted
There is a hippy here, who is really wasted and can't even say "Peace!"
LOCATION [Nowhere]
MAN
END_CREATURE
CREATURE_DESCR [Wasted Hippy]
There is a hippy here, who is really wasted and can't even say "Peace!" He has
a string of "love beads" and is smelling a bunch of scraggly flowers.
END_CREATURE_DESCR
MESSAGE [Hippy blocking UP]
The hippy won't let you pass. He shoves a flower in your face -- which you
reject.
END_MESSAGE
COMMAND UP
InRoom [Normal Hippy]
PrintMessage [Hippy blocking UP]
DoneWithTurn
END_COMMAND
MESSAGE [Attack Hippy message]
You get ready to perform the violent act, but just can't bring yourself to do
it against this peace lover.
END_MESSAGE
COMMAND ATTACK HIPPY
InRoom [Normal Hippy]
OR
InRoom [Wasted Hippy]
PrintMessage [Attack Hippy message]
DoneWithTurn
END_COMMAND
COMMAND SHOOT HIPPY
InRoom [Normal Hippy]
OR
InRoom [Wasted Hippy]
PrintMessage [Attack Hippy message]
DoneWithTurn
END_COMMAND
MESSAGE [Hippy makes peace sign]
The hippy makes a 'peace' sign by extending both his fore finger and his middle
finger in the air. Then he lowers his fore finger.
END_MESSAGE
COMMAND PEACE
InRoom [Normal Hippy]
OR
InRoom [Wasted Hippy]
PrintMessage [Hippy makes peace sign]
DoneWithTurn
END_COMMAND
COMMAND PEACE
PrintMessage "OK, $VERB$ to you, too!"
DoneWithTurn
END_COMMAND
COMMAND GIVE POT TO HIPPY
Present [Mary Jane]
InRoom [Normal Hippy]
PrintMessage "The hippy gratefully takes the pot, and starts to smoke it."
SwapLocations [Normal Hippy] [Wasted Hippy]
DoneWithTurn
END_COMMAND
COMMAND GIVE POT TO HIPPY
NOT Present [Mary Jane]
InRoom [Normal Hippy]
PrintMessage "You don't even have any pot, bucko!?"
DoneWithTurn
END_COMMAND
COMMAND GIVE POT TO HIPPY
Present [Mary Jane]
InRoom [Wasted Hippy]
PrintMessage "The hippy is already high. Any higher and he'll be on the moon."
DoneWithTurn
END_COMMAND
ROOM [Tax Collector's Lair]
Tax Collector's Lair
DOWN [Hippy Room]
LIGHT [Shining lantern]
END_ROOM
ROOM_DESCR [Tax Collector's Lair]
You are in the lair of a bad-breath breathing tax collector. Lying around the
room are huge piles of papers, bills, and old tax forms. You can leave by
going down.
END_ROOM_DESCR
NOUN [Tax Exemption Form]
Form
Exemption
There is a `One-Hour Tax exemption' form here.
SIZE 20
WEIGHT 20
LOCATION [Tax Collector's Lair]
READABLE
POINTS 10
NOUN_SYNONYMS FORMS
END_NOUN
NOUN_DESCR [Tax Exemption Form]
The form says this: `Tax exemption for one hour.' It may be used wherever tax
exemption forms are honored, except in all countries where adventurers exist.
To redeem this form, take it to...
END_NOUN_DESCR
TEXT [Tax Exemption Form]
The form says, `Tax exemption for one hour.'
END_TEXT
CREATURE [Tax Collector]
Collector
Tax
There is a mean, cruel, sadistic tax collector here!
LOCATION [Tax Collector's Lair]
HOSTILE
THRESHOLD 1000
TIME_THRESH 1000
MAN
CREATURE_SYNONYMS MAN
END_CREATURE
CREATURE_DESCR [Tax Collector]
The tax collector has very bad breath and looks mean, cruel, and sadistic.
All in all, he is not a pleasant fellow.
END_CREATURE_DESCR
CREATURE [Dead Tax Collector]
Collector
Tax
The body of the mean tax collector is buried under a huge pile of papers.
LOCATION [Nowhere]
MAN
CREATURE_SYNONYMS body man
END_CREATURE
CREATURE_DESCR [Dead Tax Collector]
The body of a mean, cruel sadistic tax collector is here, buried under a huge
pile of papers. He is very dead!
END_CREATURE_DESCR
MESSAGE [You'll get taxed]
Do you really expect to do that without being taxed? Come on now!
END_MESSAGE
COMMAND HELP
Present [Tax Collector]
PrintMessage [You'll get taxed]
DoneWithTurn
END_COMMAND
COMMAND GET
Present [Tax Collector]
PrintMessage [You'll get taxed]
DoneWithTurn
END_COMMAND
COMMAND SAVE
Present [Tax Collector]
PrintMessage [You'll get taxed]
DoneWithTurn
END_COMMAND
COMMAND INVENTORY
Present [Tax Collector]
PrintMessage [You'll get taxed]
DoneWithTurn
END_COMMAND
COMMAND LIST EXITS
Present [Tax Collector]
PrintMessage [You'll get taxed]
DoneWithTurn
END_COMMAND
COMMAND TAKE FORM
Present [Tax Collector]
PrintMessage "You don't really want those -- believe me!"
DoneWithTurn
END_COMMAND
ROOM [E-W Passage]
E-W Passage
EAST [Junction]
WEST [Sumo Room]
LIGHT [Shining lantern]
END_ROOM
ROOM_DESCR [E-W Passage]
You are in an East-West passage. There is a large sign here that says `Get a
piece of the rock' - but you, puzzled, can't see any rock here.
END_ROOM_DESCR
NOUN [Batteries]
Batteries
Dead
There are some dead batteries here. They look very old and are corroded.
NOUN_SYNONYMS battery
LOCATION [E-W Passage]
WEIGHT 5
SIZE 5
END_NOUN
NOUN_DESCR [Batteries]
They still look very old and corroded.
END_NOUN_DESCR
ROOM [Junction]
Junction
NORTH [Lake Shore]
SOUTH [North LONG Corridor]
EAST [Loud Room With Band]
WEST [E-W Passage]
LIGHT [Shining lantern]
END_ROOM
ROOM_DESCR [Junction]
You are at the junction of four corridors. An ad on the wall reads `Buy your
new solar powered lantern today! Never need batteries again!' There are
passages leading north, south, east, and west. There seems to be a VERY long
corridor to the south, and from the east you can hear a horrible noise, like
someone torturing a cow.
END_ROOM_DESCR
VARIABLE [matches left]
NOUN [matches]
Matches
Wooden
There are some matches here.
SIZE 5
WEIGHT 5
LOCATION [Junction]
PLURAL
NOUN_SYNONYMS match
END_NOUN
NOUN_DESCR [matches]
The matches are just that. Wooden matches. Not long ones or fancy matches,
just plain old regular matches. There are #VAR[matches left]# matches.
END_NOUN_DESCR
COMMAND EXAMINE MATCHES
VariableEquals [matches left] 1
PrintMessage "There is only one match left. Don't waste it!"
DoneWithTurn
END_COMMAND
ROOM [North LONG Corridor]
LONG Corridor
NORTH [Junction]
SOUTH [middle LONG Corridor]
LIGHT [Shining lantern]
END_ROOM
ROOM_DESCR [North LONG Corridor]
You are at the north end of a long corridor. The end is not visible to the
south. You can go south, further into the corridor, or north to the junction.
END_ROOM_DESCR
MESSAGE [North to Middle]
You set off on the long journey south, and walk for about an hour.
END_MESSAGE
COMMAND SOUTH
AtLocation [North LONG Corridor]
PrintMessage [North to Middle]
BlankLine
END_COMMAND
ROOM [Middle LONG Corridor]
LONG Corridor
NORTH [North LONG Corridor]
SOUTH [South LONG Corridor]
LIGHT [Shining lantern]
END_ROOM
ROOM_DESCR [Middle LONG Corridor]
You are in the middle of an extremely long corridor. It extends forever to
the north and to the south. Besides that, this place is pretty boring.
END_ROOM_DESCR
MESSAGE [Middle to South]
After a brief pause for rest, you set off to the south and travel for a while.
END_MESSAGE
COMMAND SOUTH
AtLocation [Middle LONG Corridor]
PrintMessage [Middle to South]
BlankLine
END_COMMAND
MESSAGE [Middle to North]
After a brief pause for rest, you set off to the north and travel for a while.
END_MESSAGE
COMMAND NORTH
AtLocation [Middle LONG Corridor]
PrintMessage [Middle to North]
BlankLine
END_COMMAND
ROOM [South LONG Corridor]
LONG Corridor
NORTH [Middle LONG Corridor]
SOUTH [Mirror Room]
LIGHT [Shining lantern]
END_ROOM
ROOM_DESCR [South LONG Corridor]
You are at the south end of the monstrous corridor. This is a really boring
place, because hardly anyone has the persistence necessary to walk the entire
corridor. The corridor looms to the north, and a room lies to the south.
END_ROOM_DESCR
NOUN [Tennis Shoes]
Shoes
Tennis
There are some old, ugly, dirty tennis shoes here.
WEARABLE
LOCATION [South LONG Corridor]
NOUN_SYNONYMS shoe
PLURAL
END_NOUN
NOUN_DESCR [Tennis Shoes]
The tennis shoes are very old and quite ugly and dirty. You would not be
caught dead in them (HINT HINT). You can just make out the brand-name
'Non-Skid'.
END_NOUN_DESCR
MESSAGE [South to Middle]
You muster up all the strength you have, and begin the long journey to the
north.
END_MESSAGE
COMMAND NORTH
AtLocation [South LONG Corridor]
PrintMessage [South to Middle]
BlankLine
END_COMMAND
ROOM [Mirror Room]
Mirror Room
NORTH [South LONG Corridor]
EAST [Worship Room]
SOUTH [Small Room]
LIGHT [Shining lantern]
END_ROOM
ROOM_DESCR [Mirror Room]
You are in a room, with a huge mirror covering the south wall. It is really
nice and shiny. There are passages to the north, the end not visible, and to
the east.
END_ROOM_DESCR
NOUN [broken mirror]
mirror
broken
The mirror is shattered, revealing a southern passage behind it.
UNMOVABLE
LOCATION [nowhere]
NOUN_SYNONYMS glass piece pieces
END_NOUN
NOUN_DESCR [broken mirror]
The mirror is shattered into a zillion pieces. Behind the biggest pieces, you
can see a passage to the south.
END_NOUN_DESCR
COMMAND SOUTH
AtLocation [mirror room]
NOT InRoom [broken mirror]
PrintMessage "Sorry, but you can't go that way."
DoneWithTurn
END_COMMAND
MESSAGE [Mirror Breaks]
As you look into the mirror, the mirror shatters into a zillion pieces. Behind
the biggest pieces, you can see a passage to the south.
END_MESSAGE
COMMAND EXAMINE MIRROR
AtLocation [mirror room]
NOT InRoom [Broken mirror]
DropIt [broken mirror]
PrintMessage [Mirror breaks]
DoneWithTurn
END_COMMAND
COMMAND RUB MIRROR
AtLocation [mirror room]
PrintMessage "What are you some kind of weirdo?? How kinky can you get?"
DoneWithTurn
END_COMMAND
COMMAND BREAK MIRROR
AtLocation [mirror room]
PrintMessage "What are you some kind of weirdo?? That's bad luck!"
DoneWithTurn
END_COMMAND
ROOM [Small Room]
Small Room
NORTH [Mirror Room]
EAST [Bat Room]
WEST [Cyclops Room]
LIGHT [Shining lantern]
END_ROOM
ROOM_DESCR [Small Room]
You are in an empty, small room. The shattered mirror passage leads to the
north, and another rooms lie to the east and west.
END_ROOM_DESCR
ROOM [Cyclops Room]
Cyclops Room
EAST [Small Room]
UP [Wash Room]
LIGHT [Shining lantern]
END_ROOM
ROOM_DESCR [Cyclops Room]
This is a very messy room. There are bloodstains on the walls. There is an
exit to the east and stairs leading up.
END_ROOM_DESCR
NOUN [Cyclops Sign]
Sign
Bloodstained
There is a large bloodstained sign on the west wall.
UNMOVABLE
LOCATION [Cyclops Room]
READABLE
NOUN_SYNONYMS writing
END_NOUN
NOUN_DESCR [Cyclops Sign]
The sign is quite bloodstained. The writing is rather small and hard to read.
END_NOUN_DESCR
TEXT [Cyclops Sign]
As everyone knows from Greek mythology or from reading Homer's Odyssey, the
original cyclops was killed by Ulysses. The original cyclops that Ulysses
slew was this cyclops' father and this one is scared to death of the mere
thought of ULYSSES (HINT HINT).
END_TEXT
COMMAND READ SIGN
AtLocation [Cyclops Room]
Present [Drunk Cyclops]
RandomMessage [Funny Saying #1] [Funny Saying #29]
DoneWithTurn
END_COMMAND
CREATURE [Live Cyclops]
Cyclops
mutant
There is a mutant cyclops in the center of the room.
LOCATION [Cyclops Room]
HOSTILE
THRESHOLD 1000
TIME_THRESH 1000
MAN
CREATURE_SYNONYMS beast mutant
END_CREATURE
CREATURE_DESCR [Live Cyclops]
For a cyclops, this one is horribly deformed and is obviously a mutant. He
has two baby-blue eyes -- one on each side of his nose. With those
baby-blues, he looks just like Paul Newman. He eyes you (with both eyes)
hungrily and licks his lips. He smiles and says, "You're just in time for
dinner!"
END_CREATURE_DESCR
CREATURE [Drunk Cyclops]
Cyclops
drunk
The cyclops is snoring peacefully in the corner of the room.
LOCATION [Nowhere]
MAN
CREATURE_SYNONYMS beast body
END_CREATURE
CREATURE_DESCR [Drunk Cyclops]
The cyclops is snoring peacefully in the corner of the room. He looks like he
will sleep for the rest of the game. Boy Oh Boy! Are you ever lucky!
END_CREATURE_DESCR
MESSAGE [Cyclops blocking exits]
Come on, man -- do you really expect that he is going to let you do that when
it is dinner time. Be real!!
END_MESSAGE
COMMAND GET CYCLOPS
AtLocation [Cyclops Room]
PrintMessage [You have to be kidding!]
DoneWithTurn
END_COMMAND
MESSAGE [Cyclops gets drunk]
As everyone knows from Greek mythology or from reading Homer's Odyssey, the
original cyclops was killed by Ulysses. The way that Ulysses killed the
cyclops was to give him wine to get him drunk and then he poked out the
cyclops' eye. You are not that violent, you just intended to get him drunk.
The cyclops sucks up some of the juice of the grape and then crawls over into
the corner of the room and goes to sleep,
END_MESSAGE
MESSAGE [Cyclops beats you senseless]
The cyclops laughs and asks, "Do you really think that I am dumb enough to be
afraid of a mere word like '$VERB$'? What kind of dummy do you think I am?"
At that point, the cyclops proceeds to beat you to a bloody pulp. Then he
leaves the room muttering something under his breath about "Some adventurers
are just too dumb to live to play again!"
After a very long time, you finally recover your strength. You discover that
the cyclops has reduced your score by 10 points (a stupidity penalty). Your
body and your ego are both bruised. However, you are alive.
END_MESSAGE
COMMAND ULYSSES
InRoom [Live Cyclops]
PrintMessage [Cyclops beats you senseless]
Destroy [Live Cyclops]
MinusScore 10
DoneWithTurn
END_COMMAND
COMMAND GIVE WINE TO CYCLOPS
Present [Wine]
InRoom [Live Cyclops]
PrintMessage [Cyclops gets drunk]
SwapLocations [Live Cyclops] [Drunk Cyclops]
DoneWithTurn
END_COMMAND
COMMAND GIVE POT TO ANY
Present [Mary Jane]
ObjectPresent
PrintMessage "The $OBJECT$ shows you his "Just Say NO" button!"
DoneWithTurn
END_COMMAND
ROOM [Wash Room]
Wash Room
NORTH [Grue's Lair]
DOWN [Cyclops Room]
LIGHT [Shining lantern]
END_ROOM
ROOM_DESCR [Wash Room]
You are in the 'Wash' room. There is a passage to the north and stairs
leading down.
END_ROOM_DESCR
NOUN [Washer]
Machine
Washing
Against the wall, there is a washing machine.
SIZE 100
WEIGHT 100
UNMOVABLE
LOCATION [Wash Room]
CLOSABLE
OPEN
OFF
TURNABLE
NOUN_SYNONYMS washer JulyTag
END_NOUN
NOUN_DESCR [Washer]
The washing machine is a "JulyTag" brand. It looks like it is broken.
END_NOUN_DESCR
TURN_DESCR [Washer]
You try to start the washing machine, but are unsuccessful.
END_TURN_DESCR
COMMAND FIX ANY
NOUNPresent
PrintMessage "Sorry, but you don't have the correct tools to fix the $NOUN$."
DoneWithTurn
END_COMMAND
NOUN [Coal]
Coal
Black
You see a piece of black coal here.
SIZE 20
WEIGHT 20
LOCATION [NoWhere]
POINTS 10
NOUN_SYNONYMS piece carbon lump
END_NOUN
NOUN_DESCR [coal]
The lump of coal is very clean (for a piece of coal, that is).
END_NOUN_DESCR
MESSAGE [Out pops a piece of coal]
You finally manage to turn on the washing machine. It wheerrs, bangs, bumps
and belches for a few moments and the diamond finally disappears from sight.
However, out of the bottom of the washing machine pops a lump of black coal.
The coal is quite shiny.
END_MESSAGE
COMMAND WASH DIAMOND
Present [Washer]
IsLocated [Diamond] [Washer]
PrintMessage [Out pops a piece of coal]
Destroy [Diamond]
DropIt [Coal]
DoneWithTurn
END_COMMAND
COMMAND WASH ANY
PrintMessage "Ha! Ha! Ha! The $NOUN$ isn't even dirty!"
DoneWithTurn
END_COMMAND
ROOM [Grue's Lair]
Grue's Lair
SOUTH [Wash Room]
END_ROOM
ROOM_DESCR [Grue's Lair]
You are in the lair of the infamous Grue. The walls of the room have a
strange iridescent glow. The only exit is to the south.
END_ROOM_DESCR
CREATURE [Grue]
Grue
Infamous
The infamous Grue is here. He seems rather timid, actually.
LOCATION [Grue's Lair]
MAN
GROUPMEMBER
CREATURE_SYNONYMS beast
END_CREATURE
CREATURE_DESCR [Grue]
The Grue is tiny creature -- no bigger than a small puppy. He licks your hand
and makes a noise that sounds somewhat like a cat purring. He likes you. As
you move around the room, he follows you about like a child. Aren't you
lucky?!
END_CREATURE_DESCR
MESSAGE [What a weird idea - Eat]
What a bizarre idea!! What are you -- some kind of weird cannibal?
END_MESSAGE
MESSAGE [What a weird idea - Kill]
You evil beast! How could you even think about $VERB$ing this sweet creature?
END_MESSAGE
MESSAGE [What a weird idea]
You have obviously developed a demented and distorted view of life. Probably
from playing too many adventure games. Perhaps, you should lay off those evil
things until you recover your senses and regain a more realistic perspective.
END_MESSAGE
COMMAND EAT GRUE
Present [Grue]
PrintMessage [What a weird idea - Eat]
PrintMessage [What a weird idea]
DoneWithTurn
END_COMMAND
COMMAND SHOOT GRUE
Present [Grue]
PrintMessage [What a weird idea - Kill]
PrintMessage [What a weird idea]
DoneWithTurn
END_COMMAND
COMMAND KILL GRUE
Present [Grue]
PrintMessage [What a weird idea - Kill]
PrintMessage [What a weird idea]
DoneWithTurn
END_COMMAND
COMMAND KISS GRUE
Present [Grue]
PrintMessage [What a weird idea - Kill]
PrintMessage [What a weird idea]
DoneWithTurn
END_COMMAND
FLAG [Has Patting Bonus]
MESSAGE [Pat him]
As you $VERB$ the Grue, he purrs softly and licks your hand.
END_MESSAGE
MESSAGE [Get Patting bonus]
For displaying such kindness to the infamous Grue, you get a 10 point bonus.
END_MESSAGE
COMMAND PAT GRUE
FlagOFF [Has Patting Bonus]
Present [Grue]
PrintMessage [Get Patting bonus]
PlusScore 10
TurnFlagON [Has Patting Bonus]
END_COMMAND
COMMAND PAT GRUE
Present [Grue]
PrintMessage [Pat him]
DoneWithTurn
END_COMMAND
ROOM [Bat Room]
Bat Room
SOUTH [Smelly Room]
WEST [Small Room]
LIGHT [Shining lantern]
END_ROOM
ROOM_DESCR [Bat Room]
You are in the bat room. Pictures of famous bats are hung in the room. There
is a passage to the west, but to the south it smells strongly of gas (not
fuel -- the other kind.)
END_ROOM_DESCR
NOUN [baseball bat]
Bat
Baseball
There is a large baseball bat here. It is autographed.
SIZE 20
WEIGHT 20
LOCATION [Bat Room]
READABLE
POINTS 10
END_NOUN
NOUN_DESCR [baseball bat]
The bat looks large and heavy, but awkward - a reject from last year's World
Series. It has a signature on it - `Ronald Reagan'.
END_NOUN_DESCR
TEXT [baseball bat]
The bat is an official 'Milpitas Slogger'. It is signed by `Ronald Reagan'.
END_TEXT
ROOM [Chili Contest]
Chili Contest
EAST [Wine Tasting Room]
UP [Smelly Room]
ROOM_SYNONYMS Eat Taste
LIGHT [Shining lantern]
END_ROOM
ROOM_DESCR [Chili Contest]
You are in the middle of a chili cooking and eating contest. There is a large
sign nailed to the west wall. There is a passage leading to the east.
END_ROOM_DESCR
NOUN [people]
people
lotsa
There are people milling around in small groups with bowls in their hands.
UNMOVABLE
LOCATION [Chili Contest]
PLURAL
NOUN_SYNONYMS person man woman porkers
END_NOUN
NOUN_DESCR [people]
The people are everywhere and are gobbling up bowl after bowl of chili and
really pigging out on it. A bunch of real PORKers!
END_NOUN_DESCR
MESSAGE [People ignore you]
The people just ignore you and continue eating their chili.
END_MESSAGE
COMMAND TALK TO PEOPLE
Present [People]
PrintMessage [People ignore you]
DoneWithTurn
END_COMMAND
COMMAND ASK PEOPLE
Present [People]
PrintMessage [People ignore you]
DoneWithTurn
END_COMMAND
NOUN [Chili Pot]
Chili
Hot
There is huge pot of bubbling chili in the center of the room.
SIZE 81
WEIGHT 81
LOCATION [chili Contest]
EDIBLE
POISONOUS
POINTS 10
NOUN_SYNONYMS food pot bowl bowls
END_NOUN
NOUN_DESCR [Chili Pot]
The pot is gigantic. It is bubbling furiously. The chili looks great. You
realize how long it has been since you last ate.
END_NOUN_DESCR
MESSAGE [Eat the chili]
You gobble up a couple of bowls. You really PORK out. It is great chili!
END_MESSAGE
MESSAGE [Let it rip]
After a while, you start to feel gaseous and you let a real smelly one rip
loose. Unfortunately, the gas is poisonous and even you are overcome by the
fumes. What a way to die!
END_MESSAGE
COMMAND EAT CHILI
Present [Chili Pot]
PrintMessage [Eat the chili]
PrintMessage [Let it rip]
BlankLine
GoToRoom [Funeral]
DoneWithTurn
END_COMMAND
COMMAND FART
Present [Chili Pot]
PrintMessage [Let it rip]
BlankLine
GoToRoom [Funeral]
DoneWithTurn
END_COMMAND
ROOM [Wine Tasting Room]
Wine Tasting Room
WEST [Chili Contest]
ROOM_SYNONYMS Drink Taste
LIGHT [Shining lantern]
END_ROOM
ROOM_DESCR [Wine Tasting Room]
You are in the wine tasting room. However, you notice that most of the
bottles are cheap, and aren't really that tasty. The only exit is to the west.
END_ROOM_DESCR
NOUN [wine]
Wine
Cheap
There are some bottles of some cheap wine here.
SIZE 20
WEIGHT 20
LOCATION [Wine Tasting Room]
READABLE
DRINKABLE
POISONOUS
PLURAL
NOUN_SYNONYMS bottles bottle label
POINTS 10
END_NOUN
NOUN_DESCR [wine]
The wine is a fine vintage from Jimmy Carter's own private grape fields,
in Plains, Georgia, made out of (censored), and mixed with (censored) to
produce a (censored) taste.
END_NOUN_DESCR
TEXT [wine]
According the mimeographed label, the wine is a fine vintage (specifically,
last Thursday) from Jimmy Carter's own private grape fields in Plains,
Georgia, made out of (censored), and mixed with (censored) to produce a
(censored) taste.
END_TEXT
ROOM [Smelly Room]
Smelly Room
NORTH [Bat Room]
DOWN [Chili Contest]
LIGHT [Shining lantern]
END_ROOM
ROOM_DESCR [Smelly Room]
You are in a small room, which smells amazingly bad. You can go north, or
descend to the source of the smell.
There is a large sign nailed to the east wall.
END_ROOM_DESCR
MESSAGE [No Smoking]
The sign reads: "Expiratory Distribution of Partially Ignited Hydrocarbons
into the Immediate Atmosphere Strictly Disallowed".
END_MESSAGE
COMMAND READ SIGN
AtLocation [Chili Contest]
OR
AtLocation [Smelly Room]
PrintMessage [No Smoking]
DoneWithTurn
END_COMMAND
ROOM [Worship Room]
Worship Room
SOUTH [Tomb]
WEST [Mirror Room]
LIGHT [Shining lantern]
END_ROOM
ROOM_DESCR [Worship Room]
You are in what is obviously a place of worship. There are idols of his royal
beingness Joel Berez and one large statue of him about the room. A very, very
religious aura seems to linger in the air. You'd have to pay me to come here.
You can leave this icky place by way of two passages, to the west and to the
south.
There is a large sign on the north wall.
END_ROOM_DESCR
MESSAGE [Commandment List]
It is a long list of commandments. There are many, many, many more than ten.
Your eyes scan the list and fall randomly on a commandment near the bottom of
the list.
You read...
COMMANDMENT #12592
Oh ye who write Adventure Games that torment the player with stupid puzzles:
Dost thou know the magnitude of thy sin before the gods? Yea, verily, thou
shalt be ground between two stones. Shall the angry gods cast thy body into
the whirlpool? Surely, thy eye shall be put out with a sharp stick! Even
unto the ends of the earth shalt thou wander and unto the land of the dead
shalt thou be sent at last. Surely thou shalt repent of thy low cunning.
You smile and nod your head in agreement and approval.
END_MESSAGE
COMMAND READ SIGN
AtLocation [Worship Room]
PrintMessage [Commandment List]
DoneWithTurn
END_COMMAND
MESSAGE [Now I lie (sic) me down to sleep]
You mumble the only prayer you know, 'Now I lie (sic) me down to sleep ... etc
... etc...'
The power of suggestion is obviously a very strong force with you, because you
soon fall sound asleep....
Time passes .... and finally you wake up, well rested and ready to resume your
adventure.
END_MESSAGE
COMMAND PRAY
PrintMessage [Now I lie (sic) me down to sleep]
END_COMMAND
MESSAGE [Someone steals treasures]
However, you are dismayed to discover that you have been robbed!
END_MESSAGE
COMMAND PRAY
IsCarryingTreasure 5
PrintMessage [Someone steals treasures]
SendTreasuresToRoom [Tax Collector's Lair] 4
END_COMMAND
COMMAND PRAY
DoneWithTurn
END_COMMAND
NOUN [Prayer Book]
Book
Prayer
There is a prayer book here.
SIZE 20
WEIGHT 20
LOCATION [Worship Room]
READABLE
POINTS 10
END_NOUN
NOUN_DESCR [Prayer Book]
The prayer book is a fairly large book, all black with pictures of human
sacrifices (they're playing computer adventure games.) Its title is
`201: A Sea Odyssey'
END_NOUN_DESCR
TEXT [Prayer Book]
You read for a little while, but get depressed and finally stop.
END_TEXT
VARIABLE [candles left]
NOUN [candles]
Candles
Wax
There are some wax candles here.
SIZE 10
WEIGHT 10
LOCATION [Worship Room]
PLURAL
NOUN_SYNONYMS candle
END_NOUN
NOUN_DESCR [candles]
The candles are just that. Wax candles. Not long ones or fancy candles,
just plain old regular candles. Every adventure game needs a light source
of some kind. Why should this game be any different???
There are #VAR[candles left]# candles.
END_NOUN_DESCR
COMMAND EXAMINE CANDLES
VariableEquals [candles left] 1
PrintMessage "There is only one candle left."
DoneWithTurn
END_COMMAND
ROOM [Tomb]
Tomb
NORTH [Worship Room]
LIGHT [Shining lantern]
END_ROOM
ROOM_DESCR [Tomb]
You are in the tomb of an Egyptian slave. In other words, there isn't anything
of any value. Even the body has been stolen. I guess you aren't the first one
here, buddy.
END_ROOM_DESCR
NOUN [$500 bill]
Money
Paper
There is a $500 dollar bill here.
SIZE 5
WEIGHT 5
LOCATION [Tomb]
NOUN_SYNONYMS bill
POINTS 10
END_NOUN
NOUN_DESCR [$500 bill]
The bill says $500 in each corner, has a picture of Joel Berez in the middle,
and is worth 500 dollars. How stupid can you get?
END_NOUN_DESCR
NOUN [Shovel]
Shovel
Long-handled
There is a long-handled shovel here.
SIZE 15
WEIGHT 15
LOCATION [Tomb]
NOUN_SYNONYMS spade
END_NOUN
NOUN_DESCR [Shovel]
The shovel is made of steel with a long handle.
END_NOUN_DESCR
ROOM [Sandy Beach]
Sandy Beach
SOUTH [Lake Shore]
LIGHT [Shining lantern]
END_ROOM
ROOM_DESCR [Sandy Beach]
You are on a large sandy beach. A path leads south to the lake shore.
END_ROOM_DESCR
NOUN [Large X]
X
Large
There is a large X painted on a spot in the sand.
UNMOVABLE
READABLE
LOCATION [Sandy Beach]
END_NOUN
NOUN_DESCR [Large X]
The X is about 3 feet square and painted black.
END_NOUN_DESCR
TEXT [Large X]
The X says 'X'. What did you expect, turkey?
END_TEXT
NOUN [Small Hole]
Hole
Small
A small hole has been dug in the sand.
UNMOVABLE
LOCATION [NoWhere]
END_NOUN
NOUN_DESCR [Small Hole]
The hole is circular and is about 4 feet deep and about 6 feet across.
END_NOUN_DESCR
NOUN [Large Hole]
Hole
Large
A large hole has been dug in the sand.
UNMOVABLE
LOCATION [NoWhere]
END_NOUN
NOUN_DESCR [Large Hole]
The hole is circular and is about 8 feet deep and about 12 feet across.
END_NOUN_DESCR
NOUN [Gigantic Hole]
Hole
Gigantic
A gigantic hole has been dug in the sand.
UNMOVABLE
LOCATION [NoWhere]
END_NOUN
NOUN_DESCR [Gigantic Hole]
The hole is circular and is 30 feet across. The bottom is far below.
END_NOUN_DESCR
MESSAGE [Don't have the proper tool]
Sorry, but you don't have the proper tool to do that.
END_MESSAGE
COMMAND DIG
NOT Present [Shovel]
PrintMessage [Don't have the proper tool]
DoneWithTurn
END_COMMAND
COMMAND DIG
AtLocation [Sandy Beach]
Present [Large X]
SwapLocations [Large X] [Small Hole]
PrintMessage "You manage to dig a small hole where the X was."
DoneWithTurn
END_COMMAND
COMMAND DIG
AtLocation [Sandy Beach]
Present [Small Hole]
SwapLocations [Large Hole] [Small Hole]
PrintMessage "The hole is now considerably bigger."
DoneWithTurn
END_COMMAND
COMMAND DIG
AtLocation [Sandy Beach]
Present [Large Hole]
SwapLocations [Large Hole] [Gigantic Hole]
PrintMessage "The hole is now gigantic."
DoneWithTurn
END_COMMAND
MESSAGE [You slip down the sandy side of the hole]
The sandy is very unstable and you lose your footing and tumble head over
heels to the bottom of the hole. You will never be able to climb back up
out of the hole.
END_MESSAGE
COMMAND DIG
AtLocation [Sandy Beach]
Present [Gigantic Hole]
GotoRoom [Bottom of hole]
PrintMessage [You slip down the sandy side of the hole]
DoneWithTurn
END_COMMAND
COMMAND DOWN
AtLocation [Sandy Beach]
Present [Gigantic Hole]
FlagOFF [Has dug in bottom of hole]
GotoRoom [Bottom of hole]
PrintMessage [You slip down the sandy side of the hole]
DoneWithTurn
END_COMMAND
COMMAND DOWN
AtLocation [Sandy Beach]
Present [Gigantic Hole]
FlagON [Has dug in bottom of hole]
GotoRoom [Shaft Room]
PrintMessage [You slip down the sandy side of the hole]
DoneWithTurn
END_COMMAND
COMMAND DOWN
Present [Small Hole]
OR
Present [Large Hole]
PrintMessage "You climb down into the hole -- then with great difficulty back up."
DoneWithTurn
END_COMMAND
ROOM [Bottom of Hole]
Bottom of Hole
LIGHT [Shining lantern]
ROOM_SYNONYMS UP CLIMB
END_ROOM
ROOM_DESCR [Bottom of Hole]
You are at the bottom of a very deep hole. The walls of the hole are loose
sand. It is impossible to climb out of the hole.
END_ROOM_DESCR
COMMAND UP
AtLocation [Bottom of Hole]
PrintMessage "You keep slipping back down. After a while, you give up."
DoneWithTurn
END_COMMAND
MESSAGE [You break through]
You begin to dig furiously in the sand. All of a sudden, your shovel breaks
through into empty space. The sand crumbles around the sides of the hole and
you fall into the hole. Fortunately, enough sand fell before you did to
cushion your fall as you land on a mound of sand.
END_MESSAGE
FLAG [Has dug in bottom of hole]
COMMAND DIG
AtLocation [Bottom of Hole]
GotoRoom [Shaft Room]
TurnFlagON [Has dug in bottom of hole]
PrintMessage [You break through]
DoneWithTurn
END_COMMAND
COMMAND DIG
NOT AtLocation [Bottom of Hole]
NOT AtLocation [Sandy Beach]
PrintMessage "The ground is too hard to dig."
DoneWithTurn
END_COMMAND
ROOM [Shaft Room]
Shaft Room
DOWN [Ladder Top]
ROOM_SYNONYMS DOWN CLIMB SLIDE
LIGHT [Shining lantern]
END_ROOM
ROOM_DESCR [Shaft Room]
You are standing on a mound of sand in the middle of a large cavernous room.
Far above, you can see a hole in the roof of the room, but it is too high
above you to reach. In the middle of the room is large shaft descending
through the floor into the darkness below. In the middle of that shaft is
another kind of shaft -- sort of like a 'Fire-house pole' -- that also
disappears into the darkness. The shaft appears to be the only exit from the
room.
END_ROOM_DESCR
NOUN [Shaft]
Shaft
brass
There is a shaft going down.
UNMOVABLE
LOCATION [Shaft Room]
NOUN_SYNONYMS pole sand ladder
END_NOUN
NOUN_DESCR [Shaft]
The shaft appears to made of brass. It has been smeared with some kind of
grease. It is the proverbial 'greased pole'. It would be very dangerous
to slide down this pole.
END_NOUN_DESCR
COMMAND GET SHAFT
PrintMessage [Leave it alone]
DoneWithTurn
END_COMMAND
COMMAND DOWN
AtLocation [Shaft Room]
NOT IsWearing [Tennis Shoes]
GoToRoom [Funeral]
PrintMessage "The pole is too slippery. You lose your grip and fall...."
DoneWithTurn
END_COMMAND
ROOM [Ladder Top]
Ladder Top
DOWN [Ladder Bottom]
ROOM_SYNONYMS UP CLIMB SLIDE
LIGHT [Shining lantern]
END_ROOM
ROOM_DESCR [Ladder Top]
This is a very small room. In the corner is a rickety wooden ladder, leading
downward. It might be safe to descend. In the other corner is a brass shaft
which disappears into the darkness above..
END_ROOM_DESCR
COMMAND UP
AtLocation [Ladder Top]
PrintMessage "The pole is too slippery to climb -- even with your tennis shoes."
DoneWithTurn
END_COMMAND
ROOM [Ladder Bottom]
Ladder Bottom
UP [Ladder Top]
EAST [Grating Room]
WEST [Rabbit's Warren]
ROOM_SYNONYMS UP CLIMB
LIGHT [Shining lantern]
END_ROOM
ROOM_DESCR [Ladder Bottom]
This is a rather wide room. In the corner is a rickety wooden ladder, leading
upward. To the east and west are passages leaving the room.
END_ROOM_DESCR
ROOM [Grating Room]
Grating Room
WEST [Ladder Bottom]
LIGHT [Shining lantern]
LOCKED_DOOR
END_ROOM
ROOM_DESCR [Grating Room]
This appears to be a dead end. The only exit is west, back the way you came.
END_ROOM_DESCR
NOUN [Grate]
Grate
Iron
Above you is an iron grate locked with a skull-and-crossbones lock.
UNMOVABLE
LOCATION [Grating Room]
CLOSABLE
CLOSED
LOCKABLE
LOCKED
KEY [Shaft]
NOUN_SYNONYMS grating bars lock
END_NOUN
NOUN_DESCR [Grate]
The grate is made from iron bars and is about 3 feet square. It is cemented
into place in the ceiling and is closed and locked. The lock has a
skull-and-crossbones design on it and is currently locked.
END_NOUN_DESCR
ROOM [Rabbit's Warren]
Rabbit's Warren
EAST [Ladder Bottom]
NORTH [Mine Room#1]
LIGHT [Shining lantern]
END_ROOM
ROOM_DESCR [Rabbit's Warren]
You are in a small room. There are two exits. To the east and to the north.
Above the north exit is a sign that reads 'Rabbit's Warren'. It sounds like
another one of those !@#$%^&*ing mazes.
END_ROOM_DESCR
CREATURE [Gigantic Rabbit]
Rabbit
Gigantic
There is a very angry, gigantic rabbit blocking the exit to the north.
LOCATION [Rabbit's Warren]
HOSTILE
THRESHOLD 1000
TIME_THRESH 1000
END_CREATURE
CREATURE_DESCR [Gigantic Rabbit]
The rabbit is huge. He rabbit is hobbling around using a cane, since he
appears to have lost one of his feet. It's loss has obviously left him in a
bad mood. He is quite angry and makes a number of very threatening gestures
to you.
END_CREATURE_DESCR
COMMAND NORTH
Present [Gigantic Rabbit]
PrintMessage "The rabbit won't let you pass. He hits you several times with his cane."
DoneWithTurn
END_COMMAND
MESSAGE [Rabbit beats you]
The rabbit is a quite a bit bigger and stronger than you are. He easily
counters you attack by repeatedly beating you over the head with his cane
before you can do him any damage.
END_MESSAGE
COMMAND ATTACK RABBIT
Present [Gigantic Rabbit]
PrintMessage [Rabbit beats you]
DoneWithTurn
END_COMMAND
COMMAND SHOOT RABBIT
Present [Gigantic Rabbit]
PrintMessage [Rabbit beats you]
DoneWithTurn
END_COMMAND
MESSAGE [Describe Cane]
The cane is about 3 feet long and made of ebony. It is quite sturdy. The
head of the cane is gold with various precious jewels. The rabbit is holding
be his side and occasionally shaking it at you.
END_MESSAGE
COMMAND EXAMINE CANE
Present [Gigantic Rabbit]
PrintMessage [Describe Cane]
DoneWithTurn
END_COMMAND
COMMAND GET CANE
Present [Gigantic Rabbit]
PrintMessage "Sorry, but the rabbit is not about to part with his cane."
DoneWithTurn
END_COMMAND
MESSAGE [Rabbit thanks you]
The rabbit is delighted that you have returned his foot. He puts it back
on to his hind leg and hops off into his warren. He leaves his cane behind.
END_MESSAGE
NOUN [Cane]
Cane
Jeweled
There is a jeweled cane here.
SIZE 10
WEIGHT 10
LOCATION [Nowhere]
POINTS 10
END_NOUN
NOUN_DESCR [Cane]
The cane is about 3 feet long and made of ebony. It is quite sturdy. The
head of the cane is gold with various precious jewels.
END_NOUN_DESCR
COMMAND GIVE FOOT TO RABBIT
Present [Gigantic Rabbit]
Present [Rabbit's Foot]
PrintMessage [Rabbit thanks you]
Destroy [Gigantic Rabbit]
Destroy [Rabbit's Foot]
DropIt [Cane]
DoneWithTurn
END_COMMAND
ROOM [Lake Shore]
Lake Shore
SOUTH [Junction]
NORTH [Sandy Beach]
EAST [Pitcher's Room]
ENTER [Pitcher's Room]
WEST [Diamond Mine Entrance]
ROOM_SYNONYMS EAST BOARD
LIGHT [Shining lantern]
END_ROOM
ROOM_DESCR [Lake Shore]
You are at a dock along a beautiful, but polluted, lake. Tied up to the dock
is a boat. You may enter the boat and cross the lake to the east (just use
E or EAST). To the south is a large room. To the west you see the entrance to a very
complex maze. There is a sandy beach to the north.
END_ROOM_DESCR
NOUN [boat]
Boat
Large
There is a large boat here (Invisible).
UNMOVABLE
LOCATION [Nowhere]
END_NOUN
NOUN_DESCR [boat]
There is a large boat here (Invisible).
END_NOUN_DESCR
MESSAGE [describe boat]
The boat is a very large yacht, with the name `Pork-Out' on the side. It is
not richly furnished or decorated, however, and it just takes dim adventurers
across places they can't walk through. Isn't that groovy???
END_MESSAGE
COMMAND EXAMINE BOAT
AtLocation [Lake Shore]
PrintMessage [describe boat]
DoneWithTurn
END_COMMAND
COMMAND FISH
AtLocation [Lake Shore]
PrintMessage "Be real, turkey! Just what kind of game to you think this is?"
DoneWithTurn
END_COMMAND
COMMAND GET BOAT
AtLocation [Lake Shore]
PrintMessage "Be real, turkey! Even you can't do that. It is too heavy!"
DoneWithTurn
END_COMMAND
MESSAGE [Use the boat]
You get in the boat and peacefully sail across the lake.
END_MESSAGE
MESSAGE [swim message]
You valiantly throw off your clothes and dive into the lake. However, you
suddenly remember you can't swim.
END_MESSAGE
COMMAND SWIM
AtLocation [Lake Shore]
PrintMessage [swim message]
BlankLine
GoToRoom [Funeral]
DoneWithTurn
END_COMMAND
COMMAND EAST
AtLocation [Lake Shore]
LoadWeightGT 50
PrintMessage "The boat's load is too heavy. It was built on a budget."
DoneWithTurn
END_COMMAND
COMMAND EAST
AtLocation [Lake Shore]
PrintMessage [Use the boat]
BlankLine
END_COMMAND
ROOM [Pitcher's Room]
Pitcher's Room
WEST [Lake Shore]
NORTH [Loser's Hall of Fame]
LIGHT [Shining lantern]
END_ROOM
ROOM_DESCR [Pitcher's Room]
You are in a room occupied by a crazed baseball pitcher. He is always
throwing the ball around, and you have no hope of getting to the north passage
without getting rid of him first. However, he is not that great of a pitcher
and even you can probably get a hit off of him easily. There is also a
passage to the west.
END_ROOM_DESCR
COMMAND WEST
AtLocation [Pitcher's Room]
PrintMessage [Use the boat]
END_COMMAND
MESSAGE [You'll get hit]
Sorry, but you can't get around him without getting hit by a pitched ball.
END_MESSAGE
COMMAND NORTH
AtLocation [Pitcher's Room]
PrintMessage [You'll get hit]
DoneWithTurn
END_COMMAND
MESSAGE [Swing bat message]
You swing at the ball, and hit it solidly. The line drive smashes the
pitcher's skull, and he slumps to the ground. Try to be a little more
accurate next time.
END_MESSAGE
COMMAND SWING BAT
Present [Baseball Bat]
AtLocation [Pitcher's Room]
PrintMessage [Swing bat message]
BlankLine
GoToRoom [Dead Pitcher's Room]
ChangePassageway [WEST] [Lake Shore]
DoneWithTurn
END_COMMAND
COMMAND SWING BAT
Present [Baseball Bat]
NOT AtLocation [Pitcher's Room]
PrintMessage "You fan the air ferociously, but only manage to tire yourself out."
DoneWithTurn
END_COMMAND
COMMAND SWING BAT
NOT Present [Baseball Bat]
PrintMessage "You do not have the necessary sports equipment."
DoneWithTurn
END_COMMAND
NOUN [baseball]
baseball
the
There is a baseball here.
LOCATION [Nowhere]
NOUN_SYNONYMS ball pitch
END_NOUN
NOUN_DESCR [baseball]
There is a baseball here.
END_NOUN_DESCR
COMMAND HIT BALL
ReDirectTo SWING BAT
END_COMMAND
ROOM [Dead Pitcher's Room]
Pitcher's Room
WEST [Lake Shore]
NORTH [Loser's Hall of Fame]
LIGHT [Shining lantern]
END_ROOM
ROOM_DESCR [Dead Pitcher's Room]
You are in a room, which used to home an insane baseball pitcher. He is lying
dead on the ground after some jerk hit the ball, and it killed him. You can
go to the west or to the north.
END_ROOM_DESCR
COMMAND WEST
AtLocation [Dead Pitcher's Room]
PrintMessage [Use the boat]
END_COMMAND
ROOM [Loser's Hall of Fame]
Loser's Hall of Fame
SOUTH [Dead Pitcher's Room]
LIGHT [Shining lantern]
END_ROOM
ROOM_DESCR [Loser's Hall of Fame]
You are in the Losers' Hall of Fame. There are pictures of great losers
everywhere, and you feel proud to be a loser. The only exit is back to the
south.
END_ROOM_DESCR
NOUN [Your Picture]
Portrait
Your
Your portrait is here.
SIZE 20
WEIGHT 20
LOCATION [Loser's Hall of Fame]
NOUN_SYNONYMS picture pic
POINTS 10
END_NOUN
NOUN_DESCR [Your Picture]
The portrait is too horrid to describe. To look at it would be worse than
suicide.
END_NOUN_DESCR
ROOM [Diamond Mine Entrance]
Entrance to Diamond Mine
NORTH [Mine Room#1]
EAST [Lake Shore]
LIGHT [Shining lantern]
END_ROOM
ROOM_DESCR [Diamond Mine Entrance]
You are near a hillside. There is a sign that says: 'Diamond Mine Entrance'.
There is also an arrow on the sign that points to a hole going north into the
hillside. To the east you can see a boat by a lake.
END_ROOM_DESCR
ROOM [Mine Room#1]
Inside Diamond Mine
NORTH [Mine Room#2]
LIGHT [Shining lantern]
END_ROOM
ROOM_DESCR [Mine Room#1]
You are lost in a maze of twisty little passages, all alike. However, you can
just make out some light seeping through the end of the tunnel to the north
(HINT HINT).
END_ROOM_DESCR
ROOM [Mine Room#2]
Inside Diamond Mine
NORTH [Mine Room#3]
EAST [Royal Chamber]
LIGHT [Shining lantern]
END_ROOM
ROOM_DESCR [Mine Room#2]
You are lost in a maze of twisty little passages, all alike. However, you can
just make out some light seeping through the end of the tunnel to the north
(HINT HINT). There is also an interesting-looking passage to the east.
END_ROOM_DESCR
NOUN [Diamond]
Diamond
Huge
There is a huge diamond here.
SIZE 15
WEIGHT 15
LOCATION [Mine Room#2]
NOUN_SYNONYMS jewel
END_NOUN
NOUN_DESCR [Diamond]
The diamond is quite large and looks very valuable.
END_NOUN_DESCR
ROOM [Royal Chamber]
Royal Chamber
WEST [Mine Room#2]
LOCKED_DOOR
LIGHT [Shining lantern]
END_ROOM
ROOM_DESCR [Royal Chamber]
You are small room that is richly decorated with beautiful golden furniture.
There is a passage to the west -- back the way you came.
END_ROOM_DESCR
NOUN [throne]
Throne
Golden
There is a golden throne-like chair in the center of the room.
UNMOVABLE
LOCATION [Royal Chamber]
NOUN_SYNONYMS furniture chair
END_NOUN
NOUN_DESCR [throne]
It looks like real gold. It must be worth a fortune!
END_NOUN_DESCR
NOUN [carpet]
Carpet
Persian
There is a beautiful Persian carpet on the floor.
SIZE 10
WEIGHT 10
LOCATION [Royal Chamber]
POINTS 10
NOUN_SYNONYMS rug
END_NOUN
NOUN_DESCR [carpet]
The carpet is about 6 feet square and was hand-made by some highly-skilled
craftspersons.
END_NOUN_DESCR
MESSAGE [There is nothing under the carpet]
There is nothing under the carpet. No trap doors! No secret passageways! No
treasures! Nothing! How unimaginative!! How dull!!
END_MESSAGE
COMMAND GET RUG
Present [carpet]
PrintMessage [There is nothing under the carpet]
BlankLine
END_COMMAND
COMMAND MOVE RUG
Present [carpet]
PrintMessage [There is nothing under the carpet]
BlankLine
END_COMMAND
COMMAND GET FROG
Present [Frog]
PrintMessage "The little beast hops away before you can get it."
DoneWithTurn
END_COMMAND
CREATURE [Frog]
Frog
Green
There is a small green frog hopping about the room.
LOCATION [Royal Chamber]
GROUPMEMBER
CREATURE_SYNONYMS beast kermit
END_CREATURE
CREATURE_DESCR [Frog]
The frog is quite small. It looks pretty-much like an ordinary frog -- sort of
like Kermit.
END_CREATURE_DESCR
COMMAND EAT FROG
Present [Frog]
PrintMessage [What a weird idea - Eat]
PrintMessage [What a weird idea]
DoneWithTurn
END_COMMAND
COMMAND SHOOT FROG
Present [Frog]
PrintMessage [What a weird idea - Kill]
PrintMessage [What a weird idea]
DoneWithTurn
END_COMMAND
COMMAND KILL FROG
Present [Frog]
PrintMessage [What a weird idea - Kill]
PrintMessage [What a weird idea]
DoneWithTurn
END_COMMAND
COMMAND PAT FROG
Present [Frog]
PrintMessage [What a weird idea - Kill]
PrintMessage [What a weird idea]
DoneWithTurn
END_COMMAND
COMMAND KISS FROG
Present [Frog]
PrintMessage [What a weird idea - Kill]
PrintMessage [What a weird idea]
DoneWithTurn
END_COMMAND
ROOM [Mine Room#3]
Inside Diamond Mine
NORTH [Mine Room#4]
LIGHT [Shining lantern]
END_ROOM
ROOM_DESCR [Mine Room#3]
You are lost in a maze of twisty little passages, all alike. However, you can
just make out some light seeping through the end of the tunnel to the north
(HINT HINT).
END_ROOM_DESCR
ROOM [Mine Room#4]
Inside Diamond Mine
NORTH [Mine Room#5]
LIGHT [Shining lantern]
END_ROOM
ROOM_DESCR [Mine Room#4]
You are lost in a maze of twisty little passages, all alike. However, you can
just make out some light seeping through the end of the tunnel to the north
(HINT HINT).
END_ROOM_DESCR
NOUN [Skeleton]
Skeleton
Old
A skeleton (probably a luckless adventurer) lies here.
SIZE 15
WEIGHT 15
LOCATION [Mine Room#4]
NOUN_SYNONYMS bone bones
END_NOUN
NOUN_DESCR [Skeleton]
The skeleton looks old and moldy. Ugh!!
END_NOUN_DESCR
NOUN [Skeleton keys]
Keys
Skeleton
You see a ring of skeleton keys.
SIZE 5
WEIGHT 5
LOCATION [Mine Room#4]
POSITION next to skeleton
NOUN_SYNONYMS ring key
END_NOUN
NOUN_DESCR [Skeleton keys]
The skeleton keys looks old and moldy. They are on a brass ring. Every
adventure game needs to have some keys to open things, don't you think so?
END_NOUN_DESCR
COMMAND UNLOCK ANY WITH KEYS
Present [Skeleton keys]
PrintMessage "The keys don't work. Maybe these are the wrong keys for the $VERB$."
DoneWithTurn
END_COMMAND
ROOM [Mine Room#5]
Inside Diamond Mine
NORTH [Outside Mine]
WEST [Dead End]
LIGHT [Shining lantern]
END_ROOM
ROOM_DESCR [Mine Room#5]
You are lost in a maze of twisty little passages, all alike. However, you can
just make out some light seeping through the end of the tunnel to the north
(HINT HINT).
There is a sign over a tunnel leading west that says 'DEAD END'.
END_ROOM_DESCR
COMMAND READ SIGN
AtLocation [Mine Room#5]
PrintMessage "It still says 'DEAD END', buddy!"
DoneWithTurn
END_COMMAND
ROOM [Dead End]
DEAD END
KillPlayer
END_ROOM
ROOM_DESCR [Dead End]
What's the matter with you, buddy? Can't you read? If not, you have no
business playing TEXT adventure games! Better stick to those wimpy graphic
adventure games that don't require you to be able to read, write or type.
Anyway, the sign said 'DEAD END' -- didn't it? Don't say you weren't warned!
END_ROOM_DESCR
ROOM [Outside Mine]
Outside Diamond Mine
NORTH [Diamond Mine Entrance]
EAST [Lake Shore]
LIGHT [Shining lantern]
END_ROOM
ROOM_DESCR [Outside Mine]
You finally stumble out of the mine. You see the mine entrance to the north
and the lake shore to the east.
END_ROOM_DESCR
ROOM [Loud Room With Band]
Loud Room
LIGHT [Shining lantern]
END_ROOM
ROOM_DESCR [Loud Room With Band]
You are in the loud room. There is a heavy metal band playing here. You notice
one of them has an electric guitar. There is a huge speaker in the corner.
END_ROOM_DESCR
NOUN [plug]
plug
electric
There is an electric plug here
LOCATION [nowhere]
NOUN_SYNONYMS speaker speakers ears band
END_NOUN
NOUN_DESCR [plug]
There is an electric plug here.
END_NOUN_DESCR
MESSAGE [Pull Plug message]
You do it, and the heavy metal band goes into shock because their music is not
blaring. They all drop what they are carrying and run away frantically.
END_MESSAGE
COMMAND PULL PLUG
AtLocation [Loud Room With Band]
PrintMessage [Pull Plug message]
BlankLine
GoToRoom [Loud Room]
ChangePassageway [WEST] [Junction]
DoneWithTurn
END_COMMAND
COMMAND PULL PLUG
NOT AtLocation [Loud Room With Band]
PrintMessage "You would look pretty silly doing that. I am just going to ignore it."
DoneWithTurn
END_COMMAND
COMMAND ATTACK BAND
ReDirectTo PULL PLUG
END_COMMAND
COMMAND SHOOT BAND
ReDirectTo PULL PLUG
END_COMMAND
COMMAND COVER EARS
ReDirectTo PULL PLUG
END_COMMAND
MESSAGE [Try to GET Message]
No! You ain't gunna take it! ... No, you ain't gunna take it! You ain't gunna
take it, no no...'
END_MESSAGE
COMMAND GET ANY
AtLocation [Loud Room With Band]
PrintMessage [Try to GET Message]
DoneWithTurn
END_COMMAND
MESSAGE [Sorry, but I can't hear you]
Sorry, but I can't hear you.
END_MESSAGE
COMMAND HELP
AtLocation [Loud Room With Band]
PrintMessage [Sorry, but I can't hear you]
DoneWithTurn
END_COMMAND
COMMAND INVENTORY
AtLocation [Loud Room With Band]
PrintMessage [Sorry, but I can't hear you]
DoneWithTurn
END_COMMAND
COMMAND NORTH
AtLocation [Loud Room With Band]
PrintMessage [Sorry, but I can't hear you]
DoneWithTurn
END_COMMAND
COMMAND SOUTH
AtLocation [Loud Room With Band]
PrintMessage [Sorry, but I can't hear you]
DoneWithTurn
END_COMMAND
COMMAND EAST
AtLocation [Loud Room With Band]
PrintMessage [Sorry, but I can't hear you]
DoneWithTurn
END_COMMAND
COMMAND WEST
AtLocation [Loud Room With Band]
PrintMessage [Sorry, but I can't hear you]
DoneWithTurn
END_COMMAND
COMMAND UP
AtLocation [Loud Room With Band]
PrintMessage [Sorry, but I can't hear you]
DoneWithTurn
END_COMMAND
COMMAND DOWN
AtLocation [Loud Room With Band]
PrintMessage [Sorry, but I can't hear you]
DoneWithTurn
END_COMMAND
COMMAND EXIT
AtLocation [Loud Room With Band]
PrintMessage [Sorry, but I can't hear you]
DoneWithTurn
END_COMMAND
COMMAND LIST EXITS
AtLocation [Loud Room With Band]
PrintMessage [Sorry, but I can't hear you]
DoneWithTurn
END_COMMAND
ROOM [Loud Room]
Loud Room
WEST [Junction]
EAST [Triangular Room]
LIGHT [Shining lantern]
END_ROOM
ROOM_DESCR [Loud Room]
You are in the loud room. You can see the set-up of a heavy metal band here,
but they are not in sight. There is a huge speaker in the corner of the room.
There are exits to the east and to the west.
END_ROOM_DESCR
NOUN [guitar]
Guitar
Electric
There is an electric guitar here.
SIZE 20
WEIGHT 20
LOCATION [Loud Room]
POINTS 10
END_NOUN
NOUN_DESCR [guitar]
The guitar is a basic six stringer, with a plug to go into a wall. It can only
play heavy metal, though, at not less than 500 decibels. An engraving reads:
`ACME Anti-Deafness Prevention Old People Harrasser.'
END_NOUN_DESCR
ROOM [Triangular Room]
Triangular Room
WEST [Loud Room]
DOWN [1st Level]
LIGHT [Shining lantern]
END_ROOM
ROOM_DESCR [Triangular Room]
This is a strange triangular shaped room with passages leading off in all
directions. Several of them have unfortunately been blocked by a recent
cave-in. At a point equal-distant from the room's vertices, there is a
triangular staircase leading down. Even though you shine your lantern down
the stairwell you are unable to see the bottom.
END_ROOM_DESCR
MESSAGE [It drops down the staircase]
The $NOUN$ falls down the staircase. You can hear it banging and bouncing
as it makes its journey downward. The sound gets weaker and weaker and
weaker. Finally, it stops falling or is too far away for you to hear anymore.
END_MESSAGE
COMMAND DROP ANY
NOUNPresent
AtLocation [Triangular Room]
OR
AtLocation [1st Level]
OR
AtLocation [2nd Level]
OR
AtLocation [3rd Level]
OR
AtLocation [4th Level]
PrintMessage [It drops down the staircase]
SendNOUNToRoom [Gates of Hell]
DoneWithTurn
END_COMMAND
MESSAGE [Start Down]
You step on to the staircase and begin to climb down. You climb down for
a long, long time. You are getting warmer and quite tired. You pause to
rest.
END_MESSAGE
COMMAND DOWN
AtLocation [Triangular Room]
PrintMessage [Start down]
BlankLine
END_COMMAND
MESSAGE [Going Down]
You resume your climb down. Down and down you go, round and round you go, in
a spin, lovin the spin your in, under that old black magic ... called love,
etc....
It is quite warm here. Once again, you pause to rest.
END_MESSAGE
COMMAND DOWN
AtLocation [1st Level]
PrintMessage [Going down]
BlankLine
END_COMMAND
MESSAGE [More Going Down]
You resume your climb down. It is really getting hot here. Once again, you
pause to rest.
END_MESSAGE
COMMAND DOWN
AtLocation [2nd Level]
OR
AtLocation [3rd Level]
PrintMessage [More Going down]
BlankLine
END_COMMAND
MESSAGE [Final Going Down]
With the end in sight, you make one last effort to finish these !@#$%^&ing
stairs. You can hardly stand the heat. Finally, you reach the bottom.
END_MESSAGE
COMMAND DOWN
AtLocation [4th Level]
PrintMessage [Final Going down]
BlankLine
END_COMMAND
ROOM [1st Level]
On the Stairs
UP [Triangular Room]
DOWN [2nd Level]
LIGHT [Shining lantern]
END_ROOM
ROOM_DESCR [1st Level]
You are on the stairs. You can see a room far above you.
END_ROOM_DESCR
ROOM [2nd Level]
On the Stairs
DOWN [3rd Level]
UP [1st Level]
LIGHT [Shining lantern]
END_ROOM
ROOM_DESCR [2nd Level]
You are on the stairs. The stairs seems to go on endlessly both above and
below you.
END_ROOM_DESCR
ROOM [3rd Level]
On the Stairs
DOWN [4th Level]
UP [2nd Level]
LIGHT [Shining lantern]
END_ROOM
ROOM_DESCR [3rd Level]
You are on the stairs. The stairs seems to go on endlessly both above and
below you.
END_ROOM_DESCR
ROOM [4th Level]
On the Stairs
DOWN [Gates of Hell]
UP [3rd Level]
LIGHT [Shining lantern]
END_ROOM
ROOM_DESCR [4th Level]
You are on the stairs. The stairs seems to go on endlessly above you. Far
below, you can just make out a room where the stairs end.
END_ROOM_DESCR
ROOM [Gates of Hell]
Gates of Hell
UP [4th Level]
LOCKED_DOOR
LIGHT [Shining lantern]
END_ROOM
ROOM_DESCR [Gates of Hell]
You are outside a large gateway. Above the gateway there is a large plaque
which is inscribed:
Abandon every HELP all ye who enter here!
The gate is closed. Through it you can see flames and hear cries of great
pain and agony. It is incredibly hot! The heat seems to be coming from
beyond the gate. Stairs lead up.
END_ROOM_DESCR
NOUN [Bell]
Bell
Rusty
There is an old rusty bell here.
SIZE 20
WEIGHT 20
LOCATION [Gates of Hell]
END_NOUN
NOUN_DESCR [Bell]
The bell is quite old and very rusty. There is an inscription that reads
'RING FOR ATTENDANT'.
END_NOUN_DESCR
COMMAND OPEN GATE
AtLocation [Gates of Hell]
PrintMessage "You try unsuccessfully to open the gate, but it is locked."
DoneWithTurn
END_COMMAND
FLAG [Has visited Hell]
MESSAGE [1st Bell Ring]
A few moments after you ring the bell, you hear a voice cry out, "Hold your
horses, I'm coming........damn tourists..." A little old man in a red velvet
suit appears on the other side of the gates. He produces a key from a pocket
of his coat and unlocks the gate.
"Welcome to the 12592nd level of Hell. My name is Fred and I will be your
guide for today's tour", he says.
"This level of Hell is reserved for Adventure game writers. Here, we
specialize in giving these cruel people some of the same kind of torment that
they gave to those unfortunates that played their fiendish creations. It
doesn't matter that the game players played willingly -- in their quest for
masochistic pleasures. No! No! No! Just because the victim is foolish
enough to think he or she is enjoying the experience, doesn't make the crime
any less heinous. These wicked Adventure game writers were no better than
drug pushers preying on the mental weaknesses of Adventure junkies."
"Remember, as you tour this level of Hell that these people deserve their
eternal torment! They are just being repaid for the misery they have give to
others. Do not pity them. Save you pity for their unfortunate victims!"
With that introduction finished, Fred begins the tour. You follow him down a
long winding path. You finally stop by the edge of a cliff. In the distance
below you is a dark labyrinth of high thorny hedges. In the middle of the
labyrinth, you can see two figures groping along the hedge walls. As they
reach out to touch the hedges, they recoil in pain from touching the thorns.
Fred chuckles. "That is Will Crowther and Don Woods. They started it all by
writing the first Adventure game -- called simply ADVENTURE. They are now
doomed to search in the dark through a maze of twisty little passages. They
are trying to find the vending machine to buy some batteries for their
lantern. They will search forever -- in vain. A fitting punishment, don't
you agree?"
Fred chuckles again and wanders down the path to the north. After a few
minutes you arrive at a pleasant sunny meadow. Off to the south at the edge
of the meadow is a swampy area. In the middle of the swamp, buried in the mud
is a very strange sight. A bearded man is trapped under a sleeping dragon.
He alternates between trying to wake the dragon and trying to dig himself free
in the mud. He continues to struggle, but to no avail.
Fred explains, "That is Scott Adams. He wrote ADVENTURELAND, PIRATE ADVENTURE
and many, many others. His Adventure games were the first written for
microcomputers. Now, he is getting a taste of his own medicine."
"Let's move on." Fred proceeds to walk to the east. The ground rises gently
until you find yourself overlooking a deep chasm. On one side of the chasm
you see a man. Directly across from him is a woman. Both are shouting secret
words with very hoarse voices. They continue to shout out every silly word
imaginable. There doesn't seem to be any result from their efforts except
their voices get hoarser.
"Ken and Roberta Williams. They wrote THE WIZARD AND THE PRINCESS, and KING'S
QUEST I, II, III, IV, V, VI, VII, VIII, etc." explains Fred. "After they
discover the correct secret word, Artichoke, they will get to ride in a leaky
boat with no way to fix the leak." He chuckles again.
You follow Fred as he continues on the path to the south. You finally come to
an old house and enter through a broken window (sound familiar?). Fred lifts
a rug, brush aside some leaves and you both peek into a dark room through a
small grate. Below, you see two men trapped in a brick-walled room. There
are no doors or windows in the room. The only exit is the grate and it is
locked on the outside. However, even if the grate was unlocked it would do no
good, as both men are too big to fit through the grate.
"The only way out of the room is by saying the word 'Ahriman'. Ahriman was
one of the gods of Zoroastrian mythology", Fred whispers. "After they figure
that one out, we have some really hard puzzles for them. They are Dave
Lebling and Marc Blank. They wrote the ZORK series. You know those, of
course, -- ZORK I, ZORK II, ZORK III, ZORK ZERO, BEYOND ZORK, INSIDE ZORK,
OUTSIDE ZORK, UNDER ZORK, SON OF ZORK, RETURN TO ZORK, BRIDE OF ZORK, 2ND
COUSIN OF ZORK, ZORK MINUS 47, IN SEARCH OF ZORK, ZORK'S REVENGE, ZORK -- THE
SEQUEL, THE HITCHHIKER'S GUIDE TO ZORK, NIGHT OF THE LIVING ZORK, THE
ESSENTIAL ZORK, THE NON-ESSENTIAL ZORK, ZORK TRIVIA, ZORK CONFIDENTIAL, THE
VALLEY OF ZORK, IT CAME FROM ZORK, TALES OF ZORK, THE CREATURE FROM ZORK, ZORK
UNCHAINED, ZORK OBSERVED, THE COMPLEAT ZORK, et al. For all the pain they have
caused Adventure game players, these two deserve some really terrible
punishment, but there are some things that are even too nasty and gross for
Hell."
Fred puts the leaves back over the grate, puts the rug over the leaves, and
then leads you outside the house. You continue the tour for the remainder of
the afternoon. Finally, exhausted, you return to the entrance gate.
"Well, I hope you have enjoyed the tour of level 12592 of Hell. And remember,
those fiends deserve their fate or worse. Don't pity them. Instead, pity
their victims -- those poor misguided Adventure game players who can't kick
their evil habits!", Fred concludes.
He shakes your hand, says good bye, opens the gate for you to leave and then
locks it behind you. You find yourself back outside the gate to Hell. Fred
disappears down the path on the other side.
END_MESSAGE
COMMAND RING
FlagOFF [Has visited Hell]
AtLocation [Gates of Hell]
PrintMessage [1st Bell Ring]
PlusScore 15
TurnFlagON [Has visited Hell]
DoneWithTurn
END_COMMAND
MESSAGE [Later Bell Ring]
Ding! Dong!.
END_MESSAGE
COMMAND RING
Present [Bell]
PrintMessage [Later Bell Ring]
DoneWithTurn
END_COMMAND
MESSAGE [Starting Up]
You step on to the stairs and begin to climb up. It seems like a very easy
climb and you don't even have to pause to rest. You notice that it seems to
get cooler as you climb. Finally, you reach the top of the stairs almost
refreshed for your little bout of exercise. (One of the wonders of Adventure
Games is that they need not be logical, consistent or fair. Sometimes, this
works to the player's advantage -- like now.)
END_MESSAGE
COMMAND UP
AtLocation [Gates of Hell]
PrintMessage [Starting Up]
GoToRoom [Triangular Room]
DoneWithTurn
END_COMMAND
REM SUMO Stuff
MESSAGE [You are not an undertaker]
What are you some kind of fiend? The last time I checked, you were an
adventurer -- not an undertaker. The $ADJECTIVE$ $NOUN$ is dead!
END_MESSAGE
COMMAND GET SUMO
Present [Dead Sumo]
PrintMessage [You are not an undertaker]
DoneWithTurn
END_COMMAND
COMMAND GET TAX COLLECTOR
Present [Dead Tax Collector]
PrintMessage [You are not an undertaker]
DoneWithTurn
END_COMMAND
MESSAGE [He is already dead]
What are you some kind of fiend? The $ADJECTIVE$ $NOUN$ is already dead!
END_MESSAGE
MESSAGE [Sumo Jerk Message]
Attacking with your bare hands is worse than not doing anything at all - you
can slip and fall under the sumo. Bring a weapon next game, jerk.
END_MESSAGE
MESSAGE [Sumo Dies]
The sumo, in a great rage, accidentally sits on himself. Needless to say, he
dies. Nice work.
END_MESSAGE
MESSAGE [Sumo kills you]
The sumo sits on you, and farts several times. You can guess what happens.
END_MESSAGE
MESSAGE [Fire at Sumo #1]
You're still recovering from last round.
END_MESSAGE
MESSAGE [Fire at Sumo #2]
Pretty sad case. You slip and fall, and barely avoid the sumo as he tries to
sit on you. By the way, you're also stunned.
END_MESSAGE
MESSAGE [Fire at Sumo #3]
Nice move. When you fired the gun, it ricocheted and almost hit you. Lucky.
END_MESSAGE
MESSAGE [Fire at Sumo #4]
All right! Your gun jams! Too bad, you won't be able to attack quite yet.
END_MESSAGE
MESSAGE [Fire at Sumo #5]
The shot from your gun ricochets all around the room, and finally hits the
sumo for minimal damage.
END_MESSAGE
MESSAGE [Fire at Sumo #6]
The shot scares pants off the sumo. Embarrassed, he turns around and puts
them back on.
END_MESSAGE
MESSAGE [Fire at Sumo #7]
The shot hits the sumo squarely. He starts to cry.
END_MESSAGE
MESSAGE [Fire at Sumo #9]
Your shot is perfect. The sumo is hit right in the forehead. However, he has
a fairly thick skull.
END_MESSAGE
MESSAGE [Fire at Sumo #10]
The sumo is really terrified of you. He farts on himself.
END_MESSAGE
MESSAGE [Fire at Sumo #11]
When the gun fires, the sumo gets really freaked. He screams and almost breaks
his head bashing it against a wall.
END_MESSAGE
MESSAGE [Attack Sumo #1]
You want to $VERB$ $NOUN$? You must be some kind of fruit cake!
END_MESSAGE
MESSAGE [Attack Sumo #2]
The sumo, trying to avoid looking at your face, doesn't attack.
END_MESSAGE
MESSAGE [Attack Sumo #3]
The sumo tries to sit on you, but instead misses and lands on a tack. Ouch!
END_MESSAGE
MESSAGE [Attack Sumo #5]
The sumo is still thinking about whether to step with its right or left foot
first, so it doesn't attack.
END_MESSAGE
MESSAGE [Attack Sumo #6]
The sumo tries to sit on you. However, you dive away and land on a sharp rock.
END_MESSAGE
MESSAGE [Attack Sumo #7]
The sumo falls down, and in the following earthquake you are trying to keep
your balance.
END_MESSAGE
MESSAGE [Attack Sumo #9]
The sumo looks at you. You scream in agony, and bash your head against a wall.
END_MESSAGE
MESSAGE [Attack Sumo #10]
The sumo hold up a mirror. You choke and gasp for better air for a minute or
two.
END_MESSAGE
MESSAGE [Attack Sumo #11]
The sumo sits on you, but before the second is up you escape. Every bone in
your body is broken.
END_MESSAGE
COMMAND SHOOT SUMO
Present [Dead Sumo]
Present [Handgun]
PrintMessage [He is already dead]
DoneWithTurn
END_COMMAND
COMMAND SHOOT SUMO
Chance 75
Present [Live Sumo]
Present [Handgun]
RandomMessage [Fire at Sumo #1] [Fire at Sumo #11]
DoneWithTurn
END_COMMAND
COMMAND SHOOT SUMO
Chance 50
Present [Live Sumo]
Present [Handgun]
PrintMessage [Sumo Dies]
SwapLocations [Live Sumo] [Dead Sumo]
DoneWithTurn
END_COMMAND
COMMAND SHOOT SUMO
Present [Live Sumo]
Present [Handgun]
PrintMessage [Sumo kills you]
BlankLine
GoToRoom [Funeral]
DoneWithTurn
END_COMMAND
COMMAND ATTACK SUMO
Present [Dead Sumo]
PrintMessage [He is already dead]
DoneWithTurn
END_COMMAND
COMMAND ATTACK SUMO
Chance 75
Present [Live Sumo]
PrintMessage [Sumo Jerk message]
RandomMessage [Attack Sumo #1] [Attack Sumo #11]
DoneWithTurn
END_COMMAND
COMMAND ATTACK SUMO
Chance 50
Present [Live Sumo]
PrintMessage [Sumo Dies]
SwapLocations [Live Sumo] [Dead Sumo]
DoneWithTurn
END_COMMAND
COMMAND ATTACK SUMO
Present [Live Sumo]
PrintMessage [Sumo kills you]
BlankLine
GoToRoom [Funeral]
DoneWithTurn
END_COMMAND
REM TAX COLLECTOR Stuff
MESSAGE [Tax Collector Jerk Message]
Attacking with your bare hands is worse than not doing anything at all - you
can slip and he can tax you on that. Bring a weapon next game, jerk.
END_MESSAGE
MESSAGE [Tax Collector Dies]
The collector has a fit when he doesn't have anything to tax. He compulsively
taxes himself, and has a major heart attack. He was a nice fellow away from
the job, too.
END_MESSAGE
MESSAGE [Tax Collector kills you]
Oh well. With a yell of triumph, the collector screams and hurls a mountain of
taxes at you. Guess what.
END_MESSAGE
MESSAGE [Shoot at Tax Collector #1]
Nice move. You shoot at the collector, but he taxes you on aiming the gun!
You decide not to fire - who knows how much that costs!
END_MESSAGE
MESSAGE [Shoot at Tax Collector #2]
All right. When you fire your gun, it ricochets off a pile of old taxes and
almost kills you.
END_MESSAGE
MESSAGE [Shoot at Tax Collector #3]
The shot hits the collector and wounds him, but runs away before it can be
taxed or do more damage.
END_MESSAGE
MESSAGE [Shoot at Tax Collector #4]
The collector gets scared when he can't tax you on anything. He dives under a
pile of tax forms to avoid your shot.
END_MESSAGE
MESSAGE [Shoot at Tax Collector #7]
Beautiful shot. You wasted a pile of forms, and the collector screams in pain.
END_MESSAGE
MESSAGE [Shoot at Tax Collector #8]
The tax collector gets really scared, and has to tax himself for lack of
anything else.
END_MESSAGE
MESSAGE [Shoot at Tax Collector #9]
Your perfect shot destroys a pile of papers and blows a hole in the collector.
END_MESSAGE
MESSAGE [Attack Tax Collector #1]
The collector, organizing his forms, doesn't attack.
END_MESSAGE
MESSAGE [Attack Tax Collector #2]
The collector tries to throw a property tax at you, but you don't own anything.
END_MESSAGE
MESSAGE [Attack Tax Collector #3]
He tries to tax you on your possessions, but you stole them.
END_MESSAGE
MESSAGE [Attack Tax Collector #4]
The collector tries to slap an ugly tax on you, but then you show him a picture
of himself.
END_MESSAGE
MESSAGE [Attack Tax Collector #5]
The collector taxes you on not having a brain. You disagree, but then you
clean out your ear and your head caves in. Maybe he has a point.
END_MESSAGE
MESSAGE [Attack Tax Collector #7]
The collector pushes over a stack of papers. They land on you. Painful.
END_MESSAGE
MESSAGE [Attack Tax Collector #9]
He fires a paper airplane made out of a form at you. You choke in amazement
of how it flies to well.
END_MESSAGE
MESSAGE [Attack Tax Collector #10]
You are buried under a mountain of paper, and get cut up by a paper helicopter.
END_MESSAGE
MESSAGE [Attack Tax Collector #11]
The collector taxes you on `Every breath you take, every move you make...'
- and he'll be watching you. You make like Hitler.
END_MESSAGE
COMMAND SHOOT TAX COLLECTOR
Present [Dead Tax Collector]
Present [Handgun]
PrintMessage [He is already dead]
DoneWithTurn
END_COMMAND
COMMAND SHOOT TAX COLLECTOR
Chance 75
Present [Tax Collector]
Present [Handgun]
RandomMessage [Shoot at Tax Collector #1] [Shoot at Tax Collector #9]
DoneWithTurn
END_COMMAND
COMMAND SHOOT TAX COLLECTOR
Chance 50
Present [Tax Collector]
Present [Handgun]
PrintMessage [Tax Collector Dies]
SwapLocations [Tax Collector] [Dead Tax Collector]
DoneWithTurn
END_COMMAND
COMMAND SHOOT TAX COLLECTOR
Present [Tax Collector]
Present [Handgun]
PrintMessage [Tax Collector kills you]
BlankLine
GoToRoom [Funeral]
DoneWithTurn
END_COMMAND
COMMAND ATTACK TAX COLLECTOR
Present [Dead Tax Collector]
PrintMessage [He is already dead]
DoneWithTurn
END_COMMAND
COMMAND ATTACK TAX COLLECTOR
Chance 75
Present [Tax Collector]
PrintMessage [Tax Collector Jerk Message]
RandomMessage [Attack Tax Collector #1] [Attack Tax Collector #11]
DoneWithTurn
END_COMMAND
COMMAND ATTACK TAX COLLECTOR
Chance 50
Present [Tax Collector]
PrintMessage [Tax Collector Dies]
SwapLocations [Tax Collector] [Dead Tax Collector]
DoneWithTurn
END_COMMAND
COMMAND ATTACK TAX COLLECTOR
Present [Tax Collector]
PrintMessage [Tax Collector kills you]
BlankLine
GoToRoom [Funeral]
DoneWithTurn
END_COMMAND
REM HELP
MESSAGE [Default Help Message]
No way, Jose! Ha ha! No, I won't help. For help, make out a check for $500
to David Malmberg (or better yet -- Cash), and send it to him. Help will
arrive in the mail.
END_MESSAGE
COMMAND HELP
PrintMessage [Default Help Message]
DoneWithTurn
END_COMMAND
REM EXAMINE
COMMAND EXAMINE WINDOW
AtLocation [Inside House]
OR
AtLocation [East of House]
PrintMessage "The window is smashed, but wide enough for you to get through."
DoneWithTurn
END_COMMAND
REM GET
MESSAGE [Vault Disappears]
When you try to take it, the vault disappears. This vault does its job well!!!
END_MESSAGE
COMMAND GET VAULT
InRoom [Bank Vault]
Destroy [Bank Vault]
PrintMessage [Vault Disappears]
DoneWithTurn
END_COMMAND
COMMAND GET ALL
PrintMessage "You can't see any ALL detergent here!!!"
DoneWithTurn
END_COMMAND
COMMAND DROP ALL
PrintMessage "You don't even have the ALL detergent!"
DoneWithTurn
END_COMMAND
REM SMOKE POT/USE DRUGS/LIGHT POT
VARIABLE [Joints Smoked]
COUNTER [Turns player is high]
COMMAND SMOKE POT
VariableEquals [Joints Left] 0
PrintMessage "There is no more pot left to smoke -- sorry!"
DoneWithTurn
END_COMMAND
COMMAND SMOKE POT
NOT Present [Mary Jane]
PrintMessage "You can't see any pot here."
DoneWithTurn
END_COMMAND
COMMAND SMOKE POT
Present [Mary Jane]
NOT Present [matches]
PrintMessage "With what do you wish to light it? Your dragon breath?"
DoneWithTurn
END_COMMAND
MESSAGE [You smoke a joint]
You strike up a match and start smoking a joint of pot. After a few
lung-fulls, you get very high and will stay so for about 10 turns.
END_MESSAGE
COMMAND SMOKE POT
Present [Mary Jane]
VariableGT [matches left] 0
VariableGT [Joints Left] 0
PrintMessage [You smoke a joint]
TurnCounterON [Turns player is high]
AddToVariable [Joints Smoked] 1
SubtractFromVariable [matches left] 1
SubtractFromVariable [Joints Left] 1
VariableEquals [matches left] 0
PrintMessage [That was your last match]
Destroy [matches]
END_COMMAND
COMMAND SMOKE POT
VariableEquals [Joints Left] 0
PrintMessage "Unfortunately, that was your last joint of pot."
Destroy [candles]
END_COMMAND
COMMAND SMOKE POT
DoneWithTurn
END_COMMAND
REM LIGHT
MESSAGE [No more matches]
There are no more matches left. Too bad, buddy.
END_MESSAGE
COMMAND LIGHT ANY
VariableEquals [matches left] 0
PrintMessage [No more matches]
DoneWithTurn
END_COMMAND
COMMAND LIGHT ANY
AtLocation [Chili Contest]
OR
AtLocation [Smelly Room]
PrintMessage "As you strike the match, the gas in the room explodes and guess what happens."
BlankLine
GoToRoom [funeral]
DoneWithTurn
END_COMMAND
MESSAGE [That was your last match]
That was your last match.
END_MESSAGE
COMMAND LIGHT POT
ReDirectTo SMOKE POT
END_COMMAND
COMMAND LIGHT MATCH
Present [matches]
VariableGT [matches left] 0
PrintMessage "You strike a match which glows brightly and then goes out."
SubtractFromVariable [matches left] 1
VariableEquals [matches left] 0
PrintMessage [That was your last match]
Destroy [matches]
END_COMMAND
COMMAND LIGHT MATCH
DoneWithTurn
END_COMMAND
COMMAND LIGHT CANDLE
VariableEquals [candles left] 0
PrintMessage "You know, that's impossible to do without candles."
DoneWithTurn
END_COMMAND
COMMAND LIGHT CANDLE
Present [matches]
VariableGT [matches left] 0
VariableGT [candles left] 0
PrintMessage "You light the candle which glows brightly and then goes out."
SubtractFromVariable [matches left] 1
SubtractFromVariable [candles left] 1
VariableEquals [matches left] 0
PrintMessage [That was your last match]
Destroy [matches]
END_COMMAND
COMMAND LIGHT CANDLE
VariableEquals [candles left] 0
PrintMessage "Unfortunately, that was your last candle."
Destroy [candles]
END_COMMAND
COMMAND LIGHT CANDLE
DoneWithTurn
END_COMMAND
COMMAND FART
PrintMessage "Aaaahhhhhhhhh! That was really nice!"
DoneWithTurn
END_COMMAND
COMMAND PLAY GUITAR
Present [Guitar]
PrintMessage "Sorry, but the guitar is hopelessly out of tune."
DoneWithTurn
END_COMMAND
;SOME DEFAULTS
MESSAGE [He doesn't seem to be interested]
He doesn't seem to be interested. What a lousy salesman you'd make!!!
END_MESSAGE
COMMAND SHOW ANY
PrintMessage [He doesn't seem to be interested]
DoneWithTurn
END_COMMAND
COMMAND GIVE ANY
PrintMessage [He doesn't seem to be interested]
DoneWithTurn
END_COMMAND
MESSAGE [My we're feeling violent today!]
My we're feeling violent today!
END_MESSAGE
COMMAND DESTROY ANY
PrintMessage [My we're feeling violent today!]
DoneWithTurn
END_COMMAND
COMMAND SHOOT ANY
PrintMessage [My we're feeling violent today!]
DoneWithTurn
END_COMMAND
COMMAND FIND ANY
NOUNPresent
PrintMessage "You must be blind as a bat! It is right in front of your nose, turkey!"
DoneWithTurn
END_COMMAND
COMMAND FIND ANY
PrintMessage "Sorry, but it is impossible to $VERB$ the $NOUN$, turkey!"
DoneWithTurn
END_COMMAND
REM PUT
MESSAGE [This is not a trophy case]
This is a bank vault, not a trophy case to store odds and ends. Only valuable
stuff, please.
END_MESSAGE
VARIABLE [Number of treasures in vault]
MESSAGE [You drop a treasure in vault]
As you put the treasure in the bank vault, a voice booms out: `Well done!
You have collected #VAR[Number of treasures in vault]# treasure(s) so far out of a total of [Total number of treasures].'
END_MESSAGE
MESSAGE [Win Game Message]
As you put the last treasure in the bank vault, it closes and disappears
behind a painting. Just then, a booming voice says: `You have completed
your quest in PORK I, worthy one!
However, because this voice is so amazingly loud, it starts an earthquake.
A crack opens up in the earth, and you fall into the land of PORK II !!!
END_MESSAGE
COMMAND PUT ANY IN VAULT
InRoom [Bank Vault]
NOUNPresent
NOT [Is a treasure?]
PrintMessage [This is not a trophy case]
DoneWithTurn
END_COMMAND
COMMAND PUT ANY IN VAULT
InRoom [Bank Vault]
NOUNPresent
[Is a treasure?]
AddToVariable [Number of treasures in vault] 1
END_COMMAND
COMMAND PUT ANY IN VAULT
InRoom [Bank Vault]
NOUNPresent
[Is a treasure?]
VariableEquals [Number of treasures in vault] [Total number of treasures]
PrintMessage [Win Game Message]
SendNOUNToRoom [Bank Vault]
WinGame
TurnFlagON [Quitting]
ReDirectTo SCORE
END_COMMAND
COMMAND PUT ANY IN VAULT
InRoom [Bank Vault]
NOUNPresent
[Is a treasure?]
PrintMessage [You drop a treasure in vault]
SendNOUNToRoom [Bank Vault]
DoneWithTurn
END_COMMAND
MESSAGE [Leave it alone]
A voice booms out, 'Leave the !@#$%^&ing $NOUN$ alone, turkey!'
END_MESSAGE
COMMAND GET SIGN
PrintMessage [Leave it alone]
DoneWithTurn
END_COMMAND
COMMAND GET BATTERIES
NOT NOUNPresent
PrintMessage "A voice booms out, 'You'll have to find the !@#$%^&ing batteries, turkey!'"
DoneWithTurn
END_COMMAND
COMMAND GET ANY
Present [Bank Vault]
[Is a treasure?]
NOUNIsLocated [Bank Vault]
SubtractFromVariable [Number of treasures in vault] 1
END_COMMAND
COMMAND ECHO
PrintMessage "Sorry, but '$VERB$' doesn't work in this game. Nice try, however!"
DoneWithTurn
END_COMMAND
COMMAND OOPS
PrintMessage "What do you mean 'OOPS'?. Can't you type and/or spell?"
DoneWithTurn
END_COMMAND
REM ANY Stuff
MESSAGE [Tax Collector steals treasures]
A mean, cruel, small, sadistic, and all around bad-kind-of-guy tax collector
walks into the room, and taxes you on paying taxes. He carries off all your
valuables in exchange for not being taxed.
END_MESSAGE
FLAG [First Turn of Game]
FLAG [Grue Following Player]
FLAG [Grue has taken player]
FLAG [Frog Following Player]
COMMAND ANY
FlagOFF [First Turn of Game]
TurnFlagON [First Turn of Game]
TurnFlagOFF [Quitting]
SetVariableTo [Joints Smoked] 0
SetVariableTo [matches left] 10
SetVariableTo [Joints Left] 5
SetVariableTo [candles left] 5
SetVariableTo [Battery Life] 150
SetVariableTo [Number of treasures in vault] 0
END_COMMAND
COMMAND ANY
FlagON [Lamp is ON]
SubtractFromVariable [Battery Life] 1
END_COMMAND
COMMAND ANY
FlagON [Lamp is ON]
VariableEquals [Battery Life] 26
Present [Shining lantern]
BlankLine
PrintMessage [Give hint about batteries]
BlankLine
END_COMMAND
COMMAND ANY
FlagON [Lamp is ON]
VariableLT [Battery Life] 26
VariableGT [Battery Life] 0
Present [Shining lantern]
BlankLine
PrintMessage [Your lamp is growing weaker]
BlankLine
END_COMMAND
COMMAND ANY
FlagON [Lamp is ON]
Present [Shining lantern]
VariableEquals [Battery Life] 0
TurnFlagOFF [Lamp is ON]
PrintMessage "Your lamp has just gone out."
SwapLocations [Shining lantern] [Brass unlit lantern]
BlankLine
END_COMMAND
MESSAGE [It is now dark]
It is pitch black. You can't see your hand in front of your face.
END_MESSAGE
MESSAGE [Grue will get you]
In the dark you are likely to be eaten by a gruesome Grue.
END_MESSAGE
MESSAGE [Grue got you]
You hear a rustling sound behind you. Then you are grabbed from behind and
lifted off your feet. You fight back -- but without success.
AAAaaaaaaaaaaaaarrrrrrrrrrrggggggghhhhhh!!!!
You are being carried off by a Grue. Your life will soon be over. What a
terrible way to die -- eaten by a Grue! You finally pass out from fear.
Time passes.....and passes.....and passes...................................
You finally awake and when you recover your senses, you find the Grue has just
lifted your arm up to his mouth and he is licking your hand. Perhaps this is
his way of preparing his food. He licks some more and then begins to make a
purring-like sound.
END_MESSAGE
FLAG [Continue Meta-command]
COMMAND ANY
TurnFlagOFF [Continue Meta-command]
FlagOFF [Grue has taken player]
FlagOFF [Lamp is ON]
RoomNeedsLight
PrintMessage [It is now dark]
PrintMessage [Grue will get you]
NOT AtLocation [Grue's Lair]
Chance 25
VariableEquals [Battery Life] 0
TurnFlagON [Continue Meta-command]
END_COMMAND
COMMAND ANY
FlagOFF [Continue Meta-command]
FlagOFF [Grue has taken player]
FlagOFF [Lamp is ON]
RoomNeedsLight
PrintMessage "It is too dangerous to move around in the dark!"
VerbIsDirection
DoneWithTurn
END_COMMAND
COMMAND ANY
FlagON [Continue Meta-command]
PrintMessage [Grue got you]
GoToRoom [Grue's Lair]
SendToRoom [Shining lantern] [Grue's Lair]
SendToRoom [Grue] [Grue's Lair]
SetVariableTo [Battery Life] 200
TurnFlagON [Grue has taken player]
TurnFlagON [Lamp is ON]
Destroy [Brass unlit lantern]
DoneWithTurn
END_COMMAND
MESSAGE [Grue gives you batteries]
The Grue says 'If your going to wander around the land of PORK, you had better
learn to carry plenty of spare batteries for your lantern. Here, let me fix
you up.' With that, he puts some new batteries in your lantern and sets the
lantern down.
END_MESSAGE
COMMAND ANY
FlagON [Grue has taken player]
FlagOFF [Lamp is ON]
RoomNeedsLight
PrintMessage [It is now dark]
PrintMessage [Grue gives you batteries]
DropIt [Shining lantern]
SetVariableTo [Battery Life] 200
DoneWithTurn
END_COMMAND
COMMAND ANY
InRoom [Live Sumo]
VerbIsDirection
PrintMessage [Sumo blocking exits]
DoneWithTurn
END_COMMAND
COMMAND ANY
InRoom [Live Cyclops]
VerbIsDirection
PrintMessage [Cyclops blocking exits]
DoneWithTurn
END_COMMAND
COMMAND ANY
AtLocation [Grue's Lair]
TurnFlagON [Grue Following Player]
END_COMMAND
COMMAND ANY
VerbIsDirection
FlagON [Grue Following Player]
PrintMessage "The infamous Grue scurries along close at your heels."
BlankLine
END_COMMAND
COMMAND ANY
AtLocation [Royal Chamber]
TurnFlagON [Frog Following Player]
END_COMMAND
COMMAND ANY
VerbIsDirection
FlagON [Frog Following Player]
PrintMessage "The little green frog hops along behind you."
BlankLine
END_COMMAND
COMMAND ANY
AtLocation [Polish Maze]
VerbIsDirection
PrintMessage [You wander around for a while]
LookAtRoom
END_COMMAND
COMMAND ANY
CounterGT [Turns with headache] 0
PrintMessage "Oh .... oh.... your head hurts....what a terrible headache...."
BlankLine
CounterEquals [Turns with headache] 6
TurnCounterOFF [Turns with headache]
Destroy [Headache]
END_COMMAND
COMMAND ANY
CounterGT [Turns player is high] 9
PrintMessage "The pot wears off."
BlankLine
TurnCounterOFF [Turns player is high]
DoneWithTurn
END_COMMAND
COMMAND ANY
CounterGT [Turns player is high] 0
CounterLT [Turns player is high] 10
VariableEquals [Joints Smoked] 1
PrintMessage "You are feeling pretty wasted."
BlankLine
END_COMMAND
COMMAND ANY
CounterGT [Turns player is high] 0
CounterLT [Turns player is high] 10
VariableEquals [Joints Smoked] 2
PrintMessage "You are getting tired."
BlankLine
END_COMMAND
COMMAND ANY
CounterGT [Turns player is high] 0
CounterLT [Turns player is high] 10
VariableEquals [Joints Smoked] 3
PrintMessage "You are very tired now."
BlankLine
END_COMMAND
MESSAGE [Fall asleep]
You finally fall from exhaustion. Unfortunately, the boogie man eats you
in your sleep. What a way to go!
END_MESSAGE
COMMAND ANY
CounterGT [Turns player is high] 0
CounterLT [Turns player is high] 10
VariableEquals [Joints Smoked] 4
PrintMessage [Fall asleep]
BlankLine
GotoRoom [Funeral]
DoneWithTurn
END_COMMAND
COMMAND ANY
CounterGT [Turns player is high] 0
CounterLT [Turns player is high] 10
AtLocation [Chili Contest]
OR
AtLocation [Smelly Room]
PrintMessage "Because you're so high, you don't notice the fatal reek in here."
BlankLine
GotoRoom [Funeral]
DoneWithTurn
END_COMMAND
COMMAND ANY
NOT IsCarrying [$500 bill]
NOT IsCarrying [Mary Jane]
IsSomeWhere [Tax Collector]
[Underground?]
IsCarryingTreasure 5
PrintMessage [Tax Collector steals treasures]
BlankLine
SendTreasuresToRoom [Tax Collector's Lair] 4
DoneWithTurn
END_COMMAND
COMMAND ANY PEOPLE
Present [People]
PrintMessage [People ignore you]
DoneWithTurn
END_COMMAND
MESSAGE [Funny Saying #1]
Time flies like an arrow. However, fruit flies like bananas.
END_MESSAGE
MESSAGE [Funny Saying #2]
Reality is for people who can't face science fiction.
END_MESSAGE
MESSAGE [Funny Saying #3]
People with narrow minds usually have broad tongues.
END_MESSAGE
MESSAGE [Funny Saying #4]
A penny saved is ridiculous.
END_MESSAGE
MESSAGE [Funny Saying #5]
No problem is so formidable that you can't just run away from it.
END_MESSAGE
MESSAGE [Funny Saying #6]
Schizophrenia beats being alone.
END_MESSAGE
MESSAGE [Funny Saying #7]
Help stamp out and abolish redundancy!
END_MESSAGE
MESSAGE [Funny Saying #8]
While money can't buy happiness, it certainly lets you choose your own form
of misery.
END_MESSAGE
MESSAGE [Funny Saying #9]
Grues really aren't so bad (if you use lots of catsup or ketchup -- which ever
spelling you prefer).
END_MESSAGE
MESSAGE [Funny Saying #10]
Nuke the Whales!
END_MESSAGE
MESSAGE [Funny Saying #11]
More people have died in Teddy Kennedy's car than in nuclear power plants.
END_MESSAGE
MESSAGE [Funny Saying #12]
Remember, the fact that you're paranoid doesn't mean they're NOT out to get
you!
END_MESSAGE
MESSAGE [Funny Saying #13]
I'm all for computer dating, but I wouldn't want one to marry my sister.
END_MESSAGE
MESSAGE [Funny Saying #14]
Eschew Obfuscation!
END_MESSAGE
MESSAGE [Funny Saying #15]
F U CN RD THS U CNT SPL WRTH A DM!
END_MESSAGE
MESSAGE [Funny Saying #16]
God did not create the world in seven days. He partied for six and then
pulled an all-nighter.
END_MESSAGE
MESSAGE [Funny Saying #17]
Time is just nature's way of keeping everything from happening at once.
END_MESSAGE
MESSAGE [Funny Saying #18]
If rabbits feet are so lucky, what happened to the rabbit?
END_MESSAGE
MESSAGE [Funny Saying #20]
You can fool some of the people all of the time, and all of the people some
of the time, but you can make a fool of yourself anytime.
END_MESSAGE
MESSAGE [Funny Saying #21]
Be alert! We needs more lerts.
END_MESSAGE
MESSAGE [Funny Saying #22]
A closed mouth gathers no feet.
END_MESSAGE
MESSAGE [Funny Saying #23]
After all is said and done, usually more is said than done.
END_MESSAGE
MESSAGE [Funny Saying #24]
Nothing improves with age.
END_MESSAGE
MESSAGE [Funny Saying #25]
You've got to kiss a lot of ugly frogs before you find your handsome prince
(or princess).
END_MESSAGE
MESSAGE [Funny Saying #26]
Love is the triumph of imagination over intelligence.
END_MESSAGE
MESSAGE [Funny Saying #27]
Abstain from wine, women, and song; mostly song.
END_MESSAGE
MESSAGE [Funny Saying #28]
Beauty is skin deep; ugly goes right to the bone.
END_MESSAGE
MESSAGE [Funny Saying #29]
Never stand between a fire hydrant and a dog.
END_MESSAGE
MESSAGE [AGT Info]
This game was created using the "Master's Edition" of the Adventure Game
Toolkit (AGT). The "Master's Edition" is the long-awaited and long-promised
version 2.0 of AGT and represents the response to over five years of AGT
user's requests for improvements and additional capabilities and features.
The MASTER'S EDITION of ADVENTURE GAME TOOLKIT is designed to allow a game
designer/writer to create and play his/her own high-quality text adventure
games with optional graphic illustrations, sound effects and music. Once
created, these adventure games can be shared with and enjoyed by others --
even if they do not have a copy of the Adventure Game Toolkit themselves.
FEATURES OF MASTER'S EDITION OF THE ADVENTURE GAME TOOLKIT
The Master's Edition of AGT has a number of features that make it the most
comprehensive text adventure game creation product currently available. Some
of these key features are:
* Default "look-and-feel" of Infocom adventure games with similar
screen layout and standard vocabulary and routines.
* Large standard vocabulary with potential to define many more words
unique to a specific adventure. Typical games can have a vocabulary
of 1000 words or more.
* Sophisticated parser that can understand (1) complex input commands
including pronouns (IT, HIM, HER, THEM, MY and ITS), and (2) compound
commands separated by AND or THEN or punctuation symbols, and (3)
commands addressed to characters within the game. Here are a few
examples of commands AGT can handle with ease:
GET THE FLASH LIGHT AND THEN SWITCH IT ON
PUT ON THE CLOAK, THEN EXAMINE IT; READ ITS LABEL
PLACE THE GREEN ROCK AND THE SMALL PEBBLE BEHIND THE TREE
ENTER THE HOUSE; GET ALL; EXIT; SOUTH; SOUTH THEN DOWN
SULU, SET A COURSE FOR ALPHA 14
SCOTTY, BEAM DOWN A TRICORDER AND THE QWERTY MODULE
DROP THE FOOD, THE KEY AND THE BOTTLE THEN UNLOCK THE DOOR WITH
THE BRASS KEY AND THEN LEAVE
* Function and cursor keys predefined to input frequently used commands
and move directions. Function keys may also be redefined to input
frequently used commands like THROW AXE AT DWARF or GIVE MILK BOTTLE
TO BABY.
* An OOPS feature that allows you to edit/correct your input commands.
* SCRIPT and UNSCRIPT commands to echo game output to printer.
* Optional graphic illustrations using PCX formatted pictures for
display on CGA, EGA or VGA screens. The PCX format is the most
widely available of any picture format and is supported by most PAINT
and/or DRAW programs. Plus -- a great deal of PCX "clip-art" is
available.
* Optional animation using FLI files (produced by Autodesk Animator,
Animator Pro, 3D-Studio, PC-Animate, StrataVision 3D and other
animation packages) that can be displayed on VGA screens (only). The
FLI format is the most widely used animation format. Plus -- a great
deal of FLI animation "clip-art" is available.
* Optional music and sound effects that can be played in the
"background" during the game. These sound effects can either use the
PC's internal speaker or use an AdLib or SoundBlaster (or compatible)
"sound card" (if one is available).
* Optional user-definable "look-and-feel" interface including a
menu-driven player input option that displays feasible commands for
the player to pick from.
* Optional "pop-up" hints available when the <Alt> and <h> keys are
pressed at the same time.
* Optional fonts (EGA and VGA monitors only) that can be changed to
suit the needs of the game. The Master's Edition comes with over
30 sample fonts including Old English, Scrawl, Computereze. Plus, a
Font Editor is provided that allows you to create your own unique
fonts.
* Totally "backward" compatible with all previous versions of AGT.
WHAT THE REVIEWERS HAVE SAID ABOUT THE ADVENTURE GAME TOOLKIT
"Using the Adventure Game Toolkit, anyone with an ounce of
imagination can create a text adventure game ... similar in layout
and sophistication to those made by Infocom and other commercial
developers."
-- Donald B. Trivette in PC Magazine
"The Adventure Game Toolkit (AGT) acts as a compiler which allows
for creating remarkably complex and sophisticated games in a fairly
simple way .... AGT's parser reminds me of Infocom's."
-- Scorpia in Computer Gaming World
"If you have ever wondered what it is like to create your own
adventure games, but didn't have the programming knowledge to do it,
this product is for you .... The process is easy ... and you'll have
hours of fun doing it."
-- Resul DeMaria in Public Domain Software & Shareware
"The Adventure Game Toolkit from Softworks ... provides all the
tools you need to build your own text based adventure games .... The
Adventure Game Toolkit is an extremely powerful development
package."
-- Bob Napp in "Big Blue Disk"
The Adventure & Strategy Club (of England) recently awarded the Adventure
Game Toolkit its Golden Chalice award.
DIFFERENCES BETWEEN THE CLASSIC EDITION AND THE MASTER'S EDITION OF AGT
The "Classic Edition" (i.e., the normal/old/regular version) of AGT is very
simple to use and can be used by programming novices or even by
non-programmer's to create very professional text adventures similar to those
from firms like Infocom. Versions of the "Classic Edition" are available for
IBM, Macintosh, Atari ST and Amiga computers and games created on any of these
computers can be re-compiled and played on any of the other computers. The
Classic Edition is still supported and available from Softworks as Shareware
for only $20 (or $40 including a 223 page printed manual with lots and lots of
detailed examples).
The "Master's Edition" contains all the features and capabilities of the
"Classic Edition" plus a whole lot more. It is totally compatible with the
Classic Edition and games originally developed for the Classic Edition can be
easily converted to and used with the Master's Edition. The Master's Edition
is available only for IBM (or compatible) computers. The Master's Edition is
aimed at the more sophisticated and experienced programmer/game designer. The
Master's Edition allows you to create games that are approximately twice as
large as those possible using the Classic Edition. Plus, your games can have
optional graphic illustrations, sound effects, music, "pop-up" hints, unique
fonts (EGA or VGA screens only), and a customizeable "look-and-feel" user
interface including a menu-driven player input option.
The Master's Edition is available from Softworks for only $50. This price
includes the cost of seven ZIPped disks with over 5 megabytes of goodies
including complete documentation on disk, a bunch of game creation utilities,
several brand new sample games including the complete AGT source code to:
* HUMONGOUS CAVE (believed to be the largest text adventure game
available on any microcomputer). Based on the "Colassal Cave"
adventure, but expanded to 1000 points, 300 locations, hundreds of
objects, elves and other creatures, treasures and puzzles.
* HURRY! HURRY! HURRY! -- an illustrated, musical text adventure about
a mystery in a traveling circus with all of the game's related font,
music, sound effects and pictures files.
* SHERLOCK HOLMES -- a very unusual, menu-driven adventure where you
play the famous detective and try to solve a total of 18 separate
cases. This adventure illustrates the Master's Edition's vastly
improved capability to handle questions and answers -- making it a
great way to develop tutorials or other computer-aided instruction
applications or games.
* BRAINSCAPE -- an adventure that takes place inside the brain similar
to the novels (and movie) by Isaac Asimov "Fantastic Voyage" and
"Fantastic Voyage II: Destination Brain".
* SQUYNCH -- a classic adventure in-the-style-of-Infocom in which you
challenge the evils and mysteries of the Land of Squynch. Very clever!
* PORK -- a parody of the Infocom ZORK series of adventures. If
you were frustrated by ZORK, play PORK and enjoy the sweet fruits of
revenge.
* ADVENTURELAND and PIRATE'S ADVENTURE -- two true classic games by
Scott Adams converted to AGT. See how a real master of the genre
does his magic!
WHICH VERSION IS RIGHT FOR YOU?
If you are a "power" gamer/programmer and know that you can use (or need) the
full power of the Master's Edition, then by all means -- get the Master's
Edition. If you have less experience with programming or game design, then
you should probably start with the Classic Edition. If you select the Classic
Edition, you can always upgrade later when you need the full power of the
Master's Edition -- for a special "registered AGT user" upgrade price of only
$35.
To order either the Classic Edition or the Master's Edition, just write or
call:
Softworks
43064 Via Moraga
Mission San Jose, California 94539
VISA or MasterCard accepted for telephone orders
(510) 659-0533 6:00 PM to 9:00 PM -- PST only!
To get a printed order form, just enter the COMMAND: PRINT FORM
Softworks is a member of the Association of Shareware Professionals -- your
guarantee of quality in shareware software.
┌─────────┐
┌─────┴───┐ │ (tm)
───│ │O │───────────────────
│ ┌─────┴╨──┐ │ Association of
│ │ ├─┘ Shareware
└───┤ O │ Professionals
───────│ ║ │─────────────────────
└────╨────┘ MEMBER
END_MESSAGE
MESSAGE [Do you really want to quit?]
Listen buddy, this is really a fantastic adventure so I'll give you another
chance. Do you really really really really want to quit?
END_MESSAGE
MESSAGE [Thank you for playing PORK]
Thank you for playing PORK!
END_MESSAGE
MESSAGE [I didn't think you really wanted to quit!]
I didn't think you really wanted to quit!
END_MESSAGE
;QUIT COMMANDS
FLAG [Quitting]
COMMAND QUIT
FlagOn [Quitting]
DoneWithTurn
END_COMMAND
COMMAND QUIT
PrintMessage [Do you really want to quit?]
PromptForYes (* Get YES or NO answer from keyboard *)
PrintMessage [Thank you for playing PORK]
EndGame (* OK, player entered YES -- so let's quit *)
TurnFlagON [Quitting]
ReDirectTo SCORE
END_COMMAND
COMMAND QUIT
TurnFlagOFF [Quitting]
PrintMessage [I didn't think you really wanted to quit!]
BlankLine
ReDirectTo LOOK
END_COMMAND
COMMAND SCORE
BlankLine
ScoreLT 16
PrintMessage "Your score qualifies you to the title of 'Dainty Eater'."
END_COMMAND
COMMAND SCORE
ScoreLT 26
ScoreGT 15
PrintMessage "Your score qualifies you to the title of 'Gourmet'."
END_COMMAND
COMMAND SCORE
ScoreLT 36
ScoreGT 25
PrintMessage "Your score qualifies you to the title of 'Snobby Gourmet'."
END_COMMAND
COMMAND SCORE
ScoreLT 46
ScoreGT 35
PrintMessage "Your score qualifies you to the title of 'Professional Gourmet'."
END_COMMAND
COMMAND SCORE
ScoreLT 56
ScoreGT 45
PrintMessage "Your score qualifies you to the title of 'Food Critic'."
END_COMMAND
COMMAND SCORE
ScoreLT 66
ScoreGT 55
PrintMessage "Your score qualifies you to the title of 'French Chef'."
END_COMMAND
COMMAND SCORE
ScoreLT 76
ScoreGT 65
PrintMessage "Your score qualifies you to the title of 'Averige Pigo'."
END_COMMAND
COMMAND SCORE
ScoreLT 86
ScoreGT 75
PrintMessage "Your score qualifies you to the title of 'Ill-mannered Slob'."
END_COMMAND
COMMAND SCORE
ScoreLT 96
ScoreGT 85
PrintMessage "Your score qualifies you to the title of 'Human Garbage Disposal'."
END_COMMAND
COMMAND SCORE
ScoreLT 126
ScoreGT 95
BlankLine
PrintMessage "Your score qualifies you to the title of 'Human Vacuum Cleaner'."
END_COMMAND
COMMAND SCORE
ScoreLT 156
ScoreGT 125
PrintMessage "Your score qualifies you to the title of 'PORKer'."
END_COMMAND
COMMAND SCORE
ScoreLT 1000
ScoreGT 155
PrintMessage "Your score qualifies you to the title of 'Master PORKer'."
END_COMMAND
COMMAND SCORE
BlankLine
FlagOn [Quitting]
ReDirectTo QUIT
END_COMMAND
COMMAND DEBUG
ToggleFlag 0
DoneWithTurn
END_COMMAND
INSTRUCTIONS
------------------------------
How To Play The PORK Adventure
------------------------------
COMMANDS AND VOCABULARY:
The PORK Adventure Game understands a wide variety of commands.
However, it has only a limited vocabulary, totaling approximately four
hundred words, so it can get confused. If you give it a word that it
doesn't understand, it will tell you what word it doesn't know. Try
entering your command again using a different word in place of the one
the game objected to.
Your commands should generally be in the format:
<verb> <(multiple) noun phrase(s)> <preposition> <noun phrase/object>
Some (hypothetical) examples of valid commands:
PLACE A RED ROCK IN THE SMALL BOWL
PUT THE GREEN ROCK AND THE SMALL PEBBLE BEHIND THE OAK TREE
READ MY POETRY BOOK
SWIM IN THE SWIMMING POOL
EXAMINE THE GOLD RING, THE DWARF AND THE SILVER NECKLACE
EAT THE CELERY, THE TUNA, THE APPLE AND THE ONION
THROW THE BATTLE AXE AND THE LARGE ROCK AT THE WEREWOLF
SHOOT THE BURGLAR WITH THE REVOLVER
ATTACK HIM
("HIM" will refer to last noun mentioned, e.g., the burglar)
FIRE THE LASER PISTOL AT THE ALIEN MUTANT
GET THE BOOK (also: TAKE THE BOOK)
READ IT
("IT" will refer to last noun mentioned, e.g., the book)
GET ALL (will get everything movable at the current location)
GET THE KEYS, BOTTLE, FOOD AND THE CLOAK
EXAMINE THE KEYS, BOTTLE, FOOD AND CLOAK
PUSH THE RED BUTTON AND THE GREEN BUTTON
UNLOCK THE FILE CABINET WITH THE STEEL KEY
JUMP THROUGH THE OPENING
JUMP OVER THE LOG
NORTH
SOUTHWEST
PLACE AN AXE AND THE SHIELD NEXT TO THE BIG TREE
PUT THE FOOD ON THE KITCHEN TABLE
TURN ON THE FLASHLIGHT
LIGHT THE TORCH WITH THE WOODEN MATCHES
SCREAM AT THE UGLY TROLL
CLIMB UP THE LADDER
EXTINGUISH THE FIRE (or PUT OUT THE FIRE)
DRINK THE WHITE WINE
THROW THE FIRE WOOD IN THE STOVE
PULL THE BELL CORD
WEAR THE STUPID HAT (also: PUT ON THE STUPID HAT)
TAKE OFF THE HAT (also: REMOVE THE HAT)
NE (for NORTHEAST)
DROP THE KEY AND THE BOTTLE
ENTER THE CAVE
XYZZY (i.e., a "magic" word)
TURN THE DOORKNOB
PLAY WITH THE DOG
TALK TO (or TALK WITH) THE OLD MAN (ABOUT THE WEATHER)
TELL JEFF ABOUT THE SWORD
ASK JODIE ABOUT THE CRIME
Compound commands can be created by connecting single commands (like
those above) with "AND", "THEN" or the punctuation symbols "," or ";" to
connect two or more separate commands. However, "end-of-sentence"
punctuation symbols like ".", "!" and "?" should not be used. Below are
a few examples of valid compound commands:
TURN THE DOORKNOB THEN ENTER THE CAVE
CLIMB DOWN THE LADDER THEN SOUTH, WEST AND NORTHWEST
GET THE CLOAK AND THEN EXAMINE IT; READ THE LABEL
DROP THE FOOD AND THE BOTTLE THEN UNLOCK THE DOOR AND THEN LEAVE
GET THE TORCH, LIGHT IT WITH THE WOODEN MATCHES THEN EXAMINE IT
If the game understands all of the words in your command, but still
seems confused by the command -- then try to say the same thing using
fewer words and a simpler sentence. When in doubt, simplify your
input commands as much as possible. This also saves typing effort.
SPECIAL COMMANDS:
The game uses a number of special commands for various "housekeeping"
chores. These are all pretty standard for most adventure games,
specifically:
HELP May (or may not) give you a hint.
SCORE Will summarize your progress, so far.
NOTIFY Will causes the game to tell you whenever your score
changes.
INVENTORY Will display a list of the items you are carrying, and
those items you are wearing.
BRIEF Will cause location descriptions to be brief.
VERBOSE Will cause location descriptions to be verbose.
LOOK Will give you a full (verbose) description of
your current location.
LIST EXITS Will list the obvious (visible) exits from your current
location. There may be other ways to exit the location
-- but they may not be obvious.
OOPS Will allow you to edit (using the cursor keys, and the
delete, insert and backspace keys) your previous
input command. For example, if you enter THORW ROPE by
mistake, OOPS will enable you to edit this command and
correct it to THROW ROPE.
SAVE GAME Will save the current game status on disk.
RESTORE GAME Will restore a previously saved game from disk.
SCRIPT Causes output to go to both the screen and a printer
(using the LP1 port).
UNSCRIPT Causes output to go to the screen (only).
QUIT Quits the current game session. Always exit using QUIT
-- so the game can erase some temporary data files and
save disk space!
FUNCTION AND ALT-CURSOR KEYS:
The combination of the ALT key and the cursor keys have all been
programmed to create an input command corresponding to their respective
movement or compass directions, i.e., the ALT key and the up-arrow key
causes a NORTH command to be generated, the ALT key and the home key
causes a NORTHWEST command to be generated, etc.
Similarly, the function keys have been predefined to stand for several
of the most frequently used commands. Further, by giving the command
DEFINE, you may re-define any of the function keys to give any command
you wish. For example, in this game you might find it useful to
re-define one of the function keys to give the command KILL ORC WITH AXE
or GIVE CANDY TO BABY.
Hitting the '?' key (during the game) will display a diagram of keys and
their current definitions.
"LOOK-AND-FEEL" OPTIONS:
This particular game is using a special version of the AGT (Adventure
Game Toolkit) called the "Master's Edition" which allows the user to
customize the manner in which the game's general interface is defined
and to specify the game's overall "look-and-feel." The user may define
color schemes, status line options, command input method, size and
"layout" of the screen, etc. Once the player has a set of
"look-and-feel" options he or she likes, these options may be saved as
the standard defaults for this game and any other AGT game the user
plays.
One of the options available is a unique "menu-driven" input option that
allows the player to enter game commands by selecting words from a menu.
This option is particularly helpful for players who are often frustrated
by their inability to figure out an adventure game's vocabulary -- since
the menu always displays a list of "feasible" (though not always "smart"
or even appropriate) commands from which the player may make a
selection.
The "look-and-feel" options are accessed by hitting the ESC key during
the game (i.e., not now).
SOLUTION AVAILABLE:
PORK Adventure is a relatively easy adventure -- so you should be able
to solve it yourself (after a lot of trial and error). However, if you
get totally frustrated and/or really stuck and want to give up, a
complete solution is available for no charge.
If you give up, then just send a self-addressed stamped envelope (with
the correct postage) to:
David Malmberg
43064 Via Moraga
Mission San Jose, California
94539
Be sure to enclose a note requesting a solution to PORK Adventure.
DO NOT (REPEAT -- DO NOT) EVER CALL ON THE TELEPHONE TO ASK HOW TO GET
PAST THE GRUE, OR FOR SOME OTHER HINT!!! I will be glad to provide a
solution, but I want to do it by letter, not by phone!!!
END_INSTRUCTIONS