home
***
CD-ROM
|
disk
|
FTP
|
other
***
search
/
RUN Flagazine Extra: Supplement 1: RUNSheet
/
run-supplement-1.zip
/
CALCUL.BAS
< prev
next >
Wrap
BASIC Source File
|
1989-11-24
|
2KB
|
45 lines
100 REM DECIMAAL/OCTAAL/BINAIR CALCULATOR - MONOCHROOM
110 CLS:KEY OFF:DEF SEG=0
120 PRINT "NumLock staat aan":PRINT CHR$(17)CHR$(217) "nieuwe invoer"
130 PRINT "Esc Einde":PRINT "Geen getallen > 65535"
140 A1$=CHR$(201)+STRING$(19,205)+CHR$(187)
150 A2$=CHR$(186)+STRING$(19,32)+CHR$(186)
160 A3$=CHR$(200)+STRING$(19,205)+CHR$(188)
170 A4$=CHR$(199)+STRING$(19,196)+CHR$(182)
180 A5$=CHR$(204)+STRING$(19,205)+CHR$(185)
190 LOCATE 4,30:PRINT A1$
200 FOR A=5 TO 19:LOCATE A,30:PRINT A2$:NEXT A
210 LOCATE 20,30:PRINT A3$
220 LOCATE 5,36:PRINT "DECIMAAL"
230 LOCATE 6,30:PRINT A4$:LOCATE 8,30:PRINT A5$
240 LOCATE 9,36:PRINT " OCTAAL"
250 LOCATE 10,30:PRINT A4$:LOCATE 12,30:PRINT A5$
260 LOCATE 13,34:PRINT "HEXADECIMAAL"
270 LOCATE 14,30:PRINT A4$:LOCATE 16,30:PRINT A5$
280 LOCATE 17,37:PRINT "BINAIR"
290 LOCATE 18,30:PRINT A4$
300 GOSUB 420:POKE 1047,PEEK(1047) OR 32
310 COLOR 15,0:LOCATE 7,31:I$=INKEY$
320 IF I$<>"1" AND I$<>"2" AND I$<>"3" AND I$<>"4" THEN 330 ELSE 350
330 IF I$<>"5" AND I$<>"6" AND I$<>"7" AND I$<>"8" THEN 340 ELSE 350
340 IF I$<>"9" AND I$<>"0" AND I$<>CHR$(13) AND I$<>CHR$(27) THEN 310
350 IF I$=CHR$(13) THEN S$="":GOSUB 420:GOTO 310
360 IF I$=CHR$(27) THEN POKE 1047,PEEK(1047) AND 223:CLS:END
370 S$=S$+I$:LOCATE 7,31:PRINT S$
380 IF VAL(S$)>65535! THEN BEEP:LOCATE 7,31:COLOR 31,0:PRINT S$:GOTO 310
390 LOCATE 11,31:PRINT OCT$(VAL(S$))
400 LOCATE 15,31:PRINT HEX$(VAL(S$))
410 GOSUB 450:GOTO 310
420 FOR A=7 TO 19 STEP 4
430 LOCATE A,31:PRINT STRING$(19,32)
440 LOCATE A,31:PRINT "0":NEXT A:RETURN
450 N=VAL(S$):BI$="":Q$=""
460 N=N/2
470 IF N<.5 THEN 500 ELSE Z=INT(2*(N-INT(N)))
480 IF Z>9 THEN Z=Z+7
490 Q$=Q$+CHR$(48+Z):X=X-1:GOTO 460
500 FOR A=LEN(Q$) TO 1 STEP -1
510 BI$=BI$+MID$(Q$,A,1)
520 LOCATE 19,31:PRINT BI$
530 NEXT A:RETURN