home *** CD-ROM | disk | FTP | other *** search
/ OpenStep 4.2 / Openstep-4.2-Intel-User.iso / usr / bin / vers_string < prev    next >
Text File  |  1997-03-27  |  2KB  |  61 lines
  1. #! /bin/csh -f
  2. set cflag=0 fflag=0 lflag=0 Bflag=0 nflag=0
  3. while ( $#argv > 0 )
  4.     if ( "$argv[1]" !~ -* ) break
  5.     if ( "$argv[1]" =~ *c* ) set cflag=1
  6.     if ( "$argv[1]" =~ *f* ) set fflag=1
  7.     if ( "$argv[1]" =~ *l* ) set lflag=1
  8.     if ( "$argv[1]" =~ *B* ) set Bflag=1
  9.     if ( "$argv[1]" =~ *n* ) set nflag=1
  10.     shift
  11. end
  12. if ( $#argv > 1) then
  13.     set version=$argv[2]
  14.     set rev=( `expr $version : '.*-\(.*\)'`)
  15.     if ( $status != 0 ) then
  16.         /bin/sh -c "echo ${0}: No hyphen in project root $version 1>&2"
  17.         exit(1)
  18.     endif
  19. else
  20.     set curdir=`pwd`
  21.     while ( $curdir:t != $curdir )
  22.         set version=$curdir:t
  23.         set rev=( `expr $version : '.*-\(.*\)'`)
  24.         if ( $status == 0 ) break
  25.         set curdir=$curdir:h
  26.     end
  27.     if ( $curdir:t == $curdir ) then
  28.         set curdir=`pwd`
  29.         /bin/sh -c "echo ${0}: No hyphen in project root $curdir 1>&2"
  30.         /bin/sh -c "echo ${0}: Could not determine version 1>&2"
  31.         set version=Unknown
  32.         set rev=""
  33.     endif
  34. endif
  35. if ( ! $?USER ) then
  36.     set USER=`whoami`
  37. endif
  38. if ( $#argv > 0) then
  39.     set PROG=$argv[1]
  40. else
  41.     set PROG=Unknown
  42. endif
  43. if ( $Bflag ) then
  44.     set date="NO DATE SET (-B used)"
  45. else
  46.     set date=`date`
  47. endif
  48. if ( $lflag ) then
  49.     echo "static const char SGS_VERS[160] =" '"'"@(#)LIBRARY:$PROG  PROJECT:${version}  DEVELOPER:${USER}  BUILT:${date}\n"'";'
  50. else if ( $cflag ) then
  51.     echo "const char SGS_VERS[160] =" '"'"@(#)PROGRAM:$PROG  PROJECT:${version}  DEVELOPER:${USER}  BUILT:${date}\n"'";'
  52.     echo "const char VERS_NUM[10] =" '"'"${rev}"'";'
  53. else if ( $fflag ) then
  54.     echo $PROG-$rev
  55. else if ( $nflag ) then
  56.     echo $rev
  57. else
  58.     echo "PROGRAM:$PROG  PROJECT:${version}  DEVELOPER:${USER}  BUILT:${date}"
  59. endif
  60.  
  61.