home *** CD-ROM | disk | FTP | other *** search
/ Simtel MSDOS 1992 June / SIMTEL_0692.cdr / msdos / sysutl / aux2.arc / AUX2.ASM next >
Encoding:
Assembly Source File  |  1987-03-21  |  4.3 KB  |  214 lines
  1.     title    aux2 - com2 AUX driver
  2. ;
  3. ; This program will make the AUX driver talk to the COM2 port so that Windows
  4. ; can have it's debugging terminal on COM2.
  5. ;
  6. ;    Copyright (c) Steve Brozosky, 1987
  7. ;
  8. ;        Steve Brozosky
  9. ;        2555 Raven Road
  10. ;        Pleasanton, CA  94566
  11. ;
  12. ;
  13. ;    This program is available for the Public Domain.
  14. ;
  15. ;
  16. ;    Version 1.00   January 19, 1987
  17. ;
  18. ;
  19. ;    To use, add the following line to your CONFIG.SYS:
  20. ;
  21. ;        device=aux2.sys
  22. ;
  23. ;
  24. ;    To Build this program:
  25. ;
  26. ;        masm aux2;
  27. ;        link aux2;
  28. ;        exe2bin aux2 aux2.sys
  29. ; 
  30. Cseg    segment para public 'code'
  31.  
  32.  
  33. Request       equ    es:[bx]        ;pointer to request header
  34.  
  35. RequestH   Struc          ;Request header structure
  36.         db    ?         ;length of Request Header (including data)
  37.         db    ?         ;unit code 
  38. Command    db    ?         ;command code
  39. Status       dw    ?         ;status
  40.         dq    ?         ;reserved for DOS
  41. Media       db    ?        ;media descriptor byte
  42. AddrOff       dw    ?        ;transfer address
  43. AddrSeg       dw    ?    
  44. Count       dw     ?        ;byte/sector count value
  45. Sector       dw    ?        ;starting sector value
  46. RequestH   Ends
  47.  
  48.  
  49. Aux2        proc    far
  50.  
  51.         assume    cs:Cseg, ds:nothing, es:nothing
  52. begin:
  53.  
  54. NextDev     dd    -1            ;no more devices
  55. Attribute    dw    1000100000000000b    ;char device, supports open
  56. Strategy    dw    AuxStrategy        ;ptr to device strategy code
  57. Interrupt    dw    AuxInt            ;ptr of drive interrupt code    
  58. devName     db    'AUX     '        ;logical name
  59.  
  60. RequestOff    dw    ?
  61. RequestSeg    dw    ?
  62.  
  63. ;
  64. ;    function table
  65. ;
  66. funTab        label    word
  67.         dw    Init            ;Initialization
  68.         dw    MediaCheck        ;Media check 
  69.         dw    BuildBpb        ;Build BIOS parm block
  70.         dw    IoCtlIn            ;I/O control read
  71.         dw    Read            ;Read
  72.         dw    NdRead            ;Nondestructive read
  73.         dw    InStat            ;Input status
  74.         dw    InFlush            ;Flush input buffers
  75.         dw    Write            ;Write
  76.         dw    WriteVerify        ;Write with verify
  77.         dw    OutStat            ;Output statuc
  78.         dw    OutFlush        ;Flush output buffers
  79.         dw    IoCtlOut        ;I/O control write
  80.         dw    Open            ;Open
  81.         dw    Close            ;Close
  82.  
  83. ;
  84. ;    Strategy Routine.
  85. ;
  86. ;    Input:
  87. ;      es:bx         Address of Request Header
  88. ;
  89. AuxStrategy:
  90.     mov    cs:RequestSeg,es    ;save segment of request header
  91.     mov    cs:RequestOff,bx    ;save offset of request header
  92.     ret                ;and just return
  93.  
  94. ;
  95. ;    Interrupt Routine.
  96. ;
  97. ;    Will process the previous request header.
  98. ;
  99. AuxInt:
  100.     pushf                ;save everything first
  101.     push    ds
  102.     push    es
  103.     push    ax
  104.     push    bx
  105.     push    cx
  106.     push    dx
  107.     push    di
  108.     push    si
  109.     cld
  110.  
  111.     les    bx,dword ptr cs:RequestOff ;point to request header
  112.     mov    al,Request.Command    ;get command code
  113.     shl    al,1            ;make into 16 bit offset
  114.     xor    ah,ah            ;clear high bits
  115.     lea    di,funTab        ;get address of function table
  116.     add    di,ax            ;now point to appropriate routine
  117.     jmp    word ptr [di]        ;and go to it
  118.  
  119. ;
  120. ;    Output Routines.
  121. ;
  122. Write:
  123. WriteVerify:
  124.     mov    cx, Request.Count    ;get number of bytes to write
  125.     lds    si,dword ptr Request.AddrOff    ;point to data
  126. ;
  127. OLoop:
  128.     lodsb                ;get byte to output
  129.     mov    ah,1            ;transmit character
  130.     mov    dx,1            ;go to com2
  131.     int    14h            ;call BIOS comm output routine
  132.                     ;no error checking is done here
  133.     loop    OLoop            ;send out whole string
  134.  
  135.     jmp    done            ;and exit driver
  136. ;
  137. ;
  138. ;    Input Routine  (Read 1 byte)
  139. ;
  140. Read:
  141.     les    di,dword ptr Request.AddrOff    ;point to buffer
  142. ;
  143.     mov    dx,1            ;go to com2
  144.     mov    ah,2            ;receive char from comm port
  145.     int    14h            ;call BIOS routine
  146. ;
  147.     stosb                ;put byte into buffer
  148. ;
  149.     jmp    done            ;all done, exit driver
  150.  
  151. ;
  152. ;    These routines are not supported and should just return
  153. ;    with done flag set.
  154. ;
  155. MediaCheck:
  156. BuildBpb:
  157. IoCtlIn:
  158. IoCtlOut:
  159. NdRead:
  160. InStat:
  161. InFlush:
  162. OutStat:
  163. OutFlush:
  164. Open:
  165. Close:
  166.  
  167. done:
  168.     or    Request.Status,0100h        ;set done flag in header
  169. ;
  170.     pop    si                ;and restore registers
  171.     pop    di
  172.     pop    dx
  173.     pop    cx
  174.     pop    bx
  175.     pop    ax
  176.     pop    es
  177.     pop    ds
  178.     popf
  179.     ret
  180. ;
  181. ;    Initialization routine.  Will display message and tell caller
  182. ;    where end of driver is.  This init code will then be discarded.
  183. ;
  184.  
  185. Init:
  186.     mov    ah,9                ;print to console
  187.     mov    dx,offset SignOn        ;print signon
  188.     int    21h                ;call DOS
  189. ;
  190.     mov    Request.AddrSeg, cs        ;put last address in header
  191.     mov    Request.AddrOff, offset Init
  192.  
  193.     jmp    done                ;and return from driver
  194. ;
  195. ;
  196. ;    Signon information
  197. ;
  198. SignOn:
  199.     db    13,10
  200.     db    'AUX2.SYS  Version 1.00  Steve Brozosky',13,10
  201.     db    'AUX Port Now Redirected to COM2.',13,10,13,10,'$'
  202. ;
  203. ;
  204. ;    Copyright information
  205. ;
  206.     db    'Copyright (c) Steve Brozosky, Pleasanton, California, 1987'
  207. ;
  208. Aux2    endP
  209.  
  210. Cseg    endS
  211.  
  212.     end
  213.  
  214.