home *** CD-ROM | disk | FTP | other *** search
/ Simtel MSDOS - Coast to Coast / simteldosarchivecoasttocoast2.iso / asmutil / stdlib.zip / STRICMP.ASM < prev    next >
Assembly Source File  |  1990-07-16  |  2KB  |  104 lines
  1. stdlib        segment    para public 'slcode'
  2.         assume    cs:stdlib
  3. ;
  4.         extrn    $uprtbl:byte
  5. ;
  6. ; stricmp- Compares two strings, ignoring differences in case.
  7. ;
  8. ; inputs:
  9. ;
  10. ;    es:di-    First string (The string to compare)
  11. ;    dx:si-    Second string (The string to compare against)
  12. ;
  13. ;    e.g.,
  14. ;        "if (es:di < dx:si) then ..."
  15. ;
  16. ; returns: 
  17. ;
  18. ;    cx- index into strings where they differ (points at the zero byte
  19. ;        if the two strings are equal).
  20. ; 
  21. ;    Condition codes set according to the string comparison.  You should
  22. ;    use the unsigned branches (ja, jb, je, etc.) after calling this
  23. ;    routine.
  24. ;
  25.         public    sl_stricmp
  26. ;
  27. sl_stricmp    proc    far
  28.         push    es
  29.         push    ds
  30.         push    bx
  31.         push    ax
  32.         push    si
  33.         push    di
  34.         xchg    di, si
  35.         mov    ax, es
  36.         mov    ds, ax
  37.         mov    es, dx
  38.         xor    cx, cx        ;Set initial index to zero.
  39.         lea    bx, $uprtbl
  40. ;
  41. ; In order to preserve the direction flag across this call, we have to
  42. ; test whether or not it is set here and execute two completely separate
  43. ; pieces of code (so we know which state to exit in.  Unfortunately, we
  44. ; cannot use pushf to preserve this flag since we need to return status
  45. ; info in the other flags.
  46. ;
  47.         pushf
  48.         pop    ax
  49.         test    ah, 4        ;Test direction bit.
  50.         jnz    DirIsSet
  51. sclp:        lodsb
  52.         xlat    cs:$uprtbl
  53.         mov    ah, al
  54.         mov    al, es:[di]
  55.         xlat    cs:$uprtbl
  56.         cmp    ah, al        
  57.         jne    scNE        ;If strings are <>, quit.
  58.         inc    cx            ;Increment index into strs.
  59.         inc    di        ;Incrment str2 ptr.
  60.         cmp    al, 0        ;Check for end of strings.
  61.         jne    sclp
  62.         pushf
  63.         dec    cx
  64.         popf
  65. ;
  66. scNE:        pop    di
  67.         pop    si
  68.         pop    ax
  69.         pop    bx
  70.         pop    ds
  71.         pop    es
  72.         ret            ;Return with direction flag clear.
  73. ;
  74. ;
  75. DirIsSet:    lodsb
  76.         xlat    cs:$uprtbl
  77.         mov    ah, al
  78.         mov    al, es:[di]
  79.         xlat    cs:$uprtbl        
  80.         cmp    ah, al
  81.         jne    scNE2         ;If strings are <>, quit.
  82.         inc    cx
  83.         inc    di
  84.         cmp    al, 0         ;Check for end of strings.
  85.         jne    DirIsSet
  86.         pushf
  87.         dec    cx
  88.         popf
  89. ;
  90. scNE2:        pop    di
  91.         pop    si
  92.         pop    ax
  93.         pop    bx
  94.         pop    ds
  95.         pop    es
  96.         std            ;Return with direction flag set.
  97.                 ret
  98.  
  99. sl_stricmp    endp
  100. ;
  101. ;
  102. stdlib        ends
  103.         end
  104.