home
***
CD-ROM
|
disk
|
FTP
|
other
***
search
/
RUN Flagazine Extra: Special 3
/
run-special-3.zip
/
GOOCHEL.BAS
< prev
next >
Wrap
BASIC Source File
|
1989-11-24
|
1KB
|
31 lines
100 REM GEDACHTENLEZEN - MONOCHROOM
110 A1$=CHR$(201)+STRING$(37,205)+CHR$(187)
120 A2$=CHR$(186)+STRING$(37,32)+CHR$(186)
130 A3$=CHR$(200)+STRING$(37,205)+CHR$(188)
140 CLS:KEY OFF:DEFINT A-Z
150 LOCATE 5,35:PRINT "GOOCHELEN"
160 HO=150:EE=1:MA=SQR(HO/2):Y=7
170 LOCATE 12,22:PRINT "Denk aan een getal tussen 0 en 150"
180 FOR Q=1 TO 5000:NEXT Q:BEEP
190 LOCATE 14,31:PRINT "Druk op een toets"
200 I$=INKEY$:IF I$="" THEN 200
210 KO=0:GOSUB 360:LOCATE Y,21
220 FOR G=EE TO HO
230 IF (G AND EE)=0 THEN 260
240 PRINT USING "####";G;:KO=KO+1
250 IF KO=MA THEN Y=Y+1:LOCATE Y,21:KO=0
260 NEXT G:PRINT:Y=7
270 LOCATE 18,25:PRINT "Staat uw getal hierbij (j/n)?"
280 I$=INKEY$:IF I$="" THEN 280
290 A=INSTR("NnJj",I$):IF A=0 THEN 280
300 IF A>2 THEN NU=NU+EE
310 EE=EE+EE
320 IF EE<=HO THEN 210
330 IF NU>150 OR NU=0 THEN CLS:PRINT "U bent zelf de tel kwijt geraakt":GOTO 390
340 LOCATE 18,1:PRINT STRING$(79,32):LOCATE 13,31
350 COLOR 31,0:PRINT "Uw getal is:";NU:COLOR 7,0:GOTO 390
360 LOCATE 6,20:PRINT A1$
370 FOR Z=7 TO 15:LOCATE Z,20:PRINT A2$:NEXT Z
380 LOCATE 16,20:PRINT A3$:RETURN
390 WHILE INKEY$="":WEND:END