home
***
CD-ROM
|
disk
|
FTP
|
other
***
search
/
Explore the World of Soft…e: Engineering & Science
/
Explore_the_World_of_Software_Engineering_and_Science_HRS_Software_1998.iso
/
programs
/
electrnc
/
mcgarret.exe
/
MSTRIPLP.BAS
< prev
next >
Wrap
BASIC Source File
|
1989-10-21
|
2KB
|
60 lines
100 REM BY D. MCGARRETT
105 CLS
110 PRINT "MSTRIPLP IS MSTRIP WITH OUTPUT TO PRINTER."
115 PRINT
120 PRINT "MICROSTRIP WIDTH CALCULATIONS FOR"
130 PRINT "GIVEN VALUES OF Z0,H,T, AND ER."
140 PRINT "EQUATIONS FROM WHEELER, TRANSACTIONS ON MTT, AUG 77"
150 PRINT
160 PRINT "VELOCITY FACTOR EQUATION FROM FISK, HR MAG,JAN 1978"
170 PRINT
180 PRINT "USE INCH INPUTS FOR CORRECT PHYSICAL DIMENSIONS VS. FREQUENCY"
190 PRINT
200 PRINT
210 INPUT "HEIGHT OF DIELECTRIC ="; H
220 INPUT "DIELECTRIC CONSTANT="; ER
230 INPUT "COPPER THICKNESS=(0 FOR 1 OZ CU)"; T
240 INPUT "DESIRED IMPEDANCE="; Z0
250 INPUT "FREQUENCY IN MHZ; USE 0 TO SKIP LENGTH CALCULATIONS"; FM
260 IF FM = 0 THEN 310
270 INPUT "ELECTRICAL LENGTH IS IN D egrees OR L ambda (D/L)"; AN2$
280 INPUT "ELECTRICAL LENGTH"; INLEN
290 IF AN2$ = "D" THEN LENT = (11803 / FM) * (INLEN / 360)
295 IF AN2$ = "d" THEN LENT = (11803 / FM) * (INLEN / 360)
300 IF AN2$ = "L" THEN LENT = (11803 / FM) * INLEN
305 IF AN2$ = "l" THEN LENT = (11803 / FM) * INLEN
310 IF T = 0 THEN T = .0013
320 B = EXP((Z0 / 42.4) * (ER + 1) ^ .5) - 1
330 C = ((7 + 4 / ER) / 11)
340 WP = 8 * H * SQR((B * C) + (1 + 1 / ER) / .81) / B
350 PI = 3.14159265#
360 D = (T / H) ^ 2
370 E = ((1 / PI) / ((WP / T) - .26)) ^ 2
380 DW = (T / PI) * LOG((4 * EXP(1)) / SQR(D + E))
390 DP = DW * (1 + (1 / ER)) / 2
400 W = WP - DP
410 W = INT(1000 * W + .5) / 1000
420 PRINT
430 PRINT
440 LPRINT "FOR IMPEDANCE OF"; Z0; "OHMS ON"; H; "HEIGHT"
450 LPRINT "SUBSTRATE, WITH ER="; ER; "AND"
460 LPRINT "COPPER THICKNESS OF"; T; "THEN THE"
470 LPRINT "REQUIRED LINE WIDTH IS"; W; "INCH"
480 LPRINT
490 EF = 1 + (ER - 1) * (.5 * (1 + (1 / SQR(1 + 10 / (W / H)))))
500 VP = 1 / SQR(EF)
510 VP1 = VP
520 VP = INT(1000 * VP + .5) / 1000
530 LPRINT "VELOCITY FACTOR FOR THIS LINE WIDTH IS"; VP
540 IF FM = 0 THEN 580
550 ACTLEN = LENT * VP1
560 LPRINT
570 LPRINT "LENGTH OF DESIRED LINE IS"; INT(1000 * ACTLEN + .5) / 1000
580 LPRINT
590 INPUT "ANOTHER IMPEDANCE ON THE SAME MATERIAL? Y/N"; ANS$
600 LPRINT
610 IF ANS$ = "Y" THEN 240
615 IF ANS$ = "y" THEN 240
620 END