home *** CD-ROM | disk | FTP | other *** search
/ Phoenix CD 2.0 / Phoenix_CD.cdr / 02a / njfrer.zip / NJFRERAM.ASM < prev    next >
Assembly Source File  |  1987-05-14  |  14KB  |  575 lines
  1.  
  2. ;
  3. ;   Nifty James' FREE RAM program
  4. ;   Version 2.00 of 14 May 1987
  5. ;
  6. ;   Copyright 1987 by Mike Blaszczak, all Rights Reserved.
  7. ;
  8. ;   Shareware  $7
  9. ; 
  10.  
  11. ;   ASCII Characters
  12.  
  13. tab        equ    9
  14. lf        equ    10
  15. cr        equ    13
  16. space        equ    32
  17.  
  18. ;   IBM Specific Keyboard Scan-codes
  19.  
  20. AltDown        equ    56        ; ALT scancode
  21. AltUp        equ    56 + 80h
  22. RShiftDown    equ    54        ; right-shift scancode
  23. RShiftUp    equ    54 + 80h
  24.  
  25. ;   BIOS Interrupts
  26.  
  27. Timer        equ    008h        ; BIOS 18.2Hz function
  28. Keyboard    equ    009h        ; BIOS keypress call
  29. Video        equ    010h        ; BIOS video function
  30. DiskService    equ    013h        ; BIOS/XT BIOS disk service
  31. TickTock    equ    01Ch        ; the BIOS timer trap
  32. SnagDOS        equ    028h        ; a function to snag DOS by
  33. SigVec        equ    0D0h        ; vector to see if we're installed
  34. EMM        equ    067h        ; the E/EMS memory manager
  35.  
  36. ;   I/O Ports
  37.  
  38. NMIPort        equ    020h        ; the Interrupt controller port
  39. KeyPort        equ    060h        ; the keyboard's I/O port
  40.  
  41. ;   DOS Calls
  42.  
  43. SetVec        equ    025h        ; call to set an int vector
  44. KEEP        equ    031h        ; call to Terminate and Stay Res
  45. Critical    equ    034h        ; call to get the DOS critical flag
  46. GetVec        equ    035h        ; call to get an int vector
  47. Allocate    equ    048h        ; call to allocate memory
  48. Terminate    equ    04Ch        ; call to Terminate
  49.  
  50. ;   E/EMS Routines
  51.  
  52. E_Status    equ    042h        ; call to determine free/total mem
  53.  
  54.  
  55.  ;   Public declarations for SYMDEB
  56.  
  57. PUBLIC First, StackArea, StackTop, Signature, SaveAX, SaveSS, SaveSP
  58. PUBLIC ClockVec, ClockVecO, ClockVecS, Display, DisplayOff, DisplaySeg
  59. PUBLIC DisplayPort, CriticalFlag, CriticalFlagO, CriticalFlagS, OTT, OTTO
  60. PUBLIC OTTS, OKeyVec, OKeyVecO, OKeyVecS, OSnagger, OSnaggerO, OSnaggerS
  61. PUBLIC ODiskCall, ODiskCallO, ODiskCallS, WorkFlag, UpdateFlag, AltFlag
  62. PUBLIC ShiftFlag, Ticks, InDisk, InThere, HasEMem, DiskTrap, TCTrap, TCDone
  63. PUBLIC TimeTrap, NotTime, KeyTrap, TryUpAlt, TryDnShift, TryUpShift, TripOut
  64. PUBLIC DontGotNone, CheckEMode, TripOutOut, KeyOut, WorkTrap, WorkHard
  65. PUBLIC NoWork, DoWork, EMSMode, DosMode, Calculate, CalcLoop, StickIt
  66. PUBLIC Convert2, Convert3, IsMono, SynchLow, SynchHigh, PutUp, GetOut
  67. PUBLIC CalcArea, AnswerArea, UnitsArea, BytesLine, EEMSLine, OverResident
  68. PUBLIC Already, Exit, InstallMe, NoEMM, NotMono, ExitNow, Banner
  69. PUBLIC DInstalled, EInstalled, Failed
  70. PUBLIC EMSSig
  71.  
  72.  
  73. CSeg        segment    para public 'CODE'
  74.         assume    ds:CSeg,ss:CSeg,cs:CSeg
  75.  
  76.         org    100h
  77.  
  78. extrn   Show:near    ; from NJLIB
  79.  
  80. First:        jmp    OverResident
  81.         nop
  82. StackArea    dw    19 dup(0DEADh)    ; the stack for interrupts
  83. StackTop    dw    0DEADh
  84.  
  85. Signature    db    'NJ'        ; the signature
  86.  
  87. SaveAX        dw    0        ; save the AX here
  88. SaveSS        dw    0        ; save the SS and SP here
  89. SaveSP        dw    0
  90.  
  91.  
  92.  
  93. ClockVec    label    dword        ; the original clock tick vector
  94. ClockVecO    dw    0
  95. ClockVecS    dw    0
  96.  
  97. Display        label    dword        ; pointer to display storage
  98. DisplayOff    dw    62*2
  99. DisplaySeg    dw    0B800h        ; assume the color card
  100. DisplayPort    dw    03DAh        ; display status port address
  101.  
  102. CriticalFlag    label    dword        ; the DOS critical flag
  103. CriticalFlagO    dw    0
  104. CriticalFlagS    dw    0
  105.  
  106. OTT        label    dword        ; the original BIOS Timer Trap
  107. OTTO        dw    0
  108. OTTS        dw    0
  109.  
  110. OKeyVec        label    dword        ; the original keypress vector
  111. OKeyVecO    dw    0
  112. OKeyVecS    dw    0
  113.  
  114. OSnagger    label    dword        ; the original DOS int 28h
  115. OSnaggerO    dw    0
  116. OSnaggerS    dw    0
  117.  
  118. ODiskCall    label    dword        ; the disk services place
  119. ODiskCallO    dw    0
  120. ODiskCallS    dw    0
  121.  
  122. WorkFlag    dw    0        ; semaphore; 1 if we should display
  123.                     ;         2 if we are in EEMS mode
  124. UpdateFlag    dw    0        ; semaphore; 1 if we should update
  125.  
  126. AltFlag        db    0        ; set if ALT is pressed
  127. ShiftFlag    db    0        ; set if RShift is pressed
  128.  
  129. Ticks        db    0        ; tick count for timer
  130. InDisk        db    0        ; semaphore; 1 if in disk control
  131.  
  132. InThere        db    0        ; recursiveness flag
  133. HasEMem        db    0        ; set to 1 if E/EMS is present
  134.  
  135. ; ---------------------------------------------------------------------------
  136.  
  137. DiskTrap:    inc    CS:InDisk    ; set disk handler flag
  138.         pushf
  139.         call    CS:[ODiskCall]    ; call the disk handler
  140.         pushf
  141.         dec    CS:InDisk    ; reset disk handler flag
  142.         popf
  143.         iret            ; return!
  144.  
  145. ; ---------------------------------------------------------------------------
  146.  
  147. TCTrap:        pushf
  148.         call    CS:[OTT]    ; call the original
  149.         pushf
  150.         cli
  151.         cmp    CS:[WorkFlag],0
  152.         je    TCDone
  153.         push    es
  154.         push    bx        ; check the critical flag
  155.         les    bx,CS:[CriticalFlag]
  156.         cmp    byte ptr es:[bx],0
  157.         pop    bx
  158.         pop    es
  159.         jne    TCDone
  160.  
  161.         cmp    CS:[InDisk],0    ; and the disk service flag
  162.         jne    TCDone
  163.  
  164.         jmp    WorkHard
  165.  
  166. TCDone:        popf
  167.         iret
  168.  
  169. ; ---------------------------------------------------------------------------
  170.  
  171. TimeTrap:    pushf            ; save flags
  172.         push    ax
  173.  
  174.         inc    CS:Ticks    ; increment ticks count
  175.         mov    al,CS:Ticks    ; is it time?
  176.         cmp    al,18
  177.         jne    NotTime        ; no, not yet
  178.  
  179.         xor    ax,ax        ; yes, zero time count
  180.         mov    CS:Ticks,al
  181.         mov    CS:UpdateFlag,1 ; set update flag
  182.  
  183. NotTime:    pop    ax
  184.         popf
  185.         jmp    CS:[ClockVec]
  186.         
  187. ; ---------------------------------------------------------------------------
  188.  
  189. KeyTrap:    pushf
  190.         push    ax
  191.  
  192.         in    al,KeyPort    ; get key from keyboard
  193.         cmp    al,AltDown    ; was ALT pressed?
  194.         jne    TryUpAlt    ; no.  Maybe it was released?
  195.  
  196.         mov    CS:AltFlag,1    ; yeah!  It was pressed, set flag
  197.         jmp    short TripOut    ; and flow through
  198.  
  199. TryUpAlt:    cmp    al,AltUp    ; was ALT released?
  200.         jne    TryDnShift    ; no, maybe it was shift?
  201.  
  202.         mov    CS:AltFlag,0    ; yeah!  ALT was released
  203.         jmp    short TripOut    ; reset flag and go through
  204.  
  205. TryDnShift:    cmp    al,RShiftDown    ; okay.  Maybe RShifty was pressed?
  206.         jne    TryUpShift    ;  nah, maybe  it was released?
  207.  
  208.         mov    CS:ShiftFlag,1    ; yeah! it was pressed, so set flag
  209.         jmp    short TripOut    ;  and jump through
  210.  
  211. TryUpShift:    cmp    al,RShiftUp    ; well, maybe it was released?
  212.         jne    KeyOut        ;  no, guess not, just pass it thru
  213.  
  214.         mov    CS:ShiftFlag,0    ;  yeah, it was released!
  215.  
  216. TripOut:    mov    al,CS:AltFlag    ; so, is it both ALT and RSHIFT?
  217.         and    al,CS:ShiftFlag
  218.         je    KeyOut        ; no, just pass thru
  219.  
  220.         mov    ax,CS:WorkFlag    ; yes, it was!  update workflag
  221.         inc    ax
  222.         cmp    ax,3        ; is it now off?
  223.         jne    CheckEMode    ;  no...
  224. DontGotNone:    xor    ax,ax        ;  yes, set to zero
  225.         je    TripOutOut    ;   and leave
  226.  
  227. CheckEMode:    cmp    ax,2        ; is it now EMS mode?
  228.         jne    TripOutOut    ;  no, no need to check
  229.         cmp    CS:HasEMem,1    ;  yes.  do we have EMS?
  230.         jne    DontGotNone    ;  no, set to zero
  231.  
  232. TripOutOut:    mov    CS:WorkFlag,ax
  233.  
  234. KeyOut:        pop    ax
  235.         popf
  236.  
  237.         jmp    CS:[OKeyVec]        
  238.         
  239. ; ---------------------------------------------------------------------------
  240.  
  241.  
  242. WorkTrap:    pushf            ; simulate a INT
  243.         call    CS:[OSnagger]
  244.         pushf
  245.  
  246. WorkHard:    cmp    CS:[WorkFlag],0        ; are we activated?
  247.         je    NoWork            ;  no, don't do work
  248.  
  249.         cmp    CS:[UpdateFlag],0    ; is it time to update?
  250.         je    NoWork            ;  no, don't do work
  251.  
  252.         cmp    CS:[InThere],0        ; are we getting recursive?
  253.         jne    NoWork            ;  yes, don't do work
  254.  
  255.         call    DoWork
  256. NoWork:        popf
  257.         iret        
  258.  
  259.  
  260. DoWork:        cli            ; turn off interrupts!
  261.         cld            ; and set direction up!!!
  262.         mov    CS:SaveAX,ax    ; save the stack seg from call
  263.         mov    CS:SaveSP,sp
  264.         mov    CS:SaveSS,ss
  265.  
  266.         mov    ax,cs            ; point to our local
  267.         mov    ss,ax            ;  stack segment
  268.         mov    ax,offset StackTop
  269.         mov    sp,ax
  270.  
  271.         push    bx        ; save all the regs we use
  272.         push    cx
  273.         push    dx
  274.         push    si
  275.         push    di
  276.         push    ds
  277.         push    es
  278.  
  279.         mov    ax,cs
  280.         mov    ds,ax        ; establish data seg addressing
  281.         mov    es,ax
  282.  
  283.         inc    InThere        ; don't be recursive
  284.         mov    UpDateFlag,0    ;  and don't do the work twice!
  285.  
  286.         cli            ; reallow interrupts for now
  287.  
  288.         mov    cx,5        ; move 10 bytes of message
  289.         mov    di,offset UnitsArea    ; into the units area
  290.         cmp    WorkFlag,1
  291.         je    DOSMode
  292.  
  293. EMSMode:    mov    si,offset EEMSLine
  294.     repnz    movsw
  295.         mov    ah,E_Status    ; get the E/EMS status
  296.         int    EMM        ; from the EMM
  297.     ; BX contains EEMS pages free
  298.  
  299.         xor    ax,ax
  300.         xchg    ax,bx        ; make BX:AX = number of pages
  301.         mov    cx,14        ; mulitply by 2^14
  302.         jmp    short CalcLoop    ; to get number of bytes
  303.         
  304.  
  305. DosMode:    mov    si,offset BytesLine
  306.     repnz    movsw
  307.         mov    ah,Allocate    ; try to get a major amount of mem
  308.         mov    bx,0FFFFh
  309.         int    21h        ; to see how much is free
  310.  
  311. Calculate:    xor    ax,ax        ; zero the AX
  312.         xchg    ax,bx        ; now, AX = paragraphs and BX = 0
  313.         mov    cx,4        ; get # of bytes
  314. CalcLoop:    rcl    ax,1        ; multiply by two
  315.         rcl    bx,1        ; add in carry
  316.         loop    CalcLoop
  317.  
  318. StickIt:
  319.     ; now, BX:AX contains bytes of free memory
  320.  
  321.         mov    CalcArea,ax        ; store bytes
  322.         mov    CalcArea+2,bx
  323.  
  324.         mov    di,offset AnswerArea
  325.         mov    al,space
  326.         mov    cx,7
  327.     repnz    stosb
  328.  
  329.     ; now, convert the number of bytes into ASCII, and store at
  330.     ; AnswerArea
  331.  
  332.         mov    si,offset CalcArea
  333.         dec    di
  334.  
  335. Convert2:    push    si            ; save source pointer
  336.  
  337.         xor    bx,bx            ; done flag
  338.         mov    cx,2            ; 2 words in number
  339.         xor    dx,dx            ; previous remainder
  340.         add    si,2            ; point to high end
  341.  
  342. Convert3:    push    cx            ; save count
  343.         mov    ax,[si]            ; get 16-bit digit
  344.         mov    cx,10            ; divisor of 10
  345.         div    cx            ; divide
  346.         mov    [si],ax            ; put 16-bit digit back
  347.         or    bx,ax            ; check for zero
  348.         sub    si,2            ; point to next 16-bit digit
  349.         pop    cx            ; restore count
  350.         loop    Convert3        ; do more
  351.  
  352.         or    dl,'0'        ; make remainder into decimal digit
  353.         mov    [di],dl        ; store it
  354.         dec    di        ; and fix pointer
  355.  
  356.         pop    si        ; restore source pointer
  357.         cmp    bx,0        ; was that the end?
  358.         jnz    Convert2    ; no, do more!
  359.  
  360.         mov    ah,15
  361.         int    Video
  362.         mov    cx,0B000h
  363.         cmp    al,7
  364.         je    IsMono
  365.         mov    cx,0B800h
  366.         add    ch,bh        ; add the current page to it
  367.         
  368. IsMono:        mov    DisplaySeg,cx
  369.  
  370.         les    di,Display    ; stuff it into the display!
  371.         mov    si,offset AnswerArea
  372.         mov    ah,7        ; attribute
  373.         mov    cx,18        ; 17 characters in the message:
  374.                     ; "xxxxxxx Bytes Free"
  375.  
  376.         mov    dx,DisplayPort    ; get the status port number
  377.         and    dx,dx        ;  or is it mono?
  378.         je    PutUp        ;  yeah, skip synchro
  379.  
  380. SynchLow:                ; wait for the synch to go low
  381.         in    al,dx
  382.         test    al,8
  383.         jne    SynchLow
  384.  
  385. SynchHigh:                ; wait for start of overscan
  386.         in    al,dx
  387.         test    al,8
  388.         je    SynchHigh
  389.     
  390. PutUp:        lodsb            ; load a byte of the message
  391.         stosw            ; store a word into the display
  392.         loop    PutUp        ; do the rest
  393.  
  394. GetOut:        cli            ; disallow interrupts for crucial code
  395.         dec    InThere        ; clear work flag
  396.         pop    es
  397.         pop    ds        ; reset the registers
  398.         pop    di
  399.         pop    si
  400.         pop    dx
  401.         pop    cx
  402.         pop    bx
  403.  
  404.         mov    sp,CS:SaveSP        ; restore the original stack
  405.         mov    ss,CS:SaveSS
  406.         mov    ax,CS:SaveAX
  407.  
  408.         sti                ; re-allow ints and
  409.         ret            ; return to caller
  410.  
  411. CalcArea    dw    2 dup(0)
  412.  
  413. AnswerArea    db    8 dup (' ')
  414. UnitsArea    db    "Bytes Free"
  415.  
  416. BytesLine    db    "Bytes Free"    ; message for DOS Bytes
  417. EEMSLine    db    "E/EMS Free"    ; message for EEMS Bytes
  418.  
  419. ; ---------------------------------------------------------------------------
  420.  
  421. OverResident:    mov    dx,offset Banner    ; print the banner
  422.         mov    cx,BannerLen
  423.         call    Show
  424.  
  425.         mov    ah,GetVec        ; see if already present
  426.         mov    al,SigVec
  427.         int    21h
  428.  
  429.         mov    ax,ES:[BX]        ; see if the signature
  430.         cmp    ax,'JN'            ;  is there?
  431.         jne    InstallMe
  432.  
  433. Already:    mov    dx,offset Failed    ; already installed!
  434.         mov    cx,FailedLen
  435.         call    Show
  436.  
  437. Exit:        mov    ah,Terminate        ; terminate with ERRORLEVEL
  438.         mov    al,1
  439.         int    21h
  440.  
  441. InstallMe:    ; we should install ourselves.  First, check to see if
  442.         ; there is E/EMS present.
  443.  
  444.         mov    ah,GetVec        ; get EMM Vector
  445.         mov    al,EMM
  446.         int    21h
  447.         mov    di,000Ah    ; point to device_name within
  448.                     ;  the EMM driver
  449.         mov    si,offset EMSSig
  450.         mov    cx,8
  451.         cld
  452.     repe    cmpsb            ; compare the bytes
  453.         jne    NoEMM
  454.  
  455.         mov    HasEMem,1    ; set EMEM flag to one
  456.  
  457. NoEMM:
  458.         mov    ah,Critical        ; get the DOS critical flag
  459.         int    21h
  460.         mov    CriticalFlagO,bx
  461.         mov    CriticalFlagS,es
  462.  
  463.         mov    ah,GetVec        ; handle the tick-tock
  464.         mov    al,TickTock
  465.         int    21h
  466.         mov    OTTO,bx
  467.         mov    OTTS,es
  468.  
  469.         mov    ah,SetVec
  470.         mov    al,TickTock
  471.         mov    dx,offset TCTrap
  472.         int    21h
  473.  
  474.         mov    ah,GetVec
  475.         mov    al,DiskService
  476.         int    21h
  477.         mov    ODiskCallO,bx
  478.         mov    ODiskCallS,es
  479.     
  480.         mov    ah,GetVec
  481.         mov    al,SnagDOS        ; get originial INT 028h
  482.         int    21h
  483.         mov    OSnaggerO,bx
  484.         mov    OSnaggerS,es
  485.     
  486.         mov    ah,GetVec        ; get the current keyboard vec
  487.         mov    al,Keyboard
  488.         int    21h
  489.  
  490.         mov    OKeyVecO,bx
  491.         mov    OKeyVecS,es
  492.  
  493.         mov    ah,GetVec        ; get the clock-tick vec
  494.         mov    al,Timer
  495.         int    21h
  496.  
  497.         mov    ClockVecO,bx        ; store clock vector
  498.         mov    ax,es
  499.         mov    ClockVecS,ax
  500.  
  501.         mov    ah,15        ; call BIOS to get video mode
  502.         int    Video
  503.         cmp    al,7        ; is it mono?
  504.         jne    NotMono
  505.  
  506.         mov    ax,0B000h    ; yes, change it to mono
  507.         mov    DisplaySeg,ax    
  508.         mov    ax,0
  509.         mov    DisplayPort,ax
  510.  
  511. NotMono:    mov    ah,SetVec        ; set an int vector
  512.         mov    al,Timer        ;  the timer's
  513.         mov    dx,offset TimeTrap    ; to our routine
  514.         int    21h
  515.  
  516.         mov    ah,SetVec        ; get the keypress vector
  517.         mov    al,Keyboard
  518.         mov    dx,offset KeyTrap
  519.         int    21h
  520.  
  521.         mov    ah,SetVec        ; get the snag DOS vector
  522.         mov    al,SnagDOS
  523.         mov    dx,offset WorkTrap
  524.         int    21h
  525.  
  526.         mov    ah,SetVec        ; set the signature pointer
  527.         mov    al,SigVec
  528.         mov    dx,offset Signature
  529.         int    21h
  530.  
  531.         mov    dx,offset DInstalled
  532.         mov    cx,DInstalledLen
  533.  
  534.         mov    al,HasEMem
  535.         cmp    al,0
  536.         je    ExitNow
  537.  
  538.         mov    dx,offset EInstalled
  539.         mov    cx,EInstalledLen
  540.  
  541. ExitNow:
  542.         call    Show
  543.  
  544.         mov    ah,KEEP        ; terminate and stay resident
  545.         mov    al,0    
  546.         mov    dx,offset OverResident
  547.         add    dx,15
  548.         mov    cx,4
  549.         shr    dx,cl
  550.         int    21h
  551.  
  552. ; ---------------------------------------------------------------------------
  553.  
  554. Banner        db    cr,lf,"Nifty James' FREE RAM program",cr,lf
  555.         db    "Version 2.00 of 14 May 1987",cr,lf,lf,lf
  556. BannerLen    equ    this byte - Banner
  557.  
  558. DInstalled    db    "NJFRERAM is installed!",cr,lf
  559.         db    "Press <Alt>+<RightShift> to toggle the display",cr,lf,lf
  560. DInstalledLen    equ    this byte - DInstalled
  561.  
  562. EInstalled    db    "NJFRERAM is installed!",cr,lf
  563.         db    "EEMS Mode is active.",cr,lf
  564.         db    "Press <Alt>+<RightShift> to move from DOS, to E/EMS, to off",cr,lf
  565. EInstalledLen    equ    this byte - EInstalled
  566.  
  567. Failed        db    "NJFRERAM was already present!",cr,lf,lf
  568. FailedLen    equ    this byte - Failed
  569.  
  570. EMSSig        db    "EMMXXXX0"
  571.  
  572. CSeg        ends
  573.         end    First
  574.  
  575.