home *** CD-ROM | disk | FTP | other *** search
/ Simtel MSDOS - Coast to Coast / simteldosarchivecoasttocoast.iso / pcmag / vol8n12.zip / XMSDISK.ASM < prev   
Assembly Source File  |  1989-02-13  |  28KB  |  644 lines
  1.         title   XMSDISK XMS-aware RAMdisk
  2.         page    55,132
  3.  
  4. ; XMSDISK.ASM --- XMS-aware RAMdisk device driver
  5. ; Copyright (C) 1989 Ziff Davis Communications
  6. ; PC Magazine * Ray Duncan
  7. ; Also requires ITOA.ASM and ATOI.ASM.
  8. ;
  9. ; To build:     MASM XMSDISK;
  10. ;               MASM ATOI;
  11. ;               MASM ITOA;
  12. ;               LINK XMSDISK+ATOI+ITOA;
  13. ;               EXE2BIN XMSDISK.EXE XMSDISK.BIN
  14. ;               DEL XMSDISK.EXE
  15. ;
  16. ; To install:   copy XMSDISK.SYS to the boot disk, add
  17. ;
  18. ;                       DEVICE=XMSDISK.BIN  nnnK
  19. ; 
  20. ;               to the CONFIG.SYS file.  This must follow
  21. ;               the DEVICE= line that loads the XMM (usually
  22. ;               HIMEM.SYS).  The parameter nnn is the desired
  23. ;               RAMdisk size in KB.  If nnn is missing or zero,
  24. ;               all available extended memory is used.
  25. ;
  26. _TEXT   segment public 'CODE'
  27.  
  28.         extrn   atoi:near
  29.         extrn   itoa:near
  30.  
  31.         assume  cs:_TEXT,ds:_TEXT,es:NOTHING
  32.  
  33.         org     0
  34.  
  35. maxcmd  equ     24                      ; maximum driver command code
  36.  
  37. cr      equ     0dh                     ; ASCII carriage return
  38. lf      equ     0ah                     ; ASCII line feed
  39. blank   equ     020h                    ; ASCII space code
  40. eom     equ     '$'                     ; end of message indicator
  41.  
  42. secsize equ     512                     ; bytes per sector (IBM standard)
  43. dirsize equ     256                     ; entries in root directory             
  44.  
  45. request struc                           ; request packet template
  46. len     db      ?                       ; length of request packet
  47. unit    db      ?                       ; unit number for this request
  48. command db      ?                       ; request packet's command code
  49. status  dw      ?                       ; status returned by driver
  50.         db      8 dup (?)               ; reserved area
  51. media   db      ?                       ; media descriptor byte
  52. address dd      ?                       ; memory address for transfer
  53. count   dw      ?                       ; byte/sector count value
  54. sector  dw      ?                       ; starting sector value
  55. request ends                            ; end of request packet template
  56.  
  57. header  equ     $                       ; device driver header
  58.         dd      -1                      ; link to next driver 
  59.         dw      0                       ; device attribute word
  60.         dw      strat                   ; device "Strategy" entry point
  61.         dw      intr                    ; device "Interrupt" entry point
  62.         db      1                       ; number of units, this device
  63.         db      7 dup (0)               ; reserved (block drivers)
  64.  
  65. rqptr   dd      ?                       ; far pointer to request packet
  66. savesp  dw      0                       ; save kernel SS:SP during switch
  67. savess  dw      0                       ; to driver's private stack
  68. xmm     dd      0                       ; address of XMM entry point
  69. handle  dw      0                       ; handle for extended memory block
  70. total   dw      0                       ; total extended mem available (KB)
  71. largest dw      0                       ; largest free block available (KB)
  72. alloc   dw      0                       ; extended memory allocated (KB)
  73. clust   dw      0                       ; total clusters in RAMdisk
  74. xfersec dw      0                       ; current sector for transfer
  75. xfercnt dw      0                       ; sectors successfully transferred
  76. xferreq dw      0                       ; number of sectors requested   
  77.  
  78. array   dw      bpb                     ; array of pointers to BPBs
  79.                                         ; for each logical unit
  80.  
  81. movpars equ     $                       ; XMS Function 0BH parameter block 
  82. movelen dd      0                       ; length to move in bytes
  83. shandle dw      0                       ; source handle
  84. soffset dd      0                       ; source offset or far pointer
  85. dhandle dw      0                       ; destination handle
  86. doffset dd      0                       ; destination offset or far pointer
  87.  
  88. bootrec equ     $                       ; boot record for logical sec. 0
  89.         jmp     $                       ; phony JMP at start of boot
  90.         nop                             ; sector (must be 3 bytes)
  91.         db      'IBM  3.3'              ; OEM identity field
  92.                                         ; BIOS Parameter Block (BPB)
  93. bpb     dw      secsize                 ; 0   bytes per sector
  94.         db      2                       ; 2   sectors per cluster
  95.         dw      1                       ; 3   reserved sectors
  96.         db      1                       ; 5   number of FATs
  97.         dw      dirsize                 ; 6   root directory entries
  98.         dw      0                       ; 8   total sectors
  99.         db      0f8h                    ; 0AH medium descriptor byte
  100.         dw      0                       ; 0BH sectors per FAT
  101. bootrec_len equ $-bootrec               ; length of boot record
  102.  
  103.         even                            ; force word alignment
  104.         dw      128 dup (0)
  105. stk     equ     $                       ; local stack for driver
  106.  
  107. ;
  108. ; Driver 'strategy' routine; called by MS-DOS kernel with
  109. ; ES:BX pointing to driver request packet.
  110. ;
  111. strat   proc    far                     ; driver 'strategy' routine
  112.  
  113.         mov     word ptr cs:rqptr,bx    ; save request packet address
  114.         mov     word ptr cs:rqptr+2,es
  115.         ret                             ; back to MS-DOS kernel
  116.  
  117. strat   endp
  118.  
  119. ;
  120. ; Driver 'interrupt' routine, called by MS-DOS kernel immediately
  121. ; after call to 'strategy' routine to process I/O request.
  122. ;
  123. intr    proc    far                     
  124.  
  125.         push    ax                      ; save all registers
  126.         push    bx
  127.         push    cx
  128.         push    dx
  129.         push    ds
  130.         push    es
  131.         push    di
  132.         push    si
  133.         push    bp
  134.  
  135.         mov     ax,cs                   ; make local data addressable
  136.         mov     ds,ax
  137.         mov     savess,ss               ; save DOS kernel's stack
  138.         mov     savesp,sp
  139.         mov     ss,ax                   ; set SS:SP to point to 
  140.         mov     sp,offset stk           ; (larger) local stack
  141.  
  142.         les     di,rqptr                ; ES:DI = request packet
  143.         mov     bl,es:[di.command]      ; get BX = command code
  144.         xor     bh,bh
  145.         cmp     bx,maxcmd               ; make sure it's legal
  146.         jle     intr1                   ; jump, function code is ok
  147.         mov     ax,8003h                ; return 'unknown command' error
  148.         jmp     intr2
  149.  
  150. intr1:  shl     bx,1                    ; branch to command code routine
  151.         call    word ptr [bx+dispch]    ; must return AX = status
  152.         les     di,rqptr                ; ES:DI = request packet again
  153.  
  154. intr2:  or      ax,0100h                ; merge 'done' bit into status
  155.         mov     es:[di.status],ax       ; store into request packet
  156.  
  157.         mov     ss,savess               ; restore DOS kernel's stack
  158.         mov     sp,savesp
  159.  
  160.         pop     bp                      ; restore general registers
  161.         pop     si
  162.         pop     di
  163.         pop     es
  164.         pop     ds
  165.         pop     dx
  166.         pop     cx
  167.         pop     bx
  168.         pop     ax
  169.         ret                             ; back to kernel
  170.  
  171. intr    endp
  172.  
  173. ;
  174. ; Dispatch table for driver commands
  175. ;
  176. dispch  dw      init                    ;  0 = initialize driver
  177.         dw      medchk                  ;  1 = media check on block device
  178.         dw      bldbpb                  ;  2 = build BIOS parameter block
  179.         dw      error                   ;  3 = I/O control read 
  180.         dw      read                    ;  4 = read from device
  181.         dw      error                   ;  5 = non-destructive read 
  182.         dw      error                   ;  6 = return current input status
  183.         dw      error                   ;  7 = flush device input buffers
  184.         dw      write                   ;  8 = write to device
  185.         dw      write                   ;  9 = write with verify
  186.         dw      error                   ; 10 = return current output status
  187.         dw      error                   ; 11 = flush output buffers
  188.         dw      error                   ; 12 = I/O control write 
  189.         dw      error                   ; 13 = device open        (DOS 3.0+)
  190.         dw      error                   ; 14 = device close       (DOS 3.0+)
  191.         dw      error                   ; 15 = removeable media   (DOS 3.0+)
  192.         dw      error                   ; 16 = output until busy  (DOS 3.0+)   
  193.         dw      error                   ; 17 = not used
  194.         dw      error                   ; 18 = not used
  195.         dw      error                   ; 19 = generic IOCTL      (DOS 3.2+) 
  196.         dw      error                   ; 20 = not used
  197.         dw      error                   ; 21 = not used
  198.         dw      error                   ; 22 = not used
  199.         dw      error                   ; 23 = get logical device (DOS 3.2+)
  200.         dw      error                   ; 24 = set logical device (DOS 3.2+)
  201.  
  202. ;
  203. ; Media Check routine (command code 1).  Returns code indicating
  204. ; whether medium has been changed since last access.
  205. ;
  206. medchk  proc    near
  207.  
  208.         mov     byte ptr es:[di+14],1   ; return "not changed" code
  209.         xor     ax,ax                   ; return success status
  210.         ret
  211.  
  212. medchk  endp
  213.  
  214. ;
  215. ; Build BPB routine (command code 2).  Returns pointer to valid
  216. ; BIOS Parameter Block for logical drive.
  217. ;
  218. bldbpb  proc    near
  219.  
  220.         mov     word ptr es:[di+20],cs  ; put BPB address in packet
  221.         mov     word ptr es:[di+18],offset bpb
  222.         xor     ax,ax                   ; return success status
  223.         ret
  224.  
  225. bldbpb  endp
  226.  
  227. ;
  228. ; Read routine (command code 4).  Transfers logical sector(s)
  229. ; from RAMdisk storage to specified address.
  230. ;
  231. read    proc    near
  232.  
  233.         mov     ax,es:[di.sector]       ; ES:DI = request packet
  234.         mov     xfersec,ax              ; save starting sector number
  235.         mov     ax,es:[di.count]        
  236.         mov     xferreq,ax              ; save sectors requested
  237.         mov     xfercnt,0               ; init sectors transferred count
  238.         mov     ax,word ptr es:[di.address]
  239.         mov     word ptr doffset,ax     ; requestor's buffer address
  240.         mov     ax,word ptr es:[di.address+2]
  241.         mov     word ptr doffset+2,ax
  242.         mov     ax,handle               ; source handle = extended
  243.         mov     shandle,ax              ;                 memory handle
  244.         mov     dhandle,0               ; destination handle = 0
  245.         mov     word ptr movelen,secsize; logical sector length
  246.  
  247. read1:  mov     ax,xfercnt              ; done with all sectors yet?
  248.         cmp     ax,xferreq
  249.         je      read2                   ; jump if transfer completed
  250.  
  251.         mov     ax,xfersec              ; source offset = 
  252.         mul     bpb                     ; sector no. * bytes/sector
  253.         mov     word ptr soffset,ax
  254.         mov     word ptr soffset+2,dx
  255.  
  256.         mov     ah,0bh                  ; move this sector from
  257.         mov     si,offset movpars       ; extended memory to requestor
  258.         call    xmm
  259.         or      ax,ax                   ; any error?
  260.         jz      read4                   ; yes, abort transfer
  261.  
  262.         inc     xfersec                 ; advance sector and address
  263.         add     word ptr doffset+2,(secsize/16)
  264.         inc     xfercnt                 ; count sectors transferred
  265.         jmp     read1
  266.  
  267. read2:                                  ; all sectors transferred,
  268.         xor     ax,ax                   ; return success status
  269.  
  270. read3:  les     di,rqptr                ; get address of request packet
  271.         mov     bx,xfercnt              ; return sectors transferred count
  272.         mov     es:[di.count],bx
  273.         ret
  274.  
  275. read4:  mov     ax,800bh                ; XMM error, return 'read fault'
  276.         jmp     read3
  277.  
  278. read    endp
  279.  
  280. ;
  281. ; Write (command code 8) and Write with Verify (command code 9)
  282. ; routine.  Transfers logical sector(s) from specified address
  283. ; to RAMdisk storage.
  284. ;
  285. write   proc    near
  286.  
  287.         mov     ax,es:[di.sector]       ; ES:DI = request packet
  288.         mov     xfersec,ax              ; save starting sector number
  289.         mov     ax,es:[di.count]        
  290.         mov     xferreq,ax              ; save sectors requested
  291.         mov     xfercnt,0               ; init sectors transferred count
  292.         mov     ax,word ptr es:[di.address]     
  293.         mov     word ptr soffset,ax     ; requestor's buffer address
  294.         mov     ax,word ptr es:[di.address+2]
  295.         mov     word ptr soffset+2,ax
  296.         mov     ax,handle               ; destination handle = extended
  297.         mov     dhandle,ax              ;                   memory handle
  298.         mov     shandle,0               ; zero out source handle
  299.         mov     word ptr movelen,secsize; logical sector length
  300.  
  301. write1: mov     ax,xfercnt              ; done with all sectors yet?
  302.         cmp     ax,xferreq
  303.         je      write2                  ; jump if transfer completed
  304.  
  305.         mov     ax,xfersec              ; destination offset = 
  306.         mul     bpb                     ; sector no. * bytes/sector
  307.         mov     word ptr doffset,ax
  308.         mov     word ptr doffset+2,dx
  309.  
  310.         mov     ah,0bh                  ; move this sector from
  311.         mov     si,offset movpars       ; requestor to extended memory
  312.         call    xmm
  313.         or      ax,ax                   ; any error?
  314.         jz      write4                  ; yes, abort transfer
  315.  
  316.         inc     xfersec                 ; advance sector and address
  317.         add     word ptr soffset+2,(secsize/16)
  318.         inc     xfercnt                 ; count sectors transferred
  319.         jmp     write1
  320.  
  321. write2:                                 ; all sectors successfully
  322.         xor     ax,ax                   ; transferred, return ok status
  323.  
  324. write3:
  325.         les     di,rqptr                ; get address of request packet
  326.         mov     bx,xfercnt              ; return actual transfer count
  327.         mov     es:[di.count],bx
  328.         ret
  329.  
  330. write4: mov     ax,800ah                ; XMM error, return 'write fault'
  331.         jmp     write3          
  332.  
  333. write   endp
  334.  
  335. ;
  336. ; Dummy routine for unsupported driver command codes
  337. ;
  338. error   proc    near
  339.  
  340.         mov     ax,8103h                ; return 'unknown command' error
  341.         ret
  342.  
  343. error   endp
  344.  
  345. ;
  346. ; Initialization routine, called at driver load time.  Returns
  347. ; address of 'init' label to MS-DOS as start of free memory, so
  348. ; that memory occupied by 'init' and its subroutines is reclaimed.
  349. ;
  350. init    proc    near                    ; command code 0 = initialize
  351.  
  352.         mov     ax,4300h                ; check if XMM present
  353.         int     2fh
  354.         cmp     al,80h                  ; status = installed?
  355.         je      init1                   ; yes, proceed
  356.         mov     dx,offset msg1          ; no, display error message
  357.         jmp     init8                   ; and abort installation
  358.  
  359. init1:  mov     ax,4310h                ; XMM available, request entry
  360.         int     2fh                     ; point and save it
  361.         mov     word ptr xmm,bx
  362.         mov     word ptr xmm+2,es
  363.  
  364.         mov     ah,8                    ; get available extended memory
  365.         call    xmm                     ; transfer to XMM
  366.         mov     total,dx                ; save total KB available
  367.         mov     largest,ax              ; save largest free block
  368.         cmp     largest,64              ; at least 64 KB available?
  369.         jae     init2                   ; yes, proceed
  370.         mov     dx,offset msg2          ; no, display error message
  371.         jmp     init8                   ; and abort installation
  372.  
  373. init2:  les     di,rqptr                ; let ES:DI = request packet
  374.         lds     si,es:[di+18]           ; point to CONFIG.SYS line
  375.  
  376. init3:  lodsb                           ; scan for end of driver name
  377.         cmp     al,blank
  378.         ja      init3                   ; loop while within name
  379.         dec     si                      ; point to delimiter and
  380.         call    atoi                    ; convert size parameter
  381.         push    cs                      ; make our data addressable
  382.         pop     ds
  383.         or      ax,ax                   ; size parameter missing?
  384.         jz      init4                   ; yes, use all extended memory
  385.         cmp     ax,largest              ; requested > available?
  386.         jna     init5                   ; no, jump
  387.  
  388. init4:  mov     ax,largest              ; use all of available memory
  389.  
  390. init5:  mov     alloc,ax                ; save requested size
  391.         mov     dx,ax                   ; DX = RAMdisk size in KB
  392.         mov     ah,9                    ; XMS function 9 = allocate
  393.         call    xmm                     ; transfer to XMM
  394.         or      ax,ax                   ; allocation successful?
  395.         jnz     init6                   ; yes, proceed
  396.         mov     dx,offset msg3          ; no, display error message
  397.         jmp     init8                   ; and abort installation
  398.  
  399. init6:  mov     handle,dx               ; save extended memory handle
  400.         call    makebpb                 ; set up Bios Parameter Block
  401.         call    format                  ; format the RAMdisk
  402.         jnc     init7                   ; jump if no error during format
  403.         mov     dx,offset msg4          ; formatting error, exit
  404.         jmp     init8
  405.  
  406. init7:  les     di,rqptr                ; let ES:DI = request packet
  407.         mov     al,es:[di+22]           ; get drive code from header,
  408.         add     al,'A'                  ; convert to ASCII for output
  409.         mov     ident1,al
  410.         mov     ax,total                ; convert KB available to ASCII
  411.         mov     si,offset ident2
  412.         mov     cx,10
  413.         call    itoa
  414.         mov     ax,largest              ; convert KB largest free block
  415.         mov     si,offset ident3
  416.         call    itoa
  417.         mov     ax,alloc                ; convert KB allocated to ASCII
  418.         mov     si,offset ident4
  419.         call    itoa
  420.  
  421.         mov     dx,offset ident         ; display sign-on message
  422.         mov     ah,9                    ; function 9 = display string
  423.         int     21h                     ; transfer to MS-DOS    
  424.  
  425.                                         ; set top of driver address
  426.         mov     word ptr es:[di.address],offset init
  427.         mov     word ptr es:[di.address+2],cs
  428.         mov     byte ptr es:[di+13],1   ; indicate 1 logical unit
  429.         mov     word ptr es:[di+20],cs  ; return address of BPB array
  430.         mov     word ptr es:[di+18],offset array
  431.         jmp     init9
  432.  
  433. init8:                                  ; XMSDISK initialization failed
  434.         push    dx                      ; save specific error message
  435.         mov     dx,offset errmsg        ; display error heading
  436.         mov     ah,9                    ; function 9 = display string
  437.         int     21h                     ; transfer to MS-DOS
  438.         pop     dx                      ; display error description
  439.         mov     ah,9                    ; function 9 = display string
  440.         int     21h                     ; transfer to MS-DOS
  441.  
  442.         les     di,cs:rqptr             ; let ES:DI=request packet
  443.                                         ; set driver end = driver start
  444.         mov     word ptr es:[di.address],0
  445.         mov     word ptr es:[di.address+2],cs
  446.         mov     byte ptr es:[di+13],0   ; set no. of logical units = 0
  447.  
  448. init9:  xor     ax,ax                   ; return success status 
  449.         ret
  450.  
  451. init    endp
  452.  
  453. ;
  454. ; Set up total sectors and sectors per FAT fields of BIOS Parameter
  455. ; Block according to size of RAMdisk.  Calculate and save total
  456. ; clusters (indicates whether 12-bit or 16-bit FAT will be used).
  457. ;
  458. makebpb proc    near
  459.         
  460.         mov     ax,alloc                ; get size of allocated block
  461.         mov     dx,1024                 ; convert KB to bytes
  462.         mul     dx                      ; divided by bytes/sector
  463.         div     word ptr bpb            ; gives AX = total sectors
  464.         mov     bpb+8,ax                ; update BPB with total sectors
  465.         xor     dx,dx                   ; sectors / (sectors/cluster)
  466.         xor     ch,ch                   ; = total clusters
  467.         mov     cl,byte ptr bpb+2
  468.         div     cx
  469.         mov     clust,ax                ; save total clusters   
  470.         cmp     ax,4086                 ; clusters < 4087?
  471.         jna     makeb1                  ; yes, jump 
  472.         shl     ax,1                    ; no, assume 16-bit FAT
  473.         jmp     makeb2                  ; clusters * 2 = bytes/FAT
  474.  
  475. makeb1: mov     dx,ax                   ; if clusters < 4087, 12-bit FAT
  476.         add     ax,ax                   ; clusters * 1.5 = bytes/FAT
  477.         add     ax,dx
  478.         shr     ax,1
  479.         jnc     makeb2
  480.         inc     ax                      ; round bytes up if necessary
  481.  
  482. makeb2: xor     dx,dx                   ; (bytes/FAT) / (bytes/sec)
  483.         div     word ptr bpb            ; = sectors/FAT
  484.         or      dx,dx                   ; any remainder?
  485.         jz      makeb3                  ; no,jump
  486.         inc     ax                      ; round up to next sector
  487.  
  488. makeb3: mov     bpb+0bh,ax              ; update FAT size in BPB
  489.         ret
  490.  
  491. makebpb endp
  492.  
  493. ;
  494. ; Format RAMdisk.  First write zeros into all sectors of reserved
  495. ; area, FAT, and root directory.  Then copy phony boot record to
  496. ; boot sector, initialize medium ID byte at beginning of FAT, and
  497. ; place phony volume label in first sector of root directory.
  498. ;
  499. format  proc    near            
  500.  
  501.         push    ds                      ; initialize sector buffer
  502.         pop     es                      ; to zeros so we can clear
  503.         mov     di,offset secbuf        ; out reserved area, FAT,
  504.         mov     cx,secsize              ; and root directory
  505.         xor     al,al
  506.         rep stosb
  507.  
  508.         mov     ax,bpb+6                ; no. of directory entries
  509.         mov     cx,32                   ; * (32 bytes/entry)
  510.         mul     cx                      ; = bytes in root directory
  511.         div     bpb                     ; / (bytes/sector)
  512.         or      dx,dx                   ; = sectors in root directory
  513.         jz      fmt1
  514.         inc     ax                      ; round up any partial sector
  515.  
  516. fmt1:   add     ax,bpb+3                ; + reserved sectors
  517.         add     ax,bpb+0bh              ; + sectors in FAT
  518.         mov     xferreq,ax              ; = total sectors to clear
  519.         mov     xfercnt,0               ; initialize sector counter
  520.  
  521.                                         ; set up move parameter block
  522.         mov     word ptr movelen,secsize; length to move
  523.         mov     shandle,0               ; source handle and address
  524.         mov     word ptr soffset,offset secbuf
  525.         mov     word ptr soffset+2,cs
  526.         mov     ax,handle               ; destination extended memory
  527.         mov     dhandle,ax              ; block handle
  528.         mov     word ptr doffset,0      ; initial destination offset
  529.         mov     word ptr doffset+2,0
  530.  
  531. fmt2:   mov     ah,0bh                  ; write this sector
  532.         mov     si,offset movpars       ; DS:SI = parameter block
  533.         call    xmm                     ; transfer to XMM
  534.         or      ax,ax                   ; test move status
  535.         jnz     fmt3
  536.         jmp     fmt5                    ; abort if move failed
  537.  
  538. fmt3:   add     word ptr doffset,secsize; increment destination address
  539.         adc     word ptr doffset+2,0
  540.         mov     ax,xfercnt              ; count sectors initialized
  541.         inc     ax
  542.         mov     xfercnt,ax
  543.         cmp     ax,xferreq              ; done yet?
  544.         jne     fmt2                    ; not done, write another
  545.  
  546.         mov     ax,bpb+3                ; calculate offset of first
  547.         mul     bpb                     ; FAT sector in RAMdisk buffer
  548.         mov     word ptr doffset,ax     ; set destination address
  549.         mov     word ptr doffset+2,dx
  550.  
  551.         mov     al,byte ptr bpb+0ah     ; set up medium ID byte
  552.         mov     secbuf,al               ; in first FAT sector
  553.         mov     word ptr secbuf+1,-1    ; assume 12-bit FAT
  554.         cmp     clust,4086              ; more than 4086 clusters?
  555.         jna     fmt4                    ; no, jump
  556.         mov     secbuf+3,0ffh           ; yes, use 16-bit FAT
  557.  
  558. fmt4:   mov     ah,0bh                  ; write first FAT sector
  559.         mov     si,offset movpars
  560.         call    xmm
  561.         or      ax,ax                   ; test move status
  562.         jz      fmt5                    ; abort if move failed
  563.  
  564.         mov     word ptr doffset,0      ; offset of logical sector 0
  565.         mov     word ptr doffset+2,0
  566.         mov     word ptr soffset,offset bootrec
  567.         mov     word ptr movelen,bootrec_len
  568.         mov     ah,0bh                  ; copy phony boot record
  569.         mov     si,offset movpars       ; to logical sector 0
  570.         call    xmm
  571.         or      ax,ax                   ; test move status
  572.         jz      fmt5                    ; abort if move failed
  573.  
  574.         mov     ax,bpb+0bh              ; calculate offset of first
  575.         add     ax,bpb+3                ; root directory sector
  576.         mul     bpb                     ; in RAMdisk buffer
  577.         mov     word ptr doffset,ax
  578.         mov     word ptr doffset+2,dx
  579.         mov     word ptr soffset,offset volname
  580.         mov     word ptr movelen,volname_len
  581.         mov     ah,0bh                  ; copy phony volume label
  582.         mov     si,offset movpars       ; to first directory sector
  583.         call    xmm
  584.         or      ax,ax                   ; test move status
  585.         jz      fmt5                    ; abort if move failed
  586.  
  587.         clc                             ; successful format, 
  588.         ret                             ; return CY = clear
  589.  
  590. fmt5:   stc                             ; format failed, 
  591.         ret                             ; return CY = set
  592.  
  593. format  endp
  594.  
  595. ;
  596. ; Miscellaneous data used during initialization, then discarded.
  597. ;
  598. ident   db      cr,lf,lf                ; sign-on message
  599.         db      'XMSDISK Extended Memory RAMdisk'
  600.         db      cr,lf
  601.         db      'Copyright (C) 1989 Ziff Davis Communications'
  602.         db      cr,lf
  603.         db      'PC Magazine * Ray Duncan'
  604.         db      cr,lf,lf
  605.         db      'XMSDISK will be drive '
  606. ident1  db      'X:',cr,lf
  607.         db      'Extended memory available:'
  608. ident2  db      '       KB',cr,lf
  609.         db      'Largest free memory block:'
  610. ident3  db      '       KB',cr,lf
  611.         db      'Extended memory allocated:'
  612. ident4  db      '       KB',cr,lf,eom
  613.  
  614. errmsg  db      cr,lf
  615.         db      'XMSDISK installation error:'
  616.         db      cr,lf,eom
  617.  
  618. msg1    db      'Extended Memory Manager not found.'
  619.         db      cr,lf,eom
  620.  
  621. msg2    db      'Insufficient extended memory available.'
  622.         db      cr,lf,eom
  623.  
  624. msg3    db      'Extended memory allocation failed.'
  625.         db      cr,lf,eom
  626.  
  627. msg4    db      'Unable to format RAMdisk.'
  628.         db      cr,lf,eom
  629.  
  630. volname db      'XMSDISK    '           ; phony volume label
  631.         db      08h                     ; volume label attribute byte
  632.         db      10 dup (0)
  633.         dw      0                       ; time = 00:00:00
  634.         dw      1241h                   ; date = February 1, 1989
  635.         db      6 dup (0)
  636. volname_len equ $-volname
  637.  
  638. secbuf  db      secsize dup (?)         ; sector buffer for format
  639.  
  640. _TEXT   ends
  641.         
  642.         end
  643.  
  644.