home *** CD-ROM | disk | FTP | other *** search
/ Amiga Format CD 10 / amigaformatcd10.iso / -readerstuff- / peter_hutchison / hp_drivers.lzx / hp-dj600 / Install-HP_DeskJet600 < prev    next >
Text File  |  1997-09-12  |  7KB  |  237 lines
  1. ; This is the Installationscript for the HP_DeskJet600 Printerdriver.
  2. ; The HP_DeskJet600 Printerdriver is (C) by Dieter Sabathi,
  3. ; the Installerscript was done by Bernd Gollesch.
  4. ; Everybody can use and modify this script on his own risc.
  5. ;
  6. ; $VER: Install-HP_DeskJet600 1.0 (8.9.96)Installerscript for the HP_DeskJet600 Printerdriver (C) 1996 by Dieter Sabathi
  7. ;
  8.  
  9. ; set variables that are for all languages the same one
  10.  
  11. (set #destdir-driver "DEVS:Printers")
  12. (set #destdir-guide  "HELP:")
  13. (set #destname-guide "HP_DJ600.guide")
  14.  
  15. ;because of the last installer-message
  16. (set @default-dest "")
  17.  
  18. (set #source-driver "HP_DeskJet600")
  19. (set #source-icons "%s/%s.info")
  20.  
  21. (set #icon-choice-1 "Standard")
  22. (set #icon-choice-2 "MagicWB")
  23. (set #icon-choice-3 "NewIcons")
  24.  
  25. ;get the Versionnumber of the Driver to be installed
  26.  
  27. (set #vernum1 (getversion #source-driver))
  28. (set #ver1 (/ #vernum1 65536)) 
  29. (set #rev1 (- #vernum1 (* #ver1 65536)))
  30. (set #driver-version ("%ld.%ld" #ver1 #rev1))
  31.  
  32. (debug "Versionsnummern " #driver-version)
  33.  
  34. ; Only german or english text.
  35.  
  36. (if (= @language "deutsch")
  37.  ; then
  38.   (
  39.     (set #about-text ("\n\nWillkommen zur Installation des\n\nHP_DeskJet600 Druckertreiber\n\nVersion %s\n\nCopyright © 1996 by Dieter Sabathi" #driver-version))
  40.     (set #source-guide "HP_DJ600.de.guide")
  41.     (set #noguidecopy "NICHT INSTALLIERT :-(")
  42.  
  43.     ;HELP Texte
  44.  
  45.     (set #icons-help "Das ist natürlich reine Geschmackssache.\nIch hoffe Deine bevorzugten Piktogramme sind dabei.")
  46.     (set #driver-help "Es wird kein eigenes Verzeichnis angelegt. Du solltest den Treiber nach DEVS:Printers oder SYS:Storage/Printers kopieren.")
  47.     (set #guide-help "Einmal durchlesen wäre sehr nett. Wir haben uns nämlich viel Mühe gegeben :-)")
  48.     (set #run-printerprefs-help "Du kannst jetzt gleich den Druckertreiber auswählen, wenn Du es möchtest. Ansonsten mußt Du es eben später machen :-)")
  49.  
  50.     ;normale Texte
  51.  
  52.     (set #askdir-driver-text "ACHTUNG: Es wird kein eigenes Verzeichnis angelegt. Ich würde Dir DEVS:Printers empfehlen. Ansonsten kannst Du den Druckertreiber nämlich nicht über die Prefs auswählen!")
  53.     (set #ask-guide-text "Willst Du die Guide-Datei installieren?")
  54.     (set #askdir-guide-text "ACHTUNG: Es wird kein eigenes Verzeichnis angelegt. Ich schlage halt mal HELP: vor.")
  55.     (set #ask-icon-text "Welche Piktogramme möchtest Du installiert bekommen?")
  56.     (set #copy-driver-text "Kopieren von HP_DeskJet600")
  57.     (set #copy-guide-text "Kopieren von HP_600.guide")
  58.     (set #copy-icon-text "Kopieren von %s.info")
  59.     (set #run-printerprefs "Willst Du das Printer-Preference Programm starten?")
  60.     (set #goodbye "Installation von HP Deskjet 600 fertig.\n\nDas Programm ist Freeware.\n\nWenn Du willst, kannst Du aber 20 DM oder 140 ATS an den Author senden.\n(Adresse siehe Guide-Datei)\n\n Treiber kopiert nach \"%s\"\nGuide kopiert nach \"%s\"")
  61.   )
  62.  ; else
  63.   (
  64.     (set #about-text ("\n\nWelcome to the installation of the\n\nHP_DeskJet600 Printerdriver\n\nVersion %s\n\nCopyright © 1996 by Dieter Sabathi" #driver-version))
  65.     (set #source-guide "HP_DJ600.eng.guide")
  66.     (set #noguidecopy "NOT INSTALLED :-(")
  67.  
  68.     ; HELP Texte
  69.  
  70.     (set #icons-help "Each to his own taste.\nI hope that i have included your prefered icon.")
  71.     (set #driver-help "No Drawer will be created. You should copy the Driver to DEVS:Printers or SYS:Storage/Printers.")
  72.     (set #guide-help "Please read it once. It was a hard work to do :-)")
  73.     (set #run-printerprefs-help "You can start the printer preferences now, if you want. Otherwise you have to do it later :-)")
  74.  
  75.     ;normal text
  76.  
  77.     (set #askdir-driver-text "ATTENTION: No Drawer will be created. I would copy it to DEVS:Printers. If you do not, you can't select the Printer with the Prefs-Program!")
  78.     (set #ask-guide-text "Should I install the Guide?")
  79.     (set #askdir-guide-text "ATTENTION: No Drawer will be created. How about HELP:")
  80.     (set #ask-icon-text "Wich Icons do you want?")
  81.     (set #copy-driver-text "Copy HP_DeskJet600")
  82.     (set #copy-guide-text "Copy HP_600.guide")
  83.     (set #copy-icon-text "Copy %s.info")
  84.     (set #run-printerprefs "Do you wanna start the Printer-Preference program?")
  85.     (set #goodbye "Installation of HP DeskJet 600 completed.\n\nThis is a Freeware program.\n\nIf you want, you can send 20 DM or 140 ATS to the author.\n(For the address have a look in the Guide)\n\nDriver copied to \"%s\"\nGuide copied to \"%s\"")
  86.   )
  87. ) ; end if
  88.  
  89. ; start the installation
  90.  
  91. (message #about-text)
  92. (welcome)
  93.  
  94. (set #destdir-driver
  95.     (askdir
  96.         (prompt #askdir-driver-text)
  97.         (help   (cat #driver-help "\n\n" @askdir-help))
  98.         (default #destdir-driver)
  99.     )
  100. )
  101.  
  102. (complete 13)
  103. (debug "Destination dir for driver is " #destdir-driver)
  104.  
  105. ; ask for installing guide
  106.  
  107. (set #copy-guide
  108.     (askbool
  109.         (prompt #ask-guide-text)
  110.         (help #guide-help)
  111.         (default 1)
  112.     )
  113. )
  114.  
  115. (complete 25)
  116. (debug "Copy Guide answer " #copy-guide)
  117.  
  118. ; ask vor the dir in wich the guide should be installed
  119.  
  120. (if #copy-guide
  121.  ; then
  122.  (
  123.     (set #destdir-guide
  124.         (askdir
  125.             (prompt #askdir-guide-text)
  126.             (help (cat #guide-help "\n\n" @askdir-help))
  127.             (default #destdir-guide)
  128.         )
  129.     )
  130.  )
  131.  ;else
  132.  (
  133.     (set #destdir-guide (cat #noguidecopy))
  134.  )
  135. ) ; end if
  136.  
  137. (complete 38)
  138. (debug "Dir for Guide is " #destdir-guide)
  139.  
  140. ; ask wich icons should be installed
  141.  
  142. (set #copy-icons
  143.     (askchoice
  144.         (prompt #ask-icon-text)
  145.         (help (cat #icons-help "\n\n" @askchoice-help))
  146.         (choices #icon-choice-1 #icon-choice-2 #icon-choice-3)
  147.         (default 0)
  148.     )
  149. )
  150.  
  151. (complete 50)
  152. (debug "Icon selected was " #copy-icons)
  153.  
  154. ; now start the real installation of the files
  155.  
  156. ; Printerdriver
  157.  
  158. (copylib
  159.     (prompt #copy-driver-text)
  160.     (help @copylib-help)
  161.     (source #source-driver)
  162.     (dest #destdir-driver)
  163.     (confirm)
  164. )
  165.  
  166. (complete 63)
  167. ; selected icons for driver
  168.  
  169. (copyfiles
  170.     (prompt (#copy-icon-text #source-driver))
  171.     (help @copyfiles-help)
  172.     (source (#source-icons
  173.                 (select #copy-icons
  174.                     (cat #icon-choice-1)
  175.                     (cat #icon-choice-2)
  176.                     (cat #icon-choice-3)
  177.                 )
  178.                 #source-driver
  179.             )
  180.     )
  181.     (dest #destdir-driver)
  182.     (files)
  183.     (confirm)
  184. )
  185.  
  186. (complete 75)
  187. ; Guide if selected
  188.  
  189. (if #copy-guide
  190.  ; then
  191.  (
  192.     (copylib
  193.         (prompt #copy-guide-text)
  194.         (help @copylib-help)
  195.         (source #source-guide)
  196.         (dest #destdir-guide)
  197.         (newname #destname-guide)
  198.         (confirm)
  199.     )
  200.  
  201.     (complete 88)
  202.     ; icon for Guide
  203.     (copyfiles
  204.         (prompt (#copy-icon-text #destname-guide))
  205.         (help @copyfiles-help)
  206.         (source (#source-icons
  207.                     (select #copy-icons
  208.                         (cat #icon-choice-1)
  209.                         (cat #icon-choice-2)
  210.                         (cat #icon-choice-3)
  211.                     )
  212.                     #destname-guide
  213.                 )
  214.         )
  215.         (dest #destdir-guide)
  216.         (files)
  217.         (confirm)
  218.     )
  219.  )
  220. ) ; end if
  221.  
  222. (complete 100)
  223.  
  224. ; The next command should be the same for all languages because
  225. ; it's a system default.
  226.  
  227. (run "Sys:Prefs/Printer"
  228.     (prompt #run-printerprefs)
  229.     (help #run-printerprefs-help)
  230.     (confirm)
  231. )
  232.  
  233. (exit
  234.     (#goodbye #destdir-driver #destdir-guide)
  235.     (quiet)
  236. )
  237.