oWin := TMdiChild():New( nTop, nLeft, nBot, nRight, cTitle, nStyle,;
                             oMenu, oParent, oIcon, lvScroll, nClrFore,;
                             nClrBack, oCursor, oBrush, lPixel, lhScroll,;
                             nHelpId, cbord, lSysMen, lCaption, lMin, lMax )
-------------------------------------------------------------------------------

    DEFINE WINDOW <oWin> ;
           MDICHILD ;
         [ FROM <nTop>, <nLeft> TO <nBottom>, <nRight> ] ;
         [ TITLE <cTitle> ] ;
         [ BRUSH <oBrush> ] ;
         [ CURSOR <oCursor> ] ;
         [ MENU <oMenu> ] ;
         [ ICON  <oIcon> ] ;
         [ OF <oParent> ] ;
         [ COLOR | COLORS <nClrFore> [,<nClrBack>] ];
         [ HELPID | HELP ID <nHelpId> ];
         [ STYLE <nStyle> ] ;
         [ PIXEL ] ;
         [ BORDER [ NONE | SINGLE ] ] ;
         [ NOSYSMENU | NO SYSMENU ] ;
         [ NOCAPTION | NO CAPTION | NO TITLE ] ;
         [ NOICONIZE | NOMINIMIZE ] ;
         [ NOZOOM | NO ZOOM | NOMAXIMIZE | NO MAXIMIZE ] ;
         [ VSCROLL | VERTICAL SCROLL ] ;
         [ HSCROLL | HORIZONTAL SCROLL ]


 PARAMETER:

   For a brief description of the standard Window Parameter please activate
   Related Topics:  and select  DEFINE WINDOW 


  <nHelpId>        Is the Help Topic Identifier of our MDI-Window as a 
                   numeric Constant


 DESCRIPTION:

  This Command creates a MDI CHILD Window, which is the child of an
  MDI PARENT Window. A reference to our Child Window is stored in 
  the MDI-Client's Array ::aWnd

  MDI-Childs normally have a ButtonBar instead of a Menu, and often they 
  have one Main Control, for instance a Listbox. If you want this main 
  control to be automatically activated when the Child Windows gets Focus, 
  then you have to use the Method ::SetControl()

  If your MDI-Child _has_ a Menu, then you have to end this manually when
  closing your ChildWin(>= FW 1.91) , because this Menu wan't be discarded 
  automatically, so that every run will eat up Windows resources. 
  You can release the Menu with oMdiChildWin:omenu:end()



 EXAMPLE:

     +-------------------------------------------------------------+
     |  /* Create MDI Parent Window */                             |
     |  DEFINE WINDOW oWin FROM 1,1 TO 20, 60 ;                    |
     |   TITLE "Testing the MDI Window" ;                          |
     |   MDI ;                                                     |
     |   MENU BuildMenu()                                          |
     |                                                             |
     |  SET MESSAGE OF oWin TO "Main Window"                       |
     |                                                             |
     |  /* Create MDI ChildWindow */                               |
     |  DEFINE WINDOW oWinEdit MDICHILD OF oWin ;                  |
     |   FROM 2,2 TO 20,50 ;                                       |
     |   TITLE "I am the MDI Child" ;                              |
     |   COLOR "W+/W"                                              |
     |                                                             |
     |  /* Create a main Control and register it */                |
     |  @ 4, 2 GET oget VAR cName OF oWndEdit SIZE 170,25          |
     |  oWinEdit:SetControl( oGet )                                |
     |                                                             |
     |  /* Start the Action */                                     |
     |  ACTIVATE WINDOW oWin                                       |
     +-------------------------------------------------------------+