CD-ROM Today (BR) Volume 3 #5/CDRV3N5.ISO/demo/introdm.dir/Internal_38.ls

Text File | 1996-07-12 | 2.7 KB | 138 lines

on startMovie
  global CDLocation, InDemo
  puppetSound(8)
  cursor(200)
  closeXLib()
  set the mouseDownScript to "GoMenu"
  set the keyDownScript to "GoMenu"
  resetall()
  set the soundLevel to 6
  if voidp(InDemo) then
    set InDemo to 1
    initFIles()
    if the machineType <> 256 then
      openXLib("HyperPhonic")
    end if
  end if
end

on initFIles
  global SupportPath
  if FileExists("INTRO.AIF") then
    set SupportPath to the pathName
  else
    if the machineType = 256 then
      set cdDrive to getCDdrive()
      set SupportPath to cdDrive & ":\DEMO\"
    else
      set SupportPath to "Foreign Language Demo:Foreign Language Demo:"
    end if
  end if
  set FILE to SupportPath & "CULT.MOV"
  importFileInto(cast 202, FILE)
  set FILE to SupportPath & "SPANSADM.MOV"
  importFileInto(cast 51, FILE)
end

on blankout
  set FILE to "BLANK.MOV"
  importFileInto(cast "CULT.MOV", FILE)
  importFileInto(cast "SPANSADM.MOV", FILE)
end

on FileExists name
  repeat with i = 1 to the maxinteger
    if getNthFileNameInFolder(the pathName, i) = name then
      return 1
    end if
    if getNthFileNameInFolder(the pathName, i) = EMPTY then
      return 0
    end if
  end repeat
end

on stopMovie
  cursor(0)
  if the machineType <> 256 then
    closeXLib("HyperPhonic")
  end if
end

on resetall
  global gSpeechRecOn, soundOn, AnimationOn, cursoundlevel
  clearGlobals()
  closeResFile()
  set gSpeechRecOn to 2
  set soundOn to 1
  set AnimationOn to 1
  set the soundLevel to 5
  set cursoundlevel to 5
end

on fixColors
  if (the machineType = 256) or (the colorDepth > 8) then
    return
  end if
  set fixpal to FixPalette(mnew, the stageLeft, the stageTop, the stageRight, the stageTop)
  fixpal(mPatchIt)
  fixpal(mdispose)
end

on moveMouth
  puppetSprite(25, 1)
  set startFace to the number of member "Dealer Speaking"
  set whichFace to startFace
  repeat while soundBusy(1)
    if whichFace = (startFace + 7) then
      if random(10) = 1 then
        set the visible of sprite 26 to 1
      end if
      set whichFace to startFace
    else
      set whichFace to whichFace + 1
    end if
    set the castNum of sprite 25 to whichFace
    updateStage()
    startTimer()
    repeat while the timer < 8
    end repeat
  end repeat
  set the castNum of sprite 25 to startFace
  updateStage()
  puppetSprite(25, 0)
end

on blink num
  set i to 0
  set sstatus to 0
  repeat while i <= 5
    set the visible of sprite num to sstatus
    set sstatus to not sstatus
    updateStage()
    swait(10000)
    set i to i + 1
  end repeat
end

on goMenu
  puppetSprite(26, 0)
  ridsound()
  dontPassEvent()
  DoEnd()
end

on ridsound
  if soundBusy(1) then
    sound stop 1
  end if
  if soundBusy(2) then
    sound stop 2
  end if
end

on DoEnd
  ridsound()
  cursor(0)
  go("Menu")
end