home *** CD-ROM | disk | FTP | other *** search
/ RUN Flagazine Extra: Supplement 2: Soundwriter / run-supplement-2.zip / BOEKET.BAS < prev    next >
BASIC Source File  |  1991-07-05  |  2KB  |  43 lines
  1. 1000 REM BOEKETJE GEPLUKT EN BEWERKT VOOR CGA(640x200),HERC.,EGA EN VGA
  2. 1010 DEFINT D,X-Z:GOSUB 1270:ON ERROR GOTO 0:IF FLMODE=1 THEN 1200
  3. 1020 COMMON MENUFL%
  4. 1030 XM=GH%/2:YM=GV%/2:F=3*GH%/(4*GV%):LOCATE 1,60:PRINT"Stop met Esc."
  5. 1040 YS=4:DT=10:IF GV%>300 THEN YS=6:DT=14:IF GV%>400 THEN YS=8
  6. 1050 P=3:PI=4*ATN(1):P2=2*PI:S=P2/180:FOR D=1 TO DT:M=YS*D:AA=D*PI/50
  7. 1060 FOR AN=0 TO P2 STEP S:A=AN+AA:SN=ABS(SIN(AN*P/2)):RA=M*(SN+AA)
  8. 1070 IF INKEY$=CHR$(27) THEN 1110
  9. 1080 X=F*COS(A)*RA:Y=SIN(A)*RA:IF AN=0 THEN FL=0:GOSUB 1220:GOTO 1100
  10. 1090 FL=1:GOSUB 1220
  11. 1100 NEXT AN:GOSUB 1220:NEXT D:LOCATE 1,1:GOSUB 1390
  12. 1110 CLS:FK=1:LOCATE 1,60:PRINT"Stop met Esc.":FOR D=1 TO DT:M=D*YS
  13. 1120 FOR AN=0 TO P2 STEP S:A=AN:SN=ABS(SIN(AN*P/2)):RA=M*(SN+1)
  14. 1130 IF INKEY$=CHR$(27) THEN 1200
  15. 1140 X=F*COS(A)*RA:Y=SIN(A)*RA:IF AN=0 THEN FL=0:GOSUB 1220:GOTO 1160
  16. 1150 FL=1:GOSUB 1220
  17. 1160 NEXT AN:GOSUB 1220:A=136+(D MOD 3)*17
  18. 1170 IF MD<8 OR MD=10 THEN PAINT(XP-1,YP+1),CHR$(A)+CHR$(0)+CHR$(A)+CHR$(0),N:GOTO 1190
  19. 1180 PAINT(XP-1,YP+1),(15-(D MOD 6)),N
  20. 1190 NEXT D
  21. 1200 LOCATE 1,1:PRINT "Toets <Esc>":WHILE INKEY$<>CHR$(27):WEND
  22. 1210 CLS:SCREEN 0:IF MENUFL% THEN 120
  23. 1215 END
  24. 1220 XP=XM+X:YP=YM-Y:IF FL=0 THEN XO=XP:YO=YP:RETURN
  25. 1230 N=1:IF MD>7 THEN N=2:IF FK=0 THEN N=15-(D MOD 7)
  26. 1240 IF MD=10 THEN N=1
  27. 1250 LINE(XO,YO)-(XP,YP),N:XO=XP:YO=YP:RETURN
  28. 1260 REM SUBROUTE VOOR AUTOMATISCHE AANPASSING SCREEN 12 T/M 0 STEP -1
  29. 1270 KEY OFF:CLS:SCREEN 0,0,0:MD=12:ON ERROR GOTO 1290
  30. 1280 SCREEN MD:IF MD=0 THEN 1370 ELSE 1300
  31. 1290 MD=MD-1:RESUME 1280
  32. 1300 WINDOW SCREEN(0,0)-(1,1):GH%=PMAP(1,0)+1:GV%=PMAP(1,1)+1:WINDOW
  33. 1310 PRINT "Gevonden grafische mode is SCREEN: ";MD;
  34. 1320 IF MD=12 OR MD=11 THEN PRINT "(VGA)"
  35. 1330 IF MD=9 OR MD=10 THEN PRINT "(EGA)"
  36. 1340 IF GH%=720  THEN PRINT "(Hercules)"
  37. 1350 IF MD=2 THEN IF GH%<> 720 THEN PRINT "(CGA)"
  38. 1360 PRINT "SCHERMRESOLUTIE: ";GH%;" x ";GV%;"beeldpunten":PRINT:GOSUB 1390:RETURN
  39. 1370 LOCATE 4,1:PRINT"Grafische mode niet aanspreekbaar.":PRINT
  40. 1380 PRINT"Dit programma wordt na <Esc> verlaten.":FLMODE=1:GOSUB 1390:RETURN
  41. 1390 PRINT "Toets <Esc>":WHILE INKEY$<>CHR$(27):WEND:CLS:RETURN
  42. 20000 REM EIND BOEKET
  43.