home *** CD-ROM | disk | FTP | other *** search
/ Simtel MSDOS - Coast to Coast / simteldosarchivecoasttocoast2.iso / asmutil / stdlib.zip / STRCMP.ASM < prev    next >
Assembly Source File  |  1990-10-18  |  2KB  |  98 lines
  1. stdlib        segment    para public 'slcode'
  2.         assume    cs:stdlib
  3. ;
  4. ;
  5. ; strcmp- Compares two strings.
  6. ;
  7. ; inputs:
  8. ;
  9. ;    es:di-    First string (The string to compare)
  10. ;    dx:si-    Second string (The string to compare against)
  11. ;
  12. ;    e.g.,
  13. ;        "if (es:di < dx:si) then ..."
  14. ;
  15. ; returns: 
  16. ;
  17. ;    cx- index into strings where they differ (points at the zero byte
  18. ;        if the two strings are equal).
  19. ; 
  20. ;    Condition codes set according to the string comparison.  You should
  21. ;    use the unsigned branches (ja, jb, je, etc.) after calling this
  22. ;    routine.
  23. ;
  24.         public    sl_strcmp
  25. ;
  26. sl_strcmp    proc    far
  27.         push    es
  28.         push    ds
  29.         push    bx
  30.         push    ax
  31.         push    si
  32.         push    di
  33. ;
  34. ; Swap pointers so they're more convenient for the LODSB/SCASB instrs.
  35. ;
  36.         xchg    si, di
  37.         mov    ax, es
  38.         mov    ds, ax
  39.         mov    es, dx
  40. ;
  41.         xor    bx, bx        ;Set initial index to zero.
  42. ;
  43. ; In order to preserve the direction flag across this call, we have to
  44. ; test whether or not it is set here and execute two completely separate
  45. ; pieces of code (so we know which state to exit in.  Unfortunately, we
  46. ; cannot use pushf to preserve this flag since we need to return status
  47. ; info in the other flags.
  48. ;
  49.         pushf
  50.         pop    ax
  51.         test    ah, 4        ;Test direction bit.
  52.         jnz    DirIsSet
  53. sclp:        lodsb
  54.         scasb
  55.         jne    scNE        ;If strings are <>, quit.
  56.         inc    bx            ;Increment index into strs.
  57.         cmp    al, 0        ;Check for end of strings.
  58.         jne    sclp
  59.         pushf
  60.         dec    bx
  61.         popf
  62. ;
  63. scNE:        pop    di
  64.         pop    si
  65.         mov    cx, bx
  66.         pop    ax
  67.         pop    bx
  68.         pop    ds
  69.         pop    es
  70.         ret            ;Return with direction flag clear.
  71. ;
  72. ;
  73. DirIsSet:    lodsb
  74.         scasb
  75.         jne    scNE2         ;If strings are <>, quit.
  76.         inc    bx
  77.         cmp    al, 0         ;Check for end of strings.
  78.         jne    DirIsSet
  79.         pushf
  80.         dec    bx
  81.         popf
  82. ;
  83. scNE2:        pop    di
  84.         pop    si
  85.         mov    cx, bx
  86.         pop    ax
  87.         pop    bx
  88.         pop    ds
  89.         pop    es
  90.         std            ;Return with direction flag set.
  91.                 ret
  92.  
  93. sl_strcmp    endp
  94. ;
  95. ;
  96. stdlib        ends
  97.         end
  98.