HyperLib 7/HYPERLIB-1993-VOL7-CD2.ISO.7z/HYPERLIB-1993-VOL7-CD2.ISO/ExpandedBook/ノートブック/ノートブック.rsrc/CSTR_1010_sBOOT

Text File | 1993-07-28 | 3KB | 92 lines

on installEBResources
  global EBTools
  put getStr("reqVersion") into rV
  put value(last word of the long name of this stack) into mp
  put "" into pn
  put the stacksInUse into inUse
  put mp into p
  set itemdelimiter to ":"
  delete last item of P
  repeat while P<>""
    put path(shortcatalog,"STAK",P&":") into SK
    repeat with n=1 to number(lines of SK)
      put P&":"&line n of SK into pn
      if inUse contains pn then
      else
        if getCStr(pn,"BookType")="Library" then
          put "" into P
          exit repeat
        end if
      end if
      put "" into pn
    end repeat
    delete last item of P
  end repeat
  put pn into EBTools
  delete last item of EBTools
  set itemdelimiter to ","
  if pn="" then
    answer "「ライブラリ」が見つかりません。このブックを使用するためには「ライブラリ」がこのブックが含まれているパスのどこかになければなりません。"
    go home
    exit to hypercard
  end if
  put EBTools&":" into EBTools

  set lockmessages to true
  set lockrecent to true
  if  there is a stack pn then
    lock screen
    start using stack pn
    if the result<>"" then
      answer "「"&pn&"」の組み込みに失敗しました。"&return&the result
      go home
      exit to hypercard
    end if
    get getStr("libVersion")
    if it="" or it< rV then
      answer "「"&pn&"」のバージョンが異なります。このブックを使用するためには、「"&pn&"」をアップグレードしてください。"
      go home
      exit to hypercard
    end if
    do getStr("sEBINIT")

    put "" into pn
    put getStr("tkFolder") into tkFolder
    put the stacksInUse into inUse
    put EBTools&tkFolder into P
    set itemdelimiter to ":"
    repeat while P<>""
      put path(shortcatalog,"STAK",P&":") into SK
      repeat with n=1 to number(lines of SK)
        put P&":"&line n of SK into pn
        if inUse contains pn then
        else
          if getCStr(pn,"BookType")="TOOLKIT" then
            put "" into P
            exit repeat
          end if
        end if
        put "" into pn
      end repeat
      delete last item of P
    end repeat
    global EBTKTools
    put pn into EBTKTools
    delete last item of EBTKTools
    set itemdelimiter to ","
    if pn<>"" and there is a stack pn then
      start using stack pn
      if the result<>"" then
        answer "「"&pn&"」の組み込みに失敗しました。"&return&the result
        go home
        exit to hypercard
      end if
      put EBTKTools&":" into EBTKTools
      global ebAuthor,ebAuthorStack
      put -1 into ebAuthor
      put pn into ebAuthorStack
      do getStr("TKINIT")
    end if
  end if
end installEBResources
□