home *** CD-ROM | disk | FTP | other *** search
/ RUN Flagazine Extra: Special 3 / run-special-3.zip / TACHISTO.BAS < prev    next >
BASIC Source File  |  1989-11-24  |  2KB  |  45 lines
  1. 100 REM TACHISTOSCOOP - MONOCHROOM
  2. 110 CLS:KEY OFF:RANDOMIZE VAL(RIGHT$(TIME$,2))
  3. 120 PRINT TAB(30) "TACHISTOSCOOP"
  4. 130 GOSUB 480:PRINT
  5. 140 PRINT TAB(20) "Dit programma leert u sneller lezen."
  6. 150 PRINT TAB(20) "U moet de woorden lezen en invoeren."
  7. 160 PRINT TAB(20) "De leestijden worden steeds korter"
  8. 170 PRINT TAB(20) "Nadat u per ronde twee woorden goed"
  9. 180 PRINT TAB(20) "heeft gelezen en ingevoerd.":GOSUB 480
  10. 190 PRINT:PRINT TAB(30) "Toets <Enter>"
  11. 200 I$=INKEY$:IF I$<>CHR$(13) THEN 200
  12. 210 DIM A$(28):Z=RND(-TIMER):X=500
  13. 220 FOR A=0 TO 27:READ A$(A):NEXT A
  14. 230 CLS:GOSUB 350:IF X=0 THEN 330
  15. 240 LOCATE 23,30:INPUT "Wat las u";W$
  16. 250 IF W$=C$ THEN GOSUB 500:LOCATE 13,36:PRINT "CORRECT":GOSUB 480:T=T+1:GOTO 280
  17. 260 IF W$<>C$ THEN GOSUB 500:LOCATE 13,37:PRINT "FOUT":GOSUB 480:LOCATE 13,31:PRINT C$;:F=F+1
  18. 265 LOCATE 16,33:PRINT "Toets <Enter>";
  19. 266 WHILE INKEY$<>CHR$(13):WEND
  20. 280 IF T=2 THEN LOCATE 24,25:PRINT "Tweemaal goed op";X;"milliseconden";:GOSUB 480
  21. 290 IF X<=100 AND T=2 THEN T=0:X=X-10:GOTO 310
  22. 300 IF X>=100 AND T=2 THEN T=0:X=X-100
  23. 310 IF X=0 THEN 330
  24. 320 GOTO 230
  25. 330 PRINT:PRINT "U hebt 't gehaald..."
  26. 340 PRINT:PRINT "Aantal fouten: ";F
  27. 345 WHILE INKEY$="":WEND:END
  28. 350 LOCATE 23,25:PRINT "Leestijd: ";X;"milliseconden";
  29. 360 GOSUB 500:COLOR 31,0:LOCATE 13,35:PRINT "OPGEPAST":BEEP:GOSUB 480
  30. 370 CLS:C$=A$(INT(27*RND(Z))):GOSUB 500
  31. 380 LOCATE 13,31:COLOR 15,0:PRINT C$:COLOR 7,0
  32. 390 FOR A=1 TO X:NEXT A
  33. 400 CLS:RETURN
  34. 410 DATA "kinderjuffrouw","tafelaansteker","bandrecorder","bandrecorders"
  35. 420 DATA "schoolmeester","schooljuffrouw","videorecorder","videorecorders"
  36. 430 DATA "klarinetspeler","klarinetspelers","schoolmeesters","koffiejuffrouw"
  37. 440 DATA "polshorloge","krantenbezorger","schrijfmachine","bioscoopfilm"
  38. 450 DATA "polshorloges","krantenbezorgers","armbandhorloge","kopieermachine"
  39. 460 DATA "kinderjuffrouwen","tafelaanstekers","koffiejuffrouwen","polshorloges"
  40. 470 DATA "armbandhorloges","schrijfmachines","bioscoopfilms","kopieermachines"
  41. 480 COLOR 7,0:FOR A=1 TO 4000:NEXT A:RETURN
  42. 500 LOCATE 12,30:PRINT CHR$(218)STRING$(17,196)CHR$(191)
  43. 510 LOCATE 13,30:PRINT CHR$(179)STRING$(17,32)CHR$(179)
  44. 520 LOCATE 14,30:PRINT CHR$(192)STRING$(17,196)CHR$(217):RETURN
  45.