home *** CD-ROM | disk | FTP | other *** search
/ Explore the World of Soft…e: Engineering & Science / Explore_the_World_of_Software_Engineering_and_Science_HRS_Software_1998.iso / programs / electrnc / mcgarret.exe / MSTRIPLP.BAS < prev    next >
BASIC Source File  |  1989-10-21  |  2KB  |  60 lines
  1. 100 REM  BY D. MCGARRETT
  2. 105 CLS
  3. 110 PRINT "MSTRIPLP IS MSTRIP WITH OUTPUT TO PRINTER."
  4. 115 PRINT
  5. 120 PRINT "MICROSTRIP WIDTH CALCULATIONS FOR"
  6. 130 PRINT "GIVEN VALUES OF Z0,H,T, AND ER."
  7. 140 PRINT "EQUATIONS FROM WHEELER, TRANSACTIONS ON MTT, AUG 77"
  8. 150 PRINT
  9. 160 PRINT "VELOCITY FACTOR EQUATION FROM FISK, HR MAG,JAN 1978"
  10. 170 PRINT
  11. 180 PRINT "USE INCH INPUTS FOR CORRECT PHYSICAL DIMENSIONS VS. FREQUENCY"
  12. 190 PRINT
  13. 200 PRINT
  14. 210 INPUT "HEIGHT OF DIELECTRIC ="; H
  15. 220 INPUT "DIELECTRIC CONSTANT="; ER
  16. 230 INPUT "COPPER THICKNESS=(0 FOR 1 OZ CU)"; T
  17. 240 INPUT "DESIRED IMPEDANCE="; Z0
  18. 250 INPUT "FREQUENCY IN MHZ; USE 0 TO SKIP LENGTH CALCULATIONS"; FM
  19. 260 IF FM = 0 THEN 310
  20. 270 INPUT "ELECTRICAL LENGTH IS IN D egrees OR L ambda (D/L)"; AN2$
  21. 280 INPUT "ELECTRICAL LENGTH"; INLEN
  22. 290 IF AN2$ = "D" THEN LENT = (11803 / FM) * (INLEN / 360)
  23. 295 IF AN2$ = "d" THEN LENT = (11803 / FM) * (INLEN / 360)
  24. 300 IF AN2$ = "L" THEN LENT = (11803 / FM) * INLEN
  25. 305 IF AN2$ = "l" THEN LENT = (11803 / FM) * INLEN
  26. 310 IF T = 0 THEN T = .0013
  27. 320 B = EXP((Z0 / 42.4) * (ER + 1) ^ .5) - 1
  28. 330 C = ((7 + 4 / ER) / 11)
  29. 340 WP = 8 * H * SQR((B * C) + (1 + 1 / ER) / .81) / B
  30. 350 PI = 3.14159265#
  31. 360 D = (T / H) ^ 2
  32. 370 E = ((1 / PI) / ((WP / T) - .26)) ^ 2
  33. 380 DW = (T / PI) * LOG((4 * EXP(1)) / SQR(D + E))
  34. 390 DP = DW * (1 + (1 / ER)) / 2
  35. 400 W = WP - DP
  36. 410 W = INT(1000 * W + .5) / 1000
  37. 420 PRINT
  38. 430 PRINT
  39. 440 LPRINT "FOR IMPEDANCE OF"; Z0; "OHMS ON"; H; "HEIGHT"
  40. 450 LPRINT "SUBSTRATE, WITH ER="; ER; "AND"
  41. 460 LPRINT "COPPER THICKNESS OF"; T; "THEN THE"
  42. 470 LPRINT "REQUIRED LINE WIDTH IS"; W; "INCH"
  43. 480 LPRINT
  44. 490 EF = 1 + (ER - 1) * (.5 * (1 + (1 / SQR(1 + 10 / (W / H)))))
  45. 500 VP = 1 / SQR(EF)
  46. 510 VP1 = VP
  47. 520 VP = INT(1000 * VP + .5) / 1000
  48. 530 LPRINT "VELOCITY FACTOR FOR THIS LINE WIDTH IS"; VP
  49. 540 IF FM = 0 THEN 580
  50. 550 ACTLEN = LENT * VP1
  51. 560 LPRINT
  52. 570 LPRINT "LENGTH OF DESIRED LINE IS"; INT(1000 * ACTLEN + .5) / 1000
  53. 580 LPRINT
  54. 590 INPUT "ANOTHER IMPEDANCE ON THE SAME MATERIAL? Y/N"; ANS$
  55. 600 LPRINT
  56. 610 IF ANS$ = "Y" THEN 240
  57. 615 IF ANS$ = "y" THEN 240
  58. 620 END
  59.  
  60.