home *** CD-ROM | disk | FTP | other *** search
/ Shareware Overload / ShartewareOverload.cdr / progm / dpl.zip / EDITS.D < prev    next >
Text File  |  1988-07-11  |  13KB  |  606 lines
  1. ; Doug's Programming Language  -- DPL, Version 2.22
  2. ; Copyright (c) 1988 Douglas S. Cody, All rights reserved.
  3. ;------------------------------------------------
  4. ; EDITS -- EDIT A STRING OF CHARACTERS THE SAME WAY THE
  5. ;       DOS COMMAND LINE EDITS IT'S COMMAND LINE.
  6. ;
  7. ; Entry conditions:
  8. ;    AX points to the target string
  9. ; Exit conditions:
  10. ;    AL holds the last character typed
  11. ;    No other registers modified
  12. ;    Target string modified
  13. ;
  14. SUBPGM    EDITS
  15. ;
  16. F1KEY        EQU    3B00H        ; F1 KEY - SAVE THIS CHARACTER
  17. F2KEY        EQU    3C00H        ; F2 KEY - DELETE TO END OF LINE
  18. F3KEY        EQU    3D00H        ; F3 KEY - SAVE ENTIRE LINE
  19. F4KEY        EQU    3E00H        ; F4 KEY - DELETE ENTIRE LINE
  20. F5KEY        EQU    3F00H        ; F5 KEY - DELETE TO END OF LINE
  21. F7KEY        EQU    4100H        ; F7 KEY - DELETE ENTIRE LINE
  22. INSERT        EQU    5200H        ; INSERT KEY
  23. DELETE        EQU    5300H        ; DELETE KEY
  24. HOME        EQU    4700H        ; HOME KEY
  25. ENDKEY        EQU    4F00H        ; END KEY
  26. LEFTKEY        EQU    4B00H        ; LEFT ARROW KEY
  27. RIGHTKEY    EQU    4D00H        ; RIGHT ARROW KEY
  28. ;
  29. ;-----------------------==============================-------------------------
  30. ;-----------------------====< START OF EXECUTION >====-------------------------
  31. ;-----------------------==============================-------------------------
  32. ;
  33. BEGIN    EDITS
  34.     EXTRN    _STREND:NEAR
  35.     PUSH    ES        ; SAVE EVERYTHING...
  36. ;
  37.     PUSH    DS        ; SEGMENT ARE SET TO BE THE SAME
  38.     POP    ES
  39. ;
  40.     PUSH    BP
  41.     PUSH    SI
  42.     PUSH    DX
  43.     PUSH    CX
  44.     PUSH    BX        ; + 2 SAVE THE STRING LENGTH
  45.     PUSH    AX        ; + 0 SAVE THE ORIGINAL POINTER
  46. ;
  47.     MOV    BP,SP        ; BP - X WILL HOLD WORKING LOCALS
  48. ;
  49.     MOV    SI,AX        ; SI = START OF BUFFER
  50.     ADD    BX,AX        ; AX = END OF BUFFER POINTER
  51.     PUSH    BX        ; BP - 2 END OF LINE
  52.     MOV    BYTE PTR [BX],0    ; SET A DEFAULT TERMINATOR
  53.     CALL    _STREND        ; MOVE OUT TO THE END
  54.         CMP    SI,BX        ; IS SI = BX (END OF LINE?)
  55.     JZ    EDS_PRE_000    ; YES, DON'T NULL IT OUT
  56.     CALL    NULL_TO_END    ; FLUSH THE REST OF THE STRING
  57. ;
  58. EDS_PRE_000:
  59.     MOV    SI,[BP+0]    ; RESTORE THE START OF THE STRING
  60. ;
  61. ; GET THE CURSOR X/Y & SHAPE
  62. ;
  63.     MOV    BH,[VIDPAGE]
  64.     MOV    AH,03        ; GET THE CURSOR X/Y & SHAPE
  65.     INT    10H
  66.     PUSH    DX        ; BP - 4 = ORIGINAL ROW/COLUMN
  67.     PUSH    CX        ; BP - 6 = ORIGINAL CURSOR SHAPE
  68. ;
  69.     CALL    CURSOR_SHAPE    ; PERFORM A CURSOR SHAPE MODIFICATION
  70. ;
  71. EDS_00A:
  72. ;
  73. ; PRINT THE STRING TO THE SCREEN
  74. ;
  75.     CALL    DO_HOME
  76. ;
  77. ; FETCH A KEY & PROCESS IT
  78. ;
  79. EDS_00:
  80.     CALL    CHECK_END        ; SEE IF WE'RE AT THE STRING'S END
  81. ;
  82.     INKEY    ,WAIT
  83. ;
  84. ; CHECK FOR F1/F3/HOME/END
  85. ;
  86.     CMP    AX,F1KEY        ; F1 TYPED?
  87.     JZ    EDS_15            ; YES, CONTINUE ON...
  88.     CMP    AX,RIGHTKEY        ; RIGHT ARROW KEY TYPED?
  89.     JZ    EDS_15            ; YES, CONTINUE ON...
  90. ;
  91. ; F2 OR F5 KEY CHECK
  92. ;
  93.     CMP    AX,F2KEY        ; F2 TYPED?
  94.     JZ    EDS_35            ; YES, CONTINUE ON...
  95.     CMP    AX,F5KEY        ; END TYPED?
  96.     JZ    EDS_35            ; YES, CONTINUE ON...
  97. ;
  98. ; F3 OR END KEY CHECK
  99. ;
  100.     CMP    AX,F3KEY        ; F3 TYPED?
  101.     JZ    EDS_20            ; YES, CONTINUE ON...
  102.     CMP    AX,ENDKEY        ; END TYPED?
  103.     JZ    EDS_20            ; YES, CONTINUE ON...
  104. ;
  105. ; F4 KEY CHECK
  106. ;
  107.     CMP    AX,F4KEY        ; F4 TYPED?
  108.     JZ    EDS_40            ; YES, CONTINUE ON...
  109. ;
  110. ; HOME KEY CHECK
  111. ;
  112.     CMP    AX,HOME            ; HOME TYPED?
  113.     JZ    EDS_00A            ; YES, GO PRINT ENTIRE STRING
  114. ;
  115. ; DELETE KEY CHECK
  116. ;
  117.     CMP    AX,DELETE        ; DELETE KEY TYPED?
  118.     JZ    EDS_30            ; YES, MOVE THE STRING LEFT
  119. ;
  120. ; INSERT KEY CHECK
  121. ;
  122.     CMP    AX,INSERT        ; INSERT KEY TYPED?
  123.     JZ    EDS_25            ; YES, GO FORM THE CURSOR
  124. ;
  125. ; CHECK FOR LEFT ARROW KEY
  126. ;
  127.     CMP    AX,LEFTKEY        ; LEFT ARROW KEY?
  128.     JZ    EDS_10            ; YES, GO ATTEMPT A BACKSPACE
  129. ;
  130. ; SPECIAL KEY CHECK, AH=XX,AL=00
  131. ;
  132.     CMP    AL,0            ; GOOD CHARACTER?
  133.     JZ    EDS_00            ; NO, CONTINUE WAITING
  134. ;
  135. ; CHECK FOR BACKSPACE
  136. ;
  137.     CMP    AL,08            ; BACKSPACE?
  138.     JZ    EDS_10            ; YES, GO ATTEMPT A BACKSPACE
  139. ;
  140. ; CHECK FOR EXIT DUE TO 'ESC' OR 'ENTER'
  141. ;
  142.     CMP    AL,0DH            ; CARRIAGE RETURN?
  143.     JZ    EDS_100            ; YES, EXIT HOME
  144.     CMP    AL,1BH            ; ESCAPE KEY TYPED?
  145.     JZ    EDS_100            ; YES, EXIT HOME...
  146. ;
  147. ; STORE THE CHARACTER IN THE STRING & DISPLAY THE CHARACTER
  148. ;
  149.     CALL    CHK_INS            ; CHECK INSERT STATE
  150.     MOV    [SI],AL            ; STORE IN THE TARGET STRING
  151.     INC    SI
  152.     CALL    PRTCHAR            ; GO PRINT IT
  153.     JMP    EDS_00            ; CONTINUE THE INPUT...
  154. ;
  155. ; BACKSPACE PROCESSING...
  156. ;
  157. EDS_10:
  158.     CMP    SI,[BP+0]        ; ARE WE AT THE START?
  159.     JZ    EDS_00            ; YES, TOSS THE BACKSPACE
  160.     DEC    SI            ; BACKSTEP THE TARGET POINTER
  161.     MOV    AL,08H            ; FORCE TO A BACKSPACE
  162.     CALL    PRTCHAR            ; GO 'PRINT' THE BACKSPACE
  163.     JMP    EDS_00            ; NO, GO BACK TO INPUTTING...
  164. ;
  165. ; F1 KEY PROCESSING
  166. ;
  167. EDS_15:
  168.     CALL    ORIGCHR            ; PERFORM AN F1 REPEAT
  169.     JMP    EDS_00            ; GO BACK FOR MORE
  170. ;
  171. ; F3 KEY PROCESSING
  172. ;
  173. EDS_20:
  174.     CALL    ORIGSTR            ; PERFORM AN F3 REPEAT
  175.     JMP    EDS_00            ; GO BACK FOR MORE...
  176. ;
  177. ; INSERT KEY PROCESSING
  178. ;
  179. EDS_25:
  180.     CALL    CURSOR_SHAPE        ; MODIFY THE CURSOR
  181.     JMP    EDS_00
  182. ;
  183. ; DELETE KEY PROCESSING
  184. ;
  185. EDS_30:
  186.     CALL    SHIFT_LEFT        ; MOVE STRING LEFT
  187.     CALL    PRINT_REST        ; PRINT THE STRING FROM THE CURSOR TO RIGHT
  188.     JMP    EDS_00            ; GO FOR MORE
  189. ;
  190. ; DELETE TO END OF LINE - F5,F2 PROCESSING
  191. ;
  192. EDS_35:
  193.     CALL    NULL_TO_END        ; FLUSH IT
  194.     CALL    CLEAR_REST        ; CLEAR THE SCREEN TO THE END OF LINE
  195.     JMP    EDS_00            ; GO FOR MORE
  196. ;
  197. ; DELETE THE ENTIRE LINE - F4 PROCESSING
  198. ;
  199. EDS_40:
  200.     MOV    SI,[BP+0]        ; GRAB THE START OF THE STRING
  201.     CALL    NULL_TO_END        ; FLUSH IT
  202.     MOV    DX,[BP-4]        ; GET THE ORIGINAL CURSOR POSITION
  203.     CALL    MOVE_CURSOR        ; & MOVE TO START OF SCREEN
  204.     CALL    CLEAR_REST        ; CLEAR THE SCREEN TO THE END OF LINE
  205.     JMP    EDS_00            ; GO FOR MORE
  206. ;
  207. ; CARRIAGE RETURN & ESCAPE KEY PROCESSING
  208. ;
  209. EDS_100:
  210.     PUSH    AX            ; SAVE THE RETURN CHARACTER
  211.     MOV    CX,[BP-6]        ; RESTORE THE ORIGINAL CURSOR SHAPE
  212.     MOV    AH,01
  213.     INT    10H
  214.     POP    AX
  215. ;
  216.     MOV    SP,BP            ; FLUSH THE STACK
  217.     POP    BX            ; RESTORE THE CRITICALS
  218.     POP    BX
  219.     POP    CX
  220.     POP    DX
  221.     POP    SI
  222.     POP    BP
  223.     POP    ES
  224.     RETURN
  225. ;
  226. ;
  227. ;=====================
  228. ;   ROUTINE SECTION
  229. ;    LEVEL 1
  230. ;=====================
  231. ;
  232. ;
  233. ; C H E C K _ E N D  --  MAKE SURE DS:SI IS WITHIN THE BUFFER
  234. ;
  235. ; Entry conditions:
  236. ;    DS:SI point to the string
  237. ; Exit conditions:
  238. ;    DS:SI possibly modified
  239. ;    AL possibly modified
  240. ; 
  241. CHECK_END    PROC    NEAR
  242.     CMP    SI,[BP-2]        ; ARE WE TOO FAR RIGHT?
  243.     JNZ    CKND_05            ; NO, CONTINUE ON...
  244.     DEC    SI            ; YES, MOVE BACK
  245.     MOV    AL,08
  246.     CALL    PRTCHAR
  247. ;
  248. CKND_05:
  249.     RETURN
  250.  
  251. CHECK_END    ENDP
  252. ;
  253. ;
  254. ; C H K _ I N S  --  CHECK THE INSERT STATE & MOVE THE STRING, IF SET.
  255. ;
  256. ; Entry conditions:
  257. ;    None
  258. ; Exit conditions:
  259. ;    No registers modified
  260. ; 
  261. CHK_INS    PROC    NEAR
  262.     PUSH    AX
  263.     PUSH    BX
  264.     PUSH    CX
  265. ;
  266.     MOV    AH,02
  267.     INT    16H        ; GET THE SHIFT STATE
  268.     SHL    AL,1        ; MOVE THE BIT TO THE CARRY
  269.     JNC    CHINS_10    ; EXIT IF INSERT STATE NOT SET
  270.     CALL    SHIFT_RIGHT    ; MOVE THE STRING RIGHT
  271.     CALL    PRINT_REST    ; PRINT IT TO THE SCREEN
  272. ;
  273. CHINS_10:
  274.     POP    CX
  275.     POP    BX
  276.     POP    AX
  277.     RETURN
  278.  
  279. CHK_INS    ENDP
  280. ;
  281. ;
  282. ; C L E A R _ R E S T  --  CLEAR THE REST OF THE SCREEN TO END OF FIELD
  283. ;
  284. ; Entry conditions:
  285. ;    SI points to the start of the clear
  286. ; Exit conditions:
  287. ;    AX modified
  288. ;    No other registers modified
  289. ;
  290. CLEAR_REST    PROC    NEAR
  291.     PUSH    SI
  292.     PUSH    DX
  293.     PUSH    CX
  294. ;
  295.     MOV    AH,03        ; FETCH THE CURRENT CURSOR POSITION
  296.     INT    10H
  297.     PUSH    DX        ; SAVE THE CURSOR POSITION
  298. ;
  299.     SUB    AL,AL
  300. ;
  301. CLRST_05:
  302.     CMP    SI,[BP-2]    ; ARE WE AT THE END?
  303.     JZ    CLRST_10    ; YES, DONE, SO EXIT
  304.     CALL    PRTCHAR        ; PRINT THE NULL
  305.     INC    SI        ; MOVE TO NEXT LOCATION
  306.     JMP    SHORT CLRST_05
  307. ;
  308. CLRST_10:
  309.     POP    DX        ; RESTORE THE CURSOR POSITION
  310.     MOV    AH,02
  311.     INT    10H
  312. ;
  313.     POP    CX
  314.     POP    DX
  315.     POP    SI
  316.     RETURN
  317.  
  318. CLEAR_REST    ENDP
  319. ;
  320. ;
  321. ; C U R S O R _ S H A P E  --  SET THE CURSOR SHAPE DEPENDING UPON
  322. ;                   THE INSERT STATE
  323. ;
  324. ; Entry conditions:
  325. ;    None
  326. ; Exit conditions:
  327. ;    No registers modified
  328. ; 
  329. CURSOR_SHAPE    PROC    NEAR
  330.     PUSH    AX
  331.     PUSH    BX
  332.     PUSH    CX
  333. ;
  334.     MOV    AH,02
  335.     INT    16H        ; GET THE SHIFT STATE
  336.     SHL    AL,1        ; MOVE THE BIT TO THE CARRY
  337.     MOV    BL,0
  338.     ADC    BL,0
  339.     MOV    AL,[CRTFLAG]    ; GET THE MONO/CGA FLAG
  340.     ROL    BL,1        ; MOVE IN THE MONO/CGA FLAG
  341.     SHR    AL,1
  342.     ADC    BL,0
  343. ;
  344. ; BL HOLDS THE CURSOR SHAPE INDEX
  345. ;
  346.     SUB    BH,BH
  347.     SHL    BX,1
  348.     MOV    CX,CS:CURS[BX]    ; GET THE SHAPE
  349.     MOV    AH,01
  350.     INT    10H        ; & GO SET IT
  351. ;
  352.     POP    CX
  353.     POP    BX
  354.     POP    AX
  355.     RETURN
  356.  
  357. CURSOR_SHAPE    ENDP
  358. ;
  359. CURS    LABEL    WORD
  360.     DW    0C0DH ;    BL = 0
  361.     DW    0607H ;    BL = 1
  362.     DW    000DH ;    BL = 2
  363.     DW    0007H ;    BL = 3
  364. ;
  365. ;
  366. ; D O _ H O M E  --  PRINT THE ENTIRE STRING & RESET POINTERS TO START
  367. ;
  368. ; Entry conditions:
  369. ;    DS:SI point to the start of the string
  370. ; Exit conditions:
  371. ;    AX modified
  372. ;    Cursor & string pointers, variables moved to start of string
  373. ;
  374. DO_HOME    PROC    NEAR
  375.     CALL    ORIGSTR        ; PRINT STRING & LEAVE CURSOR AT TAIL
  376.     MOV    DX,[BP-4]    ; GET THE ORIGINAL CURSOR POSITION
  377.     CALL    MOVE_CURSOR
  378.     MOV    SI,[BP+0]    ; MOVE SI TO START OF STRING
  379.     RETURN
  380.  
  381. DO_HOME    ENDP
  382. ;
  383. ;
  384. ; P R I N T _ R E S T  --  PRINT THE REST OF THE STRING TO THE SCREEN
  385. ;
  386. ; Entry conditions:
  387. ;    DS:SI point to the string
  388. ; Exit conditions:
  389. ;    No registers modidied
  390. ;
  391. PRINT_REST    PROC    NEAR
  392.     PUSH    SI            ; SAVE THE STRING POSITION
  393.     MOV    AH,03
  394.     INT    10H
  395.     PUSH    DX            ; SAVE THE CURSOR POSITION
  396. ;
  397.     CALL    ORIGSTR            ; PRINT THE STRING
  398. ;
  399.     MOV    AL,20H            ; WIPE OUT THE TRAILING CHARACTER
  400.     CALL    PRTCHAR
  401. ;
  402.     POP    DX            ; FETCH THE ORIGINAL CURSOR LOCATION
  403.     CALL    MOVE_CURSOR        ; SET THE CURSOR TO THE SAME LOCATION
  404.     POP    SI            ; RESTORE THE STRING POINTER
  405.     RETURN
  406.  
  407. PRINT_REST    ENDP
  408. ;
  409. ;
  410. ; S H I F T _ L E F T  --  MOVE THE CONTENTS OF THE STRING LEFT ONE POSITION
  411. ;
  412. ; Entry conditions:
  413. ;    DS:SI points to the start of the string
  414. ; Exit conditions:
  415. ;    No registers modified
  416. ;
  417. SHIFT_LEFT    PROC    NEAR
  418.     PUSH    CX
  419.     PUSH    SI
  420.     PUSH    DI
  421. ;
  422.     MOV    DI,SI
  423.     INC    SI
  424. ;
  425. SHLF_05:
  426.     LODSB            ; FETCH THE CHARACTER
  427.     STOSB            ; & STUFF IN PREVIOUS LOCATION
  428.     OR    AL,AL        ; DID WE MOVE THE TERMINATOR?
  429.     JNZ    SHLF_05        ; NO, GO FIND IT...
  430. ;
  431.     POP    DI
  432.     POP    SI
  433.     POP    CX
  434.     RETURN
  435.  
  436. SHIFT_LEFT    ENDP
  437. ;
  438. ;
  439. ;=====================
  440. ;   ROUTINE SECTION
  441. ;    LEVEL 2
  442. ;=====================
  443. ;
  444. ;
  445. ; N U L L _ T O _ E N D  --  NULL OUT THE REST OF THE STRING
  446. ;
  447. ; Entry conditions:
  448. ;    BP-2 holds the end of string pointer
  449. ;    SI points to the start of the clear
  450. ; Exit conditions:
  451. ;    AX modified
  452. ;    No other registers modified
  453. ;
  454. NULL_TO_END    PROC    NEAR
  455.     PUSH    SI
  456.     SUB    AL,AL    
  457. ;
  458. NLTOEN_05:
  459.     CMP    SI,[BP-2]    ; ARE WE AT THE END?
  460.     JZ    NLTOEN_10    ; YES, EXIT NOW
  461.     MOV    [SI],AL        ; SET THE TERMINATOR
  462.     INC    SI
  463.     JMP    SHORT NLTOEN_05    ; GO FOR MORE...
  464. ;
  465. NLTOEN_10:
  466.     POP    SI
  467.     RETURN
  468.  
  469. NULL_TO_END    ENDP
  470. ;
  471. ;
  472. ; O R I G S T R  --  SAVE EVERY BYTE IN THE STRING - F3 HAS BEEN TYPED
  473. ;
  474. ; Entry conditions:
  475. ;    DS:SI point to the string
  476. ; Exit conditions:
  477. ;    DS:SI advanced to the end of the string
  478. ;
  479. ORIGSTR    PROC    NEAR
  480.     CALL    ORIGCHR            ; NO, MOVE ONE CHARACTER
  481.     JNZ    ORIGSTR            ; NOT DONE YET, CONTINUE TILL ALL MOVED
  482.     RETURN
  483.  
  484. ORIGSTR    ENDP
  485. ;
  486. ;
  487. ; S H I F T _ R I G H T - MOVE THE CONTENTS OF THE STRING RIGHT
  488. ;              ONE POSITION IF THE INSERT STATE IS POSITIVE
  489. ;
  490. ; Entry conditions:
  491. ;    DS:SI points to the start of the string
  492. ; Exit conditions:
  493. ;    No registers modified
  494. ;
  495. SHIFT_RIGHT    PROC    NEAR
  496.     PUSH    AX
  497.     PUSH    SI
  498.     PUSH    DI
  499. ;
  500.     MOV    DI,SI        ; DI POINTS TO STRING TOO
  501.     MOV    AH,20H        ; PRIME THE 1ST STORAGE
  502. ;
  503. SHRT_05:
  504.     LODSB            ; FETCH THE 1ST CHARACTER
  505.     XCHG    AH,AL        ; AL = 1ST CHARACTER, AH = JUST READ CHAR
  506.     STOSB            ; SAVE THE 1ST CHARACTER
  507.     OR    AH,AH        ; IS AH THE TERMINATOR?
  508.     JNZ    SHRT_05        ; NO, CONTINUE THE SHUFFLE
  509. ;
  510.     CMP    SI,[BP-2]    ; IS SI PAST THE LAST VALID CHARACTER?
  511.     JLE    SHRT_10        ; NO, CONTINUE ON...
  512.     DEC    DI        ; YES, SO MOVE BACK TO TERMINATE IT
  513. ;
  514. SHRT_10:
  515.     MOV    AL,AH        ; SET THE NEW TERMINATOR
  516.     STOSB
  517. ;
  518.     POP    DI
  519.     POP    SI
  520.     POP    AX
  521.     RETURN
  522.  
  523. SHIFT_RIGHT    ENDP
  524. ;
  525. ;
  526. ;=====================
  527. ;   ROUTINE SECTION
  528. ;    LEVEL 3
  529. ;=====================
  530. ;
  531. ;
  532. ; O R I G C H R  --  MOVE THE STRING POINTER & DISPLAY
  533. ;             THE CHARACTER FROM THE STRING.
  534. ;
  535. ; Entry conditions:
  536. ;    DS:SI point to the string
  537. ; Exit conditions:
  538. ;    DS:SI advanced one position
  539. ;    Z = terminator encountered, NZ = character printed & saved
  540. ;
  541. ORIGCHR    PROC    NEAR
  542.     CMP    BYTE PTR [SI],0        ; TERMINATOR?
  543.     JZ    ORCH_05            ; YES, EXIT
  544.     LODSB                ; FETCH THE CHARACTER
  545.     CALL    PRTCHAR            ; PRINT THE CHARACTER
  546.     OR    AL,AL            ; SET THE RETURN FLAGS
  547. ;
  548. ORCH_05:
  549.     RETURN
  550.  
  551. ORIGCHR    ENDP
  552. ;
  553. ;
  554. ;=====================
  555. ;   ROUTINE SECTION
  556. ;    LEVEL 4
  557. ;=====================
  558. ;
  559. ;
  560. ; P R T C H A R  --  PRINT THE CHARACTER IN AL AND ADVANCE THE CURSOR
  561. ;
  562. ; Entry conditions:
  563. ;    AL holds the character
  564. ; Exit conditions:
  565. ;    CX,AX,BX,DX modified
  566. ;
  567. PRTCHAR    PROC    NEAR
  568.     MOV    BH,[VIDPAGE]
  569.     MOV    AH,0EH
  570.     INT    10H
  571.     RETURN
  572.  
  573. PRTCHAR    ENDP
  574. ;
  575. ;
  576. ;=====================
  577. ;   ROUTINE SECTION
  578. ;    LEVEL 5
  579. ;=====================
  580. ;
  581. ;
  582. ; M O V E _ C U R S O R  --  MOVE THE CURSOR TO THE ROW/COLUMN POSITION
  583. ;
  584. ; Entry conditions:
  585. ;    DH = row
  586. ;    DL = column
  587. ; Exit conditions:
  588. ;    No registers modified
  589. ;
  590. MOVE_CURSOR    PROC    NEAR
  591.     PUSH    AX
  592.     PUSH    BX
  593. ;
  594.     MOV    BH,[VIDPAGE]        ; GET THE VIDEO PAGE #
  595.     MOV    AH,02            ; SET THE CURSOR POSITION
  596.     INT    10H
  597. ;
  598.     POP    BX
  599.     POP    AX
  600.     RETURN
  601.  
  602. MOVE_CURSOR    ENDP
  603. ;
  604. ENDPGM    EDITS
  605. ;
  606.