home *** CD-ROM | disk | FTP | other *** search
/ RUN Flagazine: Run 14 / unpacked-run14.zip / PIETJE.BAS < prev    next >
BASIC Source File  |  1995-01-01  |  3KB  |  41 lines
  1. 100 REM *** Kanarie in kooi *** EGA
  2. 120 V$(0,0)="C14E1R1E1R1E1R5F1R1F7R2F2R1F4R1F22L6F2D1F17L4G2L1H8U1H4U1H4U1H2L5"
  3. 130 V$(0,0)=V$(0,0)+"U1L4D2L1U1H3L2H1L2H1L1H1L1H8U1H1U1H1U1H1U1H1U1H1U2H3U1E1"
  4. 140 V$(0,0)=V$(0,0)+"U1H2BR4P14,14BL4BG4C12U1E2R2F1D1G1L5BU1BR2P12,12BU2BR7C9"
  5. 150 V$(0,0)=V$(0,0)+"U1R1D1BD35BR23C12G4L3G1D3F1U5R8F1D3G1U5L2H1E3BR10BU2C6H2"
  6. 160 V$(1,0)="U2R1F1R2F1R3F1R5BL3BU2H2L1H4L1H4BL2BD1L1H1L1H1L1H1L1H1L1H1L1H2U2"
  7. 170 V$(1,0)=V$(1,0)+"BU8L4BL6BD1G1D1G1D2F1D1F1D1F1D1F6R1F2R2F1R1F1R2F1R2F1R2"
  8. 180 V$(1,0)=V$(1,0)+"F1R3BU3L1H1L3H1L1H1L1H1L1H1L1H1L1H1L1H3L1H3U1H1U2E1"
  9. 190 FOR M%=0 TO 1:FOR N%=1 TO LEN(V$(M%,0)):T$=MID$(V$(M%,0),N%,1)
  10. 200 A=INSTR("HLGERF"+T$,T$):T$=MID$("ERFHLG"+T$,A,1):V$(M%,1)=V$(M%,1)+T$
  11. 210 NEXT N%:NEXT M%:CLS:FOR SC%=0 TO 1:SCREEN 9,,SC%,1-SC%
  12. 220 FOR N%=0 TO 1:LINE(50+N%*15,140+N%*80)-STEP(540-N%*30,0),11:NEXT N%
  13. 230 FOR N%=-12 TO 12:FOR M%=0 TO 1:LINE(320+M%+N%*22,30)-STEP(0,290),11-M%*8
  14. 240 NEXT M%:NEXT N%:FOR N%=1 TO -1 STEP -1:FOR M%=-1 TO 1 STEP 2:COLOR 2
  15. 250 K%=N%:IF N%=-1 THEN K%=11
  16. 260 LINE(320,45)-STEP(M%*-280,40),K%:LINE-STEP(M%*35,195),K%
  17. 270 LINE-(320,280),K%:NEXT M%:IF K%<2 THEN PAINT(1,1),K%,K%
  18. 280 NEXT N%:CIRCLE(320,35),12,11:LOCATE 24,36:PRINT "<Esc>=Stop";:LOCATE 1,5
  19. 290 COLOR 9:PRINT "Sound: Koen Peters"+SPACE$(30)+"Graphics: Koos van Egmond"
  20. 300 DRAW "C7BM75,281R490M-8,+40L474M-8,-40BF2P8,7":NEXT SC%:SC%=1:Q=1
  21. 310 WHILE Q:X=202:Y=176:V=1:W=1:P=1:GOSUB 340:X=345:Y=96:W=.25:GOSUB 340
  22. 320 X=488:Y=176:W=.5:GOSUB 340:X=438:V=0:W=1:P=1:GOSUB 340
  23. 330 X=295:Y=96:W=.25:GOSUB 340:X=152:Y=176:W=.5:GOSUB 340:WEND
  24. 340 LINE(130,90)-(510,235),0,BF:FOR N%=-1 TO 1
  25. 350 CIRCLE(320+N%*143,140+ABS(N%*80)),4,15:PAINT STEP(0,0),15,15:NEXT N%
  26. 360 PSET(X,Y),14:DRAW V$(0,V):DRAW V$(1,V)
  27. 370 FOR N%=0 TO 1:LINE(130,140+N%*80)-STEP(380,0),11:NEXT N%:
  28. 380 FOR N%=-8 TO 8:FOR M%=0 TO 1:LINE(320+M%+N%*22,90)-STEP(0,145),11-M%*8
  29. 390 NEXT M%:NEXT N%:IF INKEY$=CHR$(27) THEN CLS:SCREEN 0,0,0:END
  30. 400 SC%=ABS(SC%-1):SCREEN 9,,1-SC%,1-SC%:GOSUB 420:IF P=1 THEN GOSUB 430
  31. 410 SCREEN 9,,SC%,1-SC%:GOSUB 420:RETURN
  32. 420 PALETTE 6,14:T=TIMER:WHILE ABS(T-TIMER)<W:WEND:RETURN
  33. 430 FOR C%=200 TO 300 STEP 2:FOR A%=5000 TO 2000 STEP -C%:SOUND A%,.1:GOSUB 480
  34. 440 NEXT:GOSUB 490:NEXT:FOR C%=400 TO 200 STEP -4:FOR A%=2000 TO 5000 STEP C%
  35. 450 SOUND A%,.2:GOSUB 480:NEXT:GOSUB 490:NEXT:FOR PAUSE=4 TO 64 STEP 2
  36. 460 P$=STR$(PAUSE):FOR A%=5000 TO 2000 STEP -200:PLAY "MF":SOUND A%,.1
  37. 470 GOSUB 480:NEXT A%:GOSUB 490:PLAY"MBP"+P$:NEXT:P=0:RETURN
  38. 480 IF A%>3300 AND A%<3700 THEN K%=14 ELSE K%=0:GOTO 500
  39. 490 LINE(320-(2*V-1)*121,184)-STEP(2*(2*V-1),-2),K%
  40. 500 IF INKEY$=CHR$(27) THEN CLS:SCREEN 0,0,0:END:ELSE RETURN
  41.