home *** CD-ROM | disk | FTP | other *** search
/ Simtel MSDOS - Coast to Coast / simteldosarchivecoasttocoast2.iso / sprint / spfonts4.zip / SPFONT.ASM next >
Assembly Source File  |  1989-06-27  |  32KB  |  1,400 lines
  1. ; SPFONT - software fonts for Sprint
  2. ;
  3. ; Copyright (c) 1989 Andrew D. Morrow
  4. ;
  5. ; =======================================================================
  6. ;
  7. ; Edit History:
  8. ;
  9. ;   jan89, v0.1;  called HERC, released to Borland for comments
  10. ;  6mar89, v0.2;  renamed SPFONT, supports HERC and CGA, implemented as TSR
  11. ; 13mar89, v0.2a; support video function 14 (WriteTTY); @StringInput uses it.
  12. ; 29mar89, v0.2b; experiment with loading font file from command line
  13. ; 29mar89, v0.2c; forget 2b. install font table with SPFONTLD
  14. ; 31mar89, v0.2d; detect Hercules card
  15. ;  1apr89, v0.2e; expand fonttable to 8 fonts
  16. ;                 add word-underline attribute
  17. ;  6apr89, v0.2f; if /p, fonts 1-7 will print reverse video
  18. ;--- first Compuserve release
  19. ; 17apr89, v0.2g; fix scroll-down bug (FirstScanTable needed sentinel entry)
  20. ; 29apr89, v0.3;  support different character heights (up to 16 dots)
  21. ;  3may89, v0.3a; detect SPFONT already installed, add /u uninstall option
  22. ;  9may89, v0.3b; add /b non-blinking cursor option
  23. ;                 add blink & huge cursor video functions
  24. ; 10may89, v0.3c; /a option makes CGA cursor sizing look ok with large chars
  25. ; 17may89, v0.3d; don't display cursor when positioned off the screen
  26. ; 24jun89, v0.3e; /k option for block cursor at startup
  27. ;                 remove chars 0-31 from each font (since Sprint can't
  28. ;                   use them) -- a savings of 2K-3K
  29. ;                 don't display characters when cursor is off-screen either
  30. ; 25jun89, v0.3f; jump to video functions through an address table
  31. ;                 blink & huge cursor routines return original value
  32. ;--- second Compuserve release
  33. ;
  34. ; =======================================================================
  35. ;
  36. ; Future Enhancements:
  37. ;
  38. ; - /s option prevents snow on CGA
  39. ; - /m# user-defined video mode number (if SPFONTMODE chokes other TSRs)
  40. ; - /1-/7 options to choose fewer fonts in memory (/1=/p; missing fonts
  41. ;     would be replaced by reverse video)
  42. ; - EGA/VGA support
  43. ;
  44. ;
  45. ; =======================================================================
  46. ;
  47.     DOSSEG
  48.     .MODEL TINY
  49.  
  50. ; ***********************************************************************
  51. ; *                                    *
  52. ; *    Equates                                *
  53. ; *                                    *
  54. ; ***********************************************************************
  55.  
  56. SPFONTMODE    EQU    255        ; a unique video mode number
  57. PREVIOUSMODE    EQU    254
  58.  
  59. MAXFONTS    EQU    8        ; number of fonts supported
  60. CHARSPERFONT    EQU    224        ; from 20h to FFh
  61.  
  62. ; The following equates identify the differences between HERC and CGA
  63. ; video memory. Hopefully they will adequately describe EGA and VGA as well.
  64. ;
  65.     IFDEF    HERC
  66. VIDEOBASE    EQU    0b000h        ; video page 0
  67. MAXBANKS    EQU    4
  68. BANKSIZE    EQU    02000h
  69. MAXSCANLINES    EQU    348
  70. MAXCOLUMNS    EQU    90
  71.     ELSEIFDEF CGA
  72. VIDEOBASE    EQU    0b800h
  73. MAXBANKS    EQU    2
  74. BANKSIZE    EQU    02000h
  75. MAXSCANLINES    EQU    200
  76. MAXCOLUMNS    EQU    80
  77.     ELSE
  78.     ERR    missing /dHERC or /dCGA on TASM command line!
  79.     ENDIF
  80.  
  81. MAXROWS        EQU    (MAXSCANLINES/CHARHEIGHT)
  82.  
  83. ; Values for Attribute bits.  The bit-mapping bears no relation to standard
  84. ; IBM video attribute bytes.  The only file that has to know about this
  85. ; mapping is MAIN.SPL which maps typestyle to video attribute.  Unfortunately,
  86. ; if Sprint is started without SPFONT in memory, plain characters will
  87. ; be "inivsible".  The unused bits (4,3,2) are available for future fonts.
  88. ;
  89. RV        EQU    80h        ; reverse video
  90. UN        EQU    40h        ; underline
  91. WU        EQU    20h        ; word underline
  92. SO        EQU    10h        ; strikeout
  93. ATTRIBMASK    EQU    07h        ; up to MAXFONTS fonts
  94.  
  95. ; Bios interrupts called
  96. ;
  97. VIDEOINT    EQU    10h
  98. TIMERINT    EQU    1ch
  99. ENDINT        EQU    20h
  100. DOSINT        EQU    21h
  101. TSRINT        EQU    27h
  102.  
  103. ; Video functions supported.  Internally, Sprint only calls functions 2,6,7 & 9.
  104. ; The init & reset strings in the terminal driver call function 0.  Functions
  105. ; 1,3 & 15 have been implemented to support "hardware" macros that try to
  106. ; detect a Mono or Color monitor, or that want to manipulate the cursor shape.
  107. ; Functions 14 (and indirectly, 8) are used by @StringInput who uses DOS
  108. ; calls for character i/o so that SPFMT is as DOS-compatible as possible.
  109. ; Two non-standard cursor control functions are also supported; from a Sprint
  110. ; "hardware" string, cursor blink can be turned on & off and the cursor can
  111. ; be turned into a huge "cross" for better visibility.
  112. ;
  113. SETVID        EQU    0
  114. SETCSIZE    EQU    1
  115. SETCPOS        EQU    2
  116. GETCINFO    EQU    3        ; returns cx,dx
  117. SCROLLUP    EQU    6
  118. SCROLLDN    EQU    7
  119. GETCHAR        EQU    8        ; returns ax
  120. WRTCHAR        EQU    9
  121. WRITETTY    EQU    14
  122. GETVID        EQU    15        ; returns ax,bx
  123.  
  124. SETBLINK    EQU    16
  125. SETCROSS    EQU    17
  126.  
  127. ; DOS functions called (by the initialization code only!)
  128. PUTSTR        EQU    9
  129. GETVECT        EQU    35h
  130. SETVECT        EQU    25h
  131. DEALLOC        EQU    49h
  132.  
  133. ; States of the simulated cursor.  The CBUSY state protects the cursor
  134. ; from being manipulated by a timer interrupt when a video function is
  135. ; in progress.
  136. COFF        EQU    0
  137. CON        EQU    1
  138. CBUSY        EQU    2
  139.  
  140. ; ***********************************************************************
  141. ; *                                    *
  142. ; *    Entry point                            *
  143. ; *                                    *
  144. ; ***********************************************************************
  145.  
  146.     .CODE
  147.     ORG    100h
  148. Start:    jmp    Init
  149.     DW    FontAnchor        ; so that SPFONTLD can find table
  150.  
  151. ; ***********************************************************************
  152. ; *                                    *
  153. ; *    Data Variables                            *
  154. ; *                                    *
  155. ; ***********************************************************************
  156.  
  157. ; Note: Some of the Cursor variables (Top,Bot,Row,Col) are words
  158. ; even though only the bottom byte is significant.  Doing this
  159. ; makes the DrawCharacter and CursorToggle routines smaller and
  160. ; faster.  Routines that update these variables are careful to leave
  161. ; the high-order byte untouched.
  162.  
  163. PlainFontOnly    DB    0        ; assume all fonts wanted
  164.  
  165. OldVideoMode    DB    ?
  166. VideoActive    DB    0        ; initially inactive
  167.  
  168. OldVideoInt    DD    ?
  169. OldTimerInt    DD    ?
  170.  
  171. CursorState    DB    COFF
  172. CursorCount    DB    0        ; cursor initially disabled
  173.  
  174. CursorBlink    DB    1
  175. CursorCross    DB    0
  176. CursorAdjust    DB    0
  177.  
  178. CursorTop    DW    CHARHEIGHT-2
  179. CursorBot    DW    CHARHEIGHT-1
  180.  
  181. CursorRow    DW    0
  182. CursorCol    DW    0
  183.  
  184. TempCol        DW    ?
  185. TempTop        DW    ?
  186. TempBot        DW    ?
  187.  
  188. ScrollNLines    DW    ?
  189. ScrollFill    DW    ?
  190. ScrollUpper    DW    ?
  191. ScrollLower    DW    ?
  192. ScrollRange    DW    ?
  193.  
  194. ; ***********************************************************************
  195. ; *                                    *
  196. ; *    Timer Handler & Cursor Routines                    *
  197. ; *                                    *
  198. ; ***********************************************************************
  199.  
  200. ; Turning the cursor off and on every time we write a character is a
  201. ; waste of precious CPU time.  So turning on the cursor just sets a
  202. ; flag so that the timer interrupt will truly restore the cursor
  203. ; 50-100ms later.  If more video functions are called in the meantime
  204. ; the timer will keep being deferred until the screen is "idle".
  205. ; The only problem with this scheme is that holding the up- or down-
  206. ; arrow to scroll can cause the cursor to apparently "disappear" until
  207. ; you take your finger off the key!
  208. ;
  209. ; Another advantage of hooking the timer into the cursor routines is that
  210. ; a blinking cursor can be simulated.  The blink rate could be made
  211. ; programmable (or disabled for a non-blinking cursor), and the on/off
  212. ; cycle could be made "uneven".
  213.  
  214. CursorOff:
  215.     cmp    [CursorState],CON    ; if it's on ...
  216.     jne    @@cf1
  217.     call    CursorToggle        ; ... turn it off
  218. @@cf1:    mov    [CursorState],COFF    ; ... and note the fact
  219.     ret
  220.  
  221. CursorOn:
  222.     mov    [CursorCount],2        ; reset the timer
  223.     ret
  224.  
  225. ; Timer interrupts are generated by hardware so all registers are precious.
  226. ; Pushing the registers is done in two steps to that the expensive "big"
  227. ; push is done only when needed.
  228. ;
  229. ; The CursorCount variable is only zero when SPFONT mode is inactive.
  230. ; When the driver is active, a decrement to zero causes the cursor to be
  231. ; toggled and the variable reset to a non-zero value.  The only exception
  232. ; to this is when the timer interrupt occurs when a video function is
  233. ; executing.  CursorOff (via CursorToggle) has marked the cursor BUSY,
  234. ; and the timer interrupt will return with CursorCount at zero. When
  235. ; the video function is finished, CursorOn will set CursorCount non-zero
  236. ; and the timer will gain control again some time later.
  237. ; 
  238. NewTimerHandler:
  239.     push    ax
  240.     push    ds
  241.     mov    ax,cs
  242.     mov    ds,ax
  243.  
  244.     cmp    [CursorCount],0        ; SPFONT active?
  245.     je    TimerDone        ; no, don't do anything!
  246.  
  247.     dec    [CursorCount]        ; time to toggle the cursor?
  248.     jnz    TimerDone        ; not yet
  249.  
  250.     push    es
  251.     push    di
  252.     push    bx
  253.     push    cx
  254.     push    dx
  255.  
  256.     cmp    [CursorState],COFF    ; if the cursor's off ...
  257.     jne    @@tm1
  258.     call    CursorToggle        ; ... turn it on ...
  259.     mov    [CursorState],CON
  260.     mov    [CursorCount],4        ; for about half a second
  261.     jmp    @@tm2
  262. @@tm1:
  263.     cmp    [CursorState],CON    ; if it's on ...
  264.     jne    @@tm2
  265.     cmp    [CursorBlink],0        ; ... and blinking is wanted ...
  266.     je    @@tm2
  267.     call    CursorToggle        ; ... do the opposite
  268.     mov    [CursorState],COFF
  269.     mov    [CursorCount],4
  270. @@tm2:
  271.     pop    dx
  272.     pop    cx
  273.     pop    bx
  274.     pop    di
  275.     pop    es
  276.  
  277. TimerDone:
  278.     pop    ds
  279.     pop    ax
  280.     jmp    cs:[OldTimerInt]    ; service other timers
  281.  
  282. CursorToggle:
  283.     mov    [CursorState],CBUSY    ; so a timer interrupt won't interfere
  284.     ;
  285.     cmp    [CursorCross],0        ; is a huge cursor wanted?
  286.     je    @@ct9
  287.     ;
  288.     xor    bx,bx            ; yes - toggle the whole row ...
  289.     mov    cx,MAXCOLUMNS
  290. @@ct1:    push    cx
  291.     push    bx
  292.     mov    ax,[CursorRow]
  293.     xor    cx,cx
  294.     mov    dx,CHARHEIGHT-1
  295.     call    DisplayCursor
  296.     pop    bx
  297.     inc    bx
  298.     pop    cx
  299.     loop    @@ct1
  300.     ;
  301.     xor    ax,ax            ; ... and the whole column ...
  302.     mov    cx,MAXROWS
  303. @@ct2:    push    cx
  304.     push    ax
  305.     mov    bx,[CursorCol]
  306.     xor    cx,cx
  307.     mov    dx,CHARHEIGHT-1
  308.     call    DisplayCursor
  309.     pop    ax
  310.     inc    ax
  311.     pop    cx
  312.     loop    @@ct2
  313.     ;
  314. @@ct9:    mov    ax,[CursorRow]        ; ... and/or just the exact position
  315.     mov    bx,[CursorCol]
  316.     mov    cx,[CursorTop]
  317.     mov    dx,[CursorBot]
  318.     jmp    DisplayCursor
  319.     
  320. ; ax=row, bx=col, cx=top, dx=bot
  321. DisplayCursor:
  322.     cmp    ax,MAXROWS        ; don't display cursor off the screen
  323.     jge    @@dcdone
  324.     cmp    bx,MAXCOLUMNS
  325.     jge    @@dcdone
  326.     ;
  327.     mov    [TempCol],bx
  328.     mov    [TempTop],cx
  329.     mov    [TempBot],dx
  330.     ;
  331.     IF CHARHEIGHT EQ 8
  332.      shl    ax,1            ; convert row -> ScanTable index in bx
  333.      shl    ax,1
  334.      shl    ax,1
  335.     ELSE
  336.      mov    ah,CHARHEIGHT
  337.      mul    ah
  338.     ENDIF
  339.     add    ax,[TempTop]
  340.     shl    ax,1
  341.     mov    bx,ax
  342.     ;
  343.     mov    ax,VIDEOBASE
  344.     mov    es,ax
  345.     ;
  346.     mov    cx,[TempBot]
  347.     sub    cx,[TempTop]
  348.     inc    cx
  349. @@dcloop:
  350.     mov    dx,[ScanTable+bx]
  351.     add    dx,[TempCol]
  352.     mov    di,dx
  353.     mov    al,es:[di]
  354.     xor    al,0ffh
  355.     mov    es:[di],al
  356.     add    bx,2
  357.     loop    @@dcloop
  358. @@dcdone:
  359.     ret
  360.  
  361. ; ***********************************************************************
  362. ; *                                    *
  363. ; *    Video Handler                            *
  364. ; *                                    *
  365. ; ***********************************************************************
  366.  
  367. ; Sprint is written in TurboC (I would hope!) and the manuals state
  368. ; that ax..dx and es are fair game, so we only have to save ds,si & di.
  369. ; Unfortunately, some TSR programs have been found that do not adequately
  370. ; save their registers during video calls, so in the interests of safety,
  371. ; all registers are saved.
  372. ;
  373. ; The low level routines DrawCharacter and CursorToggle destroy most
  374. ; registers so it is up to the video function to save any important
  375. ; registers.
  376. ;
  377. NewVideoHandler:
  378.     cmp    cs:[VideoActive],0ffh    ; are we in SPFONT mode?
  379.     je    ExecFunction        ; yes
  380.     cmp    ax,(SETVID*256)+SPFONTMODE ; switching to SPFONT mode?
  381.     je    ExecFunction        ; yes
  382.     jmp    cs:[OldVideoInt]    ; else pass onto old handler
  383.  
  384. ExecFunction:
  385.     push    ds            ; save important registers
  386.     push    si
  387.     push    di
  388.     mov    si,cs
  389.     mov    ds,si
  390.     ;
  391.     push    es            ; save everything else
  392.     push    dx
  393.     push    cx
  394.     push    bx
  395.     push    ax
  396.     ;
  397. @@exec:
  398.     push    ax
  399.     mov    al,ah
  400.     xor    ah,ah
  401.     sal    ax,1
  402.     mov    si,ax
  403.     pop    ax
  404.     cmp    si,ExecTableLen
  405.     jae    DoNothing
  406.     jmp    [ExecTable+si]
  407.  
  408. DoNothing:
  409.     jmp    ReturnVOID        ; video function not supported
  410.  
  411. ExecTable LABEL WORD
  412.     dw    OFFSET DoSetVideoMode
  413.     dw    OFFSET DoSetCursorSize
  414.     dw    OFFSET DoSetCursorPos
  415.     dw    OFFSET DoGetCursorInfo
  416.     dw    OFFSET DoNothing
  417.     dw    OFFSET DoNothing
  418.     dw    OFFSET DoScrollUp
  419.     dw    OFFSET DoScrollDown
  420.     dw    OFFSET DoGetCharInfo
  421.     dw    OFFSET DoWriteChar
  422.     dw    OFFSET DoNothing
  423.     dw    OFFSET DoNothing
  424.     dw    OFFSET DoNothing
  425.     dw    OFFSET DoNothing
  426.     dw    OFFSET DoWriteTTY
  427.     dw    OFFSET DoGetVideoParms
  428.     dw    OFFSET DoSetCursorBlink
  429.     dw    OFFSET DoSetCursorCross
  430. ExecTableLen EQU $-ExecTable
  431.  
  432. DoSetVideoMode:
  433.     cmp    al,SPFONTMODE        ; switch to SPFONT mode?
  434.     jne    @@sv1
  435.     mov    ah,GETVID        ; yes, remember current video mode
  436.     pushf
  437.     call    cs:[OldVideoInt]
  438.     mov    [OldVideoMode],al    ; (should we also save video page?)
  439.  
  440.     call    EnterGraphicsMode
  441.  
  442.     mov    [CursorRow],0
  443.     mov    [CursorCol],0
  444.     mov    [CursorState],COFF
  445.     mov    [CursorCount],1        ; next timer will toggle cursor on
  446.  
  447.     mov    cs:[VideoActive],0ffh    ; SPFONT active!
  448.     jmp    ReturnVOID
  449.  
  450. @@sv1:    cmp    al,PREVIOUSMODE        ; revert to previous mode?
  451.     jne    @@sv2
  452.     mov    al,[OldVideoMode]    ; yes (ah is still SETVID)
  453.  
  454. @@sv2:    mov    [CursorCount],0        ; disable the software cursor
  455.     mov    cs:[VideoActive],0    ; no longer in SPFONT
  456.     pushf
  457.     call    cs:[OldVideoInt]    ; let the old handler do the work
  458.     jmp    ReturnVOID
  459.     
  460. DoSetCursorSize:
  461.     push    cx
  462.     call    CursorOff
  463.     pop    cx
  464.  
  465.     cmp    ch,CHARHEIGHT-1        ; make sure top is 0..CHARHEIGHT-1
  466.     jle    @@sz1
  467.     mov    ch,CHARHEIGHT-1
  468. @@sz1:
  469.     cmp    cl,CHARHEIGHT-1        ; make sure bottom is 0..CHARHEIGHT-1
  470.     jle    @@sz2
  471.     mov    ch,CHARHEIGHT-1
  472. @@sz2:
  473.     cmp    ch,cl            ; make sure top <= bottom
  474.     jle    @@sz3
  475.     xchg    ch,cl
  476. @@sz3:
  477.  
  478.     IF CHARHEIGHT NE 8
  479.      cmp    [CursorAdjust],0    ; if cursor size adjusting wanted ...
  480.      je    @@sz9
  481.      cmp    cl,7            ; ... & changing CGA bottom line ...
  482.      jne    @@sz9
  483.      cmp    ch,0            ; ... then leave top line as is ...
  484.      je    @@sz8
  485.      sub    cl,ch
  486.      mov    ch,CHARHEIGHT-1
  487.      sub    ch,cl            ; ... else top = (CHARHEIGHT-1)-(bottom-top)
  488. @@sz8:     mov    cl,CHARHEIGHT-1        ; ... and set new bottom line
  489. @@sz9:
  490.     ENDIF
  491.  
  492.     mov    BYTE PTR [CursorTop],ch
  493.     mov    BYTE PTR [CursorBot],cl
  494.     call    CursorOn
  495.     jmp    ReturnVOID
  496.  
  497. DoSetCursorPos:
  498.     push    dx
  499.     call    CursorOff
  500.     pop    dx
  501.     mov    BYTE PTR [CursorRow],dh
  502.     mov    BYTE PTR [CursorCol],dl
  503.     call    CursorOn
  504.     jmp    ReturnVOID
  505.  
  506. DoGetCursorInfo:
  507.     mov    ch,BYTE PTR [CursorTop]
  508.     mov    cl,BYTE PTR [CursorBot]
  509.     mov    dh,BYTE PTR [CursorRow]
  510.     mov    dl,BYTE PTR [CursorCol]
  511.     jmp    ReturnCXDX
  512.  
  513. ; To properly determine the character/attribute under the cursor
  514. ; would require a lot of computation matching through the font tables.
  515. ; Returning just a "plain-space" seems to keep DOS perfectly happy.
  516. ;
  517. DoScrollUp:
  518.     call    ScrollPrep
  519.     call    CursorOff
  520.     call    ScrollUp
  521.     call    CursorOn
  522.     jmp    ReturnVOID
  523.  
  524. DoScrollDown:
  525.     call    ScrollPrep
  526.     call    CursorOff
  527.     call    ScrollDown
  528.     call    CursorOn
  529.     jmp    ReturnVOID
  530.  
  531. DoGetCharInfo:
  532.     mov    ax,' '*256+0        ; return char=space, attrib=plain
  533.     jmp    ReturnAX
  534.  
  535. DoWriteChar:
  536.     push    cx
  537.     push    bx
  538.     push    ax
  539.     call    CursorOff
  540.     pop    ax
  541.     pop    bx
  542.     pop    cx
  543. @@wc1:
  544.     push    cx
  545.     push    bx
  546.     push    ax
  547.     call    DrawCharacter
  548.     pop    ax
  549.     pop    bx
  550.     pop    cx
  551.     inc    BYTE PTR [CursorCol]
  552.     loop    @@wc1
  553.     call    CursorOn
  554.     jmp    ReturnVOID
  555.  
  556. ; Write a character as TTY.  @StringInput uses it so I must support it.
  557. ; Fortunately for me, only 65 characters of input is allowed (so line
  558. ; wrap should never occur) and backspace is the only editing character.
  559. ; CR & LF codes are sent when Enter is pressed, but these can be ignored
  560. ; since the screen driver repositions the cursor anyways.  Characters are
  561. ; always written in the "plain" attribute.
  562. ;
  563. ; entry: al=character
  564. DoWriteTTY:
  565.     cmp    al,0dh            ; cr?
  566.     je    @@ttyend
  567.     cmp    al,0ah            ; lf?
  568.     je    @@ttyend
  569.  
  570.     push    ax
  571.     call    CursorOff
  572.     pop    ax
  573.  
  574.     cmp    al,08h            ; backspace?
  575.     jne    @@tty1
  576.  
  577.     cmp    BYTE PTR [CursorCol],0    ; if at left edge ...
  578.     je    @@ttydone        ; ... do nothing
  579.     dec    BYTE PTR [CursorCol]    ; ... else just move cursor
  580.     jmp    @@ttydone
  581.  
  582. @@tty1:    mov    bl,0            ; plain attribute
  583.     call    DrawCharacter        ; print the char ...
  584.     inc    BYTE PTR [CursorCol]    ; ... and move the cursor
  585. @@ttydone:                ; common wrap-up
  586.     call    CursorOn
  587. @@ttyend:
  588.     jmp    ReturnVOID
  589.  
  590. ; will macros with hardware strings interpret SPFONTMODE as 'Mono' or 'Color'?
  591. DoGetVideoParms:
  592.     mov    ax,(MAXCOLUMNS*256)+SPFONTMODE
  593.     xor    bh,bh            ; always video page 0
  594.     jmp    ReturnAXBX
  595.  
  596. DoSetCursorBlink:
  597.     push    ax
  598.     call    CursorOff
  599.     pop    ax
  600.     mov    ah,[CursorBlink]    ; remember old value
  601.     cmp    al,2            ; if al >= 2 ...
  602.     jl    @@cbl1
  603.     mov    al,ah            ; ... then leave unchanged
  604. @@cbl1:    mov    [CursorBlink],al    ; store new value ...
  605.     push    ax
  606.     call    CursorOn
  607.     pop    ax
  608.     mov    al,ah            ; ... and return old one
  609.     xor    ah,ah
  610.     jmp    ReturnAX
  611.  
  612. DoSetCursorCross:
  613.     push    ax
  614.     call    CursorOff
  615.     pop    ax
  616.     mov    ah,[CursorCross]
  617.     cmp    al,2
  618.     jl    @@ccr1
  619.     mov    al,ah
  620. @@ccr1:    mov    [CursorCross],al
  621.     push    ax
  622.     call    CursorOn
  623.     pop    ax
  624.     mov    al,ah
  625.     xor    ah,ah
  626.     jmp    ReturnAX
  627.  
  628. ReturnAX:
  629.     pop    es            ; throw away saved ax
  630.     pop    bx
  631.     pop    cx
  632.     pop    dx
  633.     pop    es
  634.     jmp    VideoDone
  635. ReturnAXBX:
  636.     pop    es            ; throw away saved ax
  637.     pop    es            ; and bx
  638.     pop    cx
  639.     pop    dx
  640.     pop    es
  641.     jmp    VideoDone
  642. ReturnCXDX:
  643.     pop    ax
  644.     pop    bx
  645.     pop    es            ; throw away saved cx
  646.     pop    es            ; and dx
  647.     pop    es
  648.     jmp    VideoDone
  649. ReturnVOID:
  650.     pop    ax
  651.     pop    bx
  652.     pop    cx
  653.     pop    dx
  654.     pop    es
  655. VideoDone:
  656.     pop    di
  657.     pop    si
  658.     pop    ds
  659.     iret
  660.  
  661. ; ***********************************************************************
  662. ; *                                    *
  663. ; *    Video Subroutines                        *
  664. ; *                                    *
  665. ; ***********************************************************************
  666.  
  667. ; Scroll Up.  Although the function is defined to work on any rectangular
  668. ; area of the screen, Sprint only scrolls whole lines so the column numbers
  669. ; in cl & dl can be ignored.
  670. ;
  671. ; The technique used here is to compute the source and destination
  672. ; offsets for the first bank and the length of the block in that bank,
  673. ; then the data is moved in each of the banks.  Note that the computations
  674. ; have to take into account how many of the CHARHEIGHT scan lines of a character
  675. ; reside in a bank.  We also divide the length by 2 since we want to use
  676. ; a movsw command to move words instead of bytes.
  677. ;
  678. ; entry: al=Nlines, bh=fill attrib, ch=Upper row, dh=Lower row
  679. ;
  680. ScrollPrep:
  681.     xor    ah,ah
  682.     mov    [ScrollNLines],ax
  683.     mov    al,ch
  684.     mov    [ScrollUpper],ax
  685.     mov    al,dh
  686.     mov    [ScrollLower],ax
  687.  
  688.     sub    ax,[ScrollUpper]
  689.     inc    ax
  690.     mov    [ScrollRange],ax
  691.  
  692.     cmp    [ScrollNLines],0
  693.     je    @@su4            ; if Nlines = 0 ...
  694.     cmp    ax,[ScrollNLines]
  695.     jge    @@su5            ; ... or Range < Nlines ...
  696. @@su4:    mov    [ScrollNLines],ax    ; then Nlines = Range
  697. @@su5:
  698.  
  699.     xor    dx,dx            ; fill with zeros
  700.     test    bh,RV
  701.     jz    @@su2
  702.     dec    dx            ; fill with ones
  703. @@su2:    mov    [ScrollFill],dx
  704.     ret
  705.  
  706. ScrollUp:
  707.     cmp    ax,[ScrollNLines]    ; if scrolling whole range ...
  708.     je    @@sufill        ; ... then bypass move
  709.  
  710.     ; move data in each bank
  711.     ; compute source, destination & length for first bank
  712.     mov    ax,[ScrollUpper]
  713.     add    ax,[ScrollNLines]
  714.     shl    ax,1
  715.     mov    bx,ax
  716.     mov    si,[ScanFirstTable+bx]    ; si = U+N
  717.  
  718.     mov    ax,[ScrollUpper]
  719.     shl    ax,1
  720.     mov    bx,ax
  721.     mov    di,[ScanFirstTable+bx]    ; di = U
  722.  
  723.     mov    ax,[ScrollRange]
  724.     sub    ax,[ScrollNLines]
  725.     shl    ax,1
  726.     mov    bx,ax
  727.     mov    cx,[Rows2Words+bx]    ; cx = (L-U+1)-N
  728.  
  729.     mov    ax,VIDEOBASE
  730.     mov    es,ax
  731.     push    ds
  732.     mov    ds,ax
  733.     cld
  734.  
  735.     mov    bx,MAXBANKS
  736. @@su1:
  737.     push    cx
  738.     push    si
  739.     push    di
  740.  
  741.     rep movsw
  742.  
  743.     pop    di
  744.     pop    si
  745.     pop    cx
  746.  
  747.     add    si,BANKSIZE
  748.     add    di,BANKSIZE
  749.  
  750.     dec    bx
  751.     jnz    @@su1
  752.  
  753.     pop    ds
  754.  
  755.     ; fill empty region depending on attribute
  756.     ; compute source & length for first bank
  757. @@sufill:
  758.     mov    ax,[ScrollLower]
  759.     sub    ax,[ScrollNLines]
  760.     inc    ax
  761.     shl    ax,1            ; since ScanFirst is a word table
  762.     mov    bx,ax
  763.     mov    di,[ScanFirstTable+bx]    ; si = L-N+1
  764.  
  765.     mov    ax,[ScrollNLines]
  766.     shl    ax,1
  767.     mov    bx,ax
  768.     mov    cx,[Rows2Words+bx]    ; cx = N
  769.  
  770.     mov    ax,[ScrollFill]
  771.  
  772.     ; es and df are unchanged from above
  773.  
  774.     mov    bx,MAXBANKS
  775. @@su3:
  776.     push    cx
  777.     push    di
  778.  
  779.     rep stosw
  780.  
  781.     pop    di
  782.     pop    cx
  783.  
  784.     add    di,BANKSIZE
  785.  
  786.     dec    bx
  787.     jnz    @@su3
  788.  
  789.     ret
  790.  
  791. ScrollDown:
  792.     cmp    ax,[ScrollNLines]    ; if scrolling whole range ...
  793.     je    @@sdfill        ; ... then bypass move
  794.  
  795.     ; move data in each bank
  796.     ; compute source, destination & length for first bank
  797.     mov    ax,[ScrollRange]
  798.     sub    ax,[ScrollNLines]
  799.     add    ax,[ScrollUpper]
  800.     shl    ax,1
  801.     mov    bx,ax
  802.     mov    si,[ScanFirstTable+bx]    ; si = U+(R-N)
  803.     dec    si
  804.     dec    si
  805.  
  806.     mov    ax,[ScrollLower]
  807.     inc    ax
  808.     shl    ax,1
  809.     mov    bx,ax
  810.     mov    di,[ScanFirstTable+bx]    ; di = L+1
  811.     dec    di
  812.     dec    di
  813.  
  814.     mov    ax,[ScrollRange]
  815.     sub    ax,[ScrollNLines]
  816.     shl    ax,1
  817.     mov    bx,ax
  818.     mov    cx,[Rows2Words+bx]    ; cx = R-N
  819.  
  820.     mov    ax,VIDEOBASE
  821.     mov    es,ax
  822.     push    ds
  823.     mov    ds,ax
  824.     std
  825.  
  826.     mov    bx,MAXBANKS
  827. @@sd1:
  828.     push    cx
  829.     push    si
  830.     push    di
  831.  
  832.     rep movsw
  833.  
  834.     pop    di
  835.     pop    si
  836.     pop    cx
  837.  
  838.     add    si,BANKSIZE
  839.     add    di,BANKSIZE
  840.  
  841.     dec    bx
  842.     jnz    @@sd1
  843.  
  844.     pop    ds
  845.  
  846.     ; fill empty region depending on attribute
  847.     ; compute source & length for first bank
  848. @@sdfill:
  849.     mov    ax,[ScrollUpper]
  850.     add    ax,[ScrollNLines]
  851.     shl    ax,1            ; since ScanFirst is a word table
  852.     mov    bx,ax
  853.     mov    di,[ScanFirstTable+bx]    ; si = U+N
  854.     dec    di
  855.     dec    di
  856.  
  857.     mov    ax,[ScrollNLines]
  858.     shl    ax,1
  859.     mov    bx,ax
  860.     mov    cx,[Rows2Words+bx]    ; cx = N
  861.  
  862.     mov    ax,[ScrollFill]
  863.  
  864.     ; es and df are unchanged from above
  865.  
  866.     mov    bx,MAXBANKS
  867. @@sd3:
  868.     push    cx
  869.     push    di
  870.  
  871.     rep stosw
  872.  
  873.     pop    di
  874.     pop    cx
  875.  
  876.     add    di,BANKSIZE
  877.  
  878.     dec    bx
  879.     jnz    @@sd3
  880.  
  881.     ret
  882.  
  883. ; The critical DrawCharacter routine.  Almost any technique that make this
  884. ; routine faster is worth the effort.  The reverse, underline and strikeout
  885. ; attributes could be coded into font tables but all the combinations of 5
  886. ; attribute bits would require (2^5)*2K = 64K of font tables!  This is
  887. ; obviously too much.
  888. ;
  889. ; The code of the "inner loop" has been implemented as a macro loop
  890. ; (producing replicated code) for efficiency.
  891. ;
  892. ; Draw a character at the current row & column
  893. ; entry: al = character, bl=attribute
  894. ; uses:  ax,bx,cx,dx, si,di,es
  895. ;
  896. DrawCharacter:
  897.     test    bl,WU            ; word underline wanted?
  898.     jz    @@dc1
  899.     or    bl,UN            ; yes - assume underline ...
  900.     cmp    al,' '
  901.     jne    @@dc1
  902.     and    bl,NOT UN        ; ... except for spaces
  903. @@dc1:
  904.     cmp    [PlainFontOnly],0ffh    ; if only plain font in memory ...
  905.     jne    @@dc2
  906.     test    bl,ATTRIBMASK        ; ... and another font is wanted ...
  907.     jz    @@dc2
  908.     and    bl,NOT ATTRIBMASK    ; ... then print in plain font ...
  909.     or    bl,RV            ; ... with reverse video
  910. @@dc2:
  911.     sub    al,' '            ; adjust out unprintable characters
  912.     jnb    @@dc3
  913.     mov    al,0            ; unprintable characters print as space
  914. @@dc3:
  915.     IF CHARHEIGHT EQ 8
  916.      xor    ah,ah            ; convert char -> FontTable index in si
  917.      shl    ax,1            ; (*CHARHEIGHT bytes per entry)
  918.      shl    ax,1
  919.      shl    ax,1
  920.     ELSE
  921.      mov    ah,CHARHEIGHT
  922.      mul    ah
  923.     ENDIF
  924.     add    ax,OFFSET FontTable
  925.     mov    si,ax
  926.     mov    ax,bx            ; get attribute
  927.     and    ax,ATTRIBMASK        ; isolate font# bits
  928.     mov    cx,(CHARSPERFONT*CHARHEIGHT)
  929.     mul    cx            ; (*?K per font)
  930.     add    si,ax            ; index FontTable to desired font
  931.     mov    cx,bx            ; attribute in cl
  932.     ;
  933.     mov    ax,[CursorCol]
  934.     cmp    ax,MAXCOLUMNS
  935.     jge    @@nodraw
  936.     mov    ax,[CursorRow]
  937.     cmp    ax,MAXROWS
  938.     jge    @@nodraw
  939.     jmp    @@dc4
  940. @@nodraw: ret                ; cursor is off-screen
  941.  
  942. @@dc4:                    ; convert row -> ScanTable index in bx
  943.     IF CHARHEIGHT EQ 8
  944.      shl    ax,1
  945.      shl    ax,1
  946.      shl    ax,1
  947.     ELSE
  948.      mov    bx,CHARHEIGHT
  949.      mul    bx
  950.     ENDIF
  951.     shl    ax,1
  952.     mov    bx,ax
  953.     mov    ax,VIDEOBASE        ; es -> video memory
  954.     mov    es,ax
  955.     cld
  956.  
  957.     lup = 0
  958.     REPT CHARHEIGHT
  959.      mov    dx,[ScanTable+bx]
  960.      add    dx,[CursorCol]
  961.      mov    di,dx
  962.      lodsb
  963.      IF lup EQ (CHARHEIGHT/2)+1
  964.       test    cl,SO
  965.       jz    @@dc&lup&st
  966.       mov    al,0ffh
  967. @@dc&lup&st:
  968.      ENDIF
  969.      IF lup EQ (CHARHEIGHT-1)
  970.       test    cl,UN
  971.       jz    @@dc&lup&un
  972.       mov    al,0ffh
  973. @@dc&lup&un:
  974.      ENDIF
  975.      test    cl,RV
  976. ;     jz    @@dc&lup&rv
  977.      jz    $+4            ; since lup is not local to REPT
  978.      xor    al,0ffh
  979. ;@@dc&lup&rv:
  980.      stosb
  981.      add    bx,2
  982.     lup = lup + 1
  983.     ENDM
  984.  
  985.     ret
  986.  
  987. ClearVideo:
  988.     mov    cx,(MAXBANKS*BANKSIZE)/2
  989.     mov    ax,VIDEOBASE
  990.     mov    es,ax
  991.     xor    di,di
  992.     xor    ax,ax
  993.     cld
  994.     rep stosw
  995.     ret
  996.  
  997. ; ***********************************************************************
  998. ; *                                    *
  999. ; *    HERC Particulars (resident)                    *
  1000. ; *                                    *
  1001. ; ***********************************************************************
  1002.  
  1003.     IFDEF    HERC
  1004.  
  1005. CONFIGPORT    EQU    3bfh
  1006. HALFCONFIG    EQU    1        ; all that SPFONT requires
  1007.  
  1008. MODEPORT    EQU    3b8h
  1009. TEXTMODE    EQU    00h
  1010. GRAPHMODE    EQU    02h
  1011. SCREENOFF    EQU    00h
  1012. SCREENON    EQU    08h
  1013. BLINKOFF    EQU    00h
  1014. BLINKON        EQU    20h
  1015. GPAGE0        EQU    00h
  1016. GPAGE1        EQU    80h
  1017.  
  1018. M6845PORT    EQU    3b4h
  1019. STATUSPORT    EQU    3bah
  1020.  
  1021. graphicsreg    DB    35h,2dh,2eh,7h,5bh,2h,57h,57h,2h,3h,0,0
  1022.  
  1023. EnterGraphicsMode:
  1024.     call    ClearVideo        ; clear display first to avoid ugly "flash"
  1025.  
  1026.     mov    al,HALFCONFIG
  1027.     mov    dx,CONFIGPORT
  1028.     out    dx,al
  1029.  
  1030.     mov    al,GRAPHMODE+GPAGE0+SCREENON
  1031.     mov    dx,MODEPORT
  1032.     out    dx,al
  1033.  
  1034.     xor    ah,ah            ; starting with register 0
  1035.     mov    cx,12            ; for 12 registers
  1036.     mov    dx,M6845PORT
  1037.     mov    si,OFFSET graphicsreg
  1038.     cld
  1039.     cli
  1040. @@rv1:
  1041.     mov    al,ah
  1042.     out    dx,al            ; select register
  1043.     inc    dx
  1044.     lodsb
  1045.     out    dx,al            ; write value
  1046.     inc    ah
  1047.     dec    dx
  1048.     loop    @@rv1
  1049.     sti
  1050.  
  1051.     mov    al,GRAPHMODE+GPAGE0+SCREENON
  1052.     mov    dx,MODEPORT
  1053.     out    dx,al
  1054.     ret
  1055.  
  1056.     ENDIF
  1057.  
  1058. ; ***********************************************************************
  1059. ; *                                    *
  1060. ; *    CGA Particulars                            *
  1061. ; *                                    *
  1062. ; ***********************************************************************
  1063.  
  1064.     IFDEF    CGA
  1065.  
  1066. EnterGraphicsMode:
  1067.     mov    ax,(SETVID*256)+6    ; enter 640x200 b/w mode
  1068.     pushf
  1069.     call    cs:[OldVideoInt]
  1070.     ret
  1071.  
  1072.     ENDIF
  1073.  
  1074. ; ***********************************************************************
  1075. ; *                                    *
  1076. ; *    Tables                                *
  1077. ; *                                    *
  1078. ; ***********************************************************************
  1079.  
  1080. ; This table gives the offset from VIDEOBASE for the start of each
  1081. ; scan line.  The increase in speed by avoiding multiplications
  1082. ; is worth the space.
  1083. ScanTable LABEL WORD
  1084.     scan = 0
  1085.     rept MAXSCANLINES/MAXBANKS
  1086.      bank = 0
  1087.      rept MAXBANKS
  1088.       DW    (bank*BANKSIZE)+(scan*MAXCOLUMNS)
  1089.       bank = bank+1
  1090.      endm
  1091.      scan = scan+1
  1092.     endm
  1093.  
  1094. ScanFirstTable LABEL WORD
  1095.     scan = 0
  1096.     rept MAXROWS+1
  1097.      DW    scan*MAXCOLUMNS*(CHARHEIGHT/MAXBANKS)
  1098.      scan = scan+1
  1099.     endm
  1100.  
  1101. Rows2Words LABEL WORD
  1102.     nrows = 0
  1103.     rept MAXROWS
  1104.      DW    (nrows*MAXCOLUMNS*(CHARHEIGHT/MAXBANKS))/2
  1105.      nrows = nrows+1
  1106.     endm
  1107.  
  1108. ; The font tables.  Currently there are eight fonts implemented (plain,
  1109. ; italic, bold, bold-italic, large, subscript, superscript & other).
  1110. ;
  1111. ; FontTable MUST be the last table before the installation code!  If the
  1112. ; /p option is given then all but the first (plain) font are discarded
  1113. ; when the TSR loads.  This is for the benefit of programmers who are
  1114. ; more interested in 43 lines of text than in fonts and who want to
  1115. ; sacrifice as little ram as possible.
  1116. ;
  1117. ; FontAnchor is used by SPFONTLD to assure that it is really patching a
  1118. ; copy of SPFONT and not scribbling over just any file.
  1119. ;
  1120. FontAnchor    DB    '<SPFONT>'    ; validation string
  1121. FontTableSize    DW    (MAXFONTS*CHARSPERFONT*CHARHEIGHT)
  1122. FontValid    DB    0        ; set to ff by SPFONTLD
  1123.  
  1124. FontTable LABEL BYTE
  1125.         DB    (CHARSPERFONT*CHARHEIGHT) DUP (0)
  1126. EndPlainFonts LABEL BYTE
  1127.         DB    ((MAXFONTS-1)*(CHARSPERFONT*CHARHEIGHT)) DUP (0)
  1128. EndAllFonts LABEL BYTE
  1129.  
  1130. ; ***********************************************************************
  1131. ; *                                    *
  1132. ; *    Installation                            *
  1133. ; *                                    *
  1134. ; ***********************************************************************
  1135.  
  1136. InstallWanted    DB    0        ; assume installation not wanted
  1137.  
  1138. Herald        DB    'SPFONT for '
  1139.     IFDEF    HERC
  1140.         DB    'Hercules'
  1141.     ENDIF
  1142.     IFDEF    CGA
  1143.         DB    'CGA'
  1144.     ENDIF
  1145.         DB    ' (v0.3f) by Andrew D. Morrow','$'
  1146.  
  1147. InstallMsg    DB    ' - Installed','$'
  1148.  
  1149. UninstallMsg    DB    ' - Uninstalled','$'
  1150.  
  1151. PlainMsg    DB    ' (Plain font only)','$'
  1152.  
  1153. CrLfMsg        DB    0dh,0ah,'$'
  1154.  
  1155. HelpMsg        DB    0dh,0ah
  1156.         DB    'Syntax: SPFONT [/options]',0dh,0ah
  1157.         DB    0dh,0ah
  1158.         DB    '/i  Install',0dh,0ah
  1159.         DB    '/p  load Plain font only (no bold,italic,etc.)',0dh,0ah
  1160.         DB    '/a  Adjust cursor size commands relative to CGA 0-7',0dh,0ah
  1161.         DB    '/b  start with nonBlinking cursor',0dh,0dh
  1162.         DB    '/k  start with blocK cursor',0dh,0ah
  1163.         DB    '/u  Uninstall',0dh,0ah
  1164.         DB    '$'
  1165.  
  1166. FontMsg        DB    'Font Table not loaded. Run SPFONTLD.',0dh,0ah,'$'
  1167.  
  1168. InMemMsg    DB    'SPFONT already installed',0dh,0ah,'$'
  1169.  
  1170. CantUnMsg    DB    'Cannot Uninstall',0dh,0ah,'$'
  1171.  
  1172.     IFDEF    HERC
  1173. NoHercMsg    DB    'Cannot detect Hercules Graphics Card',0dh,0ah,'$'
  1174.     ENDIF
  1175.  
  1176.     JUMPS        ; I don't care how inefficient the init code is!
  1177.  
  1178. Init:    
  1179.     ; print herald
  1180.     mov    dx,OFFSET Herald
  1181.     mov    ah,PUTSTR
  1182.     int    DOSINT
  1183.  
  1184.     ; parse command tail
  1185.     mov    bx,0080h        ; first 'inc bx' will skip tail length
  1186. CmdLup:    inc    bx
  1187.     cmp    BYTE PTR [bx],' '    ; deblank
  1188.     je    CmdLup
  1189.     cmp    BYTE PTR [bx],0dh    ; all done?
  1190.     je    EndCmd
  1191.     cmp    BYTE PTR [bx],'/'    ; there had better be an option
  1192.     jnz    DisplayHelpMsg
  1193.     inc    bx            ; look at which option
  1194.     mov    al,BYTE PTR [bx]
  1195.     and    al,01011111b        ; quick-and-dirty capitalization
  1196.     cmp    al,'I'
  1197.     jz    SelectInstall
  1198.     cmp    al,'P'
  1199.     jz    PlainFonts
  1200.     cmp    al,'B'
  1201.     jz    BlinkOff
  1202.     cmp    al,'K'
  1203.     jz    BlockCursor
  1204.     cmp    al,'A'
  1205.     jz    AdjustOn
  1206.     cmp    al,'U'
  1207.     jz    DoUninstall
  1208.     jmp    DisplayHelpMsg
  1209.  
  1210. SelectInstall:
  1211.     mov    [InstallWanted],1
  1212.     jmp    CmdLup
  1213.  
  1214. PlainFonts:
  1215.     mov    [PlainFontOnly],0ffh
  1216.     jmp    CmdLup
  1217.  
  1218. BlinkOff:
  1219.     mov    [CursorBlink],0
  1220.     jmp    CmdLup
  1221.  
  1222. BlockCursor:
  1223.     mov    [CursorTop],0
  1224.     mov    [CursorBot],CHARHEIGHT-1
  1225.     jmp    CmdLup
  1226.  
  1227. AdjustOn:
  1228.     mov    [CursorAdjust],0ffh
  1229.     jmp    CmdLup
  1230.  
  1231. EndCmd:
  1232.     cmp    [InstallWanted],0    ; if installation was not requested
  1233.     je    DisplayHelpMsg        ; then assume that user needs help
  1234.  
  1235.     mov    ax,(GETVECT*256)+VIDEOINT
  1236.     int    DOSINT
  1237.     cmp    bx,OFFSET NewVideoHandler
  1238.     mov    dx,OFFSET InMemMsg
  1239.     je    DisplayErrorMsg
  1240.  
  1241.     cmp    [FontValid],0
  1242.     mov    dx,OFFSET FontMsg
  1243.     je    DisplayErrorMsg
  1244.  
  1245.     IFDEF    HERC
  1246.      call    DetectHercules
  1247.      mov    dx,OFFSET NoHercMsg
  1248.      jz    DisplayErrorMsg
  1249.     ENDIF
  1250.  
  1251.     ; replace 18.2Hz timer
  1252.     mov    ax,(GETVECT*256)+TIMERINT
  1253.     int    DOSINT
  1254.     mov    WORD PTR cs:[OldTimerInt],bx
  1255.     mov    bx,es
  1256.     mov    WORD PTR cs:[OldTimerInt+2],bx
  1257.  
  1258.     mov    dx,OFFSET NewTimerHandler
  1259.     push    ds
  1260.     mov    ax,cs
  1261.     mov    ds,ax
  1262.     mov    ax,(SETVECT*256)+TIMERINT
  1263.     int    DOSINT
  1264.     pop    ds
  1265.  
  1266.     ; replace video driver
  1267.     mov    ax,(GETVECT*256)+VIDEOINT
  1268.     int    DOSINT
  1269.     mov    WORD PTR cs:[OldVideoInt],bx
  1270.     mov    bx,es
  1271.     mov    WORD PTR cs:[OldVideoInt+2],bx
  1272.  
  1273.     mov    dx,OFFSET NewVideoHandler
  1274.     push    ds
  1275.     mov    ax,cs
  1276.     mov    ds,ax
  1277.     mov    ax,(SETVECT*256)+VIDEOINT
  1278.     int    DOSINT
  1279.     pop    ds
  1280.  
  1281.     ; deallocate environment segment
  1282.     mov    ax,ds:[02ch]        ; get env segment from PSP
  1283.     mov    es,ax
  1284.     mov    ah,DEALLOC
  1285.     int    DOSINT
  1286.  
  1287.     ; acknowledge installation
  1288.     mov    dx,OFFSET InstallMsg
  1289.     mov    ah,PUTSTR
  1290.     int    DOSINT
  1291.     cmp    [PlainFontOnly],0ffh
  1292.     jne    @@ai1
  1293.     mov    dx,OFFSET PlainMsg
  1294.     mov    ah,PUTSTR
  1295.     int    DOSINT
  1296. @@ai1:
  1297.     ; terminate & stay resident
  1298.     mov    dx,OFFSET EndPlainFonts
  1299.     cmp    [PlainFontOnly],0ffh
  1300.     je    @@tsr
  1301.     mov    dx,OFFSET EndAllFonts
  1302. @@tsr:    int    TSRINT
  1303.  
  1304. DoUninstall:
  1305.     mov    ax,(GETVECT*256)+VIDEOINT    ; who owns video interrupt?
  1306.     int    DOSINT
  1307.     cmp    bx,OFFSET NewVideoHandler    ; another copy of SPFONT?
  1308.     mov    dx,OFFSET CantUnMsg
  1309.     jne    DisplayErrorMsg            ; no - sorry
  1310.  
  1311.     mov    ax,(GETVECT*256)+TIMERINT    ; who owns timer interrupt?
  1312.     int    DOSINT
  1313.     cmp    bx,OFFSET NewTimerHandler    ; another copy of SPFONT?
  1314.     mov    dx,OFFSET CantUnMsg
  1315.     jne    DisplayErrorMsg            ; no - sorry
  1316.  
  1317.     ; at this point, es = segment address of original SPFONT
  1318.  
  1319.     ; restore video
  1320.     mov    dx,WORD PTR es:[OldVideoInt]
  1321.     push    ds
  1322.     mov    ax,WORD PTR es:[OldVideoInt+2]
  1323.     mov    ds,ax
  1324.     mov    ax,(SETVECT*256)+VIDEOINT
  1325.     push    es
  1326.     int    DOSINT
  1327.     pop    es
  1328.     pop    ds
  1329.  
  1330.     ; restore timer
  1331.     mov    dx,WORD PTR es:[OldTimerInt]
  1332.     push    ds
  1333.     mov    ax,WORD PTR es:[OldTimerInt+2]
  1334.     mov    ds,ax
  1335.     mov    ax,(SETVECT*256)+TIMERINT
  1336.     push    es
  1337.     int    DOSINT
  1338.     pop    es
  1339.     pop    ds
  1340.  
  1341.     ; deallocate original copy of SPFONT
  1342.     mov    ah,DEALLOC
  1343.     int    DOSINT
  1344.  
  1345.     ; acknowledge uninstallation
  1346.     mov    dx,OFFSET UninstallMsg
  1347.     mov    ah,PUTSTR
  1348.     int    DOSINT
  1349.     int    ENDINT
  1350.  
  1351. DisplayHelpMsg:
  1352.     mov    dx,OFFSET HelpMsg
  1353. DisplayErrorMsg:
  1354.     push    dx
  1355.     mov    dx,OFFSET CrLfMsg
  1356.     mov    ah,PUTSTR        ; since herald doesn't crlf
  1357.     int    DOSINT
  1358.     pop    dx
  1359.     mov    ah,PUTSTR        ; print diagnostic
  1360.     int    DOSINT
  1361.     int    ENDINT            ; and quit without doing anything
  1362.  
  1363. ; ***********************************************************************
  1364. ; *                                    *
  1365. ; *    HERC Particulars (transient)                    *
  1366. ; *                                    *
  1367. ; ***********************************************************************
  1368.  
  1369.     IFDEF    HERC
  1370.  
  1371. ; returns ax=ffff if HGC found, else 0 (Zflag set appropriately)
  1372. DetectHercules:
  1373.     mov    ah,GETVID
  1374.     int    VIDEOINT
  1375.     cmp    al,7            ; in mono text mode?
  1376.     jne    @@dh8            ; no
  1377.  
  1378.     mov    dx,STATUSPORT
  1379.     in    al,dx
  1380.     and    al,80h            ; get current vertical retrace state
  1381.     mov    ah,al            ; and store it away
  1382.  
  1383.     mov    cx,0ffffh        ; wait a long time
  1384. @@dh1:    in    al,dx
  1385.     and    al,80h            ; get vertical retrace state again
  1386.     cmp    ah,al            ; any change?
  1387.     jne    @@dh9            ; yes - it's an HGC!
  1388.  
  1389.     loop    @@dh1            ; no - keep testing
  1390.  
  1391. @@dh8:    xor    ax,ax            ; return failure
  1392.     ret
  1393.  
  1394. @@dh9:    or    ax,0ffffh        ; return success
  1395.     ret
  1396.  
  1397.     ENDIF
  1398.  
  1399.     END    Start
  1400.