+---------------------------------+
|           HIDE POPUP            |
+---------------------------------+
HIDE POPUP <popup name1>
        [, <popup name2> ... ]
        | ALL [SAVE]

-----------------------------------
Hides a popup.
-----------------------------------

HIDE POPUP removes a specified menu popup, a set of menu popups or all
menu popups from the screen or a window but not from memory.  A menu
popup must first be created with the DEFINE POPUP command before it may
be hidden.  Hiding a menu popup is not the same as deactivating it.
When a menu popup is hidden, it stays resident in memory and may be
displayed on the screen or in a window with the ACTIVATE POPUP or SHOW
POPUP commands.

You hide a specific menu popup by including its name or hide a set of
menu popups with a list of menu popup names.  Specify the keyword ALL to
hide all defined menu popups.

You can place an image of a menu popup on the screen or in a window by
including the SAVE option.  Placing an image of a menu popup on the
screen is useful during program development and testing.  Menu popup
images may be cleared from the screen or a window with the CLEAR
command.

Clauses
-------

<popup name1> [,<popup name2>...]
        List of popups to hide.

ALL
        Hides all defined popups.

SAVE
        Places image of popup on screen or in window.

+---------------------------------+
|         Program Example         |
+---------------------------------+
In this example, a menu bar is defined with four menu pads.  When one of
the menu pads is chosen, a corresponding popup is displayed.  When one
of the options in the popup is chosen, two values are passed to the
TMENU routine.  The TMENU routine hides all popups and displays a
message.

CLEAR
DEFINE MENU mainmenu
DEFINE PAD invoices  OF mainmenu PROMPT ' \<Invoices '  AT 1,00
DEFINE PAD customers OF mainmenu PROMPT ' \<Customers ' AT 1,20
ON SELECTION PAD invoices  OF mainmenu ACTIVATE POPUP invpop
ON SELECTION PAD customers OF mainmenu ACTIVATE POPUP custpop

DEFINE POPUP invpop FROM 3,1
DEFINE BAR  1 OF invpop PROMPT '\<The invoice stack'
DEFINE BAR  2 OF invpop PROMPT '\<Print one or more invoices'
DEFINE BAR  3 OF invpop PROMPT '\<Show me what my sales are'
ON SELECTION POPUP invpop DO tmenu WITH POPUP(), PROMPT()

DEFINE POPUP custpop FROM 3,14
DEFINE BAR  1 OF custpop PROMPT '\<Look at the Customer info'
DEFINE BAR  2 OF custpop PROMPT 'L\<ist my customers'
DEFINE BAR  3 OF custpop PROMPT '\<Make customer labels'
DEFINE BAR  4 OF custpop PROMPT '\<The Customer Ledger'
ON SELECTION POPUP custpop DO tmenu WITH POPUP(), PROMPT()

ACTIVATE MENU mainmenu

PROCEDURE tmenu
PARAMETER mpopup, mprompt
HIDE POPUP ALL
DO CASE
        CASE mpopup = 'INVPOP'
                @ 5,0 SAY 'Selected prompt of popup invpop is: ' + mprompt
        CASE mpopup = 'CUSTPOP'
                @ 5,0 SAY 'Selected prompt of popup custpop is: ' + mprompt
ENDCASE
WAIT
CLEAR
DEACTIVATE POPUP
RETURN

-----------------------------------

See Also:  ACTIVATE POPUP, DEFINE BAR, DEFINE POPUP, SHOW POPUP

-----------------------------------