home *** CD-ROM | disk | FTP | other *** search
/ RUN Flagazine: Run 12 / run12.zip / XPALETTE.BAS < prev    next >
BASIC Source File  |  1994-03-10  |  2KB  |  35 lines
  1. 100 REM XPALETTE.BAS GWBasic SCREEN 9 EN VGA-SCHERM. (C) Koos van Egmond
  2. 110 SCREEN 9:KEY OFF:CLS:COLOR 14:LOCATE 1,20
  3. 120 PRINT "Maak zelf uw kleuren met de OUT-statement":COLOR 7:LOCATE 4,5
  4. 130 PRINT "Standaard PALETTE instelling":FOR N=1 TO 15:KLEUR=N:COLOR N
  5. 140 IF N>7 THEN KLEUR=N+48 ELSE IF N=6 THEN KLEUR=20
  6. 150 LOCATE 5+N,5:PRINT STRING$(5,219)"  PALETTE"N","KLEUR:NEXT N
  7. 160 LINE(310,160)-STEP(124,83),6,BF:LINE STEP(-6,-5)-STEP(-112,-73),0,BF
  8. 170 COLOR 2:LOCATE 6,40:PRINT "Met de subroutine vanaf regel 380":LOCATE 7,40
  9. 180 PRINT "is het mogelijk om een kleur naar keuze":LOCATE 8,40
  10. 190 PRINT "te veranderen. Bijvoorbeeld kleur 20.":COLOR 7:LOCATE 10,40
  11. 200 PRINT "In een programma gaat dat als volgt:":COLOR 15:LOCATE 13,42
  12. 210 PRINT "KLEUR = 20":LOCATE 14,42:PRINT "ROOD  =":LOCATE 15,42
  13. 220 PRINT "GROEN =":LOCATE 16,42:PRINT "BLAUW =":LOCATE 17,42:PRINT "GOSUB 380"
  14. 230 COLOR 3:LOCATE 20,40:PRINT "Verander nu kleur 20 met (r,R,g,G,b,B)"
  15. 240 LOCATE 21,40:PRINT "Kleine letter maakt donkerder,":LOCATE 22,40
  16. 250 PRINT "hoofdletter maakt lichter.":COLOR 7:LOCATE 24,5
  17. 260 PRINT "<Esc> = stoppen";:KLEUR=20:ROOD=42:GROEN=21:BLAUW=0:COLOR 15
  18. 270 LOCATE 14,49:PRINT ROOD:LOCATE 15,49:PRINT GROEN:LOCATE 16,49:PRINT BLAUW
  19. 280 COLOR 6:LOCATE 15,60:PRINT "PALETTE 6,20":COLOR 15
  20. 290 I$=INKEY$:IF I$="" THEN GOTO 290
  21. 300 IF I$="r" AND ROOD>0 THEN ROOD=ROOD-1
  22. 310 IF I$="R" AND ROOD<63 THEN ROOD=ROOD+1
  23. 320 IF I$="g" AND GROEN>0 THEN GROEN=GROEN-1
  24. 330 IF I$="G" AND GROEN<63 THEN GROEN=GROEN+1
  25. 340 IF I$="b" AND BLAUW>0 THEN BLAUW=BLAUW-1
  26. 350 IF I$="B" AND BLAUW<63 THEN BLAUW=BLAUW+1
  27. 360 IF I$=CHR$(27) THEN CLS:SCREEN 0,0,0:END
  28. 370 GOSUB 380:GOTO 270
  29. 380 OUT &H3C6,&HFF:OUT &H3C8,KLEUR
  30. 390 OUT &H3C9,ROOD:OUT &H3C9,GROEN:OUT &H3C9,BLAUW:RETURN
  31. 400 REM /* 29/.2530,5214,4832,2800,3634,3836,5154,4599,4959,4873
  32. 410 REM /*/....3394,4425,4553,4732,4161,4586,4632,2972,1800,2198
  33. 420 REM /*/....2219,2400,2421,2395,2416,2296,1063,1845,3451
  34. 430 REM Checksum...............:  100390
  35.