home *** CD-ROM | disk | FTP | other *** search
/ Simtel MSDOS 1992 September / Simtel20_Sept92.cdr / msdos / ddjmag / ddj8606.arc / D16BIT.JUN < prev    next >
Text File  |  1986-06-30  |  8KB  |  235 lines
  1.         Listing One
  2.  
  3.  
  4.         mov     dx,seg fname    ; open a file for I/O
  5.         mov     ds,dx           ; DS:DX = ASCIIZ filespec
  6.         mov     dx,offset fname ; function 3DH = open,
  7.         mov     ax,3d02h        ; use mode 2 (read/write)
  8.         int     21h
  9.         jc      error           ; jump if open failed
  10.         mov     my_file,ax      ; save handle for file
  11.                         
  12.         .
  13.         .                       ; further file 
  14.         .                       ; processing here
  15.         .
  16.                 
  17.                                 ; now use DUP and CLOSE
  18.                                 ; to update the directory...
  19.         mov     bx,my_file      ; get handle for file
  20.         mov     ah,45h          ; function 45H = DUP handle,
  21.         int     21h
  22.         jc      error           ; jump if DUP failed
  23.         mov     bx,ax           ; now close the DUP'd handle
  24.         mov     ah,3eh          ; function 3EH = close file
  25.         int     21h             ; transfer to MS-DOS
  26.         jc      error           ; jump if close failed
  27.                                 ; otherwise directory is 
  28.                                 ; updated, continue processing 
  29.         .
  30.         .
  31. error:  .
  32.         .
  33.         .
  34.  
  35. my_file dw      0               ; handle from previous "open"
  36.  
  37. fname   db      'MYFILE.DAT',0  ; ASCIIZ filespec
  38.  
  39.  
  40.  
  41.  
  42.  
  43.  
  44.  
  45.  
  46.  
  47.  
  48. Listing Two
  49.  
  50. page 60, 120
  51. title Redirected I/O example
  52.  
  53. ;
  54. ; REDIRECT.ASM --- An illustration of 
  55. ; I/O redirection under MS-DOS 2.x or 3.x
  56. ; 
  57. ; Copyright (C) 1985 by Jerry Jankura
  58. ; Created:   6 November 1985
  59. ; Modified:  9 November 1985
  60. ;
  61. ; Abstract: This routine demonstrates redirection of I/O
  62. ; from the console to a line printer.  The method may be
  63. ; used to redirect I/O from any device to any other device.
  64. ; Requires Microsoft MS-DOS 2.X or 3.X, or DRI Concurrent 
  65. ; DOS version 4.1.
  66. ;
  67.  
  68. STD_IN          EQU     0       ; Standard input handle
  69. STD_OUT         EQU     1       ; Standard output handle
  70. STD_ERR         EQU     2       ; Standare error handle
  71. STD_AUX         EQU     3       ; Standard Auxiliary handle
  72. STD_LST         EQU     4       ; Standard printer handle
  73.  
  74. C_WRITESTR      EQU     9       ; Write string to STD_OUT
  75.  
  76. F_DUP           EQU     45H     ; Duplicate handle
  77. F_CDUP          EQU     46H     ; Force duplicate handle
  78. F_CLOSE         EQU     3EH     ; Close file handle
  79. F_WRITE         EQU     40H     ; Write to file or dev
  80.  
  81. P_TERM          EQU     4CH     ; Terminate a program
  82.  
  83. MS_DOS          EQU     21H     ; MS-DOS service request
  84.  
  85. CR              EQU     0DH     ; Carriage return
  86. LF              EQU     0AH     ; Line feed
  87.  
  88. datasg          segment para    'data'
  89.  
  90.  
  91. msg1            db      CR, LF, 'Redirected I/O example....'
  92.                 db      CR, LF
  93.                 db      CR, LF, 'This example was written using the'
  94.                 db      CR, LF, 'File I/O system services, with the'
  95.                 db      CR, LF, 'file handle being set to STD_OUT.'
  96.                 db      CR, LF, 'STD_OUT normally defaults to the'
  97.                 db      CR, LF, 'video screen, so you are reading'
  98.                 db      CR, LF, 'this message on the screen.'
  99.                 db      CR, LF
  100.  
  101. msg2            db      CR, LF, 'However, we may direct STD_OUT to'
  102.                 db      CR, LF, 'another device, such as the printer.'
  103.                 db      CR, LF, 'This message is still written to'
  104.                 db      CR, LF, 'STD-OUT, but is appears at the printer.'
  105.                 db      CR, LF, 'Again, the operating system provides'
  106.                 db      CR, LF, 'the facility to allow one file to mimic'
  107.                 db      CR, LF, 'and track another.  The Command processor'
  108.                 db      CR, LF, 'normally implements this redirection'
  109.                 db      CR, LF, 'of standard devices.'
  110.                 db      CR, LF
  111.  
  112. msg3            db      CR, LF, 'This message is written on the'
  113.                 db      CR, LF, 'Video screen, demonstrating that'
  114.                 db      CR, LF, 'a message may be redirected to the'
  115.                 db      CR, LF, 'normal STD_OUT device in the same'
  116.                 db      CR, LF, 'manner that was used to redirect'
  117.                 db      CR, LF, 'it to the printer.'
  118.                 db      CR, LF
  119.                 db      CR, LF, 'Note also that the initialized data is'
  120.                 db      CR, LF, 'stored in the data segment, rather'
  121.                 db      CR, LF, 'than in the code segment.'
  122.                 db      CR, LF
  123.                 db      CR, LF, 'Also, the messages are written using'
  124.                 db      CR, LF, 'block I/O, so a minimum number of DOS'
  125.                 db      CR, LF, 'system services are requested.'
  126.  
  127. msg4            db      0
  128.  
  129. dup_handle      dw      ?
  130. orig_handle     dw      ?
  131.  
  132. datasg          ends
  133.  
  134. stacksg         segment para stack 'stack'
  135.  
  136. mystack         db      512 dup (?)
  137.  
  138. stacksg         ends
  139.  
  140. code            segment para 'code'
  141.  
  142. assume          cs: code
  143. assume          ds: datasg
  144. assume          ss: stacksg
  145. assume          es: nothing
  146.  
  147. test_redirect   proc    far
  148.  
  149. ; Initialize stack pointer and data segment register
  150. ; to the correct values.  The stack pointer is set
  151. ; to the top of the stack segment.  The data segment
  152. ; is set to the segment of the first variable.  Note
  153. ; that at this point in time, the DS register does
  154. ; not point to the PSP.
  155.  
  156.                 mov     sp, 513 ; set up user stack
  157.                 mov     ax, seg msg1
  158.                 mov     ds, ax
  159.  
  160. ; First, write a sign-on message to the screen.  We
  161. ; will attempt to write this message to the standard
  162. ; output device.
  163.  
  164. ;       ah:     INT 21H function id.
  165. ;       bx:     file handle
  166. ;       cx:     # of bytes to transfer
  167. ;       DS:dx   points to message
  168.  
  169.                 mov     ah, F_WRITE
  170.                 mov     dx, offset msg1
  171.                 mov     bx, STD_OUT
  172.                 mov     cx, msg2-msg1
  173.                 int     MS_DOS
  174.  
  175. ; Now, we wish to redirect the output to the
  176. ; printer.  Before we force the redirection,
  177. ; we must make a copy of the standard output
  178. ; file handle and store it in the field
  179. ; orig_handle.
  180.  
  181.                 mov     bx, STD_OUT
  182.                 mov     ah, F_DUP
  183.                 int     MS_DOS
  184.                 mov     word ptr orig_handle, ax
  185.  
  186.                 mov     bx, STD_LST
  187.                 mov     ah, F_DUP
  188.                 int     MS_DOS
  189.                 mov     word ptr dup_handle, ax
  190.  
  191. ; Then, the STD_LST handle is set to track
  192. ; the STD_OUT file.
  193.  
  194.                 mov     bx, ax
  195.                 mov     cx, STD_OUT
  196.                 mov     ah, F_CDUP
  197.                 int     MS_DOS
  198.  
  199. ; Let's write a message out and try it.
  200. ; Note that we are still writing information to
  201. ; the STD_OUT device.
  202.  
  203.                 mov     ah, F_WRITE
  204.                 mov     bx, STD_OUT
  205.                 mov     cx, msg3-msg2
  206.                 mov     dx, offset msg2
  207.                 int     MS_DOS
  208.  
  209. ; Now, let's clean up and return everything
  210. ; back to its original condition.
  211.  
  212.                 mov     bx, word ptr dup_handle
  213.                 mov     ah, F_CLOSE
  214.                 int     MS_DOS
  215.  
  216.                 mov     bx, word ptr orig_handle
  217.                 mov     cx, STD_OUT
  218.                 mov     ah, F_CDUP
  219.                 int     MS_DOS
  220.  
  221.                 mov     ah, F_WRITE
  222.                 mov     bx, STD_OUT
  223.                 mov     cx, msg4-msg3
  224.                 mov     dx, offset msg3
  225.                 int     MS_DOS
  226.  
  227.                 mov     ah, P_TERM
  228.                 int     MS_DOS
  229.  
  230. test_redirect   endp
  231.  
  232. code            ends
  233.  
  234.                 end     test_redirect
  235.