oWin := TWindow():New( nTop, nLeft, nBot, nRight, cTitle, nStyle,;
                           oMenu, oBrush, oIcon, oParent, lvScroll, ;
                           lHScroll, nClrFore, nClrBack, oCursor, cBord,;
                           lSysMen, lCaption, lMin, lMax, lpixel)
-------------------------------------------------------------------------------

    DEFINE WINDOW <oWin> ;
         [ FROM <nTop>, <nLeft> TO <nBottom>, <nRight> ] ;
         [ PIXEL ] ;
         [ TITLE <cTitle> ] ;
         [ COLOR | COLORS <nClrFore> [,<nClrBack>] ];
         [ OF <oParent> ] ;
         [ BRUSH <oBrush> ] ;
         [ CURSOR <oCursor> ] ;
         [ ICON  <oIcon> ] ;
         [ MENU <oMenu> ] ;
         [ STYLE <nStyle> ] ;
         [ BORDER [ NONE | SINGLE ] ] ;
         [ NOSYSMENU | NO SYSMENU ] ;
         [ NOCAPTION | NO CAPTION | NO TITLE ] ;
         [ NOICONIZE | NOMINIMIZE ] ;
         [ NOZOOM | NO ZOOM | NOMAXIMIZE | NO MAXIMIZE ] ;
         [ VSCROLL | VERTICAL SCROLL ] ;
         [ HSCROLL | HORIZONTAL SCROLL ]



 PARAMETER:

  <oWin>           Reference to the Window Object
  <nTop .. nRight> The coordinates of our Window, we simulate text 
                   coordinates.
  <cTitle>         The title of the Window

  <oParent>        Reference to the Parent Window, if our Window is a 
                   Child Window.

  <oBrush>         Brush Object that paints the background ( the Client
                   Area ) of the Window. If this Parameter is skipped, then
                   a default Brush ist used.

  <oCursor>        Reference to a Cursor Object. This Cursor will be
                   shown when the mouse is 'on' our Window. If this Parameter
                   is skipped, then the default Cursor is used

  <oIcon>          Reference to an Icon Object to be used by the Window
                   whenever this window is minimized. If you skip this 
                   Parameter then a default MS-Windows Icon is extracted 
                   from USER.EXE

  <oMenu>          Menu Object, if you want to attach a Menu to the Window
                   This parameter should pass on a TMenu object, which
                   is normally returned from a Createmenu() UDF.

  <nStyle>         Numeric value which indicates a special Windows style
                   and characteristic. please press 
                    Related Topics:  and select  Window styles  for
                   detailed informations about the different styles

  <nClrFore>       The Foreground color (the color that is used to draw 
                   on the window). This can either be a MS-Windows COLOR 
                   number or a Clipper color string (ie "R/G") in which case 
                   the nClrBack parameter will be ignored.

  <nClrBack>       The Background color of the window. This has to be a
                   MS-Windows COLOR number, a Clipper Color Strings in
                   nClrFore defines both Fore- and Background Color


  [PIXEL]          This Keyword switches from the normal Character based
                   coordinate units to the natural Windows Pixel based. If
                   you prefer to calculate the coordinates and Sizes of the
                   Window in Pixels: here is your Hook.


  [BORDER ..]      This parameter controls the type of border that the 
                   window has. It can be one of the following character 
                   strings:
                          
                     NONE     The window will be a popup window
                     SINGLE   (Default) The window will have a thick frame


  [NOSYSMENU]      By default every Window with a title Bar has a System 
                   Menu button on the top/left corner of the window. This
                   Keyword disables the System Menu

  [NOCAPTION]      By default every Window has a Title bar. This
                   Keyword disables the Title Bar, and also the System Menu

  [NOMINIMIZE]     By default every Window with a Title Bar has also an
                   iconize Button. This Keyword disables the Button
   
  [NOMAXIMIZE]     By default every Window with a Title Bar has also an
                   maximize Button. This Keyword disables the Button

  [VSCROLL]        This Keyword attaches a vertical Scrollbar to our Window
  
  [HSCROLL]        This Keyword attaches a horizontal Scrollbar to our Window



 DESCRIPTION:

  This Command creates a standard Window. Once it is built and activated
  by ACTIVATE WINDOW, your program starts receiving all kind of 
  notifications (messages) from Windows about what Actions are happening.

  Allthough a Window is the mother of all things in Windows, it is not 
  much to say about it from the programmers side of view. Beside the
  pure Window it's also a container for all kind of elements like Menues,
  controls, Icons and Eventhandlers.


 EXAMPLE:

     +-------------------------------------------------------------+
     |      /* very Simple Window */                               |
     |      DEFINE WINDOW oWin FROM 1, 1 TO 20, 60 ;               |
     |       TITLE "My program"                                    |
     |                                                             |
     |      ACTIVATE WINDOW oWin                                   |
     +-------------------------------------------------------------+