home *** CD-ROM | disk | FTP | other *** search
/ Shareware Overload / ShartewareOverload.cdr / games / pcdowns.zip / OTB.BAS next >
BASIC Source File  |  1992-01-08  |  15KB  |  245 lines
  1. 100 KEY OFF: SCREEN 0: WIDTH 80:CLEAR,,1000
  2. 110 DEF SEG = 0: IF (PEEK(&H410) AND &H30) <> &H30 THEN GRAPH.ICS=1
  3. 120 DEF SEG=0: POKE &H417,(PEEK(&H417) OR &H40) 'force CAPS LOCK
  4. 130 DIM HORSE$(5), ODDS(5), NAM$(15), BANK(15), BET(15), RESULT(15), CHOICE(15)
  5. 140 DIM COL(5), LANE(5),NUM.PLAYERS(15),LCV(15),SELL$(15),HORSE1(65),HORSE2(65)
  6. 150 DIM MAN(10), MAN2(10),HORSE3(65),HORSE4(65)
  7. 160 IF GRAPH.ICS THEN FC=3: BC=4 ELSE GOTO 2530
  8. 170 COLOR FC,0,BC: CLS
  9. 180 LANE(1)=74: LANE(2)=98: LANE(3)=122: LANE(4)=146: LANE(5)=170
  10. 190 WIDTH 40: GOSUB 1830   '**** Logo, intro, initialization, and dims
  11. 200 GOSUB 570 '***** get # of betters, their names, & their bankrolls
  12. 210 GOSUB 690 '***** main loop body
  13. 220 GOTO 2540
  14. 230 AMT=RND*10+5: PUT (COL(LCV),LANE(LCV)),HORSE4: COL(LCV)=COL(LCV)+AMT
  15. 240 PUT (COL(LCV),LANE(LCV)),HORSE3: DELAY=0: GOSUB 290
  16. 250 PUT (COL(LCV),LANE(LCV)),HORSE3:PUT (COL(LCV),LANE(LCV)),HORSE2:GOSUB 290
  17. 260 PUT (COL(LCV),LANE(LCV)),HORSE2:PUT (COL(LCV),LANE(LCV)),HORSE1:GOSUB 290
  18. 270 PUT (COL(LCV),LANE(LCV)),HORSE1:PUT (COL(LCV),LANE(LCV)),HORSE4
  19. 280 RETURN
  20. 290 'subroutine to delay
  21. 300 FOR TIM=1 TO DELAY*1000: NEXT TIM: RETURN
  22. 310 'clear keyboard buffer
  23. 320 DEF SEG=0: POKE &H41A,PEEK(&H41C): RETURN
  24. 330 'clear text area
  25. 340 FOR LIN%= 20 TO 24: LOCATE LIN%,15: PRINT SPACE$(64);
  26. 350 NEXT LIN%: RETURN
  27. 360 'pause & wait for keypress
  28. 370 GOSUB 310 : COLOR FC+8: LOCATE 25,10: PRINT "Press any key to continue";
  29. 380 IF INKEY$="" THEN 380 ELSE COLOR FC: RETURN
  30. 390 LOCATE 25,29: COLOR 10: PRINT"Press F8 + ";CHR$(17);CHR$(196);CHR$(217);" to EXIT";: COLOR FC: RETURN
  31. 400 CLS: COLOR FC+8:LOCATE 2,31:PRINT"Today's Statistics";: LOCATE 3,31:PRINT"------- ----------";:COLOR FC
  32. 410 LOCATE 4,10:PRINT"╒";STRING$(25,205);"╤";STRING$(15,205);"╤";STRING$(20,205);"╕";
  33. 420 LOCATE 5,10:PRINT"│";TAB(36);"│";TAB(52);"│";TAB(73);"│";
  34. 430 LOCATE 6,10:PRINT"╞";STRING$(25,205);"╪";STRING$(15,205);"╪";STRING$(20,205);"╡";
  35. 440 FOR ROE=7 TO 17: LOCATE ROE,10: PRINT "│";TAB(36);"│";TAB(52);"│";TAB(73);"│";: NEXT ROE
  36. 450 LOCATE 18,10:PRINT"╘";STRING$(25,205);"╧";STRING$(15,205);"╧";STRING$(20,205);"╛";
  37. 460 COLOR FC+8: LOCATE 5,15:PRINT"Horse's Name";:LOCATE 5,40:PRINT"Lane #";:LOCATE 5,55:PRINT"Odds of Winning";
  38. 470 RANDOMIZE VAL(RIGHT$(TIME$,2))
  39. 480 FOR LCV=1 TO 5
  40. 490 WHICH = (RND*80+1)
  41. 500 FOR I=1 TO WHICH: READ HORSE.NAME$: NEXT I: RESTORE
  42. 510 FOR I=1 TO 5: IF HORSE$(I)=HORSE.NAME$ THEN OLD=1
  43. 520 NEXT I
  44. 530 IF OLD THEN OLD=0: GOTO 490
  45. 540 HORSE$(LCV)=HORSE.NAME$: ODDS(LCV)= INT(RND*30)+3: ROE=LCV*2+6
  46. 550 LOCATE ROE,15:PRINT HORSE$(LCV);: LOCATE ROE,43:PRINT LCV;: LOCATE ROE,60:PRINT ODDS(LCV);": 1";
  47. 560 NEXT LCV: COLOR FC: RETURN
  48. 570 WIDTH 80: COLOR 10,0,BC: CLS: GOSUB 390
  49. 580 LOCATE 12,15: PRINT"How many big spenders do we have today? ";:INLEN%=1: GOSUB 1660: NUM.PLAYERS=VAL(NTRY$)
  50. 590 IF (NUM.PLAYERS>0) AND (NUM.PLAYERS<10) THEN GOTO 610
  51. 600 BEEP: LOCATE 12,10: PRINT"Sorry but the maximum capicity of `PC Downs' is 1-9 players";: DELAY=2: GOSUB 290: GOTO 570
  52. 610 CLS: GOSUB 390
  53. 620 FOR COUNT=1 TO NUM.PLAYERS: LOCATE 4+COUNT,5:
  54. 630  PRINT"First name of player #";COUNT;: LINE INPUT NAM$(COUNT)
  55. 640  LOCATE 4+COUNT,36:PRINT"How much cash do you have, ";NAM$(COUNT);"? $";
  56. 650  INLEN%=10: GOSUB 1660: BANK(COUNT)=VAL(NTRY$)
  57. 660 IF BANK(COUNT)<1 THEN LOCATE 4+COUNT,36:BEEP: PRINT"With no money, all you can do is watch.";: DELAY=2: GOSUB 290: LOCATE 4+COUNT,36:PRINT SPACE$(43);: GOTO 640
  58. 670  NEXT COUNT
  59. 680 RETURN 'to do main loop body
  60. 690 '**** main loop body: get bets, simulate a race, give results, repeat
  61. 700 LOOP=LOOP+1:  GOSUB 400 'Stats for horses then get bets
  62. 710 FOR LCV=1 TO NUM.PLAYERS: GOSUB 330
  63. 720 IF BANK(LCV)>0 THEN GOTO 780 ELSE IF RESULT(LCV)=0 AND SELL$(LCV)="Y" THEN GOTO 870
  64. 730 IF SELL$(LCV)<>"Y" THEN LOCATE 20,15:PRINT"Sorry, ";NAM$(LCV);", but you are out of cash.";: LOCATE 21,15:PRINT"Would you like to sell your car? (Y/N) "; ELSE GOTO 760
  65. 740 SELL$(LCV)=INKEY$: IF SELL$(LCV)="" THEN 740 ELSE DELAY=2
  66. 750 IF SELL$(LCV)="Y" THEN LOCATE 22,15:PRINT"Since I have the advantage, I'll give you $1000 for it.";:BANK(LCV)=1000:GOSUB 290:GOSUB 330:GOTO 780 ELSE LOCATE 22,15:PRINT"Sorry, you have to pass.";:DELAY=2:GOSUB 290:GOTO 870
  67. 760 LOCATE 20,15:PRINT"Sorry, ";NAM$(LCV);", but you are out of cash again and I own your car."
  68. 770 LOCATE 21,15:PRINT"Give up gambling before you lose your shirt, too!";: DELAY=2: GOSUB 290: GOTO 870
  69. 780 LOCATE 20,15:PRINT"Okay now, ";NAM$(LCV)
  70. 790 LOCATE 21,15:PRINT"Which horse will be your choice to WIN? (Key in Lane No.)";:GOSUB 310
  71. 800 AN$=INKEY$: IF AN$="" THEN 800
  72. 810 IF (VAL(AN$)<1) OR (VAL(AN$)>5) THEN BEEP: GOTO 800 ELSE PRINT AN$;: CHOICE(LCV)= VAL(AN$)
  73. 820 LOCATE 22,15:PRINT SPACE$(64);: LOCATE 22,15:PRINT"How much will you BET? ";: INLEN%=10: GOSUB 1660: BET(LCV)=VAL(NTRY$)
  74. 830 IF BET(LCV)<=BANK(LCV) THEN GOTO 870
  75. 840 BEEP: LOCATE 22,15:PRINT"You can't bet what you don't have, ";NAM$(LCV);
  76. 850 LOCATE 23,15:PRINT"You have $";BANK(LCV);" left.";
  77. 860 DELAY=2: GOSUB 290: GOTO 820
  78. 870 NEXT LCV
  79. 880 SCREEN 1: COLOR 18,1: CLS
  80. 890 PSET(60,1):DRAW "r260 C1 g60 l260 e60 br255 bd5 d39"
  81. 900 PAINT (70,10),3,1: LINE (260,60)-(314,45),1: PAINT (300,40),3,1
  82. 910 LOCATE 25,1:PRINT"Please bring the horses to their gates!";
  83. 920 RANDOMIZE VAL(RIGHT$(TIME$,2)): ST=6
  84. 930 FOR Y = 1 TO 50 STEP 11 :NUM=ST: X=0
  85. 940 IF X>(275-Y) THEN GOTO 980 ELSE AMT=(RND*(15))+8: X=X+INT(AMT)
  86. 950     IF NUM > 1 THEN 970
  87. 960     IF  INT(X/2)=X/2 THEN PUT(X,Y),MAN ELSE PUT(X,Y),MAN2
  88. 970   NUM=NUM-1 :GOTO 940
  89. 980 ST=ST-1 :NEXT Y
  90. 990 'Draw a track and gates
  91. 1000 LINE (20,70)-(40,190),2,B
  92. 1010 LINE -(300,70),2,B: LINE (300,70)-(300,190),1
  93. 1020 LINE (20,94)-(300,94),1
  94. 1030 LINE (20,118)-(300,118),1
  95. 1040 LINE (20,142)-(300,142),1
  96. 1050 LINE (20,166)-(300,166),1
  97. 1060 FOR LCV=1 TO 5: PUT (19,LANE(LCV)),HORSE4: COL(LCV)=19: NEXT LCV
  98. 1070 LOCATE 8,1:PRINT"Lane";: LOCATE 11,2:PRINT"1";:LOCATE 14,2:PRINT"2";:LOCATE 17,2:PRINT"3";:LOCATE 20,2:PRINT"4";:LOCATE 23,2:PRINT"5"
  99. 1080 LOCATE 25,1: PRINT SPACE$(39);: LOCATE 25,17:PRINT"Ready...";:DELAY=2: GOSUB 290: SOUND 500.5,5: SOUND 500,5
  100. 1090 LOCATE 25,13:PRINT"And they're off!!";
  101. 1100 LINE (40,75)-(40,89),0: LINE -(56,89),2
  102. 1110 LINE (40,96)-(40,113),0: LINE -(56,113),2
  103. 1120 LINE (40,123)-(40,137),0: LINE -(56,137),2
  104. 1130 LINE (40,147)-(40,161),0: LINE -(56,161),2
  105. 1140 LINE (40,171)-(40,185),0: LINE -(56,185),2
  106. 1150 LCV=0
  107. 1160 IF COL(LCV)<279 THEN IF LCV<5 THEN LCV=LCV+1: GOSUB 230: GOTO 1160 ELSE LCV=0: GOTO 1160 ELSE WINNER=LCV
  108. 1170 FOR LCV=1 TO NUM.PLAYERS: IF CHOICE(LCV)=WINNER THEN RESULT(LCV)=ODDS(WINNER)*BET(LCV) ELSE RESULT(LCV)=-BET(LCV)
  109. 1180 NEXT LCV
  110. 1190 LOCATE 25,2:PRINT"The winner is...#";WINNER;",";HORSE$(WINNER);: DELAY=2: GOSUB 290
  111. 1200 SCREEN 0: WIDTH 80: COLOR FC,0,BC: CLS: LOCATE 3,35:PRINT"Results of Race #";LOOP;
  112. 1210 FOR LCV=1 TO NUM.PLAYERS: IF BET(LCV)=0 THEN 1270
  113. 1220 LOCATE 8,10:PRINT NAM$(LCV);", you bet $";BET(LCV);" on horse #";CHOICE(LCV);", `";HORSE$(CHOICE(LCV));"'";
  114. 1230 LOCATE 12,10:IF RESULT(LCV)>0 THEN PRINT"Congratulations!!  You have won with odds of ";ODDS(CHOICE(LCV));":1";: LOCATE 14,10:PRINT"YOU WIN $";ODDS(CHOICE(LCV))*BET(LCV): BANK(LCV)=BANK(LCV)+(ODDS(CHOICE(LCV))*BET(LCV))
  115. 1240 IF RESULT(LCV)<=0 THEN PRINT"Sorry, ";NAM$(LCV);"; you lose $";BET(LCV): BANK(LCV)=BANK(LCV)-BET(LCV)
  116. 1250 LOCATE 17,10:PRINT"You have $";BANK(LCV);" left to gamble with.";
  117. 1260 GOSUB 360
  118. 1270 CLS: NEXT LCV
  119. 1280 CLS: LOCATE 3,30:PRINT"Remaining Bankrolls:": LOCATE 4,30:PRINT"--------- ---------"
  120. 1290 LOCATE 6,15:PRINT"Name                                 Amount":LOCATE 7,15:PRINT"----                                 ------"
  121. 1300 LOCATE 9,1: FOR LCV=1 TO NUM.PLAYERS: IF (LCV/10) > 1 THEN GOSUB 360
  122. 1310 PRINT TAB(15); NAM$(LCV); TAB(46);:PRINT USING "$$#####,##.##";BANK(LCV): PRINT :NEXT LCV
  123. 1320 GOSUB 360
  124. 1330 AGAIN=0: FOR LCV=1 TO NUM.PLAYERS: BET(LCV)=0: IF BANK(LCV)>0 OR SELL$(LCV)<>"Y" THEN AGAIN=1
  125. 1340 NEXT LCV
  126. 1350 CLS: IF AGAIN=0 THEN GOTO 1380 ELSE LOCATE 12,18:PRINT "Will you be around for the next race? (Y/N)";
  127. 1360 AN$=INKEY$: IF AN$="" THEN 1360
  128. 1370 IF AN$="Y" THEN GOTO 690 ELSE IF AN$<>"N" THEN BEEP: GOTO 1360 ELSE GOTO 1430
  129. 1380 WIDTH 80: COLOR FC,0,BC: CLS
  130. 1390 LOCATE 8,20:PRINT"Nobody has any cash left or a car to sell."
  131. 1400 LOCATE 16,20:PRINT"Do you just want to watch the horses race? ";
  132. 1410 AN$=INKEY$: IF AN$="" THEN 1410
  133. 1420 IF AN$="Y" THEN GOTO 880
  134. 1430 CLS
  135. 1440 LOCATE 12,20:PRINT"You people better come back another day!!"
  136. 1450 DELAY=2: GOSUB 290: RETURN
  137. 1460 REM *******************************************************
  138. 1470 REM * ALPHABETIC INPUT ROUTINE                            *
  139. 1480 REM *******************************************************
  140. 1490     NTRY$=""
  141. 1500     KK$=INKEY$: IF KK$="" THEN 1500 ELSE KK%=ASC(KK$)
  142. 1510     IF KK%=13 THEN GOTO 1610  'END OF ENTRY
  143. 1520     IF KK%=8 THEN GOTO 1560   'BACKSPACE
  144. 1530     IF KK%>31 OR (KK%<28 AND KK%>13) OR (KK%<8 AND KK%>0) THEN PRINT KK$;:               NTRY$=NTRY$+KK$   'ECHO KEYSTROKE AND ADD TO ENTRY
  145. 1540     IF LEN(NTRY$) = INLEN% THEN 1610 'ENTRY FULL
  146. 1550     GOTO 1500           'GET ANOTHER CHARACTER
  147. 1560     'BACKSPACE
  148. 1570     IF LEN(NTRY$)=0 THEN 1500               'NOT IF ENTRY IS EMPTY
  149. 1580     PRINT CHR$(29);" ";CHR$(29);             'REDISPLAY BOX
  150. 1590     NTRY$=LEFT$(NTRY$,LEN(NTRY$)-1)          'DELETE LAST CHARACTER
  151. 1600     GOTO 1500                               'GET NEXT CHARACTER
  152. 1610     IF LEN(NTRY$)=0 THEN BEEP :GOTO 1490                                             ELSE PRINT SPACE$(INLEN%-LEN(NTRY$))
  153. 1620     RETURN
  154. 1630 REM ********************************************************
  155. 1640 REM * NUMERIC INPUT ROUTINE                                *
  156. 1650 REM ********************************************************
  157. 1660     DECMAL.FLAG$="F"
  158. 1670     NTRY$=""
  159. 1680     KK$=INKEY$: IF KK$="" THEN 1680 ELSE KK%=ASC(KK$)
  160. 1690     IF KK%=13 THEN GOTO 1810                 'END OF ENTRY
  161. 1700     IF KK%=8 THEN GOTO 1760                  'BACKSPACE
  162. 1710     IF KK%=45 THEN IF LEN(NTRY$)=0 THEN                                             PRINT KK$;:NTRY$=NTRY$+KK$:GOTO 1740
  163. 1720     IF KK%=46 AND DECMAL.FLAG$="F" THEN                                             PRINT KK$;:NTRY$=NTRY$+KK$:DECMAL.FLAG$="T":GOTO 1740
  164. 1730     IF KK%>47 AND KK%<58 THEN PRINT KK$;:NTRY$=NTRY$ + KK$
  165. 1740     IF LEN(NTRY$)=INLEN% THEN 1810
  166. 1750     GOTO 1680                                'GET ANOTHER CHARACTER
  167. 1760     'BACKSPACE
  168. 1770     IF LEN(NTRY$)=0 THEN 1680                'NOT IF ENTRY IS EMPTY
  169. 1780     PRINT CHR$(29);" ";CHR$(29);              'REDISPLAY BOX
  170. 1790     NTRY$=LEFT$(NTRY$,LEN(NTRY$)-1)           'DELETE LAST CHARACTER
  171. 1800     GOTO 1680                                'GET NEXT CHARACTER
  172. 1810     IF LEN(NTRY$)=0 THEN GOTO 1680 ELSE PRINT SPACE$(INLEN%-LEN(NTRY$))
  173. 1820     RETURN
  174. 1830 COLOR 15,0,0: CLS
  175. 1840 LOCATE 2,5: PRINT"╓────┐  ╓────┐"
  176. 1850 LOCATE 3,5: PRINT"║    │  ║"
  177. 1860 LOCATE 4,5: PRINT"║    │  ║"
  178. 1870 LOCATE 5,5: PRINT"╟────┘  ║"
  179. 1880 LOCATE 6,5: PRINT"║       ║"
  180. 1890 LOCATE 7,5: PRINT"║       ║"
  181. 1900 LOCATE 8,5: PRINT"║       ╙────┘"
  182. 1910 LOCATE 10,5:PRINT"╓─────┐"
  183. 1920 LOCATE 11,5:PRINT"║     │"
  184. 1930 LOCATE 12,5:PRINT"║     │"
  185. 1940 LOCATE 13,5:PRINT"║     │ ╓───┐ ║ │ │ ╓───┐ ╓────"
  186. 1950 LOCATE 14,5:PRINT"║     │ ║   │ ║ │ │ ║   │ ║"
  187. 1960 LOCATE 15,5:PRINT"║     │ ║   │ ║ │ │ ║   │ ╙───╖"
  188. 1970 LOCATE 16,5:PRINT"║     │ ║   │ ║ │ │ ║   │     ║"
  189. 1980 LOCATE 17,5:PRINT"╙─────┘ ╙───┘ ╙─┴─┘ ║   │ ────╜": COLOR 4
  190. 1990 COLOR 14:LOCATE 19,10:PRINT STRING$(20,"*");:PRINT:COLOR 10:LOCATE 21,10:PRINT STRING$(20,"*");
  191. 2000 COLOR 4:LOCATE 23,3:PRINT"Show off your skill at the track...";
  192. 2010 GOSUB 360
  193. 2020 WIDTH 80: COLOR FC,0,BC: CLS
  194. 2030 LOCATE 2,15:PRINT"Welcome to PC Downs; this is your track manager, and I"
  195. 2040 LOCATE 4,12:PRINT"hope you enjoy your time at PC Downs; the track where "
  196. 2050 LOCATE 6,12:PRINT"you can show off your betting skill, or simply work on"
  197. 2060 LOCATE 8,12:PRINT"your betting skill without the high cost of losing."
  198. 2070 LOCATE 10,15:PRINT"You will be asked for your name (for identification"
  199. 2080 LOCATE 12,12:PRINT"purposes),  how much cash you have on you (this is "
  200. 2090 LOCATE 14,12:PRINT"how much you will probably lose), and then allowed to"
  201. 2100 LOCATE 16,12:PRINT"bet on one of five horses for each race that you "
  202. 2110 LOCATE 18,12:PRINT"choose to participate in.": COLOR FC+8
  203. 2120 LOCATE 21,15:PRINT"You can exit the program at any time by pressing F8"
  204. 2130 LOCATE 23,12:PRINT"or F8 + ENTER (";CHR$(17);CHR$(196);CHR$(217);")."
  205. 2140 GOSUB 360
  206. 2150 CLS: LOCATE 12,10,0:PRINT"Please wait while I choose today's horses from the stables.";: DELAY=2 : GOSUB 290
  207. 2160 SIZE=65: OPEN "stables.dat" FOR INPUT AS #1
  208. 2180 SCREEN 1: COLOR 18,1: CLS
  209. 2190 FOR HORSE.NUM=1 TO 4: FOR R%=1 TO 11: FOR C%=1 TO 20: INPUT #1,COLR: PSET (C%+50*HORSE.NUM,R%+90),COLR: NEXT C%: NEXT R%
  210. 2200 ON HORSE.NUM GOTO 2210, 2220, 2230, 2240
  211. 2210 GET (50,90)-(70,101),HORSE1: GOTO 2250
  212. 2220 GET (100,90)-(120,101),HORSE2: GOTO 2250
  213. 2230 GET (150,90)-(170,101),HORSE3: GOTO 2250
  214. 2240 GET (200,90)-(220,101),HORSE4
  215. 2250 NEXT HORSE.NUM
  216. 2260 TIMES = 0
  217. 2270 OPEN "PERSON.DAT" FOR INPUT AS #2
  218. 2280 FOR R%=1 TO 10
  219. 2290  FOR C%= 1 TO 10
  220. 2300    INPUT #2, C :PSET(C%+250,R%+90),C
  221. 2310  NEXT C%
  222. 2320 NEXT R%
  223. 2330 IF TIMES = 0 THEN GET (250,90)-(260,100),MAN ELSE GET (250,90)-(260,100),MAN2
  224. 2340 TIMES = TIMES +1 :IF TIMES < 2 THEN 2280 ELSE CLOSE 2
  225. 2350 SCREEN 0: WIDTH 80: COLOR FC,0,BC
  226. 2360 LOCATE 12,20,0:PRINT"Now to take care of you customers.";: DELAY=1.5: GOSUB 290: RETURN
  227. 2370 DATA Ruling Lass, Lauralee Lady, Denice's Love, Racy Ronnie, Big D Money
  228. 2380 DATA Laughing Tiger, Doug's Rusty, Teza Round, Date To Dance, Mr. Ellis
  229. 2390 DATA Silent Show, Spirit Sassy, American Gem, Taylor Bilt, Mary Jello
  230. 2400 DATA Cherry Very, Boogie Who, High N Fast, Royal Highness, Aggie Special
  231. 2410 DATA Crafty Master, Poppyzon, BJ's Wish, Thief, Starview, Lucky Lucy
  232. 2420 DATA Fully At Ease, Dusty Bee, City Princess, Cannon Robey, Press Rose
  233. 2430 DATA Heart And Soul, Old Treasure, War Flea, Pacific Turf, Super Starlet
  234. 2440 DATA Tough Luck, Bred For Speed, Model Papa, Take Aim, Midnight Special
  235. 2450 DATA Winding Road, Mayfire, Gin City, Big James, Bold Greek, Double Ready
  236. 2460 DATA My Madness, Estate, Up Limit, Kim's Cutie, Next Shot, Arctic Hymn
  237. 2470 DATA Roll Me Easy, Dusting Miss, Worthy Roll, Our L.B., Machine Maid
  238. 2480 DATA Blue Eyed Mary,Dr. Dykes, Misty Gato, Sir Ashley,No Say No
  239. 2490 DATA Midnight Royal, Bitter Cold, Sea Baby, Royal Indian, Delta Water
  240. 2500 DATA Cely Seven, Cooks Apron, He Is A Tune, Victorina, Au Jacquelin
  241. 2510 DATA Valentine, Paris Cliffe, Tickled Pink, Chedaly, Privatazion
  242. 2520 DATA Bold Exclusive, Angela Jones, Lisalane, Winding Road, Bosaries,eof
  243. 2530 CLS: LOCATE 12,5:PRINT"This program uses graphics, which are not active on your machine now.    ": FC=7: GOSUB 360
  244. 2540 END
  245.