+---------------------------------+
|           SHOW POPUP            |
+---------------------------------+
SHOW POPUP <popup name1>
        [, <popup name2> ... ] | ALL
        [SAVE]

-----------------------------------
Displays previously defined popup.
-----------------------------------

This command allows you to display a popup or a set of popups on the
screen or in a window without activating them.  The popups are displayed
but may not be used.  The popups must first be defined with DEFINE POPUP
before they may be shown.

<popup name1> [, <popup name2> ... ]
        One or more popups to be placed on the screen or in a window.

ALL
        Places all currently defined popups on the screen or in a window.

SAVE
        Retains an image of popups on the screen without activating the popups.
The popup images can then be cleared from the screen or a window with
CLEAR.

+---------------------------------+
|         Program Example         |
+---------------------------------+
*** SHOW POPUP EXAMPLE ***
CLEAR
DEFINE MENU mainmenu
DEFINE PAD invoices  OF mainmenu PROMPT ' \<INVOICES ' AT 01,00
DEFINE PAD customers OF mainmenu PROMPT ' \<CUSTOMERS ' AT 01,14

ON SELECTION PAD invoices  OF mainmenu DO disppop WITH PAD()
ON SELECTION PAD customers OF mainmenu DO disppop WITH PAD()

DEFINE POPUP invpop FROM 2,0
DEFINE BAR  1 OF invpop PROMPT '\<The invoice stack'
DEFINE BAR  2 OF invpop PROMPT;
        '\<Print one or a bunch of invoices'
DEFINE BAR  3 OF invpop PROMPT '\<Show me what my sales are'

DEFINE POPUP custpop FROM 02,14
DEFINE BAR  1 OF custpop PROMPT '\<Look at the Customer info'
DEFINE BAR  2 OF custpop PROMPT 'L\<ist my customers'
DEFINE BAR  3 OF custpop PROMPT '\<Make customer labels'
DEFINE BAR  4 OF custpop PROMPT '\<The Customer Ledger'
ACTIVATE MENU mainmenu

PROCEDURE disppop
PARAMETER padname
IF UPPER(padname) = 'INVOICES'
        SHOW POPUP invpop  SAVE
ELSE
        SHOW POPUP custpop SAVE
ENDIF
@ 11,0 SAY 'This is the ' + padname + ' popup'
WAIT WINDOW
CLEAR
RETURN

In this example a menu bar is created with two menu pads.  When a menu
pad is chosen, ON SELECTION PAD calls a procedure that uses SHOW POPUP
to place corresponding popup on the screen.  Popup is displayed but may
not be used.

-----------------------------------

See Also:  ACTIVATE POPUP, DEFINE BAR, DEFINE POPUP, HIDE POPUP

-----------------------------------