DataSpace オブジェクト、CreateObject メソッドの例 (VBScript)

DataSpace オブジェクト、CreateObject メソッドの例 (VBScript)

次の例では、RDS.DataSpace の CreateObject メソッドを、既定のビジネスオブジェクトである RDSServer.DataFactory を指定して使用する方法を示します。この例をテストするには、このコードをコピーして、通常の HTML 文書の <Body> タグと </Body> タグの間に貼り付け、「ADCapi8.asp」という名前を付けて保存してください。ASP スクリプトでサーバーを識別しています。

<H2>RDS API Code Examples</H2>
<HR>
<H3>Using Query Method of RDSServer.DataFactory</H3>

<!-- RDS.DataSpace  ID RDS1-->
<OBJECT ID="RDS1" WIDTH=1 HEIGHT=1
CLASSID="CLSID:BD96C556-65A3-11D0-983A-00C04FC29E36">
</OBJECT>

<!-- RDS.DataControl with parameters set at run time -->
<OBJECT classid="clsid:BD96C556-65A3-11D0-983A-00C04FC29E33"
    ID=RDS WIDTH=1 HEIGHT=1>
</OBJECT>

<TABLE DATAsrc=#rds>
<TBODY>
  <TR>
    <TD><SPAN DATAFLD="FirstName"></SPAN></TD>
    <TD><SPAN DATAFLD="LastName"></SPAN></TD>
  </TR>
</TBODY>
</TABLE>

<HR>
<INPUT TYPE=BUTTON NAME="Run" VALUE="Run">

<H4>Click Run. The CreateObject Method of the RDS.DataSpace Object Creates an instance of the RDSServer.DataFactory.
The Query Method of the RDSServer.DataFactory is used to bring back a Recordset.</H4>

<Script Language="VBScript">
<!--
Dim DF
Dim strServer
Dim strConnect
Dim strSQL
strServer = "http://<%=Request.ServerVariables("SERVER_NAME")%>"
strConnect = "Provider=SQLOLEDB;User Id=rdsdemo;Password=rdsdemo;" & _
                  "Initial Catalog=AddrBookDB;Data Source=MyServer;"
strSQL = "Select * from Employee"

Sub Run_OnClick()
    Dim objADORs      'Create Recordset Object
    Set DF = RDS1.CreateObject("RDSServer.DataFactory", strServer)      'Get Recordset  
    Set objADORs = DF.Query(strConnect, strSQL)   
    ' Use  RDS.DataControl to bind Recordset to Data
    ' Aware Grid Control

    RDS.SourceRecordset = objADORs

End Sub
-->
</Script>

次の例では、CreateObject メソッドを使って、カスタムビジネスオブジェクトである VbBusObj.VbBusObjCls のインスタンスを作成する方法を示します。ここでは、Web サーバー名を識別する Active Server Pages スクリプトも使用しています。完全な例を表示するには、サンプルアプリケーションセレクタから、クライアント層の列にある VBScript in Internet Explorer および中間層の列にあるカスタム Visual Basic ビジネスオブジェクトを選択してください。

Sub Window_OnLoad()
    strServer = "http://<%=Request.ServerVariables("SERVER_NAME")%>"
    Set BO = ADS1.CreateObject("VbBusObj.VbBusObjCls", strServer)
    txtConnect.Value = "dsn=Pubs;uid=sa;pwd=;"
    txtGetRecordset.Value = "Select * From authors"
End Sub