home
***
CD-ROM
|
disk
|
FTP
|
other
***
search
/
Simtel MSDOS - Coast to Coast
/
simteldosarchivecoasttocoast2.iso
/
pibterm
/
pibt41e3.zip
/
FROMMAC.SCR
< prev
next >
Wrap
Text File
|
1988-02-26
|
4KB
|
108 lines
**************************************************************************
* *
* This script assists you in receiving files FROM a Macintosh *
* using Kermit. *
* *
**************************************************************************
*
* File specification for files to transfer
Declare FileSpec String
* General string for holding replies
Declare Ans String
*
PROCEDURE Help
* Holds bogus input character
Declare Ch String
* Clear the screen
Clear
* Write introductory note about setting
* up Kermit on the Mac.
*
Writeln " ----- Receive Files From Macintosh Using Kermit -----"
Writeln
Writeln "Before transferring files from the Macintosh, make sure to do"
Writeln "the following:"
Writeln
Writeln " (1) Make sure you have connected the serial ports of"
Writeln " the PC and Macintosh together correctly."
Writeln
Writeln " (2) Start up MacKermit on the Macintosh. Set its"
Writeln " communications settings to:"
Writeln
Writeln " 9600 baud"
Writeln " No parity"
Writeln
Writeln " (3) Place MacKermit in server mode."
Writeln
Input "Strike the Return or Enter key to continue." Ch
Writeln
*
ENDPROC Help
*
PROCEDURE FinServe
* Issue FINISH to remote server.
Writeln
Writeln "Finishing MacKermit server ..."
Writeln
*
Send "/finish" "ke"
*
ENDPROC FinServe
*
PROCEDURE RecFile
* Get the name of the file to receive.
*
Writeln
Input "Enter the name of the file to be received from the Mac: " FileSpec
*
* Null file spec -- quit.
*
FileSpec = TRIM( LTRIM( FileSpec ) )
*
IF ( FileSpec = '' ) THEN
Writeln
Writeln "No file name entered, quitting."
Writeln
Call FinServe
Exit
ENDIF
* Get the requested file(s).
Receive FileSpec "ke"
*
ENDPROC RecFile
*
* Ask if instructions are desired.
Writeln
Input "Do you want brief instructions on setting up the Mac? " Ans
Writeln
*
* Display help if requested.
IF ( Ans <> '' ) THEN
IF ( UpperCase( Substr( Ans, 1, 1 ) ) = 'Y' ) THEN
Call Help
ENDIF
ENDIF
* Set communications parameters.
*
* No parity.
SetParam 'PA' 'N'
* 9600 baud.
SetParam 'BA' '9600'
* 8 data bits.
SetParam 'DA' '8'
* 1 stop bit.
SetParam 'ST' '1'
* Hard-wired connection.
SetParam 'HW' '1'
* Ask if instructions are desired.
Writeln
Writeln "You will be prompted for the names of the files to be received."
Writeln "To stop, just hit the Enter or Return key (a blank file name)."
*
* Loop until null file name entered.
REPEAT
*
Call RecFile
* See if we want to send another file.
UNTIL ( 0 )
*