home
***
CD-ROM
|
disk
|
FTP
|
other
***
search
/
RUN Flagazine: Run 1
/
run1.zip
/
FANTLET.BAS
< prev
next >
Wrap
BASIC Source File
|
2014-09-03
|
2KB
|
43 lines
100 REM FANTASIELETTERS GWBASIC GRAPHICS CGA
110 CLS:KEY OFF:SCREEN 2
120 LOCATE 6,31:PRINT "Fantasieletters"
130 LOCATE 8,30:PRINT "<1> Wimpelletters"
140 LOCATE 9,30:PRINT "<2> Cirkelletters"
150 LOCATE 10,30:PRINT "<3> Kruisletters"
160 LOCATE 12,30:PRINT "Kies 1, 2 of 3";
170 INPUT A$:IF INSTR("123",A$)=0 THEN BEEP:GOTO 160
180 ON VAL(A$) GOTO 190,280,360
190 PRINT:PRINT "Woord van maximaal 8 letters: ";:LINE INPUT A$
200 IF LEN(A$)<1 OR LEN(A$)>8 THEN BEEP:GOTO 190
210 CLS:A=LEN(A$):PRINT A$:DIM XY(63,8):FOR X=0 TO A*8-1
220 FOR Y=0 TO 8:XY(X,Y)=POINT(X,Y):NEXT Y,X:CLS
230 FOR X=0 TO A*80-1 STEP .5:Z=COS(3.1415/630*X)^2*7:C=10/(10+Z)
240 FOR Y=0 TO 80:D=XY(INT(X/10),INT(Y/10))
250 IF D=1 AND E=0 THEN PSET (320+(X+325-40*A-320)*C,(Y+100)*C):E=1
260 IF D=0 AND E=1 THEN LINE -(320+(X+325-40*A-320)*C,(Y+100)*C):E=0
270 NEXT Y:NEXT X:GOSUB 460:RUN
280 PRINT:PRINT "Woord van maximaal 6 letters: ";:LINE INPUT A$
290 IF LEN(A$)<1 OR LEN(A$)>6 THEN BEEP:GOTO 280 ELSE CLS:DIM XY(48,8)
300 PRINT A$:FOR Y=0 TO 8:FOR X=0 TO 48:XY(X,Y)=POINT(X,Y):NEXT X,Y
310 CLS:FOR Y=80 TO 0 STEP -1:RY=Y+20:RX=Y+120:A=0
320 FOR X=0 TO 480 STEP 25/(Y+1):A=(X/480)*6.283-3.1415/2
330 X1=320+RX*COS(A):Y1=100+RY*SIN(A)
340 IF XY(INT(X/10),INT((80-Y)/10))=1 THEN PSET (X1,Y1)
350 NEXT X,Y:GOSUB 460:RUN
360 PRINT:PRINT "Woord van maximaal 8 letters: ";:LINE INPUT A$
370 IF LEN(A$)<1 OR LEN(A$)>8 THEN BEEP:GOTO 190 ELSE DIM XY(63,7)
380 CLS:PRINT A$:FOR X=0 TO 63:FOR Y=0 TO 7:XY(X,Y)=POINT(X,Y)
390 NEXT Y,X:CLS:FOR X=0 TO 630 STEP .4:P=10/(10+X/25):FOR Y=0 TO 70
400 B1=XY(INT(X/10),INT(Y/10)):B2=XY(INT((630-X)/10),INT(Y/10))
410 IF B1=1 AND A1=0 THEN X1=320+(X-315)*P:Y1=(Y+105)*P:A1=1
420 IF B1=0 AND A1=1 THEN X2=320+(X-315)*P:Y2=(Y+105)*P: LINE (X1,Y1)-(X2,Y2):A1=0
430 IF B2=1 AND A2=0 THEN X3=320+((630-X)-315)*P:Y3=(Y+105)*P:A2=1
440 IF B2=0 AND A2=1 THEN X4=320+((630-X)-315)*P:Y4=(Y+105)*P: Y4=(Y+105)*P:LINE (X3,Y3)-(X4,Y4):A2=0
450 NEXT Y,X:GOSUB 460:RUN
460 BEEP:LOCATE 1,1:PRINT "Toets <Enter>";:INPUT A$:RETURN
470 REM /* 36/.1292,2743,2726,2708,2673,2067,2764,1428,4409,2453
480 REM /*/....3016,2824,3342,2282,3271,3295,1772,4407,3716,3853
490 REM /*/....2710,2772,2015,2901,1439,4409,3430,3535,3595,3488
500 REM /*/....3008,4210,3294,5249,1439,3762
510 REM Checksum...............: 108297