home *** CD-ROM | disk | FTP | other *** search
/ Explore the World of Soft…e: Engineering & Science / Explore_the_World_of_Software_Engineering_and_Science_HRS_Software_1998.iso / programs / electrnc / mcgarret.exe / HEATSINK.BAS < prev    next >
BASIC Source File  |  1989-10-11  |  2KB  |  40 lines
  1. 100 REM HEAT SINK DESIGN PROGRAM
  2. 110 CLS : PRINT  "HEAT SINK DESIGN"
  3. 120 PRINT : PRINT "ALL TEMPERATURES IN DEGREE CENTEGRADE"
  4. 130 PRINT : INPUT "REQUIRED POWER DISSIPATION IN WATTS";P
  5. 140 INPUT "MAXIMUM AMBIENT TEMPERATURE";TA
  6. 150 INPUT "MAXIMUM JUNCTION TEMPERATURE";TJ
  7. 160 INPUT "JUNCTION-CASE THERMAL RESISTANCE DEG C/WATT";JC
  8. 170 PRINT  : PRINT "SELECT TYPE OF MOUNTING"
  9. 180 PRINT "     1. DRY"
  10. 190 PRINT "     2. GREASE"
  11. 200 PRINT "     3. DRY WITH MICA WASHER"
  12. 210 INPUT "     4. GREASE WITH MICA WASHER";M
  13. 220 ON M GOTO 230,240,250,260
  14. 230 RC=.25 : T$="DRY" : GOTO 270
  15. 240 RC=.1 : T$="GREASE" : GOTO 270
  16. 250 RC=.8 : T$="DRY WITH MICA WASHER" : GOTO 270
  17. 260 RC=.4 : T$="GREASE WITH MICA WASHER"
  18. 270 TS=TJ-P*(RC+JC)
  19. 280 RJ=(TJ-TA)/P
  20. 290 RS=RJ-(JC+RC)
  21. 300 TC=RC*P+TS : TJ=(RC+JC)*P+TS
  22. 330 PRINT  : INPUT"DO YOU WANT TO KNOW THE APPROXIMATE SINK VOLUME REQUIRED";A$
  23. 340 IF A$= "Y" THEN 370
  24. 345 IF A$= "y" THEN 370
  25. 350 GOSUB 420
  26. 360 GOTO 400
  27. 370 V=46.155*RS^(-1.52145) : V=INT(V*100+.5)/100
  28. 380 GOSUB 420
  29. 390 PRINT "APPROXIMATE HEAT SINK VOLUME USING ALUMINUM IS";V;"CUBIC INCHES"
  30. 400 PRINT "REQUIRED HEAT SINK THERMAL RESISTANCE=";RS;"DEGREE C/WATT OR LESS"
  31. 410 PRINT : END
  32. 420 CLS : PRINT TAB(36) "RESULTS"
  33. 430 PRINT : PRINT "USING ";T$;" CASE-SINK MOUNTING:"
  34. 440 PRINT : PRINT "MAXIMUM AMBIENT TEMPERATURE=";TA;"DEGREE C"
  35. 450 PRINT "MAXIMUM JUNCTION TEMPERATURE=";TJ;"DEGREE C"
  36. 460 PRINT "HEAT SINK TEMPERATURE=";TS;"DEGREE C"
  37. 470 PRINT "CASE-SINK TEMPERATURE=";TC;"DEGREE C"
  38. 480 PRINT  "POWER DISSIPATION=";P;"WATTS"
  39. 490 RETURN
  40.