home *** CD-ROM | disk | FTP | other *** search
/ Shareware Overload / ShartewareOverload.cdr / games / lostgold.zip / LOSTGOLD.BAS
BASIC Source File  |  1986-06-01  |  20KB  |  358 lines
  1. 10 KEY OFF:CLS
  2. 20 PRINT"░░░░░░░░░░░░░░░░░░░░░░░░░░░░░░░░░░░░░░░"
  3. 30 PRINT"░┌───────────────────────────────────┐░"
  4. 40 PRINT"░│                                   │░"
  5. 50 PRINT"░│            2038-A.BAS             │░"
  6. 60 PRINT"░│        LOST DUTCHMAN'S GOLD       │░"
  7. 70 PRINT"░│                                   │░"
  8. 80 PRINT"░│                                   │░"
  9. 90 PRINT"░│ BROUGHT TO YOU BY THE MEMBERS OF  │░"
  10. 100 PRINT"░│      ▄▄▄▄▄ ▄▄▄▄▄ ▄▄▄▄▄ ▄▄▄▄▄      │░"
  11. 110 PRINT"░│        █   █   █ █     █   █      │░"
  12. 120 PRINT"░│        █   █▄▄▄█ █     █   █      │░"
  13. 130 PRINT"░│        █   █     █     █   █      │░"
  14. 140 PRINT"░│      ▄▄█▄▄ █     █▄▄▄▄ █▄▄▄█      │░"
  15. 150 PRINT"░│                                   │░"
  16. 160 PRINT"░│      International PC Owners      │░"
  17. 170 PRINT"░│                                   │░"
  18. 180 PRINT"░│P.O. Box 10426, Pittsburgh PA 15234│░"
  19. 190 PRINT"░│                                   │░"
  20. 200 PRINT"░└───────────────────────────────────┘░"
  21. 210 PRINT"░░░░░░░░░░░░░░░░░░░░░░░░░░░░░░░░░░░░░░░"
  22. 220 PRINT
  23. 230 PRINT "       PRESS ANY KEY TO CONTINUE
  24. 240 A$=INKEY$: IF A$="" THEN 240
  25. 250 CLS
  26. 1000 REM    THIS IS THE 'ADVENTURE' GAME OF 'LOST DUTCHMAN'S GOLD',
  27. 1010 REM    FROM THE LISTING IN BYTE OF DECEMBER 1980 (PAGE 268 +)
  28. 1020 REM
  29. 1030 REM                ** CHRIS SIDENER **
  30. 1040 REM                SPRINGFIELD, VIRGINIA
  31. 1050 REM    *******************************************************************
  32. 1060 CLEAR,,4000
  33. 1070 CLS:KEY OFF
  34. 1080 PRINT "WELCOME TO THE SEARCH FOR THE LOST DUTCHMAN'S GOLD." : PRINT "I'M THE GHOST OF BACK-PACK SAM, YER GUIDE ON THIS ADVENTURE."
  35. 1090 PRINT : PRINT"YA CAN USE TWO WORD COMMANDS TO FIND CLUES 'N MOVE 'BOUT. GET, GO, PUT, DROP,"
  36. 1100 PRINT "SCORE, INVENTORY, 'N 'BOUT 100 MORE WORDS MAKE SENSE TA ME." : PRINT"ASK FER HELP IF YA GET STUMPED." : PRINT "I HOPE YA DON'T END UP A GHOST,    LIKE ME!!"
  37. 1110 PRINT:PRINT"                    GOOD LUCK ! !" : PRINT
  38. 1120 DIM T$(200)
  39. 1130 DIM N$(26,7),O$(32,3),R$(46) : B=0 : IN=B : LN=100 : LM=LN : X1=B : X2=B : T$="" : M1$=T$ : M2$=T$ : QM$=T$ : U=B : U1=B : IM=2 : BD=21 : L=1 : C$=CHR$(13)
  40. 1140 FOR L=B TO 26 : FOR I=B TO 7 : READ N$(L,I) : NEXT I,L
  41. 1150 FOR I=B TO 32 : READ O$(I,0),O$(I,1),O$(I,2) : O$(I,3)=" " : NEXT
  42. 1160 FOR I=B TO 46 : READ R$(I) : NEXT
  43. 1170 PRINT "HIT 'RETURN' TO START." : INPUT ZX : L=1 : 
  44. 1180 IF ((O$(12,2)=STR$(L) OR O$(12,3)="1") AND CL > 0) OR L < 15 THEN 1230
  45. 1190 PRINT "IT'S TOO DARK TA SEE !!" : IF L=15 AND O$(6,3) <> "1" AND O$(4,3) <> "1" THEN PRINT "YA HEAR A STRANGE NOISE !"
  46. 1200 GOTO 1560
  47. 1210 T$="OK" : RETURN
  48. 1220 B=1 : PRINT : PRINT "YA SEE : "; : RETURN
  49. 1230 IF CL=1 THEN LN=LN-1 : IF LN < 1 THEN CL=0
  50. 1240 L1=L
  51. 1250 B=0 : PRINT "YER "N$(L,0)"." : FOR J=0 TO 32 : IF VAL(O$(J,2)) <> L THEN 1370
  52. 1260 IF B=0 THEN GOSUB 1220
  53. 1270 IF O$(J,3)="-7" OR O$(J,3)="-2" THEN PRINT "BURNT ";
  54. 1280 IF J <> 1 OR VAL(O$(1,2)) <> L THEN 1310
  55. 1290 IF O$(1,3)="" THEN PRINT "UNTIED "; : GOTO 1310
  56. 1300 IF O$(1,3)="-9" THEN PRINT "DEAD ";
  57. 1310 IF O$(J,3)="-3" THEN PRINT "SMASHED ";
  58. 1320 IF L <> 26 OR J <> 32 THEN 1350
  59. 1330 IF U1 <> 0 THEN PRINT "UN";
  60. 1340 PRINT "LOCKED ";
  61. 1350 IF CL=1 AND J=12 THEN PRINT "LIT ";
  62. 1360 PRINT O$(J,0)". ";
  63. 1370 NEXT J
  64. 1380 IF U1=1 AND L=1 THEN PRINT "OPEN TRAP DOOR. ";
  65. 1390 IF N$(L,1)="" THEN PRINT : GOTO 1500
  66. 1400 IF B=0 THEN GOSUB 1220
  67. 1410 IF L <> 16 THEN 1440
  68. 1420 IF U <> 0 THEN PRINT "UN";
  69. 1430 PRINT "LOCKED "; : GOTO 1470
  70. 1440 IF L <> 17 THEN 1470
  71. 1450 IF U=1 THEN PRINT "UNLOCKED "; : GOTO 1470
  72. 1460 PRINT "BLOCKED ";
  73. 1470 PRINT N$(L,1)".
  74. 1480 IF L=17 AND U=0 THEN N$(L,2)=" "+RIGHT$(N$(L,2),3)
  75. 1490 IF L=16 AND U=1 THEN N$(L,2)="E"+RIGHT$(N$(L,2),3)
  76. 1500 PRINT : IF N$(L,2)="" THEN 1560
  77. 1510 PRINT "OBVIOUS EXITS : "; : FOR I=1 TO 4 : P$=MID$(N$(L,2),I,1) : IF P$="N" THEN PRINT "NORTH ";
  78. 1520 IF P$="S" THEN PRINT "SOUTH ";
  79. 1530 IF P$="E" THEN PRINT "EAST ";
  80. 1540 IF P$="W" THEN PRINT "WEST ";
  81. 1550 NEXT : PRINT
  82. 1560 B=0 : PRINT "=======================================
  83. 1570 PRINT: IF L=9 AND O$(22,2)="11" THEN PRINT "THAR'S NOISE UP AHEAD." : PRINT "SOUNDS LIKE INJUNS.
  84. 1580 IF L=9 AND O$(22,2)="" THEN O$(22,2)="11"
  85. 1590 INPUT " --NOW WHAT";QM$
  86. 1600 IF LN <10 AND CL=1 THEN PRINT "YER RUNNIN' LOW ON KEROSENE.
  87. 1610 REM
  88. 1620 IF QM$ <> "SCORE" THEN 1680
  89. 1630 IF L <> 6 THEN T$= "YA GET NOTHIN' FOR BEIN' HERE!" : GOTO 3820
  90. 1640 Z=0 :FOR I=14 TO 17 : IF O$(I,2) = "6" THEN Z=Z+1
  91. 1650 NEXT
  92. 1660 PRINT "YA GOT "Z" TREASURES, TOT'LIN "(Z/4)*100"%" : IF Z = 4 THEN PRINT "YA MADE IT!!": GOTO 4130
  93. 1670 T$= "YA MISSED SUN TREASURE!" : GOTO 3820
  94. 1680 IF CL=0 AND L=15 AND O$(6,3) <> "1" THEN PRINT "YE GAD!" : PRINT "YA BEEN BIT BY A RATTLER." : PRINT "YER DEAD." :GOTO 4130
  95. 1690 IF L=17 AND U=1 AND RND(1)*9+1 < 2 THEN PRINT "HOLEY CRAP! WOWIE!! IT'S A CAVE IN !! ": PRINT "THE IRON DOOR'S BLOCKED, " : PRINT "YER TRAPPED!!" : U=0
  96. 1700 IF QM$="HELP" THEN X=VAL(N$(L,3)) : ON X GOSUB 4150,4160,4170,4180,4200,4220,4230,4240, : GOTO 1180
  97. 1710 IF LEFT$(QM$,2)="GO" THEN  X1=LEN(QM$):QM$=RIGHT$(QM$,X1-2):QM$="GOO"+QM$
  98. 1720 X1 =LEN(QM$) : IF X1 <3 THEN T$="WHAT?" : GOTO 3820
  99. 1730 X3=0 : FOR X2=3 TO X1 : M1$= MID$(QM$,X2,1) : IF M1$=" " THEN X3 = X2 : X2=X1
  100. 1740 NEXT X2 : X2 = X3 : IF X3 =0 THEN X2 = X1
  101. 1750 P$ = LEFT$(QM$,3) : IF X2 < > X1 AND X2+ 3 > X1 THEN 1990
  102. 1760 II =-1 : FOR I= 0 TO 42 : IF P$=R$(I) THEN II=I
  103. 1770 NEXT : IF II > -1 THEN I= II : GOTO 1810
  104. 1780 IF X1 = X2 THEN T$= "WHAT?" : GOTO 3820
  105. 1790 T$="SORRY, BUT YA CAN'T "+ LEFT$(QM$,X2) : IF X2 < X1 THEN T$=T$ + RIGHT$(QM$,X1 - X2)
  106. 1800 T$=T$+ "." : GOTO 3820
  107. 1810 IF I < 8 AND X1=X2 THEN ON I+1 GOSUB 3970,3970,3970,4130,2060,3980,3840,3940 : GOTO 3820
  108. 1820 JJ= -1 : M1$ = MID$(QM$,X2+1,3) : FOR J= 0 TO 32 : IF M1$ = LEFT$ (O$(J,0),3) THEN JJ = J
  109. 1830 NEXT : J= JJ : IF JJ > -1 THEN 2000
  110. 1840 IF M1$ = "IRO" THEN 1960
  111. 1850 IF I=36 THEN 2400
  112. 1860 IF N$(L,1) = "" THEN 1930
  113. 1870 Z=1 : A = Z : X1 = LEN(N$(L,1)) : FOR X2 = 5 TO X1 : IF MID$(N$(L,1),X2,1) <> CHR$(46) AND X2 <> X1 THEN 1920
  114. 1880 M2$=MID$(N$(L,1),Z,3) : IF M2$=M1$ THEN 1900
  115. 1890 Z=X2+2 : A=A+1 : GOTO 1920
  116. 1900 X2=X1 : B=A : IF I=10 THEN PRINT "YA SEE NOTHIN' SPECIAL." : GOTO 1240
  117. 1910 GOTO 2000
  118. 1920 NEXT
  119. 1930 FOR X=43 TO 46 : IF M1$=R$(X) THEN X=46 : GOTO 2040
  120. 1940 NEXT
  121. 1950 IF O$(4,3) = "1" OR O$(6,3) = "1" THEN IF I=23 AND M1$= "SEL" THEN PRINT "OK" : PRINT "YER DEAD." : GOTO 4130
  122. 1960 IF I=32 THEN GOSUB 2220 : GOTO 3820
  123. 1970 IF I=33 THEN GOSUB 2340 : GOTO 3820
  124. 1980 T$ = "I CAN'T TELL WHATCHA WANT." : GOTO 3820
  125. 1990 T$ ="I MUST BE DUMB, YA DON'T MAKE SENSE." : GOTO 3820
  126. 2000 IF I < 9 THEN 2040
  127. 2010 IF J < 33 AND J > -1 THEN B= VAL(O$(J,2)) : IF B<> L AND B> 0 THEN 3810
  128. 2020 IF J > 32 THEN J= 29
  129. 2030 ON I - 8 GOSUB 2820,3040,3040,3040,2820,3440,3440,3440,3440,3640,3640,2820,2100,2100,2580,2570,2570,2380,2660,2750,2780,2170,2170,2220,2340,2820,2370,2400,3440,3430,2980,3000,3640,4250
  130. 2040 IF I < 9 THEN ON I+1 GOSUB 2420,2420,2420,4130,2060,2420,3840,3940,2980
  131. 2050 GOTO 3820
  132. 2060 IF O$(3,3) <> "1" THEN 3810
  133. 2070 PRINT "OK" : FOR I=13 TO 17 : IF VAL(O$(I,2)) = -L THEN T$ = "EUREKA! WE STRUCK GOLD?!??" : O$(I,2) = STR$(L) : RETURN
  134. 2080 NEXT
  135. 2090 T$ = "DAG NAB IT! THAR'S NOTHIN' HERE!" : RETURN
  136. 2100 IF J <> 23 THEN 2570
  137. 2110 IF L= 14 THEN O$(23,2) = "15" : GOTO 1210
  138. 2120 IF L = 15 THEN O$(23,2) = "16" : GOTO 1210
  139. 2130 IF L= 16 AND U= 1 THEN O$(23,2) = "17" : GOTO 1210
  140. 2140 IF L=17 THEN O$(23,2) = "19" : GOTO 1210
  141. 2150 IF L=19 THEN O$(23,2) = "23" : O$(23,3) = "-3
  142. 2160 GOTO 1210
  143. 2170 IF J=3 OR J=4 OR J= 6 OR J=8 OR J=9 OR J=11 OR J=12 OR J=13 OR J=19 OR J=27 OR J=28 THEN 2190
  144. 2180 GOTO 2560
  145. 2190 IF O$(J,3) = "1" THEN IN = IN-1
  146. 2200 O$(J,3) = "-3" : O$(J,2) = STR$(L) : GOTO 1210
  147. 2210 T$ = "DON'T HAFTA." : RETURN
  148. 2220 IF L <> 16 THEN 2260
  149. 2230 IF U <> 0 THEN 2210
  150. 2240 IF O$(10,3) = "1" THEN U = 1 : GOTO 1210
  151. 2250 GOTO 3810
  152. 2260 IF L <> 26 THEN 2300
  153. 2270 IF U1 <> 0 THEN 2210
  154. 2280 IF O$(10,3) = "1" THEN U1 = 1 : RETURN
  155. 2290 GOTO 3810
  156. 2300 IF O$(1,3) <> "1" THEN 2330
  157. 2310 IF O$(0,3) = "2" THEN O$(0,3) = "" : O$(0,2) = STR$(L) : GOTO 1210
  158. 2320 GOTO 2560
  159. 2330 IF CL = 1 AND O$(12,3) = "1" THEN CL=0 : GOTO 1210
  160. 2340 IF (L=16 OR L=17) AND U = 1 THEN U=0 : GOTO 1210
  161. 2350 IF L=26 AND U1 =1 THEN U1 =0 : GOTO 1210
  162. 2360 GOTO 2560
  163. 2370 T$= "YA HEAR NOTHIN' SPECIAL." : RETURN
  164. 2380 IF L <> 11 OR O$(9,3) <> "1" THEN 2980
  165. 2390 PRINT "THEY TOOK THE FIRE WATER 'N RAN." : IN=IN-1 : O$(9,2) = "" :O$(9,3) = "" : O$(22,2) = "" : RETURN
  166. 2400 IF M1$= "YOH" THEN T$= "TURKEY!" : PRINT "SORRY, YER IN THE WRONG ADVENTURE." : GOTO 3820
  167. 2410 GOSUB 1210 : T$=T$+ CHR$(13)+ RIGHT$(QM$,X1 - X2)+ "." : GOTO 3820
  168. 2420 IF B=0 THEN 2470
  169. 2430 L= VAL(N$(L,B+3)) : IF O$(1,3)= "1" AND (L=1 OR L=6 OR L=15) THEN T$ ="HE WON'T GO." : L=L1 : RETURN
  170. 2440 IF L=17 AND U=0 THEN L=L1 : GOTO 3810
  171. 2450 IF L1 = 26 AND L=1 AND U1=0 THEN L=L1 : GOTO 3810
  172. 2460 GOTO 2570
  173. 2470 IF U1 = 1 AND L=1 THEN L=26 : GOTO 1210
  174. 2480 IF U1 =1 AND M1$="TRA" AND L=26 THEN L=1 : RETURN
  175. 2490 FOR X1= 1 TO 4 : M2$= MID$(N$(L,2),X1,1) : IF M2$ <> LEFT$(M1$,1) THEN NEXT X1 : GOTO 2520
  176. 2500 FOR X2=43 TO 46 : IF M1$ <> R$(X2) THEN NEXT X2 : GOTO 2520
  177. 2510 L=VAL(N$(L,X1+3)) : IF L <> 0 THEN 2570
  178. 2520 IF L=23 THEN T$="IT'S TOO SLIPPERY." :RETURN
  179. 2530 IF L=25 THEN L=26 : RETURN
  180. 2540 IF L=26 THEN L=25 : RETURN
  181. 2550 IF L=19 THEN L=23 : PRINT "NIGH BROKE M' NECK!!" :RETURN
  182. 2560 T$= "SORRY, BUT YA CAN'T DO THAT." : RETURN
  183. 2570 B=0 : GOTO 1210
  184. 2580 IF O$(4,3) <> "1" AND O$(6,3) <> "1" THEN 2980
  185. 2590 IF J <> 1 THEN 2630
  186. 2600 Z=0 : IF O$(J,3) = "1" THEN Z=99
  187. 2610 O$(J,3) = "-9" : O$(1,2) = STR$(L)
  188. 2620 IF Z=99 THEN IN=IN-1
  189. 2630 IF J=22 THEN PRINT "YA GOT ONE!" : PRINT "BUT THE REST GOT YOU!" : GOTO 4130
  190. 2640 IF J=9 THEN T$ = "YA HIT ONE!" : RETURN
  191. 2650 GOTO 1210
  192. 2660 IF O$(18,3) <> "1" THEN 3810
  193. 2670 IF J < 0 THEN 1790
  194. 2680 IF J=4 OR (J>5 AND J<11) OR (J>14 AND J < 18) OR J=22 OR J=29 OR J > 30 THEN 2560
  195. 2690 IF O$(J,3)="1" THEN IN=IN -1
  196. 2700 O$(J,3)="-7" : O$(J,2) = STR$(L)
  197. 2710 IF J > 0 THEN 2570
  198. 2720 IF O$(0,3) <> "-7" THEN 2570
  199. 2730 O$(0,2) = STR$(L) : FOR J=5 TO 21 : IF O$(J,2) = "-1" THEN O$(J,3) = "-7"
  200. 2740 NEXT : GOTO 2570
  201. 2750 IF J <> 12 THEN 2660
  202. 2760 IF O$(J,3) <> "1" OR O$(18,3) <> "1" THEN 2660
  203. 2770 CL = 1 : GOTO 1210
  204. 2780 IF J=13 THEN PRINT "YEEECH!!" : PRINT"IT'S KEROSENE!" : PRINT "YA JUST POISONED YERSELF." : GOTO 4130
  205. 2790 IF J <> 9 THEN 2560
  206. 2800 PRINT "WHEEEE!!" : PRINT "YA GOT PLASTERED AND LOST A DAY." : IF CL=1 THEN LN=LN-10
  207. 2810 RETURN
  208. 2820 IF J > 32 OR J < 0 THEN 2860
  209. 2830 B= VAL(O$(J,2)) : IF O$(J,3) = "2" OR B=L OR B= -1 THEN 2860
  210. 2840 IF J < 22 THEN 3810
  211. 2850 T$= "IT AIN'T HERE." : RETURN
  212. 2860 IF J > 21 OR J=1 OR J= -1 THEN T$="WHO YOU THINK YA IS, PAUL BUNYON?!!" :RETURN
  213. 2870 IF O$(J,3) = "-7" THEN T$="IT'S BURNT UP 'N RUINED." : RETURN
  214. 2880 IF IN > 4 THEN T$="YA CAN'T! YER HANDS 'R FULL." : RETURN
  215. 2890 IF O$(J,3)="1" THEN PRINT "YA ALREADY GOT IT!" : RETURN
  216. 2900 IF VAL(O$(J,1))= 0 AND I <> 16 THEN 2930
  217. 2910 IN=IN+1 : IF O$(J,2) = "-1" THEN IM=IM-1 : O$(J,2)="" : O$(J,3)="1" :GOTO 2930
  218. 2920 O$(J,3)="1" : O$(J,2) =""
  219. 2930 IF J <> 9 AND J <> 11 AND J <> 2 THEN 1210
  220. 2940 IF J=9 THEN IF O$(8,2)="-6" THEN O$(8,2) = "6"
  221. 2950 IF J=11 THEN IF O$(12,2)= "-8" THEN O$(12,2)="8
  222. 2960 IF J=2 THEN IF O$(18,2)="-14" THEN O$(18,2)="14
  223. 2970 RETURN
  224. 2980 IF O$(J,3) <> "1" THEN T$= "YA DON'T HAVE IT!" :RETURN
  225. 2990 T$="OK" : IN=IN-1 : O$(J,2)= STR$(L) : O$(J,3) = "" : RETURN
  226. 3000 IF O$(5,3) <> "1" THEN 3810
  227. 3010 IF L=7 THEN L=8 : GOTO 1210
  228. 3020 IF L=12 THEN L=13
  229. 3030 GOTO 1210
  230. 3040 GOSUB 1210 : ON J+1 GOTO 3060,3100,3110,3130,3140,3150,3160,3130,3130,3170,3190,3200,3220,3230,3130,3130,3130,3130,3130,3250,3270,3290,3310,3320,3330,3350,3130,3370,3130,3130,3130,3390,3130
  231. 3050 GOTO 3130
  232. 3060 IF VAL (O$(0,3)) < 1 THEN T$= "THEY'S LUMPY OL' LEATHER SADDLEBAGS." : RETURN
  233. 3070 PRINT "THEY HOLD ";: IF IM=0 THEN PRINT "NOTHIN'." : T$="" : RETURN
  234. 3080 FOR I=6 TO 22 : IF O$(I,2) = "-1" THEN PRINT " "O$(I,0)",";
  235. 3090 NEXT : T$= CHR$(8)+"." : RETURN
  236. 3100 T$="YA SEE A WEARY OL' GREY MULE." : RETURN
  237. 3110 T$="IT'S AN OL' TORN SACK." : IF O$(18,2)= "-14" THEN O$(18,2)="14"
  238. 3120 RETURN
  239. 3130 T$="YA SEE NOTHIN' SPECIAL." : RETURN
  240. 3140 T$="IT'S AN OLD WINCHESTER SINGLE-SHOT." : RETURN
  241. 3150 T$="LOOKS LIKE A MAP TA THE LOST DUTCHMAN'S MINE! THAR'S A SKETCH OF SOME BOULDERS." : RETURN
  242. 3160 T$="NOTHIN' SPECIAL,"+C$+"JUS' A LOADED SIX SHOOTER." : RETURN
  243. 3170 IF O$(8,2) = "-6" THEN T$="LOOKS LIKE SOMETHIN'S 'HIND THE BOTTLES." : O$(8,2)="6" : RETURN
  244. 3180 GOTO 3130
  245. 3190 T$ ="THAR'R 3 KEYS, TIED WITH A LEATHER STRAP" : RETURN
  246. 3200 IF O$(12,2) = "-8" THEN T$="LOOKS LIKE THAR'S GLASS UNDER 'UM." : O$(12,2)="8" : RETURN
  247. 3210 GOTO 3130
  248. 3220 T$="IT'S AN OL' KEROSENE LAMP, FULL TA THE '"+STR$(LN)+" TURNS LEFT' MARK." : RETURN
  249. 3230 IF I=11 THEN T$="IT SEZ 'KEROSENE.'" : RETURN
  250. 3240 T$="THAR'S WRITING ON IT." : RETURN
  251. 3250 IF O$(20,2) = "-17" THEN O$(20,2) ="17" : T$="IT'S A MESSAGE !" : RETURN
  252. 3260 GOTO 3130
  253. 3270 IF I=11 THEN T$="IT SEZ :"+C$+"BRING TREASURES TO SALOON, SAY 'SCORE.'" : RETURN
  254. 3280 GOTO 3240
  255. 3290 IF I=11 THEN T$="IT SEZ.. ": PRINT"HAVEN'T YOU ANYTHING BETTER TO DO?" : RETURN
  256. 3300 GOTO 3240
  257. 3310 T$="THEY'S A SAVAGE LOOKIN' BAND,"+C$+"'N THEY SEEN YA!" : RETURN
  258. 3320 T$="JUS' AN OL' CART FULL O' ROCKS." : RETURN
  259. 3330 IF O$(5,2)="-25" THEN O$(5,2)="1" : T$="THAR'S SOMETHIN' HERE!!" : RETURN
  260. 3340 GOTO 3130
  261. 3350 IF I=11 THEN T$="IT SEZ :"+C$+"WELCOME TO FRONTIERTOWN." : RETURN
  262. 3360 GOTO 3240
  263. 3370 IF O$(10,2) ="-6" THEN O$(10,2) ="6" : T$="THAR'S A SET OF KEYS THAR!" : RETURN
  264. 3380 GOTO 3130
  265. 3390 B=INT(RND(1)*3+1) : ON B GOTO 3400,3410,3420
  266. 3400 T$="IT'S A BARREL CACTUS." : RETURN
  267. 3410 T$="IT'S A CHOLLA CACTUS." : RETURN
  268. 3420 T$="IT'S A SAGUARO CACTUS." : RETURN
  269. 3430 IF J=4 AND I=38 THEN 3570
  270. 3440 IF J <> 1 OR VAL(O$(1,3)) < 0 THEN T$="SORRY, BUT THAT AIN'T POSSIBLE." : RETURN
  271. 3450 IF I <> 38 THEN 3480
  272. 3460 IF O$(1,3) ="" THEN T$="TENDERFOOT! YA HAFTA LEAD 'IM FIRST." : RETURN
  273. 3470 GOTO 3570
  274. 3480 IF O$(1,3)="1" THEN 2980
  275. 3490 IF O$(7,3)="1" THEN IF I <> 16 THEN T$= "TRY 'LEAD.' : RETURN
  276. 3500 ON I-13 GOTO 3510,3520,3530,3560
  277. 3510 T$="HE GOT AWAY FROM YA." : RETURN
  278. 3520 T$="YER TOO SLOW, HE GOT AWAY." : RETURN
  279. 3530 IF O$(7,3) <> "1" THEN T$="BAD LUCK, YA TRIPPED AND HE RAN OFF." : O$(1,3)="" : O$(1,2) = STR$(L) : RETURN
  280. 3540 IF O$(1,3) ="" THEN 2880
  281. 3550 GOTO 2980
  282. 3560 T$="HE BUCKED YA OFF." : RETURN
  283. 3570 INPUT "WITH WHAT";QM$ : IF J=4 THEN 3610
  284. 3580 IF LEFT$(QM$+" ",3) <> "SAD" THEN T$="IT FELL OFF."+C$+"HE GOT AWAY.":O$(1,3)="" : IN=IN-1 : O$(1,2)= STR$(L) : RETURN
  285. 3590 IF O$(0,3)="1" THEN O$(0,3)="2" : IN=IN-1 : GOTO 2570
  286. 3600 GOTO 2980
  287. 3610 IF LEFT$(QM$+" ",3) <> "BUL" THEN 2560
  288. 3620 IF O$(8,3) <> "1" OR O$(4,3) <> "1" THEN 2980
  289. 3630 GOTO 1210
  290. 3640 IF O$(J,3) <> "1" THEN 2980
  291. 3650 INPUT "ON OR IN WHAT? (IE 'ON TABLE') ";QM$ : P$=LEFT$(QM$+" ",2) : IF P$ <> "IN" AND P$ <> "ON" THEN T$="HUH?" : RETURN
  292. 3660 M1$=MID$(QM$,4,3)
  293. 3670 IF P$ <> "ON" THEN 3720
  294. 3680 IF M1$="MUL" THEN 3590
  295. 3690 IF J <> 13 THEN 2980
  296. 3700 IF LM=0 THEN T$="IT'S EMPTY." : RETURN
  297. 3710 LM=0 : GOTO 2980
  298. 3720 IF M1$ <> "SAD" THEN 3760
  299. 3730 IF J < 5 OR J=19 OR J=22 THEN T$="SORRY, IT DON'T FIT." : RETURN
  300. 3740 IF IM > 4 THEN T$= "THE BAGS 'R FULL." : RETURN
  301. 3750 O$(J,2)="-1" : O$(J,3)="" : IN=IN-1 : IM = IM+1 : T$="OK" : RETURN
  302. 3760 IF M1$ = "MUL" THEN T$="YA GOT KICKED !" : RETURN
  303. 3770 IF M1$ <> "LAN" THEN 2560
  304. 3780 IF O$(13,3) <> "1" OR O$(12,3) <> "1" THEN 2980
  305. 3790 IF LM=50 THEN LN=LN+50 : LM =0 : GOTO 1210
  306. 3800 T$="JAR'S EMPTY." :RETURN
  307. 3810 T$="YA CAN'T DO THAT... YET!
  308. 3820 PRINT T$ : T$="" : GOTO 1180
  309. 3830 REM ************************** INVENTORY ****************
  310. 3840 PRINT "YA GOT WITH YA: "; : IF IN=0 AND O$(1,3) <> "1" THEN T$="NOTHIN'" : RETURN
  311. 3850 B=VAL(O$(0,3)) : X1=B : IF B <> 1 THEN 3880
  312. 3860 PRINT : PRINT O$(0,0)", CONTAINING: "; : FOR I=1 TO 22 : IF O$(I,2)="-1" THEN PRINT O$(I,0)". ";:X1=2
  313. 3870 NEXT : IF X1 <> 2 THEN PRINT "NOTHIN'! ";
  314. 3880 IF O$(1,3)="1" THEN PRINT : PRINT "THE MULE, WHICH YER LEADIN. "; : IF B=2 THEN PRINT "(CARRYIN' SADDLEBAGS) ";
  315. 3890 PRINT : X1=0 : FOR I=2 TO 22 : IF VAL(O$(I,3)) < 1 THEN 3920
  316. 3900 IF CL=1 AND I=12 THEN PRINT "LIT ";
  317. 3910 PRINT O$(I,0)". ";
  318. 3920 NEXT
  319. 3930 T$="" : RETURN
  320. 3940 IF L=19 THEN PRINT:PRINT:PRINT:PRINT:PRINT:PRINT:PRINT:PRINT:PRINT:PRINT:PRINT:PRINT:PRINT:PRINT:PRINT:PRINT:PRINT:PRINT:PRINT "YA FELL 100 FEET 'N LANDED ON THE ROCKS." : PRINT:PRINT:PRINT"        YER DEAD." : GOTO 4130
  321. 3950 IF J=23 OR J=32 OR M1$="P" THEN T$="OK" : RETURN
  322. 3960 GOTO 2560
  323. 3970 T$="WHERE?" : RETURN
  324. 3980 IF L=25 THEN L=26 : GOTO 1210
  325. 3990 IF L=26 THEN L=25
  326. 4000 GOTO 1210
  327. 4010 DATA ,,,,,,,,IN A MINER'S SHACK,WINDOW. DOOR,,1,3,3,,,IN A DESERT,ROAD. MOUNTAINS. DESERT,WNES,2,4,2,2,2,ON A DIRT PATH,MINER'SHACK. ROAD. MOUNTAINS," W ",5,1,4,2,2
  328. 4020 DATA ON A DIRT ROAD,MOUNTAINS. PATH. DESERT. TOWN,NE S,2,7,3,2,5,IN A GHOST TOWN,SALOON," N ",1,6,4,,,IN A SALOON,,W   ,1,5,,,
  329. 4030 DATA AT THE SUPERSTITION MOUNTAINS,ROAD. DESERT,"S N ",4,4,2,2,2,AT WEAVER'S NEEDLE,,NS  ,1,9,7,,
  330. 4040 DATA IN A NARROW DEFILE,BUSHES. CAVES,"  NS",1,11,10,12,8,IN A SMALL CAVE,,E   ,1,9,,,,BEHIND A BUSH,BUSH.,W   ,1,9,,,,IN A BOX CANYON,BUSHES. TREES. BOULDERS,"   S",4,12,12,12,9
  331. 4050 DATA IN FRONT OF A HIDDEN MINE,MINE SHAFT,ESNW,8,14,12,12,12,IN THE MOUTH OF A DIM MINE,MINE SHAFT,EW  ,1,15,13,,,IN A MINE,DARK TUNNEL,EW,6,16,14,,
  332. 4060 DATA AT THE END OF A TUNNEL,IRON DOOR," W  ",1,17,15,,,IN A LARGE CHAMBER,IRON DOOR,WNES,1,16,19,18,20,IN A MAZE OF TUNNELS,,NSEW,6,18,18,18,18,IN FRONT OF A PIT,DARK HOLE," S  ",7,23,17,,
  333. 4070 DATA AT AN INTERSECTION,," SNW",6,,22,17,21,IN A DEAD END TUNNEL,,E   ,8,20,,,,IN A BLOCKED TUNNEL,,N   ,8,20,,,,AT THE BOTTOM OF A SHAFT,WALLS,S   ,8,24,,,
  334. 4080 DATA IN A TUNNEL,,NS  ,6,23,25,,,AT THE END OF A TUNNEL,LADDER," N  ",6,26,24,,,AT THE TOP OF A LADDER,,,6,1,25,,
  335. 4090 DATA SADDLEBAGS,2,1,MULE,,3,BURLAP SACK,4,14,SHOVEL,4,1,RIFLE,4,1,MAP,1,-25,GUN,1,-1,CARROTS,1,-1,BOX OF RIFLE BULLETS,1,-6,WHISKEY BOTTLES,2,6,KEYS,1,-6,PILE OF BONES (MINE),2,8
  336. 4100 DATA LANTERN,2,-8,JAR OF LIQUID,1,-11,*SPANISH COINS*,1,-10,*TOURQUOISE*,1,-23,#SILVER#,1,-21,#GOLD#,1,-22,MATCHES,1,-14,CRATES,3,17,NOTE,1,-17,PAPER,1,6,INDIANS,,11
  337. 4110 DATA ORE CART,,14,BED,,1,SIGN,,5,BROKEN GLASS,,6,TABLES,,6,CHAIRS,,6,ROCKS,,10,WOODEN RAILS,,15,CACTUS,,2,TRAP DOOR,,26
  338. 4120 DATA GOO,ENT,RUN,QUI,DIG,CLI,INV,JUM,DRO,GET,EXA,REA,LOO,MOV,CAT,CHA,LEA,RID,PUT,PLA,PIC,PUS,PUL,SHO,OPE,CLO,GIV,BUR,LIG,DRI,BRE,HIT,UNL,LOC,TAK,LIS,SAY,FEE,LOA,UNT,FOL,POU,EAT,NOR,SOU,EAS,WES
  339. 4130 PRINT:PRINT: INPUT "DO YA WANNA TRY AGAIN";QM$ : IF LEFT$(QM$+" ",1)="Y" THEN RUN ELSE END
  340. 4140 REM ******** HELP **************
  341. 4150 PRINT "TRY EXAM'NIN THIN'S." : RETURN
  342. 4160 PRINT "ROADS GO PLACES." : RETURN
  343. 4170 PRINT "MAYBE THE TRAIL GOES SOMEWHAR." : RETURN
  344. 4180 IF O$(5,3) <> "1" THEN PRINT "YA GOT A MAP?" :RETURN
  345. 4190 PRINT "TRY 'FOLLOW.'" : RETURN
  346. 4200 IF VAL(O$(1,2))=L THEN PRINT "THE MULE LOOKS THIN." : RETURN
  347. 4210 GOTO 4150
  348. 4220 PRINT "KEEP GOIN'." : RETURN
  349. 4230 PRINT "IT'S SLIPRY, BUTCHA MIGHT MAKE IT DOWN." : RETURN
  350. 4240 PRINT "THIS HERS'S A MINE, YA KNOW." : RETURN
  351. 4250 IF J=7 THEN T$="THEY TASTE PURTY GOOD." : RETURN
  352. 4260 T$="CAN'T DO THAT... WEIRDO !" : RETURN
  353. 4270 INPUT "SURE ";QM$ : IF LEFT$(QM$+" ",1) <> "Y" THEN 1590
  354. 4280 GOTO 1590
  355. 4290 END
  356. "CAN'T DO THAT... WEIRDO !" : RETURN
  357. 4270 INPUT "SURE ";QM$ : IF LEFT$(QM$+" ",1) <> "Y" THEN 1590
  358. 4280 GOT