home
***
CD-ROM
|
disk
|
FTP
|
other
***
search
/
Shareware Overload
/
ShartewareOverload.cdr
/
windows
/
cmdpst62.zip
/
INSTALL.BAT
< prev
next >
Wrap
DOS Batch File
|
1989-05-18
|
11KB
|
269 lines
echo off
rem ╔════════════════════════════════════════════════════════════════╗
rem ║ INSTALL.BAT batch file to Install Wilson WindowWare Products ║
rem ╚════════════════════════════════════════════════════════════════╝
rem
rem Check for all 3 parameters...
if %1. == . goto ERR1
if %2. == . goto ERR1
if %3. == . goto ERR1
rem Check to be sure logged drive is desired floppy, and not hard disk
rem Check for file on floppy, and check common hard disk files and dirs.
if NOT EXIST INSTALL.BAT goto ERR6
if EXIST \AUTOEXEC.BAT goto ERR6
if EXIST \CONFIG.SYS goto ERR6
if EXIST \WINDOWS\NUL goto ERR6
if EXIST \DOS\NUL goto ERR6
if EXIST \WIN\NUL goto ERR6
if EXIST \WIN386\NUL goto ERR6
rem Check to make sure destination is not a floppy
if %1 == A: goto ERR2
if %1 == a: goto ERR2
if %1 == B: goto ERR2
if %1 == b: goto ERR2
rem Check to make sure destination drive exists
if NOT EXIST %1\NUL goto ERR3
rem Check to make sure 286 or 386 was entered
if %3 == 286 goto CONT2
if %3 == 386 goto CONT2
rem Obviously some obscure error ocurred. Punt.
goto ERR5
:CONT2
cls
echo ╔════════════════════════════════════════════════════════════════╗
echo ║ Wilson WindowWare Installation Batch File Ver A6 ║
echo ║ ║
echo ║ This install procedure will create a new directory on your ║
echo ║ %1 disk called WWWPRODS. This new directory will contain ║
echo ║ three subdirectories, APPLETS, BROWSER and CMDPOST. These ║
echo ║ new directories will contain the documentation files for the ║
echo ║ WindowWare products. The actual executables will be copied ║
echo ║ to the target subdirectory as specified on the command line ║
echo ║ and as shown below. ║
echo ║ ║
echo ║ This installation is targeted for a Windows/%3 system. ║
echo ╚════════════════════════════════════════════════════════════════╝
rem See if destination directory conatins WIN.INI. If not warn user
if EXIST %1%2\WIN.INI goto CONT1
echo ╔════════════════════════════════════════════════════════════════╗
echo ║ INSTALL WARNING: Destination subdirectory DOES NOT CONTAIN ║
echo ║ the WIN.INI Windows Initialization file. ║
echo ║ Installation can proceed if you add the ║
echo ║ subdirectory to your PATH statement later. ║
echo ╚════════════════════════════════════════════════════════════════╝
goto CONT1
:CONT1
echo Ready to Perform Install to %1%2
echo Press Ctrl-C to Abort
echo (or)
pause
rem Setup the installation subdirectories (may not all be necessary).
echo ╔══════════════════════════════════════╗
echo ║ Making required directories ║
echo ║ Ignore error messages here (if any) ║
echo ╚══════════════════════════════════════╝
md %1%2
md %1\wwwprods
md %1\wwwprods\applets
md %1\wwwprods\browser
md %1\wwwprods\cmdpost
echo ╔═══════════════════════════════════════════╗
echo ║ Deleting old version of products, if any ║
echo ║ ((File Not Found errors may occur here)) ║
echo ╚═══════════════════════════════════════════╝
erase %1\wwwprods\applets\*.exe
erase %1\wwwprods\applets\*.txt
erase %1\wwwprods\applets\*.ad1
erase %1\wwwprods\applets\*.1st
erase %1\wwwprods\browser\*.txt
erase %1\wwwprods\browser\*.exe
erase %1\wwwprods\browser\*.dat
erase %1\wwwprods\browser\*.ad1
erase %1\wwwprods\browser\*.1st
erase %1\wwwprods\cmdpost\*.exe
erase %1\wwwprods\cmdpost\*.txt
erase %1\wwwprods\cmdpost\*.ad1
erase %1\wwwprods\cmdpost\*.1st
erase %1\wwwprods\cmdpost\*.286
erase %1\wwwprods\cmdpost\*.386
erase %1\wwwprods\cmdpost\*.mnv
rem erase old cmdlib2.exe if it exists. it is now trash
erase %1%2\cmdlib2.exe
rem If cmdpost.mnu is here, rename it to .mnv in case its user's real menu
if NOT EXIST %1\wwwprods\cmdpost\cmdpost.mnu goto NOMNU
copy %1\wwwprods\cmdpost\cmdpost.mnu %1\wwwprods\cmdpost\cmdpost.mnv
erase %1\wwwprods\cmdpost\*.mnu
:NOMNU
echo ╔═══════════════════════════════════════════╗
echo ║ Copying packed EXE files to hard drive ║
echo ╚═══════════════════════════════════════════╝
echo Copying Aplt11.exe
copy aplt11.exe %1\wwwprods\applets
echo Copying Brow32.exe
copy brow32.exe %1\wwwprods\browser
echo Copying Cmdp62.exe
copy cmdp62.exe %1\wwwprods\cmdpost
rem log to destination disk drive
%1
echo ╔════════════════════════════════════════════════╗
echo ║ Starting Extract and Install of Command Post ║
echo ╚════════════════════════════════════════════════╝
cd \wwwprods\cmdpost
cmdp62.exe
erase cmdp62.exe
echo Copying Command Post executable files to %1%2
copy *.exe %1%2
rem If user already has a CMDPOST.MNU, for gosh sakes do not overwrite!
if EXIST %1%2\CMDPOST.MNU goto DOMOR1
echo Copying sample Command Post menu file to %1%2
copy CMDPOST.MNU %1%2
:DOMOR1
rem copy over appropriate PIF file, if the user looks like he needs one
if EXIST %1%2\COMMAND.PIF goto DOMOR2
echo Copying COMMAND.PIF to %1%2
if %3 == 286 copy COMMAND.286 %1%2\COMMAND.PIF
if %3 == 386 copy COMMAND.386 %1%2\COMMAND.PIF
:DOMOR2
rem get rid of stuff copied to the Windows directory (keep CMDPOST.MNU)
erase *.exe
erase *.286
erase *.386
echo ╔═══════════════════════════════════════════╗
echo ║ Starting Extract and Install of Browser ║
echo ╚═══════════════════════════════════════════╝
cd \wwwprods\browser
brow32.exe
erase brow32.exe
echo Copying Browser executable file to %1%2
copy *.exe %1%2
erase *.exe
echo ╔═══════════════════════════════════════════╗
echo ║ Starting Extract and Install of Applets ║
echo ╚═══════════════════════════════════════════╝
cd \wwwprods\applets
aplt11.exe
erase aplt11.exe
echo Copying Applets executable files to %1%2
copy *.exe %1%2
erase *.exe
goto AOK
:ERR6
echo ╔═════════════════════════════════════════════════════════════════╗
echo ║ INSTALL ERROR: Must be logged onto correct floppy drive ║
echo ╚═════════════════════════════════════════════════════════════════╝
pause
goto ERR1
:ERR5
echo ╔═════════════════════════════════════════════════════════════════╗
echo ║ INSTALL ERROR: Must enter Windows type as 286 or 386 ║
echo ╚═════════════════════════════════════════════════════════════════╝
pause
goto ERR1
:ERR3
echo ╔═════════════════════════════════════════════════════════════════╗
echo ║ INSTALL ERROR: Destination drive %1 does not exist. ║
echo ╚═════════════════════════════════════════════════════════════════╝
pause
goto ERR1
:ERR2
echo ╔═════════════════════════════════════════════════════════════════╗
echo ║ INSTALL ERROR: Cannot install to a floppy. ║
echo ╚═════════════════════════════════════════════════════════════════╝
pause
goto ERR1
:ERR1
echo off
cls
echo ╔═════════════════════════════════════════════════════════════════╗
echo ║ Wilson WindowWare Install Instructions ║
echo ╠═ ═ ═ ═ ═ ═ ═ ═ ═ ═ ═ ═ ═ ═ ═ ═ ═ ═ ═ ═ ═ ═ ═ ═ ═ ═ ═ ═ ═ ═ ═ ═ ═╣
echo ║ 1) Insert disk into floppy drive and logon to that drive (A:) ║
echo ║ ║
echo ║ 2) Type "INSTALL to: \subdir type" ║
echo ║ ║
echo ║ to: is the drive-ID of the HARD drive that you will be ║
echo ║ installing the WindowWare products to. ║
echo ║ \subdir is the subdirectory that the WindowWare programs ║
echo ║ will be copied into. This directory MUST CONTAIN ║
echo ║ the WIN.INI Windows Initialization file. ║
echo ║ type Is the type of Windows you will be using, ║
echo ║ either 286 or 386. Not the kind of machine you ║
echo ║ actually have. ║
echo ║ ║
echo ║ For example: ║
echo ║ INSTALL C: \WINDOWS 286 ║
echo ║ will install the products into C:\WINDOWS for Windows/286 ║
echo ║ INSTALL C: \WIN386 386 ║
echo ║ will install the products into C:\WIN386 for Windows/386 ║
echo ╚═════════════════════════════════════════════════════════════════╝
goto END
:AOK
rem change to some reasonable directory...
cd %2
cls
echo ╔════════════════════════════════════════════════╗
echo ║ WindowWare Install Completed Successfully ║
echo ║ ║
echo ║ Please refer to the following files for ║
echo ║ additional information on these products ║
echo ║ ║
echo ║ Command Post: ║
echo ║ %1\WWWPRODS\CMDPOST\$CP-READ.1ST ║
echo ║ %1\WWWPRODS\CMDPOST\CMDPOST.TXT ║
echo ║ ║
echo ║ Browser: ║
echo ║ %1\WWWPRODS\BROWSER\$BR-READ.1ST ║
echo ║ %1\WWWPRODS\BROWSER\BROWSER.TXT ║
echo ║ ║
echo ║ Applets ║
echo ║ %1\WWWPRODS\APPLETS\$AP-READ.1ST ║
echo ║ %1\WWWPRODS\APPLETS\APPLETS.TXT ║
echo ║ ║
echo ║ ║
echo ╚════════════════════════════════════════════════╝
:END