home *** CD-ROM | disk | FTP | other *** search
/ DP Tool Club 31 / CDASC_31_1996_juillet_aout.iso / vrac_os2 / e31el3.zip / EMACS / 19.31 / LISP / GOTO-ADD.EL < prev    next >
Lisp/Scheme  |  1996-05-23  |  9KB  |  230 lines
  1. ;;; goto-addr.el --- click to browse URL or to send to e-mail address
  2.  
  3. ;; Copyright (C) 1995 Free Software Foundation, Inc.
  4.  
  5. ;; Author: Eric Ding <ericding@mit.edu>
  6. ;; Maintainer: Eric Ding <ericding@mit.edu>
  7. ;; Created: 15 Aug 1995
  8. ;; Keywords: mh-e, www, mouse, mail
  9.  
  10. ;; This file is part of GNU Emacs.
  11.  
  12. ;; GNU Emacs is free software; you can redistribute it and/or modify
  13. ;; it under the terms of the GNU General Public License as published by
  14. ;; the Free Software Foundation; either version 2, or (at your option)
  15. ;; any later version.
  16.  
  17. ;; GNU Emacs is distributed in the hope that it will be useful,
  18. ;; but WITHOUT ANY WARRANTY; without even the implied warranty of
  19. ;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  20. ;; GNU General Public License for more details.
  21.  
  22. ;; You should have received a copy of the GNU General Public License
  23. ;; along with GNU Emacs; see the file COPYING.  If not, write to the
  24. ;; Free Software Foundation, Inc., 59 Temple Place - Suite 330,
  25. ;; Boston, MA 02111-1307, USA.
  26.  
  27. ;;; Commentary:
  28.  
  29. ;; This package allows you to click or hit a key sequence while on a
  30. ;; URL or e-mail address, and either load the URL into a browser of
  31. ;; your choice using the browse-url package, or if it's an e-mail
  32. ;; address, to send an e-mail to that address.  By default, we bind to
  33. ;; the [mouse-2] and the [C-c return] key sequences.
  34.  
  35. ;; INSTALLATION
  36. ;;
  37. ;; To use goto-address in a particular mode (for example, while
  38. ;; reading mail in mh-e), add something like this in your .emacs file:
  39. ;; 
  40. ;; (add-hook 'mh-show-mode-hook 'goto-address)
  41. ;;
  42. ;; By default, goto-address now sends using `mail' instead of `mh-send'.
  43. ;; To use mh-e to send mail, add the following to your .emacs file:
  44. ;;
  45. ;; (setq goto-address-mail-method 'goto-address-send-using-mh-e)
  46. ;;
  47. ;; The mouse click method is bound to [mouse-2] on highlighted URL's or
  48. ;; e-mail addresses only; it functions normally everywhere else.  To bind
  49. ;; another mouse click to the function, add the following to your .emacs
  50. ;; (for example):
  51. ;;
  52. ;; (setq goto-address-highlight-keymap
  53. ;;   (let ((m (make-sparse-keymap)))
  54. ;;     (define-key m [S-mouse-2] 'goto-address-at-mouse)
  55. ;;     m))
  56. ;;
  57.  
  58. ;; BUG REPORTS
  59. ;;
  60. ;; Please send bug reports to me at ericding@mit.edu.
  61.  
  62. ;; Known bugs/features:
  63. ;; * goto-address-mail-regexp only catches foo@bar.org style addressing,
  64. ;;   not stuff like X.400 addresses, etc.
  65. ;; * regexp also catches Message-Id line, since it is in the format of
  66. ;;   an Internet e-mail address (like Compuserve addresses)
  67. ;; * If show buffer is fontified after goto-address-fontify is run
  68. ;;   (say, using font-lock-fontify-buffer), then font-lock face will
  69. ;;   override goto-address faces.
  70.  
  71. ;;; Code:
  72.  
  73. (require 'browse-url)
  74.  
  75. ;;; I don't expect users to want fontify'ing without highlighting.
  76. (defvar goto-address-fontify-p t
  77.   "*If t, URL's and e-mail addresses in buffer are fontified.
  78. But only if `goto-address-highlight-p' is also non-nil.")
  79.  
  80. (defvar goto-address-highlight-p t
  81.   "*If t, URL's and e-mail addresses in buffer are highlighted.")
  82.  
  83. (defvar goto-address-fontify-maximum-size 30000
  84.   "*Maximum size of file in which to fontify and/or highlight URL's.")
  85.  
  86. (defvar goto-address-mail-regexp
  87.   "[-a-zA-Z0-9._]+@\\([-a-zA-z0-9_]+\\.\\)+[a-zA-Z0-9]+"
  88.   "A regular expression probably matching an e-mail address.")
  89.  
  90. (defvar goto-address-url-regexp
  91.   (concat "\\b\\(s?https?\\|ftp\\|file\\|gopher\\|news\\|"
  92.       "telnet\\|wais\\):\\(//[-a-zA-Z0-9_.]+:"
  93.       "[0-9]*\\)?[-a-zA-Z0-9_=?#$@~`%&*+|\\/.,]*"
  94.       "[-a-zA-Z0-9_=#$@~`%&*+|\\/]")
  95.   "A regular expression probably matching a URL.")
  96.  
  97. (defvar goto-address-mail-method
  98.   'goto-address-send-using-mail
  99.   "*Function to compose mail.
  100. Two pre-made functions are `goto-address-send-using-mail' (sendmail);
  101. and `goto-address-send-using-mh-e' (MH-E).")
  102.  
  103. (defvar goto-address-highlight-keymap
  104.   (let ((m (make-sparse-keymap)))
  105.     (define-key m [mouse-2] 'goto-address-at-mouse)
  106.     m)
  107.   "keymap to hold goto-addr's mouse key defs under highlighted URLs.")
  108.  
  109. (defun goto-address-fontify ()
  110.   "Fontify the URL's and e-mail addresses in the current buffer.
  111. This function implements `goto-address-highlight-p'
  112. and `goto-address-fontify-p'."
  113.   (save-excursion
  114.     (let ((inhibit-read-only t)
  115.       (inhibit-point-motion-hooks t)
  116.       (modified (buffer-modified-p)))
  117.       (goto-char (point-min))
  118.       (if (< (- (point-max) (point)) goto-address-fontify-maximum-size)
  119.       (progn
  120.         (while (re-search-forward goto-address-url-regexp nil t)
  121.               (let ((s (match-beginning 0))
  122.                     (e (match-end 0)))
  123.         (goto-char e)
  124.         (and goto-address-fontify-p
  125.              (put-text-property s e 'face 'bold))
  126.         (put-text-property s e 'mouse-face 'highlight)
  127.         (put-text-property
  128.          s e 'local-map goto-address-highlight-keymap)))
  129.         (goto-char (point-min))
  130.         (while (re-search-forward goto-address-mail-regexp nil t)
  131.               (let ((s (match-beginning 0))
  132.                     (e (match-end 0)))
  133.         (goto-char (match-end 0))
  134.         (and goto-address-fontify-p
  135.              (put-text-property (match-beginning 0) (match-end 0)
  136.                     'face 'italic))
  137.         (put-text-property (match-beginning 0) (match-end 0)
  138.                    'mouse-face 'secondary-selection)
  139.         (put-text-property
  140.          s e 'local-map goto-address-highlight-keymap)))))
  141.       (and (buffer-modified-p)
  142.        (not modified)
  143.        (set-buffer-modified-p nil)))))
  144.  
  145. ;;; code to find and goto addresses; much of this has been blatantly
  146. ;;; snarfed from browse-url.el
  147.  
  148. ;;;###autoload
  149. (defun goto-address-at-mouse (event)
  150.   "Send to the e-mail address or load the URL clicked with the mouse.
  151. Send mail to address at position of mouse click.  See documentation for
  152. `goto-address-find-address-at-point'.  If no address is found
  153. there, then load the URL at or before the position of the mouse click."
  154.   (interactive "e")
  155.   (save-excursion
  156.     (let ((posn (event-start event)))
  157.       (set-buffer (window-buffer (posn-window posn)))
  158.       (goto-char (posn-point posn))
  159.       (let ((address
  160.          (save-excursion (goto-address-find-address-at-point))))
  161.     (if (string-equal address "")
  162.         (let ((url (browse-url-url-at-point)))
  163.           (if (string-equal url "")
  164.           (error "No e-mail address or URL found")
  165.         (funcall browse-url-browser-function url)))
  166.       (funcall goto-address-mail-method address))))))
  167.  
  168. ;;;###autoload
  169. (defun goto-address-at-point ()
  170.   "Send to the e-mail address or load the URL at point.
  171. Send mail to address at point.  See documentation for
  172. `goto-address-find-address-at-point'.  If no address is found
  173. there, then load the URL at or before point."
  174.   (interactive)
  175.   (save-excursion
  176.     (let ((address (save-excursion (goto-address-find-address-at-point))))
  177.       (if (string-equal address "")
  178.       (let ((url (browse-url-url-at-point)))
  179.         (if (string-equal url "")
  180.         (error "No e-mail address or URL found")
  181.           (funcall browse-url-browser-function url)))
  182.     (funcall goto-address-mail-method address)))))
  183.  
  184. (defun goto-address-find-address-at-point ()
  185.   "Find e-mail address around or before point.
  186. Then search backwards to beginning of line for the start of an e-mail
  187. address.  If no e-mail address found, return the empty string."
  188.   (let ((bol (save-excursion (beginning-of-line) (point))))
  189.     (re-search-backward "[^-_A-z0-9.@]" bol 'lim)
  190.     (if (or (looking-at goto-address-mail-regexp)  ; already at start
  191.         (let ((eol (save-excursion (end-of-line) (point))))
  192.           (and (re-search-forward goto-address-mail-regexp eol 'lim)
  193.            (goto-char (match-beginning 0)))))
  194.     (buffer-substring (match-beginning 0) (match-end 0))
  195.       "")))
  196.  
  197. (defun goto-address-send-using-mh-e (to)
  198.   (require 'mh-comp)
  199.   (mh-find-path)
  200.   (let ((cc (mh-read-address "Cc: "))
  201.     (subject (read-string "Subject: "))
  202.     (config (current-window-configuration)))
  203.     (delete-other-windows)
  204.     (mh-send-sub to cc subject config)))
  205.  
  206. (fset 'goto-address-send-using-mhe 'goto-address-send-using-mh-e)
  207.  
  208. (defun goto-address-send-using-mail (to)
  209.   (mail-other-window nil to)
  210.   (and (goto-char (point-min))
  211.        (end-of-line 2)))
  212.  
  213. ;;;###autoload
  214. (defun goto-address ()
  215.   "Sets up goto-address functionality in the current buffer.
  216. Allows user to use mouse/keyboard command to click to go to a URL
  217. or to send e-mail.
  218. By default, goto-address binds to mouse-2 and C-c RET.
  219.  
  220. Also fontifies the buffer appropriately (see `goto-address-fontify-p' and
  221. `goto-address-highlight-p' for more information)."
  222.   (interactive)
  223.   (local-set-key "\C-c\r" 'goto-address-at-point)
  224.   (if goto-address-highlight-p
  225.       (goto-address-fontify)))
  226.  
  227. (provide 'goto-addr)
  228.  
  229. ;;; goto-addr.el ends here.
  230.