home *** CD-ROM | disk | FTP | other *** search
/ RUN Flagazine Extra: Special 3 / run-special-3.zip / MEESTERB.BAS < prev    next >
BASIC Source File  |  1992-06-17  |  3KB  |  52 lines
  1. 100 REM MEESTERBREIN GWBASIC GEWOON (C) RUN FLAGAZINE
  2. 110 KEY OFF:CLS:COLOR 15,0:RANDOMIZE TIMER:DIM KPC(4,1),KI(4,1)
  3. 120 LOCATE 2,2:PRINT CHR$(201);STRING$(76,CHR$(205));CHR$(187)
  4. 130 LOCATE 3,2:PRINT CHR$(186);SPACE$(76);CHR$(186):LOCATE 3,4:COLOR 14,0
  5. 140 PRINT "RUN  << MASTER-MIND >>  MONO   Raad de verborgen figuren in max 10 beurten"
  6. 150 COLOR 15,0:LOCATE 4,2:PRINT CHR$(200);STRING$(76,CHR$(205));CHR$(188)
  7. 160 LOCATE 7,10:PRINT CHR$(201);STRING$(9,CHR$(205));CHR$(187)
  8. 170 LOCATE 8,10:PRINT CHR$(186);
  9. 180 FOR N=1 TO 4:PRINT " ";CHR$(177);:NEXT N:PRINT " ";CHR$(186)
  10. 190 LOCATE 9,10:PRINT CHR$(199);STRING$(9,CHR$(196));CHR$(182)
  11. 200 FOR N=10 TO 19:LOCATE N,10:PRINT CHR$(186);" . . . . ";CHR$(186):NEXT N
  12. 210 LOCATE 20,10:PRINT CHR$(200);STRING$(9,CHR$(205));CHR$(188)
  13. 220 COLOR 14,1:LOCATE 7,30:PRINT CHR$(15);:COLOR 7,1:PRINT " is aantal op de juiste plaats"
  14. 230 COLOR 14,1:LOCATE 8,30:PRINT CHR$(22);:COLOR 7,1:PRINT " is aantal op de verkeerde plaats"
  15. 240 COLOR 15,0:LOCATE 9,30:PRINT CHR$(201);STRING$(9,CHR$(205));CHR$(187)
  16. 250 FOR N=10 TO 19:LOCATE N,30:PRINT CHR$(186);" . . . . ";CHR$(186):NEXT N
  17. 260 LOCATE 20,30:PRINT CHR$(200);STRING$(9,CHR$(205));CHR$(188)
  18. 270 FOR N=1 TO 6:COLOR 14,1:LOCATE 12,50+N*2:PRINT " ";CHR$(N);" ":NEXT N
  19. 280 COLOR 14,1:LOCATE 18,52 :PRINT "<Esc> RUN-desktop"
  20. 290 COLOR 7,1:LOCATE 13,52:PRINT " 1 2 3 4 5 6 ":LOCATE 22,5
  21. 300 PRINT "Bepaal met de pijltjestoetsen de plaats van invoer en tik een nummer in."
  22. 310 LOCATE 23,5:PRINT "Denkt u de goede combinatie gevonden te hebben, druk dan op <Enter>."
  23. 320 COLOR 14,1:LOCATE 24,5:PRINT "LET OP!!! ";
  24. 330 COLOR 7,1:PRINT "Er kunnen dubbele figuren verborgen zijn.";
  25. 340 FOR N=1 TO 4:KPC(N,1)=INT(RND*6)+1:NEXT N:B=1:KOL=1
  26. 350 LOCATE B+9,10+2*KOL,1
  27. 360 I$=INKEY$:IF I$=CHR$(0)+"K" THEN KOL=KOL-1:IF KOL<1 THEN KOL=1
  28. 370 IF I$=CHR$(0)+"M" THEN KOL=KOL+1:IF KOL>4 THEN KOL=4
  29. 380 IF I$>"0" AND I$<"7" THEN KI(KOL,1)=VAL(I$):COLOR 14,0:PRINT CHR$(VAL(I$))
  30. 390 IF I$=CHR$(13) THEN GOSUB 420:IF PG=4 OR B=11 THEN 520
  31. 400 IF I$=CHR$(27) THEN 600
  32. 410 GOTO 350
  33. 420 FA=0:FOR N=1 TO 4:FA=FA+SGN(KI(N,1)):NEXT N:IF FA<4 THEN BEEP:GOTO 510
  34. 430 PG=0:FOR N=1 TO 4:IF KI(N,1)=KPC(N,1) THEN KI(N,0)=1:KPC(N,0)=1:PG=PG+1
  35. 440 NEXT N
  36. 450 AG=0:FOR N=1 TO 4:FOR M=1 TO 4
  37. 460 IF KI(N,1)=KPC(M,1) AND KI(N,0)=0 AND KPC(M,0)=0 THEN KI(N,0)=1:KPC(M,0)=1:AG=AG+1
  38. 470 NEXT M,N
  39. 480 COLOR 14,0:FOR N=1 TO PG:LOCATE B+9,30+2*N:PRINT CHR$(15):NEXT N
  40. 490 FOR N=PG+1 TO AG+PG:LOCATE B+9,30+2*N:PRINT CHR$(22):NEXT N
  41. 500 B=B+1:KOL=1:FOR N=1 TO 4:KI(N,1)=0:KI(N,0)=0:KPC(N,0)=0:NEXT N
  42. 510 RETURN
  43. 520 FOR N=1 TO 4:COLOR 14,0:LOCATE 8,10+N*2:PRINT CHR$(KPC(N,1)):NEXT N
  44. 530 LOCATE 16,52,0:IF PG=4 THEN PRINT "Geraden in";B-1;"beurten.":GOTO 550
  45. 540 PRINT "Niet geraden."
  46. 550 LOCATE 18,52 :PRINT "Nog een keer? [j/n]"
  47. 560 I$=INKEY$:IF I$="n" OR I$="N" THEN 600
  48. 570 IF I$<>"j" AND I$<>"J" THEN 560
  49. 580 FOR N=1 TO 4:KI(N,1)=0:KI(N,0)=0:KPC(N,0)=0:NEXT N:AG=0:PG=0
  50. 590 LOCATE 16,52:PRINT SPACE$(22):LOCATE 18,52:PRINT SPACE$(19):GOTO 150
  51. 600 CLS:END
  52.