home *** CD-ROM | disk | FTP | other *** search
/ RUN Flagazine: Run 1 / run1.zip / RACE.BAS < prev    next >
BASIC Source File  |  2014-09-03  |  3KB  |  46 lines
  1. 100 REM Paardenrace door Wim Engelfriet GW-BASIC MONO
  2. 110 SCREEN 0:KEY OFF:A$="CDEFGAB>C<":COLOR 15,0
  3. 120 DIM PA$(4),PB$(4),PC$(4),P(4),VOOR$(4):FOR I=1 TO 4:P(I)=3:NEXT
  4. 130 DIM LA(4),KA(4),LB(4),KB(4),LC(4),KC(4):LN$="   "+STRING$(75,196)
  5. 140 RW$=STRING$(79,32)+STRING$(79,29):E$=CHR$(27)
  6. 150 H$=CHR$(11):L$=CHR$(29):R$=CHR$(32):U$=CHR$(30):D$=CHR$(31)
  7. 160 FOR I=1 TO 4:H1$=RIGHT$(STR$(I),1)
  8. 170 PA$(I)="   _____/=":PB$(I)="  /[_"+H1$+"_]":PC$(I)="   /\ /\":NEXT I
  9. 180 RANDOMIZE(TIMER):CLS:KEY OFF:GOTO 230
  10. 190 B$=INPUT$(1):IF INSTR("JjNn",B$)=0 THEN 190 ELSE PRINT B$:RETURN
  11. 200 CLS:PRINT TAB(32) "RUN - PAARDENRACE":PRINT STRING$(80,205);:RETURN
  12. 210 FOR W=1 TO 999:NEXT:RETURN
  13. 220 FOR W=1 TO 100:NEXT:RETURN
  14. 230 GOSUB 200:FOR I=1 TO 4:LOCATE I*4,1:LA(I)=CSRLIN:KA(I)=POS(0)
  15. 240 PRINT PA$(I):LOCATE I*4+1,1:LB(I)=CSRLIN:KB(I)=POS(0):PRINT PB$(I)
  16. 250 LOCATE I*4+2,1:LC(I)=CSRLIN:KC(I)=POS(0):PRINT PC$(I):PRINT LN$:NEXT
  17. 260 HH$=STRING$(2,219):NM$="Getipt wordt paard nr: "
  18. 270 LOCATE 20,4:FOR I=1 TO LEN(NM$):PRINT MID$(NM$,I,1);:GOSUB 220:NEXT
  19. 280 H1=INT(RND*4)+1:H1$="<"+RIGHT$(STR$(H1),1)+">":PRINT H1$;
  20. 290 NM$="   Welk paard kiest U (1-4)? "
  21. 300 FOR I=1 TO LEN(NM$):PRINT MID$(NM$,I,1);:GOSUB 220:NEXT
  22. 310 B$=INPUT$(1):IF B$="" OR VAL(B$)<1 OR VAL(B$)>4 THEN 310                        ELSE PRINT " <"B$">":B=VAL(B$)
  23. 320 PLAY "MLT255L64XA$;XA$;XA$;XA$;XA$;"
  24. 330 NM$=CHR$(219)+"S"+HH$+"T"+HH$+"A"+HH$+"R"+HH$+"T"+CHR$(219)
  25. 340 FOR I=1 TO LEN(NM$):LOCATE I+5,1:PRINT MID$(NM$,I,1):NEXT
  26. 350 HH$=CHR$(219):NM$=HH$+"F"+HH$+"I"+HH$+"N"+HH$+"I"+HH$+"S"+HH$+"H"+HH$
  27. 360 FOR I=1 TO LEN(NM$):LOCATE I+5,80:PRINT MID$(NM$,I,1):NEXT:BEEP
  28. 370 FOR J=1 TO 200:FOR I=1 TO 4:P(I)=INT(RND*2):IF J=1 THEN P(I)=2
  29. 380 KA(I)=KA(I)+P(I):KB(I)=KB(I)+P(I):KC(I)=KC(I)+P(I)
  30. 390 LOCATE LA(I),KA(I):KA(I)=POS(0):PRINT PA$(I)
  31. 400 LOCATE LB(I),KB(I):KB(I)=POS(0):PRINT PB$(I)
  32. 410 LOCATE LC(I),KC(I):KC(I)=POS(0):PRINT PC$(I)
  33. 420 IF KA(I)=>LEN(LN$)-8 THEN HULP$=RIGHT$(STR$(I),1):GOTO 440
  34. 430 GOSUB 220:NEXT I,J
  35. 440 PLAY "MLT255L12":FOR I=25 TO 40:J=I+3:K=I+7:PLAY "N=I;":NEXT
  36. 450 LOCATE 21,4:PRINT"Het beste paard is: <";HULP$;">  U heeft ";
  37. 460 IF VAL(HULP$)=B THEN PRINT"goed";:GOTO 480
  38. 470 PRINT"fout";
  39. 480 PRINT" gekozen!  Nog eens (J/N)? ";:GOSUB 190
  40. 490 IF B$="j" OR B$="J" THEN 230 ELSE CLS:END
  41. 500 REM /* 39/.2594,3515,3405,2672,3295,1936,3554,2461,3893,4165
  42. 510 REM /*/....1677,1651,3632,4032,4268,3440,3981,3282,2162,3289
  43. 520 REM /*/....4626,2193,3128,3400,3678,3797,3433,2900,2647,2651
  44. 530 REM /*/....2655,3422,1100,3544,4101,2696,0970,2970,2194
  45. 540 REM Checksum...............:  119009
  46.