Compuserve Login Skript
;-------------- Anfang
proc main
set port databits 7
set port parity even
delay 2
transmit "<cr>"
waitfor "ame:"
transmit "CIS<cr>"
waitfor "ID:"
transmit $USERID
transmit "/GO:PPPCONNECT<cr>"
waitfor "word:"
transmit $PASSWORD
transmit "<cr>"
waitfor "PPP"
set port databits 8
set port parity none
endproc
;-------------- Ende
Skript fⁿr eine RAS-Verbindung zu CompuServe.
Die Adressen:
149.174.211.5 DNS-Adresse
149.174.213.5 DNS-Adresse
Skript:
;***********************************************
;* Login-Skript fⁿr die Einwahl ins
;* Internet ⁿber Datex-J und Compuserve
;* (Telefonnummer in Deutschland: 01910)
;***********************************************
;* Version 2.1 (c) 1996 Wolfgang Wirth
;* Letzte ─nderung am 22:06 19.09.96
;* Email: 71333.1421@compuserve.com
;***********************************************
proc main
string ErrStr
;***********************************************
;*** Dial-up Port auf 8n1 setzen
set port databits 8
set port parity none
;***********************************************
;*** Hier befinden wir uns auf der T-Online
; Startseite. Als erstes muss ein Dezimalpunkt
; mit <CR> geschickt werden, um auf einen
; "Text-Dekoder" hinzuweisen.
;
delay 3
transmit ".^M"
;***********************************************
;*** Hier befinden wir uns auf der T-Online
; Login-Seite. Wenn das Wort "kennung"
; erscheint, wird die Compuserve-
; Kennung geschickt. Ein <CR> ist nicht
; n÷tig, da die Seite automatisch nach
; der Kennungseingabe wechselt.
;
waitfor "kennung" until 30
if !$SUCCESS then
Errstr="Datex-J-Kennung"
goto fehler
endif
transmit "000255975978"
;***********************************************
;*** Hier befinden wir uns auf der Compuserve
; Login-Seite. Punkt "2" steht fⁿr Login von
; Mitgliedern. Ein <CR> wird geschickt, um
; auch die nachfolgende Seite zu quittieren.
;
transmit "2^M"
;***********************************************
;*** Datex-J haben wir jetzt passiert. Jetzt stehen
; wir bei Compuserve auf der Matte. Das System
; fragt hier nach dem Host-Namen, der in unserem
; Fall "CIS" lautet und mit einem <CR> abgeschlos-
; sen werden muss.
;
waitfor "Host Name:" until 30
if !$SUCCESS then
Errstr="Compuserve Host-Name"
goto fehler
endif
transmit "CIS^M"
;***********************************************
;*** Jetzt muss unsere CIS-Anwenderkennung ⁿbermittelt
; werden. Es wird die Systemvariable $USERID benutzt,
; die den entsprechenden Eintrag aus dem Anwahl-
; Dialog enthΣlt. Die ID wird mit dem Parameter
; RAW gesendet, damit keine Steuer- bzw. Sonder-
; zeichenⁿbersetzung auf dem Host stattfindet.
; Das Kommando fⁿr einen PPP-Connect kann man gleich
; an die ID mitanhΣngen. Das ganze muss mit einem <CR>
; abgeschlossen werden.
;
waitfor "User ID:" until 30
if !$SUCCESS then
Errstr="Compuserve Anwenderkennung"
goto fehler
endif
transmit $USERID, raw
transmit "/go:pppconnect^M"
;***********************************************
;*** Mit der ▄bermittlung des Passwortes wird das Login
; abgeschlossen. Es wird die Systemvariable $PASSWORD
; benutzt, die den entsprechenden Eintrag aus dem
; Anwahl-Dialog enthΣlt. Das Passwort wird mit dem
; Parameter RAW gesendet, damit keine Steuer- bzw.
; Sonderzeichenⁿbersetzung auf dem Host stattfindet.
; Das ganze muss mit einem <CR> abgeschlossen werden.
;
waitfor "Password:" until 30
if !$SUCCESS then
Errstr="Compuserve Anwenderpasswort"
goto fehler
endif
transmit $PASSWORD, raw
transmit "^M"
;***********************************************
;*** Damit ist das Login abgeschlossen. Wir warten
; jetzt nur noch auf eine kleine Quittierung vom
; System
;
waitfor "One moment please" until 60
;***********************************************
;*** Hurra - Wir stehen im Internet! Das Skript endet
; hier und das Login-Fenster schlie▀t sich.
;
goto ende
;***********************************************
;*** Mist! Ein Fehler ist aufgetreten.
; Der Grund wird ⁿber Modem-Echo ins
; Verbindungsfenster geleitet
;
fehler:
transmit "+++" ; Modem in Komandomodus schicken
delay 3 ; Komandomoduszwangspause
waitfor "ok", "0" until 5 ; Auf OK oder 0 warten
transmit "ate1^M" ; Modem: Echo ein
waitfor "ok", "0" until 2 ; Auf OK oder 0 warten
; Fehlerinformation senden (kommt als Echo ins Fenster)
transmit "*** VERBINDUNGSFEHLER:^M^J"
transmit "*** " + ErrStr + " wurde nicht angefordert^M^J"
transmit "*** Das Skript wird daher abgebrochen.^M^J"
delay 3 ; Anwender Zeit zum Lesen lassen
transmit "ath0^M" ; Modem soll auflegen
delay 10 ; Zeit fⁿr System zum Gen. des
halt ; Meldungsfensters
;***********************************************
ende:
endproc
 |
Copyright ⌐ 1996/2000 by Frank Ullrich